SoundMixer  - AS3

Spécifie le mode de lecture audio de tous les objets Sound. Sur les périphériques mobiles, cette priorité définit les priorités du son et les valeurs par défaut en fonction des langues de la plate-forme. Dans les environnements de bureau et de télévision, aucune différence fonctionnelle n’existe entre les modes de lecture audio.

Les valeurs valides de cette propriété sont définies dans la classe AudioPlaybackMode.

Remarque : sur iOS, si une application utilise audioPlaybackMode=AudioPlaybackMode.VOIX, les autres applications ne peuvent pas modifier ce paramètre et utiliser AudioPlaybackMode.MEDIA.

Utilisez le moins possible le mode AudioPlaybackMode.VOICE et essayez de passer au mode AudioPlaybackMode.MEDIA dès que possible après la fin de l’appel vocal afin de permettre la lecture d’autres applications en mode multimédia.

Lorsque vous changez le mode de lecture audio sur iOS, les applications natives de lecture audio se mettent brièvement en pause.

La valeur par défaut est AudioPlaybackMode.MEDIA.

Eléments de l’API associés

Durée, en secondes, de préchargement dans une mémoire tampon d’un son en flux continu imbriqué avant que la diffusion en continu ne commence. Les données d’un son chargé, y compris sa durée de préchargement en mémoire tampon, ne sont pas accessibles par un fichier SWF appartenant à un autre domaine, sauf si vous mettez en place un fichier de régulation interdomaines. Pour plus d’informations sur la sécurité et le son, voir la description de la classe Sound. Les données d’un son chargé, y compris sa durée de préchargement en mémoire tampon, ne sont pas accessibles par le code d’un fichier appartenant à un autre domaine, sauf si vous mettez en place un fichier de régulation interdomaines. Néanmoins, dans le sandbox d’application d’une application AIR, le code peut accéder aux données dans des fichiers de son à partir de n’importe quelle source. Pour plus d’informations sur la sécurité et le son, voir la description de la classe Sound.

La propriété SoundMixer.bufferTime affecte uniquement la durée de mise en mémoire tampon des sons en flux continu imbriqués dans un fichier SWF. Elle n’a aucune incidence sur les objets Sound créés dynamiquement (autrement dit, créés dans ActionScript). La valeur de SoundMixer.bufferTime ne peut pas remplacer ni définir la durée de mise en mémoire tampon par défaut spécifiée dans l’objet SoundLoaderContext qui est transmis à la méthode Sound.load().

Eléments de l’API associés

Objet SoundTransform contrôlant les propriétés audio globales. Un objet SoundTransform comprend les propriétés de réglage du volume, du déplacement panoramique, ainsi que des haut-parleurs gauche et droit. L’objet SoundTransform utilisé dans cette propriété fournit des paramètres audio finaux qui sont appliqués à la totalité des sons après l’application de paramètres audio individuels.

Eléments de l’API associés

Active/désactive le haut-parleur du téléphone lorsque le périphérique est en mode vocal. Par défaut, les téléphones intelligents utilisent l’écouteur du téléphone pour la sortie audio lorsque SoundMixer.audioPlaybackMode est définie sur AudioPlaybackMode.VOICE. La propriété useSpeakerphoneForVoice permet de remplacer la sortie par défaut de sorte que vous puissiez implémenter le bouton d’un haut-parleur dans une application de téléphone. Cette propriété n’a pas d’effet dans les modes autres que AudioPlaybackMode.VOICE. Dans les environnements de bureau et de télévision, cette propriété n’a aucun effet.

Remarque : sur iOS, si votre application a défini audioPlaybackMode=VOICE et qu’une autre application effectue également la lecture en mode voix, vous ne pouvez pas définir useSpeakerphoneForVoice=true.

Remarque : sous Android, vous devez définir android.permission.MODIFY_AUDIO_SETTINGS dans le descripteur d'application AIR ou que la modification de cette valeur n'aura aucun effet. En outre, le paramètre est un réglage de périphérique global. Les autres applications qui s'exécutent sur le périphérique peuvent à tout moment modifier le paramètre de périphérique sous-jacent.

La valeur par défaut est false.

Eléments de l’API associés

Détermine si des sons sont inaccessibles en raison de restrictions de sécurité. Par exemple, un son chargé à partir d’un domaine différent de celui du contenu appelant cette méthode est inaccessible si le serveur du son ne possède pas de fichier de régulation d’URL autorisant l’accès au domaine de ce domaine. Le son peut cependant être chargé et lu, mais les opérations de bas niveau, telles que l’extraction de métadonnées ID3 pour le son, ne peuvent pas être exécutées sur des sons inaccessibles.

Pour le contenu d’une application AIR dans le sandbox de sécurité de l’application, l’appel à cette méthode renvoie toujours false. Tous les sons, y compris ceux chargés d’autres domaines, sont accessibles au contenu dans le sandbox de sécurité de l’application.

Eléments de l’API associés

Génère un instantané de l’onde sonore actuelle et le place dans l’objet ByteArray spécifié. Les valeurs sont mises en forme comme des valeurs à virgule flottante normalisées allant de -1,0 à 1,0. L’objet ByteArray transmis au paramètre outputArray est remplacé par de nouvelles valeurs. La taille de l’objet ByteArray créé est fixée à 512 valeurs à virgule flottante, les 256 premières représentant le canal gauche et les autres le canal droit.

Remarque : cette méthode est soumise aux restrictions relatives à la sécurité des fichiers locaux et aux restrictions concernant le chargement interdomaines. Si vous utilisez des fichiers locaux ou des sons chargés à partir d’un serveur appartenant à un autre domaine que le contenu appelant, vous devez peut-être contourner les restrictions liées au sandbox par le biais d’un fichier de régulation interdomaines. Pour plus d’informations, voir la description de la classe Sound. En outre, cette méthode ne permet pas d’extraire des données de flux RTMP, même si elle est appelée par un contenu résidant dans le même domaine que le serveur RTMP.

Cette méthode est prise en charge sur RTMP dans Flash Player 9.0.115.0 et versions ultérieures, ainsi que dans Adobe AIR. Vous pouvez contrôler l’accès aux flux sur un serveur FMS (Flash Media Server) dans un script coté serveur. Pour plus de détails, voir les propriétés Client.audioSampleAccess et Client.videoSampleAccess dans le Guide de référence du langage ActionScript d’Adobe Flash Media Server côté serveur.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Arrête tout son en cours de lecture.

>Dans Flash Professional, cette méthode n’arrête pas la tête de lecture. Les sons diffusés en continu sont émis de nouveau lorsque la tête de lecture passe au-dessus des images les contenant.

Pour utiliser cette propriété, tenez compte du modèle de sécurité suivant :

• Par défaut, l’appel de la méthode SoundMixer.stopAll() arrête uniquement les sons se trouvant dans le même sandbox de sécurité que l’objet qui appelle la méthode. Les sons dont la lecture n’a pas été lancée à partir du sandbox de l’objet appelant ne sont pas arrêtés.
• Lorsque vous chargez le son à l’aide de la méthode load() de la classe Sound, vous pouvez spécifier un paramètre context qui est un objet SoundLoaderContext. Si vous réglez la propriété checkPolicyFile de l’objet SoundLoaderContext sur true, Flash Player ou Adobe AIR recherche un fichier de régulation interdomaines sur le serveur à partir duquel le son est chargé. Si le serveur dispose d’un fichier de régulation interdomaines qui autorise le domaine du contenu appelant, ce fichier peut arrêter le son chargé par le biais de la méthode SoundMixer.stopAll() ; dans le cas contraire, il ne peut pas l’arrêter.

Néanmoins, dans Adobe AIR, le contenu du sandbox de sécurité application (contenu installé avec l’application AIR) n’est pas soumis à ces restrictions de sécurité.

Pour plus d’informations concernant la sécurité, voir la rubrique du Pôle de développement Flash Player : Sécurité (disponible en anglais uniquement).

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}