| Pacchetto | flashx.textLayout.elements |
| Classe | public class FlowGroupElement |
| Ereditarietà | FlowGroupElement  FlowElement Object |
| Sottoclassi | ParagraphFormattedElement, SubParagraphGroupElementBase |
| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Non potete creare direttamente un oggetto FlowGroupElement. Una chiamata a new FlowGroupElement() genera un'eccezione di tipo Error.
Proprietà MXML predefinitamxmlChildren
Elementi API correlati
Proprietà pubbliche
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate| Proprietà | Definito da | ||
|---|---|---|---|
 | alignmentBaseline : *
TextLayoutFormat: specifica la linea di base a cui deve allinearsi la linea di base dominante. | FlowElement | |
| backgroundAlpha : *
TextLayoutFormat: valore alfa (trasparenza) per lo sfondo (adotta il valore predefinito se undefined durante la cascata). | FlowElement | |
| backgroundColor : *
TextLayoutFormat: colore di sfondo del testo (adotta il valore predefinito se undefined durante la cascata). | FlowElement | |
| baselineShift : *
TextLayoutFormat: quantità di spostamento della linea di base dal valore dominantBaseline. | FlowElement | |
| blockProgression : *
TextLayoutFormat: specifica un avanzamento orizzontale o verticale del posizionamento delle righe. | FlowElement | |
| breakOpportunity : *
TextLayoutFormat: controlla il punto in cui sono consentite le interruzioni di riga quando il testo con a capo automatico viene suddiviso su più righe. | FlowElement | |
| cffHinting : *
TextLayoutFormat: il tipo di approssimazione CFF utilizzato per questo testo. | FlowElement | |
| clearFloats : *
TextLayoutFormat: controlla il modo in cui il testo scorre intorno a un float. | FlowElement | |
| color : *
TextLayoutFormat: colore del testo. | FlowElement | |
| columnCount : *
TextLayoutFormat: numero di colonne di testo (utilizza il valore predefinito se è undefined durante la cascata). | FlowElement | |
| columnGap : *
TextLayoutFormat: specifica la quantità di spazio per il margine, espressa in pixel, da lasciare tra le colonne (utilizza il valore predefinito se è undefined durante la cascata). | FlowElement | |
| columnWidth : *
TextLayoutFormat: la larghezza della colonna è espressa in pixel (utilizza il valore predefinito se è undefined durante la cascata). | FlowElement | |
| computedFormat : flashx.textLayout.formats:ITextLayoutFormat [sola lettura]
Restituisce gli attributi del formato calcolato attivi per questo elemento. | FlowElement | |
| constructor : Object
Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. | Object | |
| coreStyles : Object [sola lettura] Restituisce il coreStyles per questo FlowElement. | FlowElement | |
| digitCase : *
TextLayoutFormat: Il tipo di cifre (ascendenti/discendenti) utilizzato per questo testo. | FlowElement | |
| digitWidth : *
TextLayoutFormat: il tipo di larghezza delle cifre (ascendenti/discendenti) utilizzato per questo testo. | FlowElement | |
| direction : *
TextLayoutFormat: specifica il livello di incorporamento bidirezionale predefinito del testo nel blocco di testo. | FlowElement | |
| dominantBaseline : *
TextLayoutFormat: specifica quale linea di base dell'elemento si aggancia ad alignmentBaseline per determinare la posizione verticale dell'elemento sulla riga. | FlowElement | |
| firstBaselineOffset : *
TextLayoutFormat: specifica la posizione della linea di base della prima riga nel contenitore. | FlowElement | |
| fontFamily : *
TextLayoutFormat: il nome del carattere da utilizzare o un elenco di nomi di caratteri separati da virgola. | FlowElement | |
| fontLookup : *
TextLayoutFormat: la ricerca di caratteri da utilizzare. | FlowElement | |
| fontSize : *
TextLayoutFormat: la dimensione del testo in pixel. | FlowElement | |
| fontStyle : *
TextLayoutFormat: lo stile del testo. | FlowElement | |
| fontWeight : *
TextLayoutFormat: lo spessore del testo. | FlowElement | |
| format : flashx.textLayout.formats:ITextLayoutFormat Le proprietà TextLayoutFormat applicate direttamente a questo elemento. | FlowElement | |
| id : String
Assegna un nome identificativo all'elemento, rendendo possibile l'impostazione di uno stile per l'elemento mediante un riferimento all'id. | FlowElement | |
| justificationRule : *
TextLayoutFormat: la regola utilizzata per la giustificazione del testo in un paragrafo. | FlowElement | |
| justificationStyle : *
TextLayoutFormat: lo stile utilizzato per la giustificazione del paragrafo. | FlowElement | |
| kerning : *
TextLayoutFormat: le crenature regolano i pixel tra determinate coppie di caratteri per migliorare la leggibilità. | FlowElement | |
| leadingModel : *
TextLayoutFormat: specifica il modello di interlinea, che corrisponde a una combinazione di base e direzione dell'interlinea. | FlowElement | |
| ligatureLevel : *
TextLayoutFormat: controlla quali legature definite nel carattere possono essere utilizzate nel testo. | FlowElement | |
| lineBreak : *
TextLayoutFormat: controlla il ritorno a capo automatico all'interno del contenitore (adotta il valore predefinito se undefined durante la cascata). | FlowElement | |
| lineHeight : *
TextLayoutFormat: controllo di interlinea (Leading) per il testo. | FlowElement | |
| lineThrough : *
TextLayoutFormat: se true, applica il carattere barrato, ovvero una linea tracciata a metà del testo. | FlowElement | |
| linkActiveFormat : *
TextLayoutFormat: definisce gli attributi di formattazione utilizzati per i collegamenti nello stato normal. | FlowElement | |
| linkHoverFormat : *
TextLayoutFormat: definisce gli attributi di formattazione utilizzati per i collegamenti nello stato hover, quando il mouse è all'interno dei limiti di un collegamento (rollover). | FlowElement | |
| linkNormalFormat : *
TextLayoutFormat: definisce gli attributi di formattazione utilizzati per i collegamenti nello stato normal. | FlowElement | |
| listAutoPadding : *
TextLayoutFormat: specifica un rientro automatico per il bordo iniziale degli elenchi quando il valore di riempimento dell'elenco su quel lato è auto. | FlowElement | |
| listMarkerFormat : *
TextLayoutFormat: definisce i marcatori di elenco degli attributi di formattazione. | FlowElement | |
| listStylePosition : *
TextLayoutFormat: i valori validi sono ListStylePosition.INSIDE, ListStylePosition.OUTSIDE, FormatValue.INHERIT. Il valore predefinito è undefined e indica che non è impostato. Se durante la cascata i valori sono undefined, questa proprietà erediterà il valore da un elemento antenato. | FlowElement | |
| listStyleType : *
TextLayoutFormat: i valori validi sono ListStyleType.UPPER_ALPHA, ListStyleType.LOWER_ALPHA, ListStyleType.UPPER_ROMAN, ListStyleType.LOWER_ROMAN, ListStyleType.NONE, ListStyleType.DISC, ListStyleType.CIRCLE, ListStyleType.SQUARE, ListStyleType.BOX, ListStyleType.CHECK, ListStyleType.DIAMOND, ListStyleType.HYPHEN, ListStyleType.ARABIC_INDIC, ListStyleType.BENGALI, ListStyleType.DECIMAL, ListStyleType.DECIMAL_LEADING_ZERO, ListStyleType.DEVANAGARI, ListStyleType.GUJARATI, ListStyleType.GURMUKHI, ListStyleType.KANNADA, ListStyleType.PERSIAN, ListStyleType.THAI, ListStyleType.URDU, ListStyleType.CJK_EARTHLY_BRANCH, ListStyleType.CJK_HEAVENLY_STEM, ListStyleType.HANGUL, ListStyleType.HANGUL_CONSTANT, ListStyleType.HIRAGANA, ListStyleType.HIRAGANA_IROHA, ListStyleType.KATAKANA, ListStyleType.KATAKANA_IROHA, ListStyleType.LOWER_ALPHA, ListStyleType.LOWER_GREEK, ListStyleType.LOWER_LATIN, ListStyleType.UPPER_ALPHA, ListStyleType.UPPER_GREEK, ListStyleType.UPPER_LATIN, FormatValue.INHERIT. Il valore predefinito è undefined e indica che non è impostato. Se durante la cascata i valori sono undefined, questa proprietà erediterà il valore da un elemento antenato. | FlowElement | |
| locale : *
TextLayoutFormat: le impostazioni internazionali del testo. | FlowElement | |
| mxmlChildren : Array
Aggiunge un array di elementi secondari a questo oggetto. | FlowGroupElement | ||
| numChildren : int [sola lettura]
Restituisce il numero di elementi FlowElement secondari di questo oggetto FlowGroupElement. | FlowGroupElement | ||
| paddingBottom : *
TextLayoutFormat: margine inferiore in pixel. | FlowElement | |
| paddingLeft : *
TextLayoutFormat: margine sinistro in pixel. | FlowElement | |
| paddingRight : *
TextLayoutFormat: margine destro in pixel. | FlowElement | |
| paddingTop : *
TextLayoutFormat: margine superiore in pixel. | FlowElement | |
| paragraphEndIndent : *
TextLayoutFormat: un numero che specifica, in pixel, la quantità di rientro del bordo finale del paragrafo. | FlowElement | |
| paragraphSpaceAfter : *
TextLayoutFormat: un numero che specifica la quantità di spazio, in pixel, da lasciare dopo il paragrafo. | FlowElement | |
| paragraphSpaceBefore : *
TextLayoutFormat: un numero che specifica la quantità di spazio, in pixel, da lasciare prima del paragrafo. | FlowElement | |
| paragraphStartIndent : *
TextLayoutFormat: un numero che specifica, in pixel, la quantità di rientro del bordo iniziale del paragrafo. | FlowElement | |
| parent : FlowGroupElement [sola lettura] Restituisce l'elemento principale di questo oggetto FlowElement. | FlowElement | |
| parentRelativeEnd : int [sola lettura] Restituisce la fine relativa di questo oggetto FlowElement nell'elemento principale. | FlowElement | |
| parentRelativeStart : int [sola lettura] Restituisce l'inizio relativo di questo oggetto FlowElement nell'elemento principale. | FlowElement | |
| renderingMode : *
TextLayoutFormat: la modalità di rendering utilizzata per questo testo. | FlowElement | |
| styleName : *
TextLayoutFormat: assegna una classe identificativa all'elemento, rendendo possibile l'impostazione di uno stile per l'elemento mediante un riferimento allo styleName. | FlowElement | |
| styles : Object [sola lettura] Restituisce gli stili per questo FlowElement. | FlowElement | |
| tabStops : *
TextLayoutFormat: specifica le tabulazioni associate al paragrafo. | FlowElement | |
| textAlign : *
TextLayoutFormat: l'allineamento delle righe nel paragrafo in relazione al contenitore. | FlowElement | |
| textAlignLast : *
TextLayoutFormat: l'allineamento dell'ultima o della sola riga nel paragrafo in relazione al contenitore con testo giustificato. | FlowElement | |
| textAlpha : *
TextLayoutFormat: valore alfa (trasparenza) per il testo. | FlowElement | |
| textDecoration : *
TextLayoutFormat: la formattazione del testo. | FlowElement | |
| textIndent : *
TextLayoutFormat: un valore Number che specifica, in pixel, la quantità di rientro della prima riga del paragrafo. | FlowElement | |
| textJustify : *
TextLayoutFormat: specifica le opzioni per la giustificazione del testo. | FlowElement | |
| textLength : int [sola lettura]
Restituisce la lunghezza totale del testo appartenente a questo oggetto FlowElement e dei relativi elementi secondari. | FlowElement | |
| textRotation : *
TextLayoutFormat: determina il numero di gradi di rotazione di questo testo. | FlowElement | |
| tracking : Object [sola scrittura]
Imposta il tracciamento ed è sinonimo della proprietà trackingRight. | FlowElement | |
| trackingLeft : *
TextLayoutFormat: numero espresso in pixel (o percentuale di fontSize, ad esempio 120%) che indica la quantità di tracciamento (crenatura manuale) da applicare a sinistra di ogni carattere. | FlowElement | |
| trackingRight : *
TextLayoutFormat: numero espresso in pixel (o percentuale di fontSize, ad esempio 120%) che indica la quantità di tracciamento (crenatura manuale) da applicare a destra di ogni carattere. | FlowElement | |
| typeName : String
Ogni FlowElement ha un typeName. | FlowElement | |
| typographicCase : *
TextLayoutFormat: il tipo di carattere tipografico (maiuscolo/minuscolo) utilizzato per questo testo. | FlowElement | |
| userStyles : Object Consente di lettere e scrivere stili utente in un oggetto FlowElement. | FlowElement | |
| verticalAlign : *
TextLayoutFormat: allineamento verticale o giustificazione (utilizza il valore predefinito se è undefined durante la cascata). | FlowElement | |
| whiteSpaceCollapse : *
TextLayoutFormat: comprime o mantiene gli spazi vuoti durante l'importazione del testo in un oggetto TextFlow. | FlowElement | |
| wordSpacing : *
TextLayoutFormat: specifica la spaziatura ottimale, minima e massima (come moltiplicatore della larghezza di uno spazio normale) da utilizzare tra le parole durante la giustificazione. | FlowElement | |
Metodi pubblici
| Metodo | Definito da | ||
|---|---|---|---|
Classe base - una chiamata a new FlowGroupElement() genera un'eccezione di tipo Error. | FlowGroupElement | ||
Aggiunge un oggetto FlowElement secondario. | FlowGroupElement | ||
Aggiunge un oggetto FlowElement secondario nella posizione di indice specificata. | FlowGroupElement | ||
| Cancella lo stile specificato dal parametro styleProp da questo oggetto FlowElement. | FlowElement | |
|
Crea una copia profonda di questo oggetto FlowElement, inclusi gli eventuali elementi secondari, copiando il contenuto tra le due posizioni di caratteri specificate e restituendo la copia come oggetto FlowElement. | FlowElement | |
| Confronta gli oggetti userStyles con gli oggetti userStyles di otherElement. | FlowElement | |
Data una posizione di testo relativa, trova l'indice del primo FlowElement secondario che contiene la posizione relativa. | FlowGroupElement | ||
Data una posizione di testo relativa, trova l'elemento foglia che contiene la posizione relativa. | FlowGroupElement | ||
|
Restituisce la posizione di inizio dell'elemento nel flusso di testo come un indice assoluto. | FlowElement | |
|
Restituisce il carattere nella posizione specificata, relativa a questo oggetto FlowElement. | FlowElement | |
| Restituisce il codice di carattere nella posizione specificata, relativa a questo oggetto FlowElement. | FlowElement | |
Restituisce l'oggetto secondario FlowElement nella posizione di indice specificata. | FlowGroupElement | ||
Cerca l'oggetto FlowElement specificato tra gli oggetti secondari e restituisce la relativa posizione di indice. | FlowGroupElement | ||
|
Restituisce l'inizio di questo elemento relativo a un elemento antenato. | FlowElement | |
Restituisce il primo FlowLeafElement discendente di questo gruppo. | FlowGroupElement | ||
Restituisce l'ultimo FlowLeafElement discendente di questo gruppo. | FlowGroupElement | ||
| Restituisce il successivo oggetto FlowElement di pari livello nella gerarchia del flusso di testo. | FlowElement | |
|
Restituisce l'oggetto ParagraphElement associato a questo elemento. | FlowElement | |
| Restituisce il precedente oggetto FlowElement di pari livello nella gerarchia del flusso di testo. | FlowElement | |
| Restituisce il valore dello stile specificato dal parametro styleProp, che specifica il nome dello stile e può includere il nome di qualsiasi userStyle. | FlowElement | |
[override] | FlowGroupElement | ||
|
Risale la gerarchia del flusso di testo per restituire l'oggetto TextFlow radice per l'elemento. | FlowElement | |
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
| Chiamato per gli oggetti MXML dopo che è stato creato l'oggetto di implementazione e tutte le proprietà del componente specificate nel tag MXML sono state inizializzate. | FlowElement | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
Rimuove l'oggetto secondario FlowElement specificato dal gruppo. | FlowGroupElement | ||
Rimuove l'oggetto secondario FlowElement nella posizione di indice specificata. | FlowGroupElement | ||
Sostituisce gli elementi secondari nel gruppo con i nuovi elementi specificati. | FlowGroupElement | ||
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
| Imposta lo stile specificato dal parametro styleProp sul valore specificato dal parametro newValue. | FlowElement | |
|
Crea una copia di questo oggetto FlowElement, copiando il contenuto tra le due posizioni di caratteri specificate. | FlowElement | |
Divide questo oggetto nella posizione specificata dal parametro childIndex. | FlowGroupElement | ||
|
Divide questo oggetto FlowElement in corrispondenza della posizione specificata dal parametro relativePosition, che corrisponde a una posizione relativa nel testo per questo elemento. | FlowElement | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
|
Restituisce la rappresentazione in formato stringa dell'oggetto specificato. | Object | |
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
Descrizione delle proprietà
mxmlChildren | proprietà |
mxmlChildren:Array| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Aggiunge un array di elementi secondari a questo oggetto. Utilizza il metodo replaceChildren() per aggiungere ogni elemento all'array. Destinato all'uso durante l'importazione di codice mxml compilato.
Implementazione
public function get mxmlChildren():Array public function set mxmlChildren(value:Array):voidGenera
TypeError — Se l'elemento dell'array non è un oggetto FlowElement o String.
|
Elementi API correlati
numChildren | proprietà |
Descrizione della funzione di costruzione
FlowGroupElement | () | Funzione di costruzione |
public function FlowGroupElement()| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Classe base - una chiamata a new FlowGroupElement() genera un'eccezione di tipo Error.
Descrizione dei metodi
addChild | () | metodo |
public function addChild(child:FlowElement):FlowElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Aggiunge un oggetto FlowElement secondario. Il nuovo elemento secondario viene aggiunto alla fine dell'elenco di elementi secondari.
Parametri
child:FlowElement — L'elemento secondario da aggiungere.
|
FlowElement — L'oggetto FlowElement secondario aggiunto.
|
Esempio ( Come utilizzare questo esempio )
In questo esempio viene chiamato
addChild() per aggiungere un'estensione a un paragrafo e aggiungere il paragrafo al flusso di testo.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_addChildExample extends Sprite
{
public function FlowGroupElement_addChildExample()
{
// create string for text flow
var simpleText:String = "It was a dark and stormy night.";
// define TextFlow, ParagraphElement, and SpanElement objects
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement;
span.text = simpleText;
// add span to paragraph and add paragraph to text flow
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign composer and controller and update controller to display text
textFlow.flowComposer.addController(new ContainerController(this,200,200));
textFlow.flowComposer.updateAllControllers();
}
}
}
addChildAt | () | metodo |
public function addChildAt(index:uint, child:FlowElement):FlowElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Aggiunge un oggetto FlowElement secondario nella posizione di indice specificata.
Parametri
index:uint — indice della posizioni in cui aggiungere l'elemento secondario; la prima posizione corrisponde a 0.
| |
child:FlowElement — L'elemento secondario da aggiungere.
|
FlowElement — L'oggetto FlowElement secondario aggiunto.
|
Genera
RangeError — La posizione index non è compresa nell'intervallo.
|
Esempio ( Come utilizzare questo esempio )
In questo esempio viene chiamato addChildAt per aggiungere tre estensioni a un paragrafo.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_addChildAtExample extends Sprite
{
public function FlowGroupElement_addChildAtExample()
{
// define text strings for the contents of the text flow
var textA:String = "It was a dark and stormy night. ";
var textB:String = "The quick red fox jumped over the lazy brown dog. ";
var textC:String = "Mary had a little lamb. ";
// define TextFlow, ParagraphElement and SpanElement objects
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span1:SpanElement = new SpanElement();
var span2:SpanElement = new SpanElement();
var span3:SpanElement = new SpanElement();
span1.text = textA;
span2.text = textB;
span3.text = textC;
// add spans at specified positions
paragraph.addChildAt(0, span2);
paragraph.addChildAt(0, span1);
paragraph.addChildAt(1, span3);
textFlow.addChild(paragraph);
// assign composer, controller, and update to display text
textFlow.flowComposer.addController(new ContainerController(this,200,200));
textFlow.flowComposer.updateAllControllers();
}
}
}
findChildIndexAtPosition | () | metodo |
public function findChildIndexAtPosition(relativePosition:int):int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Data una posizione di testo relativa, trova l'indice del primo FlowElement secondario che contiene la posizione relativa. La posizione relativa può essere contenuta in più elementi, in quanto la lunghezza degli oggetti FlowElement è pari a zero.
Esamina gli elementi secondari per trovare l'oggetto FlowElement che contiene la posizione relativa. La posizione relativa fornita è relativa a questo oggetto FlowElement.
Parametri
relativePosition:int — la posiziona relativa di questo elemento
|
int — indice del primo elemento secondario contenente relativePosition
|
Esempio ( Come utilizzare questo esempio )
Questo esempio trova l'indice dell'elemento secondario nella posizione relativa all'interno del testo e ne imposta il colore sul rosso.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_findChildIndexAtPositionExample extends Sprite
{
public function FlowGroupElement_findChildIndexAtPositionExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Peter Piper picked a </flow:span>"+
"<flow:span fontStyle=\"italic\"> peck </flow:span>"+
"<flow:span>of pickle peppers.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// add composer and controller
textFlow.flowComposer.addController(new ContainerController(this,200,200));
// find the index of the child containing relative offset 21; set color to red
var index:int = textFlow.findChildIndexAtPosition(21);
textFlow.getChildAt(index).color = 0xFF0000;
// display text
textFlow.flowComposer.updateAllControllers();
}
}
}
findLeaf | () | metodo |
public function findLeaf(relativePosition:int):FlowLeafElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Data una posizione di testo relativa, trova l'elemento foglia che contiene la posizione relativa.
Cerca nella gerarchia degli elementi di flusso per trovare l'oggetto FlowLeafElement che contiene la posizione specificata. La posizione specificata è relativa a questo oggetto FlowElement.
Parametri
relativePosition:int — indice di testo relativo da cercare.
|
FlowLeafElement — l'elemento foglia contenente la posizione relativa
|
Esempio ( Come utilizzare questo esempio )
Questo esempio crea due paragrafi, trova l'oggetto FlowLeafElement nella posizione relativa 55 e ne imposta il colore sul rosso.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_findLeafExample extends Sprite
{
public function FlowGroupElement_findLeafExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>It was a dark and stormy night</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Peter Piper picked a </flow:span>"+
"<flow:span fontStyle=\"italic\"> peck </flow:span>"+
"<flow:span>of pickle peppers.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// add composer and controller
textFlow.flowComposer.addController(new ContainerController(this,200,200));
// find the FlowLeafElement object containing relative offset 55; set color to red
var leaf:SpanElement = textFlow.findLeaf(55) as SpanElement;
leaf.color = 0xFF0000;
// display text
textFlow.flowComposer.updateAllControllers();
}
}
}
getChildAt | () | metodo |
public function getChildAt(index:int):FlowElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce l'oggetto secondario FlowElement nella posizione di indice specificata.
Parametri
index:int — la posizione in cui trovare l'oggetto FlowElement.
|
FlowElement — l'oggetto secondario FlowElement nella posizione specificata.
|
Esempio ( Come utilizzare questo esempio )
Questo esempio utilizza il metodo
getChildAt() per accedere a un paragrafo nel flusso di testo e cambiare il colore di una delle sue estensioni in rosso.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_getChildAtExample extends Sprite
{
public function FlowGroupElement_getChildAtExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Peter Piper picked a </flow:span>"+
"<flow:span fontStyle=\"italic\"> peck </flow:span>"+
"<flow:span>of pickle peppers.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// add composer and controller
textFlow.flowComposer.addController(new ContainerController(this,200,200));
// find the paragraph at index position 1
var para:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
// find the span at index position 1 of the paragraph and color it red
para.getChildAt(1).color = 0xFF0000;
// display text
textFlow.flowComposer.updateAllControllers();
}
}
}
getChildIndex | () | metodo |
public function getChildIndex(child:FlowElement):int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Cerca l'oggetto FlowElement specificato tra gli oggetti secondari e restituisce la relativa posizione di indice.
Parametri
child:FlowElement — L'elemento dell'oggetto FlowElement da individuare tra gli elementi secondari.
|
int — La posizione di indice dell'oggetto secondario specificato. Se child non viene trovato, restituisce -1.
|
getFirstLeaf | () | metodo |
public function getFirstLeaf():FlowLeafElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce il primo FlowLeafElement discendente di questo gruppo.
RestituisceFlowLeafElement — il primo oggetto FlowLeafElement.
|
Esempio ( Come utilizzare questo esempio )
Questo esempio crea due paragrafi, trova il primo oggetto FlowLeafElement e ne imposta il colore sul rosso.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_getFirstLeafExample extends Sprite
{
public function FlowGroupElement_getFirstLeafExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>It was a </flow:span>"+
"<flow:span fontStyle=\"italic\">dark and stormy</flow:span>"+
"<flow:span> night.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// get first FlowLeafElement object and set its color to red
var leaf:SpanElement = textFlow.getFirstLeaf() as SpanElement;
leaf.color = 0xFF0000;
// add composer and controller and update controller to display text
textFlow.flowComposer.addController(new ContainerController(this,200,200));
textFlow.flowComposer.updateAllControllers();
}
}
}
getLastLeaf | () | metodo |
public function getLastLeaf():FlowLeafElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Restituisce l'ultimo FlowLeafElement discendente di questo gruppo.
RestituisceFlowLeafElement — l'ultimo oggetto FlowLeafElement.
|
Esempio ( Come utilizzare questo esempio )
Questo esempio crea due paragrafi, trova l'ultimo oggetto FlowLeafElement e ne imposta il colore sul rosso.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_getLastLeafExample extends Sprite
{
public function FlowGroupElement_getLastLeafExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>It was a dark and stormy night</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Peter Piper picked a </flow:span>"+
"<flow:span fontStyle=\"italic\"> peck </flow:span>"+
"<flow:span>of pickle peppers.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// add composer and controller
textFlow.flowComposer.addController(new ContainerController(this,600,600));
//find last leaf, set its color to red and display text
var leaf:SpanElement = textFlow.getLastLeaf() as SpanElement;
leaf.color = 0xFF0000;
textFlow.flowComposer.updateAllControllers();
}
}
}
getText | () | metodo |
removeChild | () | metodo |
public function removeChild(child:FlowElement):FlowElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Rimuove l'oggetto secondario FlowElement specificato dal gruppo.
Parametri
child:FlowElement — L'elemento secondario da rimuovere.
|
FlowElement — L'oggetto FlowElement secondario rimosso.
|
Genera
ArgumentError — L'oggetto child non viene trovato.
|
Esempio ( Come utilizzare questo esempio )
Questo esempio rimuove la terza estensione del secondo paragrafo del flusso di testo.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_removeChildExample extends Sprite
{
public function FlowGroupElement_removeChildExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p id='para1'>"+
"<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
"</flow:p>"+
"<flow:p id='para2'>"+
"<flow:span id='span2'>Peter Piper picked a </flow:span>"+
"<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
"<flow:span id='span4'>of pickle peppers.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// add composer and controller
textFlow.flowComposer.addController(new ContainerController(this,600,600));
// get paragraph with ID = 'para2' and remove its child with name = 'span4'
var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
parent.removeChild(textFlow.getElementByID("span4"));
// update controller to display text
textFlow.flowComposer.updateAllControllers();
}
}
}
removeChildAt | () | metodo |
public function removeChildAt(index:uint):FlowElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Rimuove l'oggetto secondario FlowElement nella posizione di indice specificata.
Parametri
index:uint — posizione in cui rimuovere l'elemento secondario.
|
FlowElement — L'oggetto FlowElement secondario rimosso dalla posizione specificata.
|
Genera
RangeError — La posizione index non è compresa nell'intervallo.
|
Esempio ( Come utilizzare questo esempio )
Questo esempio chiama
removeChildAt() per rimuovere il secondo di tre paragrafi.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_removeChildAtExample extends Sprite
{
public function FlowGroupElement_removeChildAtExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>It was a dark and stormy night. </flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>Mary had a little lamb. </flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow, import text, add composer and controller
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this,200,200));
// remove child at index position 1 (with first position = 0); display text
textFlow.removeChildAt(1);
textFlow.flowComposer.updateAllControllers();
}
}
}
replaceChildren | () | metodo |
public function replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Sostituisce gli elementi secondari nel gruppo con i nuovi elementi specificati. Utilizzate i parametri beginChildIndex e endChildIndex per regolare l'operazione come indicato di seguito:
- Per eliminare elementi, non passate alcun elemento sostitutivo.
- Per inserire elementi, passate lo stesso valore per
beginChildIndexe perendChildIndex. I nuovi elementi vengono inseriti prima dell'indice specificato. - Per aggiungere elementi, passate
numChildrenperbeginChildIndexe perendChildIndex.
In caso contrario questo metodo sostituisce gli elementi specificati, a partire dall'elemento in beginChildIndex fino a endChildIndex escluso.
Parametri
beginChildIndex:int — Il valore di indice della posizione iniziale dell'intervallo sostitutivo nell'array di elementi secondari.
| |
endChildIndex:int — Il valore di indice che segue la posizione finale dell'intervallo sostitutivo nell'array di elementi secondari.
| |
... rest — Gli elementi da utilizzare per la sostituzione dell'intervallo di elementi specificato. Può essere una sequenza contenente elementi di flusso o array di relativi vettori.
|
Genera
RangeError — L'oggetto beginChildIndex o endChildIndex specificato non rientra nell'intervallo.
|
Esempio ( Come utilizzare questo esempio )
Questo esempio sostituisce le tre estensioni del secondo paragrafo con due nuove estensioni.
package flashx.textLayout.elements.examples {
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class FlowGroupElement_replaceChildrenExample extends Sprite
{
public function FlowGroupElement_replaceChildrenExample()
{
// xml markup that defines the attributes and contents of a text flow
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p id='para1'>"+
"<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
"</flow:p>"+
"<flow:p id='para2'>"+
"<flow:span id='span2'>Peter Piper picked a </flow:span>"+
"<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
"<flow:span id='span4'>of pickle peppers.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// define TextFlow object and import xml markup
var textFlow:TextFlow = new TextFlow();
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
// define two new SpanElement objects
var span1:SpanElement = new SpanElement();
var span2:SpanElement = new SpanElement();
span1.text = "Mary had a little lamb. ";
span2.text = "And this little pig stayed home. ";
// add composer and controller
textFlow.flowComposer.addController(new ContainerController(this,200,600));
// get paragraph with ID = 'para2' and replace its children with span1 and span2
var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
parent.replaceChildren(0, 3, [span1, span2]);
// update controller to display text
textFlow.flowComposer.updateAllControllers();
}
}
}
splitAtIndex | () | metodo |
public function splitAtIndex(childIndex:int):FlowGroupElement| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10, AIR 1.5 |
Divide questo oggetto nella posizione specificata dal parametro childIndex. Se l'elemento di questo gruppo ha un elemento principale, crea una copia superficiale (shallow copy) di questo oggetto e sostituisce i relativi elementi secondari con gli elementi fino all'indice. Sposta nella copia gli elementi che seguono childIndex.
Parametri
childIndex:int |
FlowGroupElement — il nuovo oggetto FlowGroupElement.
|
Genera
RangeError — se childIndex è maggiore della lunghezza dell'elemento secondario.
|
Tue Jun 12 2018, 02:44 PM Z