MouseEvent  - AS3

Indica si la tecla Alt está activa (true) o inactiva (false). Sólo se admite en Windows. En otros sistemas operativos, la propiedad siempre se establece como false.

Indica si se pulsa el botón principal del ratón (true) o no (false).

Indica si el evento MouseDown forma parte o no de una secuencia de varios clics. Este parámetro es cero en cualquier evento mouse que no sea MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown o MouseEvent.rightMouseUp. Es posible detectar un clic sencillo, un doble clic o una secuencia de varios clics con el parámetro clickCount. Por ejemplo, un evento MouseEvent.mouseDown y MouseEvent.mouseUp inicial tendrán un valor clickCount de 1, y el segundo evento MouseEvent.mouseDown y MouseEvent.mouseUp de una secuencia de doble clic tendrá un valor clickCount de 2. Si el ratón se mueve lo suficiente o si se interrumpe la secuencia de varios clics por algún motivo, el siguiente evento MouseEvent.mouseDown tendrá un valor clickCount de 1. El evento doubleClick sigue activándose del modo esperado.

Indica si la tecla Comando está activada (sólo en Mac).

El valor de la propiedad commandKey tiene el mismo valor que la propiedad ctrlKey en Mac. Siempre es false en Windows o Linux.

Indica si la tecla Control está activada en Mac y si la tecla Ctrl está activada en Windows o Linux.

En Windows o Linux, indica si la tecla Ctrl está activa (true) o inactiva (false). En Macintosh, indica si está activada la tecla Control o Comando.

Indica el número de líneas que debe desplazarse la visualización por cada vuelta de la rueda del ratón. Un valor delta positivo indica un desplazamiento hacia arriba; un valor negativo indica un desplazamiento hacia abajo. Los valores típicos van del 1 al 3, pero una rotación más rápida puede generar valores más grandes. Este parámetro depende del dispositivo y del sistema operativo y suele ser configurable por el usuario. Esta propiedad sólo se aplica al evento MouseEvent.mouseWheel.

Si es true, la propiedad relatedObject se establece como null por motivos relacionados con entornos limitados de seguridad. Si el valor nominal de relatedObject es una referencia a un objeto DisplayObject en otro entorno limitado, relatedObject se establece como null a no ser que disponga de permiso en ambas direcciones dentro de los límites del entorno limitado. Puede establecer los permisos llamando a Security.allowDomain() desde un archivo SWF, o bien proporcionando un archivo de política desde el servidor de un archivo de imagen y estableciendo la propiedad LoaderContext.checkPolicyFile al cargar la imagen.

Elementos de API relacionados

Cuando el bloqueo del ratón está desactivado, la coordenada horizontal en la que se produce el evento relativo a la clase Sprite contenida. Desactive el bloqueo del ratón estableciendo Stage.mouseLock como false.

Cuando el bloqueo del ratón está activado, localX y localY son 0. Utilice movementX y movementY para determinar los cambios a posición del ratón cuando el bloqueo del ratón está activado.

Elementos de API relacionados

Cuando el bloqueo del ratón está desactivado, la coordenada vertical en la que se produce el evento relativo a la clase Sprite contenida. Desactive el bloqueo del ratón estableciendo Stage.mouseLock como false.

Cuando el bloqueo del ratón está activado, localX y localY son 0. Utilice movementX y movementY para determinar los cambios a posición del ratón cuando el bloqueo del ratón está activado.

Elementos de API relacionados

Cuando el bloqueo del ratón está activado, el cambio en la posición del ratón en la dirección X desde el último evento de ratón. Active el bloqueo del ratón estableciendo Stage.mouseLock como true.

Cuando el bloqueo del ratón está activado:

• localX y localY contienen 0.
• movementX y movementY contienen valores delta.
• movementX y movementY nunca se transforman en función de la transformación del escenario. Esto significa que siempre permanecen en las coordenadas de la pantalla.

movementX y movementY son 0 cuando Stage.mouseLock es false.

Elementos de API relacionados

Cuando el bloqueo del ratón está activado, el cambio en la posición del ratón en la dirección Y desde el último evento de ratón. Active el bloqueo del ratón estableciendo Stage.mouseLock como true.

Cuando el bloqueo del ratón está activado:

• localX y localY contienen 0.
• movementX y movementY contienen valores delta.
• movementX y movementY nunca se transforman en función de la transformación del escenario. Esto significa que siempre permanecen en las coordenadas de la pantalla.

movementX y movementY son 0 cuando Stage.mouseLock es false.

Elementos de API relacionados

Referencia a un objeto de la lista de visualización relacionado con el evento. Por ejemplo, si se produce un evento mouseOut, relatedObject representa el objeto de la lista de visualización al que ahora apunta el dispositivo de señalización. Esta propiedad se aplica a los eventos mouseOut, mouseOver, rollOut y rollOver.

El valor de esta propiedad puede ser null en dos casos: si no hay ningún objeto relacionado, o si lo hay, pero se encuentra en un entorno limitado de seguridad al que no tiene acceso. Utilice la propiedad isRelatedObjectInaccessible() para determinar cuál de estas razones es la pertinente.

Elementos de API relacionados

Indica si la tecla Mayús está activa (true) o inactiva (false).

La coordenada horizontal en la que se produce el evento en las coordenadas globales del escenario. Esta propiedad se calcula al establecer localX.

La coordenada vertical en la que se produce el evento en las coordenadas globales del escenario. Esta propiedad se calcula al establecer localY.

Crea un objeto de evento que contiene información sobre eventos de ratón. Los objetos de evento se transfieren como parámetros a los detectores de eventos.

Crea una copia del objeto MouseEvent y define el valor de cada propiedad para que coincida con el del objeto original.

Devuelve una cadena con todas las propiedades del objeto MouseEvent. La cadena tiene el siguiente formato:

[MouseEvent type=value bubbles=value cancelable=value ... delta=value]

Si se ha modificado la lista de visualización, da instrucciones a Flash Player o a Adobe AIR para que muestre la representación tras finalizar el procesamiento del evento.

Define el valor de la propiedad type de un objeto de evento click.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

La constante MouseEvent.CONTEXT_MENU define el valor de la propiedad type de un objeto de evento contextMenu.

Este evento tiene las propiedades siguientes:

Define el valor de la propiedad type de un objeto de evento doubleClick. La propiedad doubleClickEnabled debe ser true para que un objeto genere el evento doubleClick.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento middleClick.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento middleMouseDown.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento middleMouseUp.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento mouseDown.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento mouseMove.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Define el valor de la propiedad type de un objeto de evento mouseOut.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento mouseOver.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento mouseUp.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento mouseWheel.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento releaseOutside.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento rightClick.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento rightMouseDown.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento rightMouseUp.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento rollOut.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento rollOver.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

1. El ejemplo declara propiedades para el tamaño (100 x 100 píxeles) y el color de fondo (naranja) para utilizarlos después al dibujar el cuadrado.
2. El constructor crea un nuevo objeto ChildSprite child. Su constructor dibuja en primer lugar un cuadrado naranja de 100 x 100 píxeles en las coordenadas (0,0) llamando a su método draw() y, a continuación, añade siete detectores/suscriptores de eventos.
   • click / clickHandler(): Se distribuye cuando el usuario hace clic una sola vez con el botón izquierdo del ratón sobre el cuadrado.
   • doubleClick / doubleClickHandler(): Se distribuye cuando el usuario hace doble clic con el botón izquierdo del ratón sobre el cuadrado.
   • mouseDown / mouseDownHandler(): Al hacer clic en el objeto ChildSprite (el cuadrado naranja), se imprime un mensaje trace() en la pantalla y, seguidamente, se llama a ChildSprite.draw(), que dibuja un cuadrado amarillo oscuro en el lugar que ocupaba el cuadrado azul claro dibujado en mouseOverHandler(). El método mouseDownHandler() también añade un detector de eventos mouseMove y el suscriptor mouseMoveHandler() (se describe a continuación), que procesa los movimientos del ratón. Posteriormente se llama al método startDrag(), que permite que se arrastre el objeto Sprite.
   • mouseOut / mouseOutHandler(): Se distribuye cada vez que el puntero sale del área cuadrada. Se llama al método draw() para devolver el cuadrado a su tamaño y color normales.
   • mouseOver / mouseOverHandler(): Se distribuye cuando el puntero del ratón se encuentra sobre el cuadrado. El método redibuja el cuadrado para que sea más grande y para que el color de fondo sea amarillo oscuro.
   • mouseUp / mouseUpHandler(): Cuando el usuario suelta el botón del ratón, se elimina el detector de eventos mouseMove y se llama a stopDrag, que fija el cuadrado en su lugar correspondiente.
   • mouseMove/mouseMoveHandler(): se llama a este método como parte de la función mouseDownHandler(), y se distribuye cuando el usuario pulsa el botón izquierdo del ratón y arrastra el recuadro.
   • mouseWheel / mouseWheelHandler(): Se distribuye cuando el usuario gira la rueda del ratón sobre el cuadrado.
3. Se añade la instancia de ChildSprite child a la lista de visualización por medio de addChild(), que dibuja rápidamente el cuadrado naranja.

Notas:

• La clase MouseEventExample no debe ser la raíz del documento.
• Algunos de los métodos de eventos mencionados arriba declaran una variable local sprite, a la que se asigna la modificación de event.target para escribir Sprite.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}