Date  - AS3

Dzień miesiąca (liczba całkowita od 1 do 31) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Dzień miesiąca (liczba całkowita od 1 do 31) określony przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Dzień tygodnia (0 oznacza niedzielę, 1 - poniedziałek itd.) określony przez ten obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Dzień tygodnia (0 oznacza niedzielę, 1 - poniedziałek itd.) określony przez ten obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Pełny rok (liczba czterocyfrowa, jak np. 2000) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Czterocyfrowy rok określony przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Godzina (liczba całkowita od 0 do 23) dnia określona przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Godzina (liczba całkowita od 0 do 23) dnia określona przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Liczba milisekund (liczba całkowita od 0 do 999) określona przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Liczba milisekund (liczba całkowita od 0 do 999) określona przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Liczba minut (liczba całkowita od 0 do 59) określona przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Liczba minut (liczba całkowita od 0 do 59) określona przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Miesiąc (0 oznacza styczeń, 1 - luty itd.) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Miesiąc (od 0 [styczeń] do 11 [grudzień]) określony przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Liczba sekund (liczba całkowita od 0 do 59) określona przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

Liczba sekund (liczba całkowita od 0 do 59) określona przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

Liczba milisekund liczona od północy 1 stycznia 1970 (czasu uniwersalnego) do godziny określonej przez obiekt Date. Za pomocą tej metody można przedstawić określony punkt w czasie podczas porównania co najmniej dwóch obiektów Date.

Powiązane elementy interfejsu API

Różnica (w minutach) między czasem uniwersalnym (UTC) a lokalnym ustawionym na komputerze. Ta wartość określa liczbę minut, które należy dodać do lokalnego czasu ustawionego na komputerze, aby obliczyć czas UTC. Jeśli czas ustawiony na komputerze jest późniejszy od czasu UTC, ta wartość będzie ujemna.

Powiązane elementy interfejsu API

Tworzy nowy obiekt Date, który zawiera określoną datę i godzinę.

Konstruktor Date() może przyjąć do siedmiu parametrów (year, month, ..., millisecond) w celu określenia daty i godziny z dokładnością do milisekundy. Data zawarta w nowo utworzonym obiekcie Date zależy od liczby oraz typu danych przekazanych argumentów.

• W przypadku braku przekazania argumentów obiektowi Date zostaje przypisana bieżąca data i godzina.
• W przypadku przekazania jednego argumentu o typie danych Number do obiektu Date zostaje przypisana wartość czasu w oparciu o liczbę milisekund liczoną od 1 stycznia 1970 0:00:000 GMT, określoną przez ten pojedynczy argument.
• W przypadku przekazania jednego argumentu o typie danych String, gdzie ten ciąg znaków będzie zawierał poprawną datę, w obiekcie Date pojawi się wartość czasu w oparciu o tę datę.
• Przesłanie co najmniej dwóch argumentów spowoduje, że do obiektu Date zostanie przypisana wartość czasu w oparciu o przekazane wartości argumentów reprezentujące dla tej daty rok, miesiąc, dzień, godzinę, minutę, sekundę i milisekundy.

Data określona w ciągu znaków przekazanym do konstruktora klasy Date może być w wielu formatach. Musi jednak zawierać wartości przynajmniej dla dnia, miesiąca oraz roku. Na przykład ciąg Feb 1 2005 będzie poprawny, ale ciąg Feb 2005 już nie. Poniższa lista zawiera niektóre z poprawnych formatów:

• Dzień tygodnia Miesiąc Dzień Godzina:Minuta:Sekunda GMT Rok (na przykład, „Tue Feb 1 00:00:00 GMT-0800 2005”, który odpowiada metodzie toString())
• Dzień tygodnia Miesiąc Dzień Godzina:Minuta:Sekunda AM/PM (na przykład, „Tue Feb 1 2005 12:00:00 AM”, który odpowiada metodzie toLocaleString())
• Dzień tygodnia Miesiąc Dzień Rok (na przykład, „Tue Feb 1 2005”, który odpowiada metodzie toDateString())
• Miesiąc/Dzień/Rok (na przykład, „02/01/2005”)
• Miesiąc/Rok (na przykład „02/2005”)

Powiązane elementy interfejsu API

Zwraca dzień miesiąca (liczbę całkowitą z zakresu od 1 do 31) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

Zwraca dzień tygodnia (0 oznacza niedzielę, 1 - poniedziałek itd.) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

Zwraca pełny rok (liczbę czterocyfrową, np. 2000) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

Zwraca godzinę (liczbę całkowitą od 0 do 23) dnia określoną przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

Zwraca liczbę milisekund (liczbę całkowitą od 0 do 999) określoną przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var now:Date = new Date();
trace(now.getMilliseconds());

Zwraca liczbę minut (liczbę całkowitą od 0 do 59) określoną przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

Zwraca miesiąc (0 oznacza styczeń, 1 - luty itd.) określony przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

Zwraca liczbę sekund (liczbę całkowitą od 0 do 59) określoną przez obiekt Date (według czasu lokalnego). Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

var now:Date = new Date();
trace(now.getSeconds());

Zwraca liczbę milisekund od północy 1 stycznia 1970 (czasu uniwersalnego) do godziny określonej przez obiekt Date. Za pomocą tej metody można przedstawić określony punkt w czasie podczas porównania co najmniej dwóch obiektów Date.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }
 

Zwraca różnicę (w minutach) między czasem uniwersalnym (UTC) a czasem lokalnym na komputerze.

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

Zwraca dzień miesiąca (liczbę całkowitą od 1 do 31) określony przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

Zwraca dzień tygodnia (0 oznacza niedzielę, 1 - poniedziałek itd.) określony przez ten obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

Zwraca czterocyfrowy rok określony przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

Zwraca godzinę (liczbę całkowitą od 0 do 23) określoną przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Zwraca liczbę milisekund (liczbę całkowitą od 0 do 999) określoną przez obiekt Date (według czasu UTC).

var now:Date = new Date();
trace(now.getUTCMilliseconds());

Zwraca liczbę minut (liczbę całkowitą od 0 do 59) określoną przez obiekt Date (według czasu UTC).

var now:Date = new Date();
trace(now.getUTCMinutes());

Zwraca miesiąc (0 [styczeń] do 11 [grudzień]) określony przez obiekt Date (według czasu UTC).

Powiązane elementy interfejsu API

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

Zwraca liczbę sekund (liczbę całkowitą od 0 do 59) określoną przez obiekt Date (według czasu UTC).

var now:Date = new Date();
trace(now.getUTCSeconds());

Konwertuje ciąg reprezentujący datę w formie liczby milisekund, które upłynęły od 1 stycznia 1970 (według czasu UTC).

Parametry

     Day Mon DD HH:MM:SS TZD YYYY
     

     Wed Apr 12 15:30:17 GMT-0700 2006
     

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD
     

Powiązane elementy interfejsu API

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

Ustawia dzień miesiąca według czasu lokalnego i zwraca nowy czas w milisekundach. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Parametry

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

Ustawia rok według czasu lokalnego i zwraca nowy czas w milisekundach. Jeśli parametry month i day zostaną określone, ich wartość będzie zgodna z czasem lokalnym. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Wywołanie metody nie powoduje modyfikacji innych pól obiektu Date. Jednakże metody Date.getUTCDay() i Date.getDay() mogą zgłosić nową wartość w przypadku zmiany dnia tygodnia będącej wynikiem wywołania danej metody.

Parametry

Powiązane elementy interfejsu API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

Ustawia godzinę według czasu lokalnego i zwraca nowy czas w milisekundach. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Parametry

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

Ustawia milisekundy według czasu lokalnego i zwraca nowy czas w milisekundach. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Parametry

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

Ustawia minuty według czasu lokalnego i zwraca nowy czas w milisekundach. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Parametry

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

Ustawia miesiąc (opcjonalnie dzień miesiąca) według czasu lokalnego i zwraca nowy czas w milisekundach. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Parametry

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

Ustawia sekundy według czasu lokalnego i zwraca nowy czas w milisekundach. Określenie czasu lokalnego odbywa się w systemie operacyjnym, w którym uruchomione jest środowisko wykonawcze Flash.

Parametry

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

Ustawia datę w milisekundach liczonych od północy 1 stycznia 1970 i zwraca nowy czas w milisekundach.

Parametry

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

Ustawia dzień miesiąca zgodnie z uniwersalnym czasem UTC i zwraca nowy czas w milisekundach. Wywołanie tej metody nie powoduje modyfikacji innych pól obiektu Date . Jednakże metody Date.getUTCDay() i Date.getDay() mogą zgłosić nową wartość w przypadku zmiany dnia tygodnia będącej wynikiem wywołania danej metody.

Parametry

Powiązane elementy interfejsu API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

Ustawia rok według czasu uniwersalnego (UTC) i zwraca nowy czas w milisekundach.

Opcjonalnie za pomocą tej metody można również ustawić miesiąc i jego dzień. Wywołanie tej metody nie powoduje modyfikacji innych pól. Jednakże metody Date.getUTCDay() i Date.getDay() mogą zgłosić nową wartość, jeśli dzień tygodnia uległ zmianie w wyniku wywołania danej metody.

Parametry

Powiązane elementy interfejsu API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

Ustawia godzinę według czasu uniwersalnego (UTC) i zwraca nowy czas w milisekundach. Opcjonalnie można określić minuty, sekundy oraz milisekundy.

Parametry

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

Ustawia milisekundy zgodnie z czasem uniwersalnym (UTC) i zwraca nowy czas w milisekundach.

Parametry

var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

Ustawia minuty według czasu uniwersalnego (UTC) i zwraca nowy czas w milisekundach. Opcjonalnie można określić sekundy i milisekundy.

Parametry

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

Ustawia miesiąc (opcjonalnie dzień) według czasu uniwersalnego (UTC) i zwraca nowy czas w milisekundach. Wywołanie tej metody nie powoduje modyfikacji innych pól. Jednakże metody Date.getUTCDay() i Date.getDay() mogą zgłosić nową wartość, jeśli dzień tygodnia uległ zmianie w wyniku wywołania danej metody.

Parametry

Powiązane elementy interfejsu API

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

Ustawia sekundy (opcjonalnie milisekundy) według czasu uniwersalnego (UTC) i zwraca nowy czas w milisekundach.

Parametry

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

Zwraca tylko dzień i datę w postaci ciągu znaków, a nie zawiera informacji o czasie ani strefie czasowej. Porównanie z następującymi metodami:

• Date.toTimeString(), która zwraca tylko czas i strefę czasową.
• Date.toString(), która oprócz dnia i daty zwraca również czas i strefę czasową.

Powiązane elementy interfejsu API

var now:Date = new Date();
trace(now);
trace(now.toDateString());

Dostarcza możliwą do przesłonięcia metodę, która pozwala na dostosowywanie kodowania JSON wartości w obiekcie Date.

Metoda JSON.stringify() szuka metody toJSON() w każdym obiekcie, który przegląda. Jeżeli metoda toJSON() zostanie odnaleziona, metoda JSON.stringify() wywołuję ją dla każdej wartości, którą napotka, przekazując klucz będący w parze z tą wartością.

Obiekt Date zapewnia domyślną implementację metody toJSON() zwracającą dane wyjściowe metody Date.toString(). Klienci, którzy chcą eksportować obiekty Date do klasy JSON w dowolnym innym formacie, mogą dostarczyć swoje własne implementacje. Można to zrobić, ponownie definiując metodę toJSON() prototypu klasy.

Metoda toJSON() może zwracać wartość dowolnego typu. W przypadku zwrócenia obiektu metoda stringify() przeszukuje rekurencyjnie ten obiekt. Jeżeli metoda toJSON() zwraca ciąg, to metoda stringify() nie działania rekurencyjnie i kontynuuje przeglądanie.

Parametry

Powiązane elementy interfejsu API

Zwraca ciąg znaków reprezentujący tylko dzień i datę, nie dostarcza natomiast informacji o czasie i strefie czasowej. Ta metoda zwraca taką samą wartość jak metoda Date.toDateString. Porównanie z następującymi metodami:

• Date.toTimeString(), która zwraca tylko czas i strefę czasową.
• Date.toString(), która oprócz dnia i daty zwraca również czas i strefę czasową.

Powiązane elementy interfejsu API

Zwraca ciąg znaków reprezentujący dzień, datę i godzinę (według czasu lokalnego). Porównanie z metodą Date.toString(), która zwraca takie same dane (oraz dodatkowo dane strefy czasowej), gdzie rok umieszczony zostaje na końcu ciągu znaków.

Zwraca ciąg znaków reprezentujący tylko godzinę, a nie zawiera informacji o dniu, dacie, roku i strefie czasowej. Porównanie z metodą Date.toTimeString(), która zwraca czas i strefę czasową.

Powiązane elementy interfejsu API

Zwraca ciąg znaków reprezentujący dzień, datę, godzinę i strefę czasową. Format wyświetlanej daty jest następujący:

     Day Mon Date HH:MM:SS TZD YYYY
     

Na przykład:

     Wed Apr 12 15:30:17 GMT-0700 2006
     

var now:Date = new Date();
trace(now);

Zwraca tylko czas i strefę czasową w postaci ciągu znaków, a nie zawiera informacji o dniu ani dacie. Porównanie z metodą Date.toDateString(), która zwraca tylko dzień i datę.

Powiązane elementy interfejsu API

Zwraca ciąg znaków reprezentujący dzień, datę i godzinę (według uniwersalnego czasu UTC). Na przykład data 1 stycznia 2005 roku jest zwracana jako Tue Feb 1 00:00:00 2005 UTC.

Powiązane elementy interfejsu API

Zwraca liczbę milisekund między północą 1 stycznia 1970 (czasu uniwersalnego), a czasem określonym przez parametry. Ta metoda korzysta z czasu uniwersalnego, podczas gdy konstruktor Date korzysta z czasu lokalnego.

Ta metoda umożliwia przesłanie daty czasu uniwersalnego do konstruktora klasy Date. Ponieważ konstruktor klasy Date dopuszcza liczbę milisekund jako argument, za pomocą metody Date.UTC() można przekonwertować datę czasu uniwersalnego na odpowiednią liczbę milisekund i przesłać ją jako argument do konstruktora klasy Date:

Parametry

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

Zwraca liczbę milisekund od północy 1 stycznia 1970 (czasu uniwersalnego) do godziny określonej przez obiekt Date.