Video  - AS3

Anger typen av filter som tillämpas på avkodad video i efterbehandlingen. Standardvärdet är noll och det värdet låter videokompressorn använda avkodningsfiltret om det behövs.

Videokomprimering kan resultera i oönskade grafikdefekter. Du kan använda egenskapen deblocking för att ställa in filter som minskar blockering och, för video som komprimerats med On2-kodeken, ringing.

Blocking avser synliga brister mellan gränserna för blocken som skapar varje videobildruta. Ringing avser förvrängda kanter runt element i en videobild.

Två avkodningsfilter finns: ett i Sorenson-kodeken och ett i On2 VP6-kodeken. Ett avringningsfilter är dessutom tillgängligt när du använder On2 VP6-kodeken. Om du vill ställa in ett filter använder du ett av följande värden:

• 0 – låter videokompressorn använda avkodningsfiltret om det behövs.
• 1 – avkodningsfiltret används inte.
• 2 – Sorenson-avkodningsfiltret används.
• 3 – (endast för On2-video) On2-avkodningsfiltret används, men inget avringningsfilter.
• 4 – (endast för On2-video) On2-avkodningsfiltret och avringningsfiltret används.
• 5 – (endast för On2-video) On2-avkodningsfiltret och ett On2-avringningsfilter med högre prestanda används.

Om ett värde som är högre än 2 väljs för video när Sorenson-kodeken används, använder Sorenson-dekodern läge 2 automatiskt.

Avkodningsfilter påverkar övergripande uppspelningsprestanda och behövs oftast inte för video med hög bandbredd. Om ett användarsystem inte är tillräckligt kraftfullt kan du få problem med uppspelning av video med ett avkodningsfilter aktiverat.

Anger om videon ska utjämnas (interpoleras) när den skalas. För att utjämning ska fungera måste miljön vara inställd på hög kvalitet (standard). Standardvärdet är false (ingen utjämning).

För videouppspelning med Flash Player 9.0.115.0 och senare versioner ska egenskapen ställas in på true för att dra fördel av bildoptimering med mipmapping.

Ett heltal som anger videoflödets höjd i pixlar. För direktflöden är värdet detsamma som egenskapen Camera.height för det Camera-objekt som spelar in videoflödet. För inspelade videofiler är det här värdet höjden på videon. För inspelad video skickas NetStream.Video.DimensionChange-händelsen när detta värde ändras.

Du kan till exempel använda egenskapen för att se till att användaren ser video med samma storlek som den spelas in med, oavsett Video-objektets faktiska storlek på scenen.

Relaterade API-element

Ett heltal som anger videoflödets bredd i pixlar. För direktflöden är värdet detsamma som egenskapen Camera.width för det Camera-objekt som spelar in videoflödet. För inspelade videofiler är det här värdet bredden på videon. För inspelad video skickas NetStream.Video.DimensionChange-händelsen när detta värde ändras.

Du kan till exempel använda egenskapen för att se till att användaren ser video med samma storlek som den spelas in med, oavsett Video-objektets faktiska storlek på scenen.

Relaterade API-element

Skapar en ny Video-instans. Om inga värden för width- och height-parametrarna anges används standardvärdena. Du kan även ställa in width- och height-egenskaperna i Video-objektet efter den ursprungliga konstruktionen med Video.width och Video.height. Om ett nytt Video-objekt skapas är inte nollvärden för width eller height tillåtna. Om du skickar noll används standardvärdena.

Om du har skapat videon anropar du metoden DisplayObjectContainer.addChild() eller DisplayObjectContainer.addChildAt() och lägger till Video-objektet i ett överordnat DisplayObjectContainer-objekt.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Anger ett videoflöde från en kamera som ska visas inom Video-objektets gränser i programmet.

Använd den här metoden för att bifoga livevideo som har spelats in av användaren i Video-objektet. Du kan spela upp livevideo lokalt på samma dator eller enhet som den spelas in på eller skicka den till Flash Media Server och använda servern för att direktuppspela videon för andra användare.

Obs! I ett iOS AIR-program kan kameravideo inte visas när programmet använder GPU-återgivningsläge.

Parametrar

Relaterade API-element

Anger ett videoflöde som ska visas inom Video-objektets gränser i programmet. Videoströmmen är antingen en videofil som spelas upp med NetStream.play(), ett Camera-objekt eller null. Om du använder en videofil kan den lagras på det lokala filsystemet eller på Flash Media Server. Om värdet på argumentet netStream är null spelas videofilmen inte längre upp i Video-objektet.

Du behöver inte använda den här metoden om videofilen bara innehåller ljud. Ljuddelen av en videofil spelas upp automatiskt när NetStream.play() anropas. Om du vill styra ljudet som associeras med en videofil använder du egenskapen soundTransform för det NetStream-objekt som spelar upp videofilen.

Parametrar

Relaterade API-element

Raderar den bild som för tillfället visas i Video-objektet (inte i videoströmmen). Den här metoden är användbar för hantering av den aktuella bilden. Du kan till exempel radera den sista bilden eller visa väntelägesinformation utan att dölja Video-objektet.

Relaterade API-element

I det här exemplet placeras koden som skapar Video- och NetStream-objekten och anropar Video.attachNetStream() och NetStream.play() i en hanterarfunktion. Hanteraren anropas bara om försöket att ansluta till NetConnection-objektet lyckas, vilket är när netStatus-händelsen returnerar ett infoobjekt med en code-egenskap som visar om åtgärden lyckades. Du bör vänta tills anslutningen har upprättats innan du anropar NetStream.play().

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }