TextConverter - Adobe ActionScript® 3（AS3 ）API リファレンス

パッケージ	flashx.textLayout.conversion
クラス	public class TextConverter
継承	TextConverter Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

これは、インポートとエクスポートを処理するゲートウェイクラスです。Text Layout Framework の変換機能の一元的なアクセスポイントとなります。定義済みおよびユーザー定義の入力コンバーターや出力コンバーター用のレジストリ以外に、一連の変換メソッドが含まれます。

変換後のデータの形式は定義されていません。ユーザーが作成したコンバーターは、目的の形式を任意に受け入れて返すことができます。共通の形式は、ストリング、XML、および ByteArray インスタンスです。コンバーターの作成者は、どの形式がサポートされているかを文書化する必要があります。

例を表示

さらに例を参照

Creating a TextFlow object with the TextConverter class

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		numFormats : int [静的] [読み取り専用] 形式の名前。	TextConverter

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void [静的] 読み込み / 書き出し用の新しい形式を登録します。	TextConverter
		addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void [静的] 指定された位置における読み込み / 書き出し用の新しい形式を登録します。	TextConverter
		export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object [静的] TextFlow を指定された形式にエクスポートします。	TextConverter
		getExporter(format:String):flashx.textLayout.conversion:ITextExporter [静的] 書き出しコンバーターを作成して返します。その後、TextFlow からソースストリングまたは XML オブジェクトへの書き出しにこのコンバーターを使用できます。	TextConverter
		getFormatAt(index:int):String [静的] インデックス番目の形式の形式名を返します。	TextConverter
		getFormatDescriptorAt(index:int):FormatDescriptor [静的] インデックス番目の形式の FormatDescriptor を返します。	TextConverter
		getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter [静的] 読み込みコンバーターを作成して返します。その後、ソースストリング、XML オブジェクト、またはユーザー定義のデータ形式から TextFlow への読み込みにこのコンバーターを使用できます。	TextConverter
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow [静的] 指定された形式で、ソースコンテンツから TextFlow を作成します。	TextConverter
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		removeFormat(format:String):void [静的] 形式を削除します。	TextConverter
		removeFormatAt(index:int):void [静的] インデックス位置の形式を削除します。	TextConverter
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

パブリック定数

	定数		定義元
		PLAIN_TEXT_FORMAT : String = "plainTextFormat" [静的] プレーンテキスト形式です。	TextConverter
		TEXT_FIELD_HTML_FORMAT : String = "textFieldHTMLFormat" [静的] HTML 形式です。	TextConverter
		TEXT_LAYOUT_FORMAT : String = "textLayoutFormat" [静的] TextLayout 形式です。	TextConverter

プロパティの詳細

numFormats

プロパティ

numFormats:int [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

形式の名前。

実装
public static function get numFormats():int

メソッドの詳細

addFormat

()

メソッド

public static function addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

読み込み / 書き出し用の新しい形式を登録します。新しい形式は、末尾に最低優先度の形式として追加されます。位置は、外部クリップボードからの読み込み時などに、どの形式を使用するかについて複数の選択肢があるクライアントにとって重要です。新しい形式では、読み込みや書き出しをサポートできます。形式が既に追加されている場合、その形式は複数の位置に存在します。最初に見つかった形式が使用されます。

パラメーター

	`format:String` — 登録する読み込みコンバータークラスまたは null

	`importerClass:Class` — 登録する書き出しコンバータークラスまたは null

	`exporterClass:Class` — コンバータークラスにタグ付けする形式ストリング。形式には任意の名前を付けることができますが、一意にする必要があります。

	`clipboardFormat:String` — クリップボードとの間での変換時にクリップボード形式として使用されるストリング。形式でクリップボードアクセスがサポートされていない場合、これを null にします。

addFormatAt

()

メソッド

 public static function addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定された位置における読み込み / 書き出し用の新しい形式を登録します。位置は、外部クリップボードからの読み込み時などに、どの形式を使用するかについて複数の選択肢があるクライアントにとって重要です。数値が低いほど、優先度が高くなります。優先度の高いコンバーターが最初に試されます。新しい形式では、読み込みや書き出しをサポートできます。形式が既に追加されている場合、その形式は複数の位置に存在します。最初に見つかった形式が使用されます。

パラメーター

	`index:int` — 登録する読み込みコンバータークラスまたは null

	`format:String` — 登録する書き出しコンバータークラスまたは null

	`importerClass:Class` — コンバータークラスにタグ付けする形式ストリング

	`exporterClass:Class` (default = `null`) — クリップボードとの間での変換時にクリップボード形式として使用されるストリング。形式でクリップボードアクセスがサポートされていない場合、これを null にします。

	`clipboardFormat:String` (default = `null`)

export

()

メソッド

public static function export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

TextFlow を指定された形式にエクスポートします。

このクラスによって提供されている静的定数の 1 つ、MIME タイプ、またはユーザー定義のエクスポーター用のユーザー定義の形式を使用して、format パラメーターを指定します。

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

ConversionType クラスによって提供されている静的定数の 1 つ、またはユーザー定義のエクスポーター用のユーザー定義のデータタイプを使用して、書き出し後のデータのタイプを conversionType パラメーターで指定します。

ConversionType.STRING_TYPE
ConversionType.XML_TYPE

指定された形式での TextFlow の表現を返し、エラー時には null を返します。

パラメーター

	`source:flashx.textLayout.elements:TextFlow` — ソースコンテンツ

	`format:String` — 出力形式

	`conversionType:String` — エクスポートされたデータのタイプ

戻り値

Object — TextFlow のオブジェクトエクスポート形式、または null（エラー時）

getExporter

()

メソッド

public static function getExporter(format:String):flashx.textLayout.conversion:ITextExporter

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

書き出しコンバーターを作成して返します。その後、TextFlow からソースストリングまたは XML オブジェクトへの書き出しにこのコンバーターを使用できます。多数の個別エクスポートを実行する必要がある場合は、この関数を使用します。これは、flashx.textLayout.conversion.TextConverter.export() を呼び出すことと同じです。

このクラスによって提供されている静的定数の 1 つを使用して、format パラメーターを指定します。

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

形式が複数回追加されている場合は、最初に見つかった形式が使用されます。

パラメーター

format:String — エクスポートデータのターゲット形式です。

戻り値

flashx.textLayout.conversion:ITextExporter — 指定された形式で書き出し可能な ITextExporter テキストエクスポーターです。

例 ( この例の使用方法 )

次のコードスニペットは、getExporter メソッドを使用して、フォーマットされたテキストの繰り返しエクスポートを実行する方法を示しています。


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ConversionType;
    import flashx.textLayout.conversion.ITextExporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getExporter_example 
    {
        // Serialize the TextFlow into a String
        public function export(textFlow:TextFlow):String
        {
            var exporter:ITextExporter = TextConverter.getExporter(TextConverter.TEXT_LAYOUT_FORMAT);
            return exporter.export(textFlow, ConversionType.STRING_TYPE) as String;
        }
    }
}

getFormatAt

()

メソッド

public static function getFormatAt(index:int):String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

インデックス番目の形式の形式名を返します。

パラメーター

index:int

戻り値

String

getFormatDescriptorAt

()

メソッド

public static function getFormatDescriptorAt(index:int):FormatDescriptor

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

インデックス番目の形式の FormatDescriptor を返します。

パラメーター

index:int

戻り値

FormatDescriptor

getImporter

()

メソッド

 public static function getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

読み込みコンバーターを作成して返します。その後、ソースストリング、XML オブジェクト、またはユーザー定義のデータ形式から TextFlow への読み込みにこのコンバーターを使用できます。多数の個別読み込みを実行する必要がある場合、または読み込み中にエラーを処理する場合、このメソッドを使用します。これは、flashx.textLayout.conversion.TextConverter.importToFlow() を呼び出すことと同じです。

このクラスによって提供されている静的定数の 1 つを使用して format パラメーターを指定するか、MIME タイプまたはユーザー定義のデータ形式を使用します。

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

形式が複数回追加されている場合は、最初に見つかった形式が使用されます。

パラメーター

	`format:String` — ソースコンテンツの形式です。flashx.textLayout.conversion.TextConverter.TEXT_LAYOUT_FORMAT、PLAIN_TEXT_FORMAT、TEXT_FIELD_HTML_FORMAT などからの定数、MIME タイプ、またはユーザー定義の形式を使用します。

	`config:IConfiguration` (default = `null`) — このインポート中に使用する構成です。null は現在のデフォルトを使用することを示します。`ITextImporter.configuration` プロパティを使用して構成を設定することもできます。

戻り値

flashx.textLayout.conversion:ITextImporter — ソースデータを読み込みできる、ITextImporter テキストインポーター

例 ( この例の使用方法 )

次のコードスニペットは、getImporter メソッドを使用して、フォーマットされたテキストの繰り返しインポートを実行する方法を示しています。エラーは各 importToFlow の呼び出し開始時にクリアされます。


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ITextImporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getImporter_example 
    {
        public function importAndCheckErrors():TextFlow
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var importer:ITextImporter = TextConverter.getImporter(TextConverter.TEXT_LAYOUT_FORMAT);
            importer.throwOnError = false;
            var textFlow:TextFlow = importer.importToFlow(markup);
            if (!textFlow)
            {
                var errors:Vector.<String> = importer.errors;
                //deal with import errors
            }
            return textFlow;
        }
    }
}

importToFlow

()

メソッド

 public static function importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定された形式で、ソースコンテンツから TextFlow を作成します。

このクラスによって提供されている静的定数の 1 つ、または MIME タイプを使用して format パラメーターを指定するか、ユーザーが登録したインポーター用のユーザー定義の値を使用します。

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

パラメーター

	`source:Object` — ソースコンテンツ

	`format:String` — ソースコンテンツの形式

	`config:IConfiguration` (default = `null`) — 新規 TextFlow の作成時に使用する IConfiguration

戻り値

flashx.textLayout.elements:TextFlow — ソースから作成された TextFlow、または null（エラー時）

removeFormat

()

メソッド

public static function removeFormat(format:String):void

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

形式を削除します。形式が複数回追加されている場合は、最初に見つかった形式のみが削除されます。

パラメーター

format:String — 削除するコンバーター形式ストリング

removeFormatAt

()

メソッド

public static function removeFormatAt(index:int):void

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

インデックス位置の形式を削除します。

パラメーター

index:int — 削除する形式

定数の詳細

PLAIN_TEXT_FORMAT

定数

public static const PLAIN_TEXT_FORMAT:String = "plainTextFormat"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

プレーンテキスト形式です。これは、簡易なフォーマットされていないストリングからの TextFlow の作成、または TextFlow からの簡易なフォーマットされていないストリングの作成に使用します。

TEXT_FIELD_HTML_FORMAT

定数

public static const TEXT_FIELD_HTML_FORMAT:String = "textFieldHTMLFormat"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

HTML 形式です。これは、HTML 形式を使用する TextFlow との間でのインポートおよびエクスポートに使用します。Text Layout Framework HTML では、flash.text パッケージの TextField クラスでサポートされるタグと属性のサブセットがサポートされます。

次の表に、インポートおよびエクスポート処理でサポートされている HTML タグと属性を示します（TextField でサポートされ Text Layout Framework でサポートされないタグと属性については、その旨記載しています）。

タグ	説明
アンカータグ	`<a>` タグはハイパーリンクを作成するもので、次の属性を指定できます。 `target`：ページをロードする先のターゲットウィンドウの名前を指定します。オプションには、`_self`、`_blank`、`_parent`、および `_top` があります。`_self` オプションは現在のウィンドウ内の現在のフレームを指定します。`_blank` は新しいウィンドウを指定します。`_parent` は現在のフレームの親を指定します。`_top` は現在のウィンドウ内のトップレベルのフレームを指定します。 `href`：URL を指定します。URL は、ページをロードしている SWF ファイルの場所に対して絶対的でも相対的でもかまいません。 URL への絶対的な参照の例としては `http://www.adobe.com`、相対的な参照の例としては `/index.html` が挙げられます。絶対 URL には先頭に http:// を付けます。それがない場合は、相対 URL と見なされます。注意：TextField クラスと異なり、ActionScript の `link` イベントはサポートされません。`a:link`、`a:hover`、`a:active` スタイルもサポートされません。
ボールドタグ	`<b>` タグは、テキストをボールドで表示します。ボールド体を利用できるフォントで使用する必要があります。
ブレークタグ	`<br>` タグは、テキストに改行を作成します。
フォントタグ	`<font>` タグは、テキストを表示するフォントまたはフォントリストを指定します。フォントタグには、次の属性を指定できます。 `color`：16 進数のカラー（`#FFFFFF`）値のみがサポートされます。 `face`：使用するフォントの名前を指定します。次の例が示すように、カンマで区切られたフォント名の一覧を指定することもできます。その場合、Flash Player は最初に利用可能なフォントを選択します。指定したフォントがローカルのコンピューターシステムにインストールされていないか、または SWF ファイルに組み込まれていない場合、Flash Player は代替フォントを選択します。 `size`：フォントのサイズを指定します。絶対ピクセルサイズ（16 や 18 など）、または相対ポイントサイズ（+2 や -4 など）を使用できます。 `letterspacing`：各文字の右側に適用するトラッキング（手動カーニング）をピクセル単位で指定します。 `kerning`：カーニングが有効か無効かを指定します。0 以外の値を指定すると、カーニングが有効になります。0 を指定すると、カーニングが無効になります。
イメージタグ	`<img>` タグは、外部イメージファイル（JPEG、GIF、PNG）、SWF ファイル、およびムービークリップをテキスト内に埋め込みます。 `<img>` タグには、次の属性を指定できます。 `src`：イメージファイルまたは SWF ファイルへの URL、またはライブラリ内のムービークリップシンボルへのリンケージ識別子を指定します。この属性は必須です。他の属性はすべて省略可能です。外部ファイル（JPEG、GIF、PNG および SWF ファイル）は、完全にダウンロードされるまで表示されません。 `width`：挿入されるイメージ、SWF ファイル、またはムービークリップのピクセル単位の幅です。 `height`：挿入されるイメージ、SWF ファイル、またはムービークリップのピクセル単位の高さです。注意：TextField クラスと異なり、`align`、`hspace`、`vspace`、`id`、`checkPolicyFile の各属性はサポートされません。`
イタリックタグ	`<i>` タグは、指定されたテキストをイタリックで表示します。イタリック体を利用できるフォントで使用する必要があります。
リスト項目タグ	注意：TextField クラスと異なり、リスト項目タグはサポートされません。
段落タグ	`<p>` タグは新しい段落を作成します。`<p>` タグには、次の属性を指定できます。 align：段落内のテキストの行揃えを指定します。有効な値は、`left`、`right`、`justify`、および `center` です。 class：スタイル設定に使用できるクラス名を指定します。
範囲タグ	`<span>` タグには、次の属性を指定できます。 class：スタイル設定に使用できるクラス名を指定します。span タグは、スタイルシートで定義されたスタイルの設定によく使用されますが、TLFTextField インスタンスはスタイルシートをサポートしていません。span タグを TLFTextField で使用できるのは、style プロパティを使用してクラスを参照する場合です。また、`<span fontFamily="Arial">Hi there</span>` のように、span タグ内に直接プロパティを挿入することもできます。ただし、span タグのネストはサポートされていません。
テキストフォーマットタグ	`<textformat>` タグを使用すれば、テキストフィールド内において TextFormat クラスのいくつかの段落フォーマットプロパティ（行間、一行目インデント、インデント、タブストップなど）を指定できます。`<textformat>` タグは、ビルトイン HTML タグと組み合わせて使用できます。 `<textformat>` タグでは、次のような属性を指定できます。 `indent`：左インデントから段落の先頭文字までの一行目インデントを指定します。`TextFormat.indent` に相当します。正の数と負の数の両方を使用できます。 `blockindent`：段落内のすべての行に適用されるインデントを指定します。 `leftmargin`：段落の左インデントをポイント単位で指定します。`TextFormat.leftMargin` に相当します。 `rightmargin`：段落の右インデントをポイント単位で指定します。`TextFormat.rightMargin` に相当します。 `leading`：行のアセントと前の行のディセント間の行送り（行の高さ）をピクセル単位で指定します。 `tabstops`：段落のタブストップ位置を示すカンマ区切りのリストを指定します。
下線タグ	`<u>` タグを付けたテキストには下線が引かれます。

不明なタグが読み込まれると、textFieldHTMLFormat インポーターは、単一の FlowElement の typeName プロパティをそのタグ名に設定するか、DivElement または SubParagraphGroupElement を作成してその typeName プロパティをタグ名に設定します。

textFieldHTMLFormat エクスポーターは、typeName を XML タグとして書き出します（デフォルト値と異なる場合）。

TEXT_LAYOUT_FORMAT

定数

public static const TEXT_LAYOUT_FORMAT:String = "textLayoutFormat"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

TextLayout 形式です。これは、TextLayout マークアップ形式を使用する TextFlow との間でのインポートおよびエクスポートに使用します。Text Layout 形式は次のエラーを検出します。

予期しない名前空間
不明なエレメント
不明な属性

例この例の使用方法

TextConverter_example.as

次の例は、TextConverter 変換クラスの使用方法を示しています。標準マークアップ形式のテキストは TextFlow オブジェクトにインポートされてから表示されます。その後、テキストは XML 形式にエクスポートされます。

package flashx.textLayout.conversion.examples 
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.conversion.ConversionType;

    public class TextConverter_example extends Sprite
    {
        public function TextConverter_example()
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var textFlow:TextFlow = TextConverter.importToFlow(markup, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 50));
            textFlow.flowComposer.updateAllControllers();
            //export to XML
            var xmlOut:XML = TextConverter.export(textFlow,TextConverter.TEXT_LAYOUT_FORMAT, ConversionType.XML_TYPE) as XML;
        }
    }
}

法律上の注意 | プライバシーポリシー

TextConverter - AS3

クラス x

numFormats

addFormat

addFormatAt

export

getExporter

getFormatAt

getFormatDescriptorAt

getImporter

importToFlow

removeFormat

removeFormatAt

PLAIN_TEXT_FORMAT

TEXT_FIELD_HTML_FORMAT

TEXT_LAYOUT_FORMAT