| Pacchetto | flashx.textLayout.elements |
| Classe | public final class ParagraphElement |
| Ereditarietà | ParagraphElement  ParagraphFormattedElement FlowGroupElement FlowElement Object |
| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Proprietà MXML predefinitamxmlChildren
Altri esempi
Elementi API correlati
Proprietà pubbliche
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditateMetodi pubblici
| Metodo | Definito da | ||
|---|---|---|---|
Funzione di costruzione - rappresenta un paragrafo in un flusso di testo. | ParagraphElement | ||
 |
Aggiunge un oggetto FlowElement secondario. | FlowGroupElement | |
|
Aggiunge un oggetto FlowElement secondario nella posizione di indice specificata. | FlowGroupElement | |
| Cancella lo stile specificato dal parametro styleProp da questo oggetto FlowElement. | FlowElement | |
|
Crea una copia profonda di questo oggetto FlowElement, inclusi gli eventuali elementi secondari, copiando il contenuto tra le due posizioni di caratteri specificate e restituendo la copia come oggetto FlowElement. | FlowElement | |
| Confronta gli oggetti userStyles con gli oggetti userStyles di otherElement. | FlowElement | |
|
Data una posizione di testo relativa, trova l'indice del primo FlowElement secondario che contiene la posizione relativa. | FlowGroupElement | |
|
Data una posizione di testo relativa, trova l'elemento foglia che contiene la posizione relativa. | FlowGroupElement | |
Scorre in avanti dalla posizione fornita per individuare la posizione nel testo dell'atomo successivo, quindi restituisce l'indice. | ParagraphElement | ||
Restituisce l'indice del limite della parola successiva nel testo. | ParagraphElement | ||
Scorre indietro dalla posizione fornita per individuare la posizione nel testo dell'atomo precedente, quindi restituisce l'indice. | ParagraphElement | ||
Restituisce l'indice del limite della parola precedente nel testo. | ParagraphElement | ||
|
Restituisce la posizione di inizio dell'elemento nel flusso di testo come un indice assoluto. | FlowElement | |
|
Restituisce il carattere nella posizione specificata, relativa a questo oggetto FlowElement. | FlowElement | |
| Restituisce il codice di carattere nella posizione specificata, relativa a questo oggetto FlowElement. | FlowElement | |
|
Restituisce l'oggetto secondario FlowElement nella posizione di indice specificata. | FlowGroupElement | |
|
Cerca l'oggetto FlowElement specificato tra gli oggetti secondari e restituisce la relativa posizione di indice. | FlowGroupElement | |
|
Restituisce l'inizio di questo elemento relativo a un elemento antenato. | FlowElement | |
|
Restituisce il primo FlowLeafElement discendente di questo gruppo. | FlowGroupElement | |
|
Restituisce l'ultimo FlowLeafElement discendente di questo gruppo. | FlowGroupElement | |
Restituisce il paragrafo che segue quello corrente, oppure null se non sono presenti altri paragrafi. | ParagraphElement | ||
| Restituisce il successivo oggetto FlowElement di pari livello nella gerarchia del flusso di testo. | FlowElement | |
|
Restituisce l'oggetto ParagraphElement associato a questo elemento. | FlowElement | |
Restituisce il paragrafo che precede quello corrente, oppure null se il paragrafo corrente è il primo in TextFlow. | ParagraphElement | ||
| Restituisce il precedente oggetto FlowElement di pari livello nella gerarchia del flusso di testo. | FlowElement | |
| Restituisce il valore dello stile specificato dal parametro styleProp, che specifica il nome dello stile e può includere il nome di qualsiasi userStyle. | FlowElement | |
| [override] | FlowGroupElement | |
|
Risale la gerarchia del flusso di testo per restituire l'oggetto TextFlow radice per l'elemento. | FlowElement | |
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
| Chiamato per gli oggetti MXML dopo che è stato creato l'oggetto di implementazione e tutte le proprietà del componente specificate nel tag MXML sono state inizializzate. | FlowElement | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
|
Rimuove l'oggetto secondario FlowElement specificato dal gruppo. | FlowGroupElement | |
|
Rimuove l'oggetto secondario FlowElement nella posizione di indice specificata. | FlowGroupElement | |
|
Sostituisce gli elementi secondari nel gruppo con i nuovi elementi specificati. | FlowGroupElement | |
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
| Imposta lo stile specificato dal parametro styleProp sul valore specificato dal parametro newValue. | FlowElement | |
|
Crea una copia di questo oggetto FlowElement, copiando il contenuto tra le due posizioni di caratteri specificate. | FlowElement | |
|
Divide questo oggetto nella posizione specificata dal parametro childIndex. | FlowGroupElement | |
|
Divide questo oggetto FlowElement in corrispondenza della posizione specificata dal parametro relativePosition, che corrisponde a una posizione relativa nel testo per questo elemento. | FlowElement | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
|
Restituisce la rappresentazione in formato stringa dell'oggetto specificato. | Object | |
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
Descrizione della funzione di costruzione
ParagraphElement | () | Funzione di costruzione |
public function ParagraphElement()| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Funzione di costruzione - rappresenta un paragrafo in un flusso di testo.
Descrizione dei metodi
findNextAtomBoundary | () | metodo |
public function findNextAtomBoundary(relativePosition:int):int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Scorre in avanti dalla posizione fornita per individuare la posizione nel testo dell'atomo successivo, quindi restituisce l'indice. Il termine atomo rappresenta sia gli elementi grafici che i caratteri (inclusi i gruppi tipografici di caratteri combinati), ovvero le entità indivisibili che compongono una riga di testo.
Parametri
relativePosition:int — posizione nel testo da cui iniziare, contando da 0
|
int — indice nel testo dell'atomo successivo
|
Elementi API correlati
Esempio ( Come utilizzare questo esempio )
In questo esempio vengono trovati i limiti dell'atomo successivo da determinati offset in un paragrafo.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextAtomBoundary extends Sprite
{
public function ParagraphElement_findNextAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next atom boundaries from offsets 5 and 10
var atomBoundary:int = paragraph.findNextAtomBoundary(4);
trace(atomBoundary); // 5
atomBoundary = paragraph.findNextAtomBoundary(10);
trace(atomBoundary); // 11
}
}
}
findNextWordBoundary | () | metodo |
public function findNextWordBoundary(relativePosition:int):int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce l'indice del limite della parola successiva nel testo.
Scorre in avanti dalla posizione fornita per individuare la posizione successiva nel testo che inizia o termina una parola.
Parametri
relativePosition:int — posizione nel testo da cui iniziare, contando da 0
|
int — indice nel testo del limite della parola successiva
|
Esempio ( Come utilizzare questo esempio )
In questo esempio vengono trovati i limiti della parola successiva in un paragrafo da determinati offset.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextWordBoundary extends Sprite
{
public function ParagraphElement_findNextWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findNextWordBoundary(0);
trace(wordBoundary); // 5
wordBoundary = paragraph.findNextWordBoundary(12);
trace(wordBoundary); // 13
}
}
}
findPreviousAtomBoundary | () | metodo |
public function findPreviousAtomBoundary(relativePosition:int):int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Scorre indietro dalla posizione fornita per individuare la posizione nel testo dell'atomo precedente, quindi restituisce l'indice. Il termine atomo rappresenta sia gli elementi grafici che i caratteri (inclusi i gruppi tipografici di caratteri combinati), ovvero le entità indivisibili che compongono una riga di testo.
Parametri
relativePosition:int — posizione nel testo da cui iniziare, contando da 0
|
int — indice nel testo del gruppo precedente
|
Elementi API correlati
Esempio ( Come utilizzare questo esempio )
In questo esempio vengono trovati i limiti dell'atomo precedente da determinati offset in un paragrafo.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousAtomBoundary extends Sprite
{
public function ParagraphElement_findPreviousAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous atom boundaries from offsets 6 and 13
var atomBoundary:int = paragraph.findPreviousAtomBoundary(6);
trace(atomBoundary); // 5
atomBoundary = paragraph.findPreviousAtomBoundary(13);
trace(atomBoundary); // 12
}
}
}
findPreviousWordBoundary | () | metodo |
public function findPreviousWordBoundary(relativePosition:int):int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce l'indice del limite della parola precedente nel testo.
Scorre indietro dalla posizione fornita per individuare la posizione precedente nel testo che inizia o termina una parola.
Parametri
relativePosition:int — posizione nel testo da cui iniziare, contando da 0
|
int — indice nel testo del limite della parola precedente
|
Esempio ( Come utilizzare questo esempio )
In questo esempio vengono trovati i limiti della parola precedente in un paragrafo da determinati offset.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousWordBoundary extends Sprite
{
public function ParagraphElement_findPreviousWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findPreviousWordBoundary(22);
trace(wordBoundary); // 17
wordBoundary = paragraph.findPreviousWordBoundary(11);
trace(wordBoundary); // 6
}
}
}
getNextParagraph | () | metodo |
public function getNextParagraph():ParagraphElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce il paragrafo che segue quello corrente, oppure null se non sono presenti altri paragrafi.
RestituisceParagraphElement — il paragrafo successivo o null se non sono presenti altri paragrafi.
|
Elementi API correlati
Esempio ( Come utilizzare questo esempio )
In questo esempio vengono importati tre paragrafi di testo dal codice xml, viene eseguito l'accesso al primo paragrafo utilizzando getChildAtIndex(0) e viene utilizzato getNextParagraph() per accedere al secondo paragrafo.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getNextParagraph extends Sprite
{
public function ParagraphElement_getNextParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get first paragraph
var p:ParagraphElement = textFlow.getChildAt(0) as ParagraphElement;
// get next paragraph and display its content
var nextParagraph:ParagraphElement = p.getNextParagraph();
trace("nextParagraph.text is: " + nextParagraph.getText());
}
}
}
getPreviousParagraph | () | metodo |
public function getPreviousParagraph():ParagraphElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce il paragrafo che precede quello corrente, oppure null se il paragrafo corrente è il primo in TextFlow.
RestituisceParagraphElement |
Elementi API correlati
Esempio ( Come utilizzare questo esempio )
In questo esempio vengono importati tre paragrafi di testo dal codice xml, viene eseguito l'accesso al secondo paragrafo utilizzandogetChildAtIndex(1) e viene utilizzato getPreviousParagraph() per accedere al primo paragrafo.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getPreviousParagraph extends Sprite
{
public function ParagraphElement_getPreviousParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get second paragraph (first = 0)
var p:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
// get previous paragraph and display its content
var prevParagraph:ParagraphElement = p.getPreviousParagraph();
trace("prevParagraph.text is: " + prevParagraph.getText());
}
}
}
ParagraphElementExample.as
In questo esempio vengono creati e formattati tre paragrafi di testo.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flash.text.engine.FontPosture;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.formats.TextLayoutFormat;
public class ParagraphElementExample extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// Create Strings of text for the paragraphs
private var para1String:String = "In the first paragraph of a "
private var para1String2:String = "cheap"
private var para1String3:String ="Western novel, a cowboy meets a saloon girl.";
private var para2String:String = "In the middle of the cheap novel a really bad guy, "+
"who is having a relationship with the saloon girl, sees the cowboy help "+
"her onto her horse as she smiles at him warmly."
private var para3String:String = "In the last paragraph of the cheap novel, the cowboy kills "+
"the really bad guy in a shootout in the middle of main street and "+
"then rides into the sunset with the saloon girl on the back of his horse.";
public function ParagraphElementExample()
{
// create a TextLayoutFormat object to use in formatting the paragraphs
var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
var paragraph1:ParagraphElement = new ParagraphElement();
// create the ParagraphElement objects
var paragraph2:ParagraphElement = new ParagraphElement();
var paragraph3:ParagraphElement = new ParagraphElement();
// create the SpanElement objects to hold the content of the paragraphs
var p1Span1:SpanElement = new SpanElement();
var p1Span2:SpanElement = new SpanElement();
var p1Span3:SpanElement = new SpanElement();
var p2Span:SpanElement = new SpanElement();
var p3Span:SpanElement = new SpanElement();
// assign the strings of text for the 1st paragraph to spans
p1Span1.text = para1String;
p1Span2.text = para1String2;
p1Span2.fontStyle = FontPosture.ITALIC; // italicize 'cheap'
p1Span3.text = para1String3;
// add spans to first paragraph
paragraph1.addChild(p1Span1);
paragraph1.addChild(p1Span2);
paragraph1.addChild(p1Span3);
// assign the string of text for the 2nd paragraph to a span
// and add the span to the second paragraph
p2Span.text = para2String;
paragraph2.addChild(p2Span);
// assign the string of text for the 3rd paragraph to a span
// and add the span to the third paragraph
p3Span.text = para3String;
paragraph3.addChild(p3Span);
// add the paragraphs to the TextFlow
textFlow.addChild(paragraph1);
textFlow.addChild(paragraph2);
textFlow.addChild(paragraph3);
// set the text formatting properties
textLayoutFormat.fontSize = 14;
textLayoutFormat.textIndent = 15;
textLayoutFormat.paragraphSpaceAfter = 15;
textLayoutFormat.paddingTop = 4;
textLayoutFormat.paddingLeft = 4;
// assign the format object to the TextFlow
textFlow.hostFormat = textLayoutFormat;
// assign a controller to the stage and update it to compose and
// display the text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
ParagraphElementExample2.as
In questo esempio viene importato codice in un oggetto TextFlow. Il codice xml definisce gli stessi tre paragrafi di testo e la relativa formattazione dell'esempio precedente.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
public class ParagraphElementExample2 extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// xml markup that defines the attributes and contents of a text flow
private var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>In the first paragraph of a </flow:span>"+
"<flow:span fontStyle=\"italic\">cheap</flow:span>"+
"<flow:span> Western novel, a cowboy meets a saloon girl.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the middle of the cheap novel a really bad guy, </flow:span>"+
"<flow:span>who is having a relationship with the saloon girl, sees the cowboy help </flow:span>"+
"<flow:span>her onto her horse as she smiles at him warmly.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the last paragraph of the cheap novel, the cowboy kills the really </flow:span>"+
"<flow:span> bad guy in a shootout in the middle of main street and then rides into the sunset with </flow:span>"+
"<flow:span>the saloon girl on the back of his horse.</flow:span>" +
"</flow:p>"+
"</flow:TextFlow>";
public function ParagraphElementExample2()
{
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
Tue Jun 12 2018, 02:44 PM Z