File  - AS3

Folder zawierający pliki instalowane z aplikacją.

Właściwość url dla tego obiektu korzysta ze schematu URL app (a nie ze schematu URL file). Oznacza to, że ciąg znaków url jest określany zaczynając od "app:" (a nie "file:"). Również jeżeli zostanie utworzony obiekt File względny wobec katalogu File.applicationDirectory (za pomocą metody resolvePath()), to właściwość url tego obiektu File również używa schematu URL app.

Uwaga: Nie można zapisywać do plików lub katalogów, których ścieżki korzystają ze schematu URL app:. Nie można również usuwać ani tworzyć plików i katalogów, których ścieżki korzystają ze schematu URL app:. Modyfikowanie zawartości w katalogu aplikacji nie jest zalecane ze względów bezpieczeństwa. Na niektórych platformach takie operacje są blokowane przez system operacyjny. Do przechowywania danych właściwych dla aplikacji najlepiej jest używać katalogu przechowywania aplikacji (File.applicationStorageDirectory). Jeżeli zajdzie potrzeba, aby zawartość (w katalogu przechowywania aplikacji) miała dostęp do funkcji dotyczących uprawnień aplikacji (interfejsów API aplikacji AIR), można udostępnić te funkcje za pomocą mostu obszaru izolowanego.

Właściwość applicationDirectory zapewnia sposób odwoływania się do katalogu aplikacji, który działa na różnych platformach. Jeśli obiekt File zostanie ustawiony za pomocą właściwości nativePath lub url, tak aby odwoływał się do katalogu aplikacji, wówczas ścieżka będzie działała tylko na tej platformie, dla której jest poprawna.

W systemie Android właściwość nativePath obiektu File wskazującego katalog aplikacji jest pustym ciągiem. W celu uzyskania dostępu do plików aplikacji należy użyć właściwości url.

Powiązane elementy interfejsu API

Prywatny katalog zapisywania aplikacji.

Każda aplikacja AIR ma niepowtarzalny, trwały katalog przechowywania aplikacji, który jest tworzony podczas pierwszego dostępu do katalogu File applicationStorageDirectory. Ten katalog jest unikalny dla każdej aplikacji i każdego użytkownika. Katalog ten jest dogodnym miejscem przechowywania danych właściwych dla użytkownika lub aplikacji.

W przypadku odinstalowania aplikacji AIR od platformy zależy, czy program odinstalowujący usunie katalog przechowywania aplikacji i zawarte w nim pliki.

Właściwość url dla tego obiektu korzysta ze schematu URL app-storage (a nie ze schematu URL file). Oznacza to, że ciąg znaków url jest określany zaczynając od "app-storage:" (nie "file:"). Również jeżeli zostanie utworzony obiekt File względny wobec katalogu File.applicationStoreDirectory (za pomocą metody resolvePath()), to właściwość url tego obiektu File również używa schematu URL app-storage (tak jak w przykładzie).

Właściwość applicationStorageDirectory zapewnia sposób odwoływania się do katalogu przechowywania aplikacji, który działa na różnych platformach. Jeśli obiekt File zostanie ustawiony za pomocą właściwości nativePath lub url, tak aby odwoływał się do katalogu przechowywania aplikacji, wówczas ścieżka będzie działała tylko na tej platformie, dla której jest poprawna.

Uwaga (dotyczy tylko systemu Mac OS): Aby zapewnić zgodność z wymaganiami sklepu Mac App Store, lokalizacja fizyczna stosowana przez środowisko AIR 3.2 uległa zmianie w wersji AIR 3.3:

• Przestrzeń nazw wersji 3.2 lub starszej: ~/Biblioteki/Preferences/identyfikator_aplikacji/Local Store/
• Przestrzeń nazw wersji 3.3 lub nowszej: sciezka/Biblioteki/Application Support/identyfikator_aplikacji/Local Store/, gdzie sciezka to albo ~/Biblioteki/Containers/identyfikator_pakietu/Data (w środowisku obszaru izolowanego) lub ~ (poza środowiskiem obszaru izolowanego)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Katalog bufora aplikacji.

Właściwość cacheDirectory umożliwia odnoszenie się do katalogu bufora. Aplikacja powinna przechowywać w katalogu bufora pliki, które są pobierane z serwera lub mogą zostać ponownie wygenerowane. W tym katalogu należy na przykład umieszczać pliki bufora bazy danych i pobraną zawartość, taką jak dane używane w aplikacjach czasopism czy map.

Jeśli obiekt File zostanie ustawiony jako odniesienie do katalogu bufora przy użyciu właściwości nativePath lub url, będzie funkcjonował tylko na platformach, na których dana ścieżka jest prawidłowa.

Jeśli system operacyjny nie obsługuje katalogu bufora, właściwość cacheDirectory ma wartość null.

Katalog pulpitu użytkownika.

Właściwość desktopDirectory zapewnia sposób odwoływania się do katalogu pulpitu, który działa na różnych platformach. Jeśli obiekt File zostanie ustawiony za pomocą właściwości nativePath lub url, tak aby odwoływał się do katalogu pulpitu, wówczas ścieżka będzie działała tylko na tej platformie, dla której jest poprawna.

Jeżeli system operacyjny nie obsługuje katalogu pulpitu, zamiast niego jest używany odpowiedni katalog w systemie plików.

Na urządzeniach telewizyjnych ze środowiskiem AIR nie funkcjonuje pojęcie katalogu pulpitu użytkownika. Z tego powodu właściwość desktopDirectory odnosi się do tej samej lokalizacji (tego samego katalogu) co właściwość File.userDirectory. Katalog użytkownika jest unikatowy dla aplikacji.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Katalog dokumentów użytkownika.

W systemie Windows jest to katalog Moje dokumenty (na przykład: C:\Documents and Settings\Moje dokumenty). W systemie Mac OS lokalizacja domyślna to /Users/nazwaUżytkownika/Documents. W systemie Linux lokalizacja domyślna to /home/nazwaUżytkownika/Documents (w angielskiej wersji językowej), a wartość właściwości zachowuje zgodność z ustawieniem xdg-user-dirs.

Właściwość documentsDirectory zapewnia sposób odwoływania się do katalogu dokumentów, który działa na różnych platformach. Jeśli obiekt File zostanie ustawiony za pomocą właściwości nativePath lub url, tak aby odwoływał się do katalogu dokumentów, wówczas ścieżka będzie działała tylko na tej platformie, dla której jest poprawna.

Jeżeli system operacyjny nie obsługuje katalogu dokumentów, zamiast niego jest używany odpowiedni katalog w systemie plików.

Na urządzeniach telewizyjnych ze środowiskiem AIR nie funkcjonuje pojęcie katalogu dokumentów użytkownika. Z tego powodu właściwość documentsDirectory odnosi się do tej samej lokalizacji (tego samego katalogu) co właściwość File.userDirectory. Katalog użytkownika jest unikatowy dla aplikacji.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Wskazuje, czy plik lub katalog, do którego istnieje odwołanie, został pobrany (z Internetu), czy nie.

Ta właściwość ma znaczenie tylko w systemach operacyjnych, w których pliki mogą być oznaczone jako pobrane:

• Windows XP z dodatkiem Service Pack 2 lub późniejszym oraz w systemie Windows Vista
• Mac OS 10.5 i późniejsze wersje

W systemach, w których pobrane pliki nie są oznaczane, takich jak Linux, ta właściwość nie ma znaczenia (jest ustawiona na false).

Powiązane elementy interfejsu API

Wskazuje, czy istnieje plik lub katalog, którego dotyczy odwołanie. Wartość wynosi true, jeżeli obiekt File wskazuje na istniejący plik lub katalog; w innym przypadku wartość wynosi false.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Obiekt Icon zawierający ikony zdefiniowane dla pliku. Obiekt Icon jest tablicą obiektów BitmapData odpowiadających różnym stanom ikon. W systemie Linux obiekt Icon nie zawiera żadnych ikon. W systemie Android właściwość icon przyjmuje wartość null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Wskazuje, czy odwołanie odnosi się do katalogu. Jeżeli obiekt File wskazuje na katalog, wartość wynosi true; w przeciwnym przypadku wartość wynosi false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Czy plik lub katalog, do którego istnieje odwołanie, jest „ukryty”. Wartością jest true, jeżeli plik lub katalog, do którego istnieje odwołanie, jest ukryty; wartość false jeżeli jest inaczej.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Wskazuje, czy katalog, do którego istnieje odwołanie, jest pakietem.

Wartością jest true, jeżeli katalog, do którego istnieje odwołanie, jest pakietem; wartość false, jeżeli jest inaczej. Należy zauważyć, że klasa File nie pozwala na bezpośrednie tworzenie pakietów.

• W systemie Mac OS katalogi mogą być oznaczone jako pakiety i wyświetlane są w Finderze jako pojedyncze pliki (a nie katalogi). Ta właściwość ma wartość true, jeżeli katalog, do którego istnieje odwołanie, jest pakietem, a wartość false, jeżeli plik nie jest katalogiem, nie istnieje lub nie jest pakietem.
• W innych systemach operacyjnych ta właściwość jest zawsze ustawiona na wartość false.

Wskazuje, czy odniesienie jest łączem symbolicznym.

Jeżeli obiekt File jest łączem symbolicznym, to wartością jest true; wartość false, jeżeli jest inaczej. Należy zauważyć, że klasa File nie pozwala na bezpośrednie tworzenie pakietów.

Łącza symboliczne to rozwiązanie, dzięki któremu plik może wskazywać inny plik lub katalog na dysku. Mimo podobieństw łącza symboliczne nie są tym samym, co aliasy w systemie Mac OS oraz skróty w systemie Windows. Skrót lub alias są zawsze zgłaszane jako pliki (a nie katalogi), odczytywanie i zapisywanie w skrócie lub aliasie nigdy nie wpływa na wskazywany przez nie pierwotny plik lub katalog. Z drugiej strony łącze symboliczne z reguły zachowuje się tak, jak plik lub katalog, na który wskazuje. Może być zgłoszony jako plik lub katalog, odczytywanie i zapisywanie w łączu symbolicznym wpływa na wskazywany przez nie plik lub katalog (nie na łącze). Jednak operacja usunięcia łącza symbolicznego powoduje usunięcie tylko łącza, a nie obiektu docelowego.

Łącza symboliczne są obsługiwane w systemach Mac^® OS^®, Linux i Windows^® Vista^®. Dodatkowo w systemie Windows właściwość isSymbolicLink dla obiektu File odnoszącego się do punktu połączenia (używanego w systemie plików NTFS) jest ustawiona na wartość true.

Sekwencja znaków kończących wiersz w systemie operacyjnym hosta.

W systemach Mac OS i Linux jest to znak przesunięcia o wiersz (szesnastkowy kod znaku: 0x0A). W systemie operacyjnym Windows jest to znak powrotu karetki (szesnastkowy kod znaku: 0x0D) poprzedzany znakiem przesunięcia o wiersz (szesnastkowy kod znaku: 0x0A).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Pełna ścieżka w postaci odpowiadającej systemowi operacyjnemu hosta. W systemach Mac OS i Linux znak prawego ukośnika (/) jest używany jako separator ścieżki. W systemie Windows można ustawić właściwość nativePath, podając ciąg znaków zawierający ukośniki lub ukośniki odwrotne (\), a środowisko AIR automatycznie zastąpi ukośniki odpowiednimi ukośnikami odwrotnymi.

Przed napisaniem kodu w celu bezpośredniego ustawienia właściwości nativePath, należy rozważyć, czy dokonanie tego nie spowoduje utworzenia kodu specyficznego dla platformy. Na przykład ścieżka rodzima "C:\\Documents and Settings\\bob\\Desktop" jest poprawna jedynie w systemie Windows. Lepszym sposobem jest użycie następujących właściwości statycznych, które reprezentują najczęściej używane katalogi i są poprawne na wszystkich platformach:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Następnie można użyć metody resolvePath() w celu uzyskania ścieżki względnej wobec tych katalogów.

Niektóre interfejsy API Flex, takie jak właściwość source klasy SWFLoader, korzystają z adresu URL (właściwość url obiektu File), a nie ze ścieżki natywnej (właściwość nativePath).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Katalog zawierający plik lub katalog, do którego odnosi się ten obiekt File.

Jeżeli plik lub katalog nie istnieje, właściwość parent nadal zwraca obiekt File wskazujący na katalog zawierający, nawet jeżeli nie istnieje.

Właściwość ta jest taka sama jak wartość zwracana dla resolvePath(".."), z wyjątkiem sytuacji, gdy katalogiem głównym jest null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Sprawdź, czy system otrzymał pozwolenie na dostęp do systemu plików.

Powiązane elementy interfejsu API

Wskazuje, czy środowisko wykonawcze zapobiega wykonywaniu kopii zapasowych tego obiektu File w środowisku rozproszonym.

Jeśli ta właściwość ma wartość true, plik nie podlega automatycznemu wykonywaniu kopii zapasowej na platformach, które oferują taką usługę. Ta właściwość ma domyślnie wartość false.

Znak separatora składnika ścieżki systemu operacyjnego hosta.

W systemach Mac OS i Linux jest to znak prawego ukośnika (/). W systemie Windows jest to znak lewego ukośnika (\).

Uwaga: Używając znaku lewego ukośnika w literale ciągu znaków, należy pamiętać o wprowadzaniu znaków podwójnie (jak w "directory\\file.ext"). Każda para lewych ukośników w literale ciągu znaków reprezentuje jeden lewy ukośnik w ciągu.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Ilość miejsca dostępna do użycia w danej lokalizacji File, określona w bajtach.

Jeśli obiekt File odwołuje się do katalogu, parametr spaceAvailable wskazuje ilość miejsca w katalogu, jaką mogą wykorzystać pliki. Jeśli obiekt File odwołuje się do pliku, parametr spaceAvailable określa ilość miejsca, jaką może zajmować plik (także w przypadku wzrostu wielkości). Jeśli lokalizacja pliku nie istnieje, parametr spaceAvailable jest ustawiony na 0. Jeśli obiekt File odwołuje się do odniesienia symbolicznego, parametr spaceAvailable określa ilość miejsca w lokalizacji, na którą wskazuje odniesienie symboliczne.

Zwykle ilość miejsca dostępnego dla katalogu lub pliku jest taka sama, jak ilość miejsca dostępnego w woluminie zawierającym katalog lub plik. Jednak możliwe jest, że podczas określania ilości dostępnego miejsca uwzględniane będą limity dla katalogów.

Dodanie pliku lub katalogu do woluminu zwykle wiąże się z wymaganiem większej ilości miejsca niż rzeczywisty rozmiar pliku lub rzeczywisty rozmiar zawartości katalogu. Przykład: system operacyjny może wymagać większej ilości miejsca w celu zapisania informacji o indeksie. Lub wymagane sektory dysku mogą wykorzystywać dodatkową ilość miejsca. Ponadto dostępna ilość miejsca zmienia się dynamicznie. Dlatego nie można oczekiwać, że cała określona ilość zostanie przypisana dla zapisu plików.

Domyślne kodowanie używane przez system operacyjny komputera.

Dopuszczalne wartości to "windows-1252" "shift-jis", "cn-gb", "iso-8859-1" oraz inne. Pełną listę zawiera sekcja Obsługiwane zestawy znaków.

Tej wartości można używać podczas korzystania z metod readMultiByte() i writeMultiByte() klasy FileStream.

Powiązane elementy interfejsu API

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

Adres URL dla tej ścieżki pliku.

Jeśli to jest odwołanie do ścieżki w katalogu przechowywania aplikacji, schemat adresu URL wygląda następująco "app-storage"; jeśli to jest odwołanie do ścieżki w katalogu aplikacji, schemat adresu URL wygląda następująco "app"; w innym wypadku schemat wygląda następująco "file".

Podczas przydzielania wartości do właściwości url można używać pustych znaków (a nie "%20"). Środowisko AIR automatycznie dekoduje ciąg znaków (na przykład zamieni spacje na "%20").

Powiązane elementy interfejsu API

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Katalog użytkownika.

W systemie Windows jest to katalog nadrzędny katalogu Moje dokumenty (na przykład: C:\Documents and Settings\userName). W systemie Mac OS jest to katalog /Users/nazwaUżytkownika W systemie Linux jest to katalog /home/nazwaUżytkownika.

Właściwość userDirectory zapewnia sposób odwoływania się do katalogu użytkownika, który działa na różnych platformach. Jeśli właściwość nativePath lub url obiektu File zostanie ustawiona bezpośrednio, ścieżka będzie działała tylko na tej platformie, dla której jest poprawna.

Jeżeli system operacyjny nie obsługuje katalogu użytkownika, zamiast niego jest używany odpowiedni katalog w systemie plików.

Na urządzeniach telewizyjnych ze środowiskiem AIR właściwość userDirectory odnosi się do unikatowego dla aplikacji katalogu użytkownika.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Funkcja konstruktora dla klasy File.

Po przekazaniu argumentu path obiekt File wskazuje na określoną ścieżkę, a właściwości nativePath i url są ustawione, tak aby odzwierciedlać tą ścieżkę.

Mimo możliwości przekazania argumentu path w celu określenia ścieżku pliku, należy rozważyć, czy dokonanie tego nie spowoduje utworzenia kodu specyficznego dla platformy. Na przykład ścieżka rodzima "C:\\\\Documents and Settings\\bob\\Desktop" lub adres URL "file:///C:/Documents%20and%20Settings/bob/Desktop" są poprawne jedynie w systemie Windows. Lepszym sposobem jest użycie następujących właściwości statycznych, które reprezentują najczęściej używane katalogi i są poprawne na wszystkich platformach:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Następnie można użyć metody resolvePath() w celu uzyskania ścieżki względnej wobec tych katalogów. Na przykład poniższy kod ustawia obiekt File, tak aby wskazywał na plik settings.xml w katalogu przechowywania aplikacji.

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Ważne: Jeśli ciąg znaków adresu URL zostanie przekazany w parametrze path, adres URL zostanie zdekodowany w celu wyznaczenia ścieżki do pliku. Na przykład: instrukcja new File("file:///c:/test/demo%20file%201%2e0.txt") utworzy obiekt File ze ścieżką rodzimą "c:\test\demo file 1.0.txt". (Adres URL używa przedrostków schematów file:, app: lub app-storage:). Jeśli jednak przedrostki poprawnych adresów URL zostaną pominięte, ciąg znaków ścieżki będzie traktowany jako ścieżka rodzima i nie nastąpi dekodowanie. Takie zachowanie należy wziąć pod uwagę podczas sprawdzania poprawności ścieżek pobieranych z potencjalnie niezaufanych źródeł. W przypadku prostego sprawdzania poprawności wejściowego ciągu znaków dekodowanie adresu URL może umożliwić agresorowi ominięcie pewnych etapów sprawdzania poprawności. Należy zawsze sprawdzać poprawność ostatecznej ścieżki zainicjowanego obiektu File:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Powiązane elementy interfejsu API

Wyświetla okno dialogowe wybierania katalogów, pozwalające użytkownikowi na wybór katalogu. Po wybraniu przez użytkownika tego katalogu, zdarzenie select jest wywoływane. Właściwość target zdarzenia select jest obiektem File, wskazującym na wybrany katalog.

Okno dialogowe wyboru katalogu nie zawsze jest wyświetlane przed oknami, których właścicielami są inne okna (przed oknami z wartością właściwości owner inną niż null). Aby uniknąć problemów z kolejnością, przed wywołaniem tej metody należy ukryć okna mające właścicieli.

Uwaga: Właściwość browseForDirectory nie jest obsługiwana na urządzeniach z systemem Android. Obiekt File natychmiast wywołuje zdarzenie cancel.

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Wyświetla okno dialogowe Otwórz plik pozwalające użytkownikowi na wybór pliku do otwarcia.

Po wybraniu przez użytkownika tego pliku, zdarzenie select jest wywoływane. Właściwość target zdarzenia select jest obiektem File, wskazującym na zaznaczony plik.

Okno dialogowe otwierania plików nie zawsze jest wyświetlane przed oknami, których właścicielami są inne okna (przed oknami z wartością właściwości owner inną niż null). Aby uniknąć problemów z kolejnością, przed wywołaniem tej metody należy ukryć okna mające właścicieli.

Uwaga: Na urządzeniach z systemem Android nie można ustawić tytułu okna dialogowego pliku. Parametr title jest ignorowany.

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Wyświetla okno dialogowe Otwórz plik pozwalające użytkownikowi na wybór jednego lub wielu plików do otwarcia.

Po wybraniu plików przez użytkownika wywoływane jest zdarzenie selectMultiple. Właściwość target zdarzenia select jest obiektem File. W odróżnieniu od metody browseForOpen() w metodzie browseForOpenMultiple ten obiekt File nie jest aktualizowany w celu odwołania do któregokolwiek z wybranych plików. Zamiast tego, wynikowe zdarzenie selectMultiple zawiera tablicę wybranych plików.

Okno dialogowe otwierania plików nie zawsze jest wyświetlane przed oknami, których właścicielami są inne okna (przed oknami z wartością właściwości owner inną niż null). Aby uniknąć problemów z kolejnością, przed wywołaniem tej metody należy ukryć okna mające właścicieli.

Uwaga: Na urządzeniach z systemem Android nie można ustawić tytułu okna dialogowego pliku. Parametr title jest ignorowany.

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Wyświetla okno dialogowe zapisywania pliku, w którym użytkownik może wybrać lokalizację docelową pliku.

Po wybraniu przez użytkownika pliku jest wywoływane zdarzenie select. Właściwość target zdarzenia select jest obiektem File, wskazującym na wybrane miejsce docelowe zapisu.

Okno dialogowe zapisywania pliku nie zawsze jest wyświetlane przed oknami, których właścicielami są inne okna (przed oknami z wartością właściwości owner inną niż null). Aby uniknąć problemów z kolejnością, przed wywołaniem tej metody należy ukryć okna mające właścicieli.

Uwaga: Na urządzeniach z systemem Android nie można ustawić tytułu okna dialogowego pliku. Parametr title jest ignorowany.

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Anuluje każde trwające działanie asynchroniczne.

Przekształca ścieżkę pliku do postaci kanonicznej.

Jeżeli obiekt File reprezentuje istniejący plik lub katalog, funkcja sprowadzająca do postaci kanonicznej przekształca ścieżkę tak, aby była ona zgodna z faktyczną nazwą pliku lub katalogu. Jeżeli obiekt File jest łączem symbolicznym, funkcja sprowadzająca do postaci kanonicznej dostosowuje ścieżkę tak, aby była zgodna z plikiem lub katalogiem, na który wskazuje łącze, niezależnie od tego, czy wskazywany plik lub katalog istnieje. Gdy w systemach, w których jest rozróżniana wielkość liter (na przykład Linux), istnieje wiele plików z nazwami różniącymi się jedynie wielkością liter, metoda canonicalize() dostosowuje ścieżkę tak, aby była ona zgodna z pierwszym znalezionym plikiem (w kolejności określonej przez system plików).

Ponadto sprowadzenie do postaci kanonicznej w systemie Windows powoduje konwersję nazw skróconych na długie nazwy plików.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Zwraca kopię tego obiektu File. Rejestracje zdarzeń nie są kopiowane.

Uwaga: Ta metoda nie kopiuje samego pliku. Tworzy kopię instancji obiektu File ActionScript. Do kopiowania pliku służy metoda copyTo().

Kopiuje plik lub katalog z lokalizacji określonej przez obiekt File do lokalizacji określonej przez parametr newLocation. Proces kopiowania tworzy wymagane katalogi nadrzędne (jeżeli jest to możliwe). W przypadku zastępowania plików przy użyciu metody copyTo() atrybuty plików również są zastępowane.

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Rozpoczyna kopiowanie pliku lub katalogu z lokalizacji określonej przez obiekt File do lokalizacji określonej przez parametr destination.

Po zakończeniu wywoływane jest zdarzenie complete (sukces) lub ioError (niepowodzenie). Proces kopiowania tworzy wymagane katalogi nadrzędne (jeżeli jest to możliwe).

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Tworzy określony katalog i niezbędne katalogi nadrzędne. Jeżeli katalog istnieje, żadne działanie nie zostanie podjęte.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Zwraca odniesienie do nowego katalogu tymczasowego. Jest to nowy katalog w ścieżce systemowego katalogu tymczasowego.

Ten sposób pozwala na identyfikację nowego, niepowtarzalnego katalogu, bez konieczności wysyłania zapytania do systemu, aby sprawdzić czy ten katalog jest nowy i niepowtarzalny.

Katalog tymczasowy nie jest automatycznie usuwany na niektórych urządzeniach, dlatego warto rozważyć jego usunięcie przed zamknięciem aplikacji.

Powiązane elementy interfejsu API

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Zwraca odniesienie do nowego pliku tymczasowego. Jest to nowy plik w ścieżce systemowego katalogu tymczasowego.

Ten sposób pozwala na identyfikację nowego, niepowtarzalnego pliku, bez konieczności wysyłania zapytania do systemu w celu sprawdzenia czy ten plik jest nowy i niepowtarzalny.

Można skasować plik tymczasowy przed zamknięciem aplikacji, ponieważ nie jest on usuwany automatycznie.

Powiązane elementy interfejsu API

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Usuwa katalog. Jeśli dany obiekt File jest faktycznie łączem symbolicznym do katalogu, wówczas usunięte zostanie łącze, a nie katalog.

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Usuwa katalog asynchronicznie. Jeśli dany obiekt File jest faktycznie łączem symbolicznym do katalogu, wówczas usunięcie obejmie łącze, a nie katalog.

Parametry

Powiązane elementy interfejsu API

Usuwa plik. Jeśli dany obiekt File jest w istocie łączem symbolicznym, wówczas usunięte zostanie łącze, a nie docelowy plik.

Powiązane elementy interfejsu API

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Usuwa plik asynchronicznie. Jeśli dany obiekt File jest w istocie łączem symbolicznym, wówczas usunięcie objemuje łącze, a nie plik docelowy.

Powiązane elementy interfejsu API

Zwraca tablicę obiektów File, odpowiadającą plikom i katalogom w katalogu reprezentowanym przez ten obiekt File. Metoda ta nie przeszukuje zawartości podkatalogów.

Powiązane elementy interfejsu API

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Pobiera asynchronicznie tablicę obiektów File, odpowiadającą plikom i katalogom w katalogu reprezentowanym przez ten obiekt File.

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Znajduje ścieżkę względną pomiędzy dwoma ścieżkami File.

Ścieżka względna jest listą składników, które mogą być dołączone (rozpoznane) do tego odwołania w celu lokalizacji drugiego (parametr) odwołania. Ścieżka względna jest zwracana za pomocą znaku separatora "/".

Opcjonalnie, ścieżka względna może zawierać odwołania "..", ale takie ścieżki nie przekroczą widocznych granic wolumenu.

Parametry

Zwraca tablicę obiektów File zawierającą katalogi głównego systemu plików.

Na przykład w systemie Windows jest to lista wolumenów takich jak dysk C: lub dysk D:. Pusty napęd, taki jak CD lub DVD, do którego nie włożono żadnego dysku, nie jest zawarty w tej tablicy. W systemach Mac OS i Linux ta metoda zawsze zwraca unikalny katalog główny komputera (katalog „/”).

W systemach plików, w których nie można odczytać katalogu głównego, na przykład w systemie plików systemu Android, właściwości zwróconego obiektu File mogą nie odzwierciedlać prawdziwych wartości. Na przykład właściwość spaceAvailable w systemie Android przyjmuje wartość 0.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Przenosi plik lub katalog z lokalizacji określonej przez obiekt File do lokalizacji określonej przez parametr destination.

Aby zmienić nazwę pliku, należy ustawić parametr destination tak, aby wskazywał na ścieżkę prowadzącą do katalogu pliku, lecz by nazwa pliku była inna.

Proces przenoszenia tworzy wymagane katalogi nadrzędne (jeżeli jest to możliwe).

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Rozpoczyna przenoszenie pliku lub katalogu z lokalizacji określonej przez obiekt File do lokalizacji określonej przez parametr newLocation.

Aby zmienić nazwę pliku, należy ustawić parametr destination tak, aby wskazywał na ścieżkę prowadzącą do katalogu pliku, lecz by nazwa pliku była inna.

Proces przenoszenia tworzy wymagane katalogi nadrzędne (jeżeli jest to możliwe).

Parametry

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Przenosi plik lub katalog do kosza.

Uwaga: w systemach operacyjnych, które nie obsługują folderu kosza umożliwiającego przywracanie, następuje natychmiastowe usunięcie plików.

Powiązane elementy interfejsu API

Przenosi asynchronicznie plik lub katalog do kosza.

Uwaga: W systemach operacyjnych, które nie obsługują folderu kosza umożliwiającego przywracanie, następuje natychmiastowe usunięcie plików.

Powiązane elementy interfejsu API

Otwiera plik w aplikacji zarejestrowanej przez system operacyjny w celu otwarcia pliku tego typu.

Środowisko AIR uniemożliwia użycie metody File.openWithDefaultApplication() w celu otwierania niektórych plików. W systemie Windows środowisko AIR uniemożliwia otwieranie plików określonych typów (pliki o określonych rozszerzeniach, wymienionych poniżej. W systemach Mac OS i Linux środowisko AIR uniemożliwia otwieranie plików uruchamianych w określonych aplikacjach, które wymieniono poniżej. Próba otwarcia jednego z tych plików za pomocą metody openWithDefaultApplication() spowoduje wyjątek. Jednak te ograniczenia nie dotyczą aplikacji AIR zainstalowanych za pomocą instalatora natywnego (rozszerzone profile aplikacji); mogą otwierać pliki dowolnych typów.

Nie można otwierać dokumentów z katalogu aplikacji.

W tabelach poniżej przedstawiono rozszerzenia plików, które są zabronione w systemie Windows, a także aplikacje zabronione w systemach Mac OS i Linux:

Powiązane elementy interfejsu API

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Wysyła żądanie udzielenia pozwolenia na dostęp do systemu plików.

Tworzy nowy obiekt File ze ścieżką względną w stosunku do ścieżki danego obiektu File w oparciu o parametr path (ciąg znaków).

Wartością parametru path jest ścieżka względna lub bezwzględna.

Jeśli zostanie określona ścieżka względna, określony parametr path jest dołączany na końcu ścieżki obiektu File. Jednak użycie znaków ".." w ścieżce path, może zwrócić wynikową ścieżkę, która nie jest pochodną obiektu File. Odniesienie wynikowe nie musi odnosić się do rzeczywistej lokalizacji systemu plików.

Jeśli zostanie określone odwołanie do ścieżki bezwzględnej, metoda zwróci obiekt File wskazujący na tę ścieżkę. W odniesieniu do ścieżki bezwzględnej powinna być stosowana poprawna składnia ścieżki rodzimej dla systemu operacyjnego, z którego korzysta użytkownik (np. "C:\\test" w systemie Windows). Nie należy stosować adresu URL (takiego jak „file:///c:/test") jako parametru path.

Wszystkie ścieżki wynikowe są normalizowane następująco:

• Każdy element ''." jest ignorowany.
• Każdy element ".." pobiera swój element nadrzędny.
• Brak ".." węzeł ten przekazuje odnośnik sięgający do katalogu głównego systemu plików lub głównego miejsca przechowywania trwałego dla aplikacji; jest to ignorowane.

Jako separatora ścieżek należy zawsze używać znaku ukośnika w prawo (/). W systemie Windows można użyć ukośnika (\), ale nie jest to zalecane. Użycie ukośnika może prowadzić do tego, że aplikacje nie będą działać na innych platformach.

W systemie Linux w nazwach plików i katalogów rozróżniana jest wielkość liter.

Parametry

Wywoływane, gdy zostanie anulowane trwające działanie asynchroniczne.

To zdarzenie ma następujące właściwości:

Wywoływane, gdy zakończy się działanie asynchroniczne.

To zdarzenie ma następujące właściwości:

Wywoływane, gdy lista katalogów jest dostępna jako wynik wywołania metody getDirectoryListingAsync().

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy wystąpi błąd podczas działania pliku asynchronicznego.

To zdarzenie ma następujące właściwości:

Rozsyłane, gdy aplikacja zażąda pozwolenia na dostęp do systemu plików. Sprawdź wartość właściwości status, aby zobaczyć, czy pozwolenie zostało udzielone czy nie.

Powiązane elementy interfejsu API

Wywoływane, gdy działanie narusza ograniczenia zabezpieczeń.

To zdarzenie ma następujące właściwości:

Wywoływane po wybraniu przez użytkownika pliku lub katalogu z okna dialogowego przeglądania plików lub katalogów.

To zdarzenie ma następujące właściwości:

Wywoływane po wybraniu przez użytkownika plików z okna dialogowego otworzonego za pomocą wywołania metody browseForOpenMultiple().

Powiązane elementy interfejsu API