Camera  - AS3

Mängden rörelse kameran känner av. Värdena ligger i intervallet 0 (ingen rörelse känns av) till 100 (mycket rörelse känns av). Med värdet för den här egenskapen an du bedöma om du ska skicka en inställningen till metoden setMotionLevel().

Om kameran är tillgänglig men inte används på grund av att metoden Video.attachCamera() inte har anropats, ställs egenskapen in på -1.

Om du endast direktuppspelar okomprimerad, lokal video ställs egenskapen bara in om du har kopplat funktionen till händelsehanteraren. I annat fall är den odefinierad.

Relaterade API-element

Den maximala bandbredd (i byte) som den pågående utgående videomatningen kan använda. Ett värde på 0 betyder att videomatningen kan använda så mycket bandbredd som krävs för att upprätthålla önskad kvalitet på bildrutenivå.

Om du vill ställa in den här egenskapen använder du setQuality()-metoden.

Relaterade API-element

Den hastighet med vilken kameran spelar in data, i bildrutor per sekund. Du kan inte ange den här egenskapen men du kan använda metoden setMode() om du vill ställa in en relaterad egenskap, fps, som anger maximal bildrutehastighet som du vill att kameran ska spela in med.

Relaterade API-element

Den maximala hastighet med vilken kameran kan spela in data, i bildrutor per sekund. Högsta möjliga hastighet beror på kamerans kapacitet. Den här bildrutehastigheten går kanske inte att uppnå.

• Om du vill ställa in önskat värde för egenskapen använder du metoden setMode().
• Om du vill bestämma den hastighet som kameran spelar in data med använder du egenskapen currentFPS.

Relaterade API-element

Aktuell inspelningshöjd i pixlar. Om du vill ställa in önskat värde för egenskapen använder du metoden setMode().

Relaterade API-element

Ett nollbaserat indexvärde som anger placeringen av kameran i arrayen Camera.names, där alla tillgängiga kameror listas.

Relaterade API-element

Egenskapen isSupported är true om klassen Camera stöds på den aktuella plattformen, och i annat fall är värdet false.

Hur många videobildrutor som överförs fullständigt (kallas nyckelbildrutor) i stället för att interpoleras av videokomprimeringsalgoritmen. Standardvärdet är 15, vilket betyder att var 15:e bildruta är en nyckelbildruta. Värdet 1 innebär att alla bildrutor är nyckelbildrutor. Tillåtna värden är 1 till 300.

Relaterade API-element

Anger om en lokal visning av vad kameran spelar in komprimeras och dekomprimeras (true) på samma sätt som för en direktsändning med Flash Media Server, eller inte komprimeras (false). Standardvärdet är false.

Det kan vara bra att komprimera flödet i testsyfte, till exempel för att kunna se inställningarna för videokvalitet, men det kräver betydande processorkraft. Den lokala visningen komprimeras, redigeras för överföring som om den skulle sändas via en direktanslutning och dekomprimeras sedan för lokal visning.

Om du vill ställa in det här värdet använder du Camera.setLoopback(). Om du vill ställa in den komprimeringsmängd som används när egenskapen är true använder du Camera.setQuality().

Relaterade API-element

Mängden rörelse som krävs för att aktivera activity-händelsen. Giltiga värden är från 0 till 100. Standardvärdet är 50.

Det går att visa video oavsett värdet på egenskapen motionLevel. Mer information finns i setMotionLevel().

Relaterade API-element

Antalet millisekunder mellan den tidpunkt kameran slutar identifiera rörelse och den tidpunkt händelsen activity aktiveras. Standardvärdet är 2000 (2 sekunder).

Om du vill ställa in det här värdet använder du setMotionLevel().

Relaterade API-element

Ett booleskt värde som anger om användaren har nekat åtkomst till kameran (true) eller tillåtit åtkomst (false) i dialogrutan Sekretess i Flash Player. Om det här värdet ändras skickas status-händelsen iväg.

Relaterade API-element

Den nuvarande kamerans namn enligt kameramaskinvaran.

Relaterade API-element

En array med strängar som innehåller namnen på alla tillgängliga kameror. Vid åtkomst till denna array kommer dialogrutan Sekretess i Flash Player inte att visas. Arrayen tillhandahåller det nollbaserade indexvärdet för varje kamera och antalet kameror i systemet (med hjälp av names.length).

Anrop av egenskapen names kräver en omfattande undersökning av maskinvaran. I de flesta fall kan du använda standardkameran.

Relaterade API-element

Avgör om programmet har beviljats behörighet att använda kameran.

Relaterade API-element

Anger på vilken sida av enheten som kameran är placerad.

Använd egenskapen position för att bestämma om en kamera på en mobil enhet finns på framsidan eller baksidan av enheten. Med följande funktion kontrolleras alla tillgängliga kameror tills en kamera med den önskade placeringen hittas. Om det inte finns någon kamera med den önskade placeringen kommer standardkameran att returneras.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

På mobila enheter är kameraplaceringen normalt antingen CameraPosition.FRONT eller CameraPosition.BACK. Om det inte går att bestämma kameraplaceringen kommer standardvärdet att vara CameraPosition.UNKNOWN. På stationära datorer är placeringen alltid CameraPosition.UNKNOWN.

Konstanter för giltiga värden i denna egenskap definieras i klassen CameraPosition.

Relaterade API-element

Den bildkvalitetsnivå som krävs, utifrån den komprimeringsmängd som används för varje bildruta. Tillåtna värden på quality ligger i intervallet 1 (lägsta kvalitet, maximal komprimering) till 100 (högsta kvalitet, ingen komprimering). Standardvärdet är 0, vilket innebär att bildkvaliteten kan variera efter behov för att undvika att tillgänglig bandbredd överskrids.

Om du vill ställa in den här egenskapen använder du setQuality()-metoden.

Relaterade API-element

Aktuell inspelningsbredd i pixlar. Om du vill ställa in önskat värde för egenskapen använder du metoden setMode().

Relaterade API-element

Fyller en bytearray från ett rektangulärt område med pixeldata

Skriver ett heltal utan tecken (ett icke-multiplicerat 32-bitars pixelvärde) för varje pixel i bytearrayen. Arrayen ändras till det antal byte som krävs för att rymma alla pixlar.

Parametrar

Relaterade API-element

Fyller en vektor från ett rektangulärt område med pixeldata.

Skriver ett heltal utan tecken (ett icke-multiplicerat 32-bitars pixelvärde) för varje pixel i vektorn. Vektorn ändras till det antal byte som krävs för att rymma alla pixlar.

Parametrar

Relaterade API-element

Kopierar den sista bildrutan till en bitmapp.

Den här metoden kopierar innehållet i den sista bildrutan till en BitmapData-instans.

Parametrar

Relaterade API-element

Returnerar en referens till ett Camera-objekt för videoinspelning. För att kunna börja spela in videon måste du koppla Camera-objektet till ett Video-objekt (se Video.attachCamera()). Om du vill sända video till Flash Media Server anropar du NetStream.attachCamera() för att koppla Camera-objektet till ett NetStream-objekt.

Flera anrop till metoden getCamera() hänvisar till samma kameradrivrutin. Om koden innehåller kod som firstCam:Camera = getCamera() och secondCam:Camera = getCamera(), hänvisar både firstCam och secondCam till samma kamera, den kamera som är användarens standardkamera.

På mobila enheter med både en främre och bakre kamera kan du endast spela in video från en kamera i taget.

Normalt bör du inte överföra ett värde för name-parametern. Du använder i stället getCamera() för att returnera en referens till standardkameran. Via panelen med kamerainställningar (beskrivs senare i det här avsnittet) kan användaren ange vilken standardkamera som ska användas.

Du kan inte ange behörighetsinställningen för att tillåta eller neka användarens åtkomst till kameran med hjälp av ActionScript, men du kan visa dialogrutan för kamerainställning (Adobe Flash Player-inställningar) där användaren kan ange kamerabehörigheten. När en SWF-fil som använder metoden attachCamera() försöker att koppla den kamera som returneras av metoden getCamera() till ett Video- eller NetStream-objekt, visas en dialogruta där användaren kan välja att tillåta eller neka åtkomst till kameran. (Kontrollera att programfönstret är minst 215 x 138 pixlar. Detta är minimistorleken för att dialogrutan ska kunna visas i Flash Player.) När användaren gör en inställning i dialogrutan för kamerainställningar returneras ett informationsobjekt i status-händelsen, som anger användarens svar: Camera.muted anger att användaren har nekat en kamera åtkomst och Camera.Unmuted anger att användaren har tillåtit en kamera åtkomst. Om du vill avgöra om användaren har tillåtit eller nekat åtkomst till kameran utan att hantera status-händelsen kan du använda egenskapen muted.

I Flash Player kan användaren ange permanenta sekretessinställningar för en viss domän genom att högerklicka (Windows och Linux) eller Control-klicka (Macintosh) samtidigt som en SWF-fil spelas upp och därefter välja Inställningar, öppna dialogrutan Sekretess och markera Kom ihåg. Om Kom ihåg markeras uppmanas användaren inte längre att tillåta eller inte tillåta att SWF-filer från den här domänen ska få åtkomst till din kamera.

Obs! Metoden attachCamera() aktiverar inte dialogrutan för att tillåta eller neka åtkomst till kameran, om användaren har nekat åtkomst genom att markera Kom ihåg i dialogrutan Flash Player-inställningar. I det här fallet kan du uppmana användaren att ändra inställningen för att tillåta eller neka, genom att använda Security.showSettings(SecurityPanel.PRIVACY) för att visa panelen Sekretess i Flash Player för användaren.

Om getCamera() returnerar null, används antingen kameran av ett annat program eller så finns det ingen kamera installerad. Om du vill avgöra om det finns en installerad kamera använder du egenskapen names.length. Om du vill visa kamerainställningarna i Flash Player, där användaren kan välja vilken kamera som ska användas av getCamera(), använder du Security.showSettings(SecurityPanel.CAMERA).

Att söka genom maskinvaran efter kameror tar tid. När minst en kamera har hittats sker ingen ytterligare genomsökning av maskinvaran under spelarinstansens livstid. Om inga kameror hittas söks maskinvaran emellertid igenom varje gång getCamera anropas. Detta är praktiskt om det finns en kamera, men den är inaktiverad. Om det finns en Försök igen-knapp i SWF-filen som anropar getCamera kan kameran hittas utan att användaren behöver starta om SWF-filen.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Begär kamerabehörighet för programmet.

Anger vilka videobildrutor som överförs fullständigt (kallas keyframes) i stället för att interpoleras av videokomprimeringsalgoritmen. Den här metoden gäller endast om du överför video med Flash Media Server.

Videokomprimeringsalgoritmen i Flash komprimerar video genom att bara överföra det som har ändrats sedan förra bildrutan i videon. Dessa delar betraktas som interpolerade bildrutor. Bildrutor i en video kan vara interpolerade efter innehållet i den föregående bildrutan. En nyckelbildruta är dock en videobildruta som är komplett. Den är inte interpolerad från tidigare bildrutor.

Om du vill bestämma hur ett värde för parametern keyFrameInterval ska ställas in måste du ta hänsyn till både bandbreddsanvändning och videouppspelningsåtkomst. Om du till exempel anger ett högre värde för keyFrameInterval (inte skickar bildrutor lika ofta) minskar bandbreddsanvändningen. Det kan dock ta längre tid att placera spelhuvudet vid en viss punkt i videon. Ännu tidigare videobildrutor kan behöva interpoleras innan videon kan spelas upp igen.

Om du anger ett lägre värde för keyFrameInterval (skickar bildrutor lite oftare) ökar bandbreddsanvändningen eftersom alla videobildrutor överförs oftare, men det kanske inte tar lika lång tid att söka efter en viss videobildruta i en inspelad video.

Parametrar

Relaterade API-element

Anger om ett komprimerat videoflöde ska användas för lokal visning av kameran. Den här metoden gäller endast om du överför video med Flash Media Server. Om du ställer in compress på true kan du se mer exakt hur videon kommer att visas för användare när de visar den i realtid.

Även om ett komprimerat flöde är användbart i testsyfte, som t.ex. vid förhandsgranskning av videokvalitetsinställningar, kostar det mycket eftersom den lokala visningen inte bara komprimeras. Den komprimeras, redigeras för överföring över en liveanslutning, och sedan dekomprimeras den för lokal visning.

Om du vill ange den komprimeringsmängd som används när du ställer in compress på true använder du Camera.setQuality().

Parametrar

Relaterade API-element

Ställer in kamerans inspelningsläge på det inbyggda läge som bäst passar de angivna kraven. Om kameran inte har ett inbyggt läge som matchar alla parametrar som du skickar, väljs ett inspelningsläge som mest liknar det begärda. Denna ändring kan medföra att bilden beskärs och bildrutor utesluts.

Standard är att bildrutor utesluts under körning om det behövs för att upprätthålla bildstorleken. Om du vill minimera antalet uteslutna bildrutor, även om det innebär att bildstorleken blir mindre, skickar du false för favorArea-parametern.

När du väljer ett inbyggt läge görs försök att upprätthålla det begärda bildformatet så långt det är möjligt. Anta att du skickar kommandot myCam.setMode(400, 400, 30) och att de maximala bredd- och höjdvärdena som är tillgängliga för kameran är 320 och 288, då kommer både bredd och höjd att ställas in på 288. Genom att ge dessa egenskaper samma värde upprätthålls bildförhållandet 1:1 så som du begärde.

Om du vill bestämma vilka värden som är kopplade till egenskaperna efter att det läge som bäst passar de begärda värdena har valts, använder du egenskaperna width, height och fps.

Om du använder Flash Media Server kan du också spela in enstaka bildrutor eller skapa fotografering i tidsintervaller. Mer information finns i NetStream.attachCamera().

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Anger hur mycket rörelse som krävs för att skicka en activity-händelse. Du kan ange hur många tusendels sekunder som ska gå utan aktivitet innan det bedöms som att rörelsen avstannat och händelsen skickas.

Obs! Det går att visa video oavsett värdet på parametern motionLevel. Parametern avgör endast när och under vilka omständigheter händelsen skickas, inte om video faktiskt spelas in eller visas.

Om du vill att kameran inte ska känna av rörelse alls skickar du värdet 100 för parametern motionLevel. Då skickas aldrig activity-händelsen. (Du vill antagligen bara använda det här värdet i testsyfte, om du till exempel tillfälligt inaktiverar alla hanterare som normalt skulle utlösas när händelsen skickas.)

Om du vill ange den rörelsemängd som kameran känner av för tillfället använder du egenskapen activityLevel. Rörelsekänslighetsvärden motsvarar direkt aktivitetsvärden. Ingen rörelse motsvarar aktivitetsvärdet 0. Konstant rörelse motsvarar aktivitetsvärdet 100. Aktivitetsvärdet är lägre än rörelsekänslighetens värde när du inte flyttar på dig. Om du flyttar på dig överskrider aktivitetsvärdena ofta ditt rörelsekänslighetsvärde.

Den här metoden liknar metoden Microphone.setSilenceLevel(). Båda metoderna används för att ange när activity-händelsen ska skickas. Metoderna påverkar dock publiceringsflöden på helt olika sätt:

• Microphone.setSilenceLevel() är utformad för att optimera bandbredd. När ett ljudflöde anses tyst, skickas inga ljuddata. I stället skickas ett enda meddelande som indikerar att tystnad har påbörjats.
• Camera.setMotionLevel() är utformat för att känna av rörelse och påverkar inte bandbreddsanvändning. Även om ett videoflöde inte känner av rörelse skickas fortfarande video.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Ställer in maximal bandbredd per sekund eller den bildkvalitet som behövs för den pågående utgående videomatningen. Den här metoden gäller endast om du överför video med Flash Media Server.

Använd metoden om du vill ange vilka element i den utgående videomatningen som är viktigast för programmet; bandbreddsanvändning eller bildkvalitet.

• Om du vill indikera att bandbreddsanvändning prioriteras skickar du värdet för bandwidth och 0 för quality. Under körningen överförs videon med högsta möjliga kvalitet inom den angivna bandbredden. Vid behov sänks bildkvaliteten för att undvika att den angivna bandbredden överskrids. Normalt minskar kvaliteten när rörelsen ökar.
• Om du vill ange att kvalitet ska prioriteras skickar du 0 för bandwidth och ett numeriskt värde för quality. Under körningen används så mycket bandbredd som krävs för att den angivna kvaliteten ska kunna upprätthållas. Vid behov sänks bildrutehastigheten för att bildkvaliteten ska upprätthållas. Normalt ökar bandbredden när rörelsen ökar.
• Om du vill ange att både bandbredd och kvalitet är lika viktiga skickar du numeriska värden till båda parametrarna. Under körningen överförs video i den angivna kvaliteten men utan att den angivna bandbredden överskrids. Vid behov sänks bildrutehastigheten för att bildkvaliteten ska kunna upprätthållas utan att den angivna bandbredden överskrids.

Parametrar

Relaterade API-element

Skickas när en kamera startar eller avslutar en session. Anropa Camera.setMotionLevel() för att ange hur mycket rörelse som krävs för att aktivera en activity-händelse med activating-värdet true, eller hur lång tid som ska gå utan aktivitet för att aktivera en activity-händelse med activating-värdet false.

Den här händelsen har följande egenskaper:

Skickas när programmet begär behörighet att använda kameran på enheten. Kontrollera värdet för egenskapen status för att avgöra om behörighet beviljades eller nekades

Relaterade API-element

Skickas när en kameras status rapporteras. Innan en kamera används visas dialogrutan Sekretess så att användaren kan tillåta eller neka tillgång till kameran. Om värdet för egenskapen code är "Camera.muted" tillåter användaren inte att SWF-filen får tillgång till användarens kamera. Om värdet för egenskapen code är "Camera.Unmuted" tillåter användaren att SWF-filen får åtkomst till användarens kamera.

Obs! Den här händelsen skickas inte på AIR-plattformen. Den används endast i Flash Player.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas efter att en ny kamerabildruta har bearbetats av miljön och är tillgänglig för att kopieras.

Den här händelsen har följande egenskaper:

Relaterade API-element

Obs! En kamera måste vara ansluten till datorn för att det här ska fungera.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}