PrintJobOptions

パッケージ	flash.printing
クラス	public class PrintJobOptions
継承	PrintJobOptions Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9

PrintJobOptions クラスには PrintJob.addPage() メソッドの options パラメーターと一緒に使用するプロパティが含まれています。addPage() の詳細については、PrintJob クラスを参照してください。

関連する API エレメント

PrintJob
PrintJob.addPage()

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		pixelsPerInch : Number = NaN ビットマップに使用する解像度を ppi（ピクセル/インチ）で指定します。	PrintJobOptions
		printAsBitmap : Boolean = false 印刷ジョブのコンテンツがビットマップとベクター形式のどちらで印刷されるかを指定します。	PrintJobOptions
		printMethod : String 最適な印刷方法が Flash ランタイムによって選択されるように指定するか、またはベクター形式あるいはビットマップ形式での印刷を作成者が明示的に選択するように指定します。	PrintJobOptions

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		PrintJobOptions(printAsBitmap:Boolean = false) 新しい PrintJobOptions オブジェクトを作成します。	PrintJobOptions
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

プロパティの詳細

pixelsPerInch

プロパティ

public var pixelsPerInch:Number = NaN

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

ビットマップに使用する解像度を ppi（ピクセル/インチ）で指定します。デフォルト値は Number.NaN で、ネイティブのプリンター解像度が使用されることを示します。

この解像度設定は、ビットマップ形式での印刷とベクター形式での印刷の両方で使用されます。ビットマップ形式で印刷する場合、解像度によって、ページ全体のラスタライズが制御されます。ベクター形式で印刷する場合、解像度によって、ビットマップやグラデーションなどの特定のコンテンツのラスタライズが制御されます。

printAsBitmap

プロパティ

public var printAsBitmap:Boolean = false

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9

印刷ジョブのコンテンツがビットマップとベクター形式のどちらで印刷されるかを指定します。デフォルト値は false で、ベクター形式で印刷されることを示します。

印刷するコンテンツにビットマップイメージが含まれる場合は、アルファ透明効果とカラー効果を含めるために printAsBitmap を true に設定します。コンテンツにビットマップイメージが含まれない場合は、より品質の高いベクター形式で印刷します（デフォルトのオプション）。

例えば、コンテンツをビットマップとして印刷するには、次のシンタックスを使用します。

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);

注意：Adobe AIR では、Mac OS のベクター形式印刷はサポートされていません。

関連する API エレメント

PrintJobOptions.printMethod

例 ( この例の使用方法 )

次の例は、画像をロードして矩形のフレームに配置した後、画像をビットマップとして印刷します。

コンストラクターによって画像（image.jpg）がロードされます。このとき、Loader オブジェクトと URLRequest オブジェクトが使用されます。また、ロード中にエラーが発生したかどうかが調べられます。ここでは、ファイルが SWF ファイルと同じディレクトリにあることを想定しています。SWF ファイルは、「ローカルでの再生に関するセキュリティ」を「ローカルファイルにのみアクセスする」に設定してコンパイルする必要があります。
画像がロード（イベントが完了）すると、completeHandler() メソッドが呼び出されます。
completeHandler() メソッドによって BitmapData オブジェクトが作成され、そのオブジェクトに画像（ビットマップ）がロードされます。Sprite オブジェクト（フレーム）に矩形が描画され、beginBitmapFill() メソッドを使用して矩形に画像（BitmapData オブジェクト）が表示されます。Matrix オブジェクトも使用され、矩形に合うようにイメージが拡大 / 縮小されます。これによってイメージが歪む場合があります。この例では、矩形に合うことを確認するために使用されています。イメージが表示されたら、printPage() メソッドが呼び出されます。
printPage() メソッドによって、印刷ジョブの新しいインスタンスが作成され、印刷処理が開始されます。この処理でユーザーに対して印刷ダイアログボックスが表示され、印刷ジョブのプロパティの値が設定されます。addPage() メソッドには、印刷ジョブに関する詳細な設定項目があります。ここでは、画像があるフレーム（Sprite オブジェクト）をベクター形式ではなくビットマップ形式として印刷するように設定されます。options は PrintJobOptions クラスのインスタンスです。その printAsBitmap プロパティは、ビットマップとして印刷するために true に設定されています（デフォルトの設定は false）。

注意：この例には、ごくわずかのエラー処理だけが定義されています。

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

printMethod

プロパティ

printMethod:String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

最適な印刷方法が Flash ランタイムによって選択されるように指定するか、またはベクター形式あるいはビットマップ形式での印刷を作成者が明示的に選択するように指定します。

このプロパティに、PrintMethod クラスで定義された次のいずれかの値を設定します。

PrintMethod.AUTO：印刷するコンテンツに基づいて、ベクター形式での印刷またはビットマップ形式での印刷が自動的に選択されるように指定します。ベクター形式の印刷方法でコンテンツが忠実に再現できる場合は、ベクター形式での印刷が使用されます。透明効果などの効果が含まれている場合は、ベクター形式ではなく、ビットマップ形式での印刷が使用されます。
PrintMethod.VECTOR：ベクター形式での印刷を指定します。この設定は、printAsBitmap を false に設定することと同じです。
PrintMethod.BITMAP：ビットマップ形式での印刷を指定します。printAsBitmap をtrue に設定することと同じです。

printMethod に、サポートされているこれらの値のいずれかが設定されると、printAsBitmap は無視されます。

デフォルト値は null で、printAsBitmap プロパティが使用されます。

実装
public function get printMethod():String
public function set printMethod(value:String):void

例外

ArgumentError — 指定された printMethod は、PrintMethod クラスで定義された値の 1 つではありません。

コンストラクターの詳細

()

コンストラクター

public function PrintJobOptions(printAsBitmap:Boolean = false)

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9

新しい PrintJobOptions オブジェクトを作成します。このオブジェクトを PrintJob.addPage() メソッドの options パラメーターに渡します。

パラメーター

printAsBitmap:Boolean (default = false) — true の場合、このオブジェクトはビットマップとして印刷されます。false の場合、このオブジェクトはベクターとして印刷されます。

印刷するコンテンツにビットマップイメージが含まれる場合は、アルファ透明効果とカラー効果を含めるために printAsBitmap プロパティを true に設定します。コンテンツにビットマップイメージが含まれない場合は、このパラメーターを省略して、より品質の高いベクター形式で印刷します（デフォルトオプション）。

注意：Adobe AIR では、Mac OS のベクター形式印刷はサポートされていません。

関連する API エレメント

PrintJob.addPage()

法律上の注意 | プライバシーポリシー

PrintJobOptions - AS3

パッケージx

言語エレメント

付録

パッケージ flash.printing

pixelsPerInch

printAsBitmap

printMethod

PrintJobOptions