SimpleButton  - AS3

사용자가 hitTestState 객체를 선택할 때의 버튼 상태인 버튼 "다운" 상태를 나타내는 시각적 객체로 사용할 표시 객체를 지정합니다.

관련 API 요소

버튼의 활성 여부를 지정하는 부울 값입니다. 비활성화 상태인 경우, 즉 enabled 속성을 false로 설정한 경우 버튼을 볼 수는 있지만 클릭할 수는 없습니다. 기본값은 true입니다. 이 속성은 특정 부분을 탐색할 수 없게 하려는 경우에 유용합니다. 예를 들어 현재 표시된 페이지에서 버튼을 비활성화하여 해당 버튼을 클릭할 수 없고 페이지를 다시 로드할 수 없도록 할 수 있습니다.

참고: 버튼의 mouseClick을 방지하려면 enabled와 mouseEnabled 속성을 모두 false로 설정합니다.

버튼의 히트 테스트 객체로 사용할 표시 객체를 지정합니다. 기본 버튼의 경우, hitTestState 속성을 overState 속성과 동일한 표시 객체로 설정합니다. hitTestState 속성을 설정하지 않으면 SimpleButton이 비활성 상태가 되어 사용자 입력 이벤트에 응답하지 않습니다.

관련 API 요소

버튼 위에 포인터를 놓았을 때의 버튼 상태인 버튼 오버 상태를 나타내는 시각적 객체로 사용할 표시 객체를 지정합니다.

관련 API 요소

이 버튼에 할당된 SoundTransform 객체입니다. SoundTransform 객체에는 볼륨, 패닝, 왼쪽 스피커 할당, 오른쪽 스피커 할당 등을 설정할 수 있는 속성이 포함되어 있습니다. 이 SoundTransform 객체는 모든 버튼 상태에 적용되며, 포함된 사운드에만 영향을 줍니다.

관련 API 요소

SimpleButton 또는 MovieClip 등의 다른 표시 객체에서 사용자 입력 릴리스 이벤트를 수신할 수 있는지 여부를 나타냅니다. trackAsMenu 속성을 사용하면 메뉴를 만들 수 있습니다. 모든 SimpleButton 또는 MovieClip 객체에서 trackAsMenu 속성을 설정할 수 있습니다. trackAsMenu 속성이 존재하지 않는 경우 기본 비헤이비어는 false입니다.

trackAsMenu 속성은 언제든지 변경이 가능하며 변경된 버튼에는 즉시 새 비헤이비어가 적용됩니다.

버튼 위에 포인터를 놓지 않았을 때의 버튼 상태인 버튼 업 상태를 나타내는 시각적 객체로 사용할 표시 객체를 지정합니다.

관련 API 요소

true로 설정된 경우 버튼 위로 포인터를 가져가면 손 모양 커서가 표시되도록 하는 부울 값입니다. 이 속성이 false로 설정된 경우 화살표 모양 커서가 대신 표시됩니다. 기본값은 true입니다.

useHandCursor 속성은 언제든지 변경이 가능하며, 변경된 버튼에는 즉시 새 커서 비헤이비어가 적용됩니다.

새 SimpleButton 인스턴스를 만듭니다. 다양한 버튼 상태를 나타내는 표시 객체의 일부 또는 모두는 생성자에서 매개 변수로 설정될 수 있습니다.

1. SimpleButtonExample() 생성자에서 SimpleButton 유형의 새 CustomSimpleButton 객체 button이 만들어져 CustomSimpleButton 생성자 메서드를 호출합니다. button 객체가 표시 목록에 추가됩니다. 버튼의 색상과 크기는 다음 단계에서 결정됩니다.
2. CustomSimpleButton 클래스에서 인스턴스 속성을 선언합니다. 이 속성은 나중에 해당 상태를 기준으로 button의 크기와 배경색을 제어하는 데 사용됩니다. 일반 상태의 경우 주황색, 마우스를 위에 놓은 상태의 경우 어두운 노란색, 마우스를 아래에 놓은 상태의 경우 밝은 파란색입니다. button의 상태에 관계없이 해당 사각형의 크기는 size 속성을 사용하여 80픽셀로 설정됩니다.
3. CustomSimpleButton 클래스에 대한 생성자 함수가 downState, overState, upState, hitTestState 및 useHandCursor 속성을 ButtonDisplayState 클래스의 4개 인스턴스로 설정합니다.
4. ButtonDisplayState 클래스에서 생성자가 사각형의 크기와 배경색에 대한 값을 설정하고 draw() 메서드를 호출합니다.
5. draw() 메서드는 생성자에 설정된 크기와 배경색을 사용하여 버튼 상태를 기준으로 사각형을 다시 그립니다.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}