| Paquete | flash.ui |
| Clase | public final class Multitouch |
| Herencia | Multitouch  Object |
| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.1, AIR 2, Flash Lite 4 |
- flash.events.TouchEvent
- flash.events.GestureEvent
- flash.events.GesturePhase
- flash.events.TransformGestureEvent
- flash.events.PressAndTapGestureEvent
Utilice las clases enumeradas para escribir código que gestione los eventos de toque. Utilice la clase Multitouch para determinar la compatibilidad del entorno actual para dicha interacción y para gestionar la compatibilidad de la interacción táctil si el entorno actual admite entrada táctil.
No puede crear un objeto Multitouch directamente a partir del código ActionScript. Si llama a new Multitouch(), se emitirá una excepción.
Nota: la función Multitouch no es compatible en archivos SWF incorporados en HTML que se ejecuta en Mac OS.
Más información
Christian Cantrell: Soporte multitáctil y de gestos en la plataforma de Flash
Lee Brimelow: preguntas frecuentes sobre Flash Player 10.1 multitáctil
Piotr Walczyszyn: desarrollo de tecnología multitáctil en Flex
Elementos de API relacionados
flash.events.GestureEvent
flash.events.TransformGestureEvent
flash.events.GesturePhase
flash.events.PressAndTapGestureEvent
flash.events.MouseEvent
flash.events.EventDispatcher.addEventListener()
Ocultar propiedades públicas heredadas
Mostrar propiedades públicas heredadas| Propiedad | Definido por | ||
|---|---|---|---|
 | constructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada. | Object | |
| inputMode : String [estática]
Identifica el modo multitáctil para la gestión de eventos de toque y de gestos. | Multitouch | ||
| mapTouchToMouse : Boolean [estática]
Especifica si el motor de ejecución de AIR asigna eventos táctiles a eventos de ratón. | Multitouch | ||
| maxTouchPoints : int [estática] [solo lectura]
El número máximo de puntos táctiles simultáneos admitidos por el entorno actual. | Multitouch | ||
| supportedGestures : Vector.<String> [estática] [solo lectura]
Un conjunto de vectores (un conjunto de tipos de valores de cadena) de tipos de contacto multitáctil admitidos en el entorno actual. | Multitouch | ||
| supportsGestureEvents : Boolean [estática] [solo lectura]
Indica si el entorno actual admite o no la entrada de gestos, como girar dos dedos alrededor de una pantalla táctil. | Multitouch | ||
| supportsTouchEvents : Boolean [estática] [solo lectura]
Indica si el entorno actual admite o no la entrada táctil básica, como el toque con un solo dedo. | Multitouch | ||
inputMode | propiedad |
inputMode:String| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.1, AIR 2, Flash Lite 4 |
Identifica el modo multitáctil para la gestión de eventos de toque y de gestos. Utilice esta propiedad para administrar si los eventos se distribuyen o no como eventos de toque con varios puntos de contacto, como eventos específicos para los distintos gestos (como el giro o el desplazamiento), como un único punto de contacto (toque), o como ninguno en absoluto (el contacto se gestiona como un evento de ratón). Para definir esta propiedad, utilice valores de la clase flash.ui.MultitouchInputMode.
El valor predeterminado es gesture.
Implementación
public static function get inputMode():String public static function set inputMode(value:String):voidElementos de API relacionados
Ejemplo ( Cómo utilizar este ejemplo )
Multitouch.inputMode=MultitouchInputMode.TOUCH_POINT;
var mySprite:Sprite = new Sprite();
var myTextField:TextField = new TextField();
mySprite.graphics.beginFill(0x336699);
mySprite.graphics.drawRect(0,0,40,40);
addChild(mySprite);
mySprite.addEventListener(TouchEvent.TOUCH_TAP, taphandler);
function taphandler(e:TouchEvent): void {
myTextField.text = "I've been tapped";
myTextField.y = 50;
addChild(myTextField);
}
mapTouchToMouse | propiedad |
mapTouchToMouse:Boolean| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 3 |
Especifica si el motor de ejecución de AIR asigna eventos táctiles a eventos de ratón.
Si es true, valor predeterminado, el motor de ejecución de AIR distribuye un evento de ratón además de un evento táctil para entradas táctiles. Si es false, el motor de ejecución no distribuye ningún un evento de ratón adicional. Si establece esta propiedad en false, puede provocar que código existente, las bibliotecas y las estructuras que se basen en eventos de ratón funcionen incorrectamente en dispositivos que admiten entrada táctil.
Implementación
public static function get mapTouchToMouse():Boolean public static function set mapTouchToMouse(value:Boolean):voidElementos de API relacionados
maxTouchPoints | propiedad |
maxTouchPoints:int [solo lectura] | Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.1, AIR 2, Flash Lite 4 |
El número máximo de puntos táctiles simultáneos admitidos por el entorno actual.
Nota: En Android, el valor devuelto es 2 para los dispositivos que admiten más de dos puntos táctiles.
Implementación
public static function get maxTouchPoints():intElementos de API relacionados
supportedGestures | propiedad |
supportedGestures:Vector.<String> [solo lectura] | Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.1, AIR 2, Flash Lite 4 |
Un conjunto de vectores (un conjunto de tipos de valores de cadena) de tipos de contacto multitáctil admitidos en el entorno actual. El conjunto de cadenas se puede utilizar como tipos de eventos para registrar detectores de eventos. Los posibles valores son constantes de las clases GestureEvent, PressAndTapGestureEvent y TransformGestureEvent (como GESTURE_PAN).
Si el motor de ejecución se Flash está en un entorno que no admite gestos multitáctiles, el valor es null.
Nota: en Mac OS 10.5.3 y versiones posteriores, Multitouch.supportedGestures devuelve valores no null (posiblemente indican incorrectamente que se admiten eventos de gestos) incluso si el hardware actual no admite entrada de gestos.
Utilice esta propiedad para probar la compatibilidad con gestos multitáctiles. Seguidamente, utilice los controladores de eventos para los gestos multitáctiles disponibles. Para los gestos que no se admiten en el entorno actual, necesitará crear una gestión de eventos alternativa.
Implementación
public static function get supportedGestures():Vector.<String>Elementos de API relacionados
flash.events.MouseEvent
flash.events.EventDispatcher.addEventListener()
flash.events.GestureEvent
flash.events.PressAndTapGestureEvent
flash.events.TransformGestureEvent
Ejemplo ( Cómo utilizar este ejemplo )
Multitouch.supportedGestures cambia para incluir todos los gestos disponibles en entorno actual de software y hardware en el motor de ejecución de Flash. Si el conjunto de vectores Multitouch.supportedGestures no contiene ninguno de los gestos TransformGestureEvent, no se añade ningún detector de eventos para ese gesto. Este ejemplo proviene de Holly Schinsky.
Multitouch.inputMode = MultitouchInputMode.GESTURE;
for each (var item:String in Multitouch.supportedGestures) {
trace("gesture " + item);
if (item == TransformGestureEvent.GESTURE_PAN)
img.addEventListener(TransformGestureEvent.GESTURE_PAN, onPan);
else if (item == TransformGestureEvent.GESTURE_ROTATE)
img.addEventListener(TransformGestureEvent.GESTURE_ROTATE, onRotate);
else if (item == TransformGestureEvent.GESTURE_SWIPE)
img.addEventListener(TransformGestureEvent.GESTURE_SWIPE, onSwipe);
else if (item == TransformGestureEvent.GESTURE_ZOOM)
img.addEventListener(TransformGestureEvent.GESTURE_ZOOM, onZoom);
}
supportsGestureEvents | propiedad |
supportsGestureEvents:Boolean [solo lectura] | Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.1, AIR 2, Flash Lite 4 |
Indica si el entorno actual admite o no la entrada de gestos, como girar dos dedos alrededor de una pantalla táctil. Los eventos de gestos se enumeran en las clases TransformGestureEvent, PressAndTapGestureEvent y GestureEvent.
Nota: en Mac OS 10.5.3 y versiones posteriores, este valor siempre es true. Multitouch.supportsGestureEvent devuelve true incluso si el hardware no admite eventos de gestos.
Implementación
public static function get supportsGestureEvents():BooleanElementos de API relacionados
supportsTouchEvents | propiedad |
supportsTouchEvents:Boolean [solo lectura] | Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.1, AIR 2, Flash Lite 4 |
Indica si el entorno actual admite o no la entrada táctil básica, como el toque con un solo dedo. Los eventos de toque se enumeran en la clase TouchEvent.
Implementación
public static function get supportsTouchEvents():BooleanElementos de API relacionados
Multitouch.supportedGestures devuelve null y asignar null al vector de cadenas provoca un error en tiempo de ejecución). Si se admiten eventos de gestos, el ejemplo muestra los eventos de la clase TransformGestureEvent admitidos en el entorno actual:
package {
import flash.ui.Multitouch;
import flash.ui.MultitouchInputMode;
import flash.display.Sprite;
import flash.text.TextField;
public class MultitouchExample extends Sprite {
Multitouch.inputMode = MultitouchInputMode.GESTURE;
public function MultitouchExample() {
if(Multitouch.supportsGestureEvents){
var supportedGesturesVar:Vector.<String> = Multitouch.supportedGestures;
var deviceSupports:TextField = new TextField();
deviceSupports.width = 200;
deviceSupports.height = 200;
deviceSupports.wordWrap = true;
for (var i:int=0; i<supportedGesturesVar.length; ++i) {
deviceSupports.appendText(supportedGesturesVar[i] + ", ");
addChild(deviceSupports);
}
}
}
}
}
Tue Jun 12 2018, 02:12 PM Z