NativeWindow  - AS3

Indica si la ventana es la ventana de la aplicación activa.

Utilice el método activate() para hacer que una ventana sea activa.

Elementos de API relacionados

Indica si la ventana siempre está delante del resto de ventanas (incluidas las de otras aplicaciones).

Existen dos grupos de ventanas en el orden de profundidad del sistema. Las ventanas del grupo alwaysInFront siempre se muestran por delante del resto de ventanas. Se determina normalmente el orden de profundidad de las ventanas dentro del mismo grupo. Dicho de otro modo, al activar una ventana coloca delante del resto de ventanas de su grupo.

Si cambia alwaysInFront de false a true, la ventana se coloca delante de todas las demás ventanas. Si cambia la propiedad de true a false, la ventana se envía detrás de todas las ventanas con estado "alwaysInFront", pero sigue delante del resto de ventanas. Si se configura la propiedad en su valor actual, no cambia el orden de profundidad de las ventanas. La configuración de la propiedad alwaysInFront de una ventana que tiene un propietario no tiene ningún efecto.

La propiedad alwaysInFront debe establecerse como true en contadas ocasiones, ya que las ventanas con esta configuración se muestran por delante de otras aplicaciones, incluso si éstas están activas.

Notas sobre el comportamiento del SO:

• Algunos gestores de ventanas de Linux no muestran las ventanas que tienen la propiedad alwaysInFront establecida en por delante de ventanas a pantalla completa.
• En Mac^® OS X, establecer alwaysInFront como true no produce ningún efecto si la propiedad displayState del escenario de la ventana es fullScreen o fullScreenInteractive.

windowObj.alwaysInFront = true;

displayObject.stage.nativeWindow.alwaysInFront=true;

window.nativeWindow.alwaysInFront = true;

Tamaño y ubicación de la ventana.

Las dimensiones de una ventana incluyen cualquier posible fondo cromático del sistema. Las dimensiones de un escenario de ventana son iguales que las de la ventana menos el tamaño de cualquier control de aspecto del sistema. Cambiar la anchura y la altura de la ventana cambia también las propiedades stageWidth y stageHeight del escenario. Ocurre también lo contrario: cambiar las dimensiones del escenario afecta al tamaño de la ventana.

En una ventana HTML raíz, las propiedades outerWidth y outerHeigth equivalen a las propiedades height y width de la ventana. Las propiedades innerWidth y innerHeight equivalen a las propiedades stage.stageWidth y stage.stageHeight menos el grosor de cualquier barra de desplazamiento automática presente en la ventana.

Un evento resize se distribuye siempre que cambia la anchura o la altura de la ventana. Del mismo modo, se distribuye un evento move siempre que cambia el origen (x,y) de la ventana. En Mac OS y en Windows, establecer la propiedad bounds directamente no distribuye un evento moving o resizing. Sin embargo, en Linux la propiedad NativeWindow sí distribuye eventos moving y resizing cuando se establece la propiedad bounds.

Definir la propiedad bounds de una ventana equivale a definir sus propiedades x, y, width y height. Del mismo modo, definir cualquiera de las dimensiones por separado equivale a definir la propiedad bounds. Cuando se definen todas las dimensiones al mismo tiempo mediante la propiedad bounds, se distribuye un número menor de eventos.

No se puede garantizar el orden en que se establecen las dimensiones individuales. En los gestores de ventanas de Linux que no permiten que las ventanas superen el área del escritorio, la modificación de una propiedad individual puede bloquearse, incluso si el resultado final de aplicar los cambios a la propiedad obtuviera como resultado una ventana aceptada.

Si la anchura o altura especificada es menor que el valor mínimo o mayor que el valor máximo de anchura y altura permitido, la anchura o la altura de la ventana se fija en el tamaño permitido más cercano. Los factores que determinan la anchura y altura máxima y mínima son los siguientes:

• Las propiedades minSize y maxSize del objeto NativeWindow
• Los límites máximo y mínimo del sistema operativo, que son los valores de NativeWindow.systemMinSize y NativeWindow.systemMaxSize.
• La anchura y altura máximas de una ventana en Adobe AIR, que es, en ambos casos, 4095 píxeles. (En AIR 1.5 y versiones anteriores, el ancho y alto máximo de una ventana 2.880 píxeles.)
• La anchura y altura mínimas requeridas por cualquier fondo cromático del sistema visualizado.

Los valores de píxeles se redondean al entero más próximo cuando cambia la posición o las dimensiones de una ventana.

Elementos de API relacionados

windowObj.bounds = new Rectangle(200, 200, 1000, 800);

displayObject.stage.nativeWindow.bounds = new Rectangle(20, 20, 800, 600);

window.nativeWindow.bounds = new air.Rectangle(20, 20, 800, 600);

Indica si se ha cerrado la ventana.

Al acceder a las propiedades siguientes de una ventana cerrada emite un error de funcionamiento no permitido:

• title
• bounds
• x, y, width, height
• displayState
• visible

Del mismo modo, al llamar a los siguientes métodos en una ventana cerrada también emite un error de funcionamiento no permitido:

• minimize()
• maximize()
• restore()
• startResize()
• startMove()

var isWindowClosed:Boolean = windowObj.closed;

var isWindowClosed:Boolean = displayObject.stage.nativeWindow.closed;

var isWindowClosed = window.nativeWindow.closed;

El estado de visualización de la ventana.

Las constantes de los posible valores se definen en la clase NativeWindowDisplayState:

• NativeWindowDisplayState.NORMAL
• NativeWindowDisplayState.MINIMIZED
• NativeWindowDisplayState.MAXIMIZED

Elementos de API relacionados

var state:String = windowObj.displayState;

Altura de la ventana, en píxeles.

Las dimensiones de una ventana incluyen los controles de aspecto de la ventana del sistema que aparece. La altura del área de visualizacíon utilizable dentro de una ventana está disponible en la propiedad Stage.stageHeight.

Cambiar la propiedad height de una ventana equivale a cambiar la altura mediante la propiedad bounds.

Si la altura especificada es menor o mayor que el valor de altura máximo permitido, la altura de la ventana se fija en el tamaño permitido más cercano. Los factores que determinan la altura máxima y mínima son los siguientes:

• Las propiedades minSize.x y maxSize.x del objeto NativeWindow
• Los límites máximo y mínimo del sistema operativo, que son los valores de NativeWindow.systemMinSize.x y NativeWindow.systemMaxSize.x.
• La altura máxima de una ventana en Adobe AIR, que es 4.095 píxeles (2.880 píxeles en AIR 1.5 y versiones anteriores).

En Linux, establecer la propiedad height es una operación asíncrona.

Para detectar si se ha completado el cambio de altura, detecte el evento resize que se distribuye en todas las plataformas.

Los valores píxeles se redondean al entero más próximo cuando cambia la altura de la ventana.

Elementos de API relacionados

Indica si el sistema del cliente admite ventanas nativas.

Informa sobre la configuración de maximización utilizada para crear la ventana.

No es posible modificar la configuración de maximizable una vez creada la ventana.

Nota: algunos gestores de ventanas de Linux permiten que el usuario maximice las ventanas incluso cuando la propiedad maximizable se establece en false.

Elementos de API relacionados

Tamaño máximo de la ventana.

El límite del tamaño se especifica como coordenadas de un objeto Point. La propiedad x del punto corresponde a la anchura de la ventana y la propiedad y, a la altura de la ventana.

La restricción maxSize se fuerza para operaciones de cambio de tamaño de ventana invocadas mediante código ActionScript y a través del sistema operativo.

Al configurar maxSize, cambian los límites de la ventana si están por encima del nuevo tamaño máximo.

Si la anchura o altura especificada es mayor que el valor de anchura y altura máximo permitido, la anchura de la ventana se fija en el tamaño permitido más cercano. Los factores que determinan la anchura y altura máxima y mínima son los siguientes:

• El límite máximo del sistema operativo, que es el valor NativeWindow.systemMaxSize.
• La anchura y altura máximas de una ventana en Adobe AIR, que es, en ambos casos, 4095 píxeles. (En AIR 1.5 y versiones anteriores, el ancho y alto máximo de una ventana 2.880 píxeles.)

Nota: en algunos sistemas operativos como Mac OS X, al maximizar una ventana únicamente se amplía hasta el valor de maxSize incluso si la ventana maximizada es más pequeña que la pantalla del sistema operativo. La ventana permanece en su estado de maximización.

Elementos de API relacionados

windowObj.maxSize = new Point(1040,920);

displayObject.stage.nativeWindow.maxSize = new Point(800,600);

window.nativeWindow.maxSize = new air.Point(960,960);

Menú nativo de la ventana.

Si se asigna un objeto NativeMenu a la propiedad menu de la ventana, se visualiza un menú nativo en la ventana si NativeWindow.supportsMenu es true, a no ser que la propiedad systemChrome de la ventana sea NativeWindowSystemChrome.NONE.

Nota: está permitido asignar asigna un menú a una ventana si su propiedad NativeWindow.supportsMenu es false o si la propiedad systemChrome es NativeWindowSystemChrome.NONE, pero no produce ningún efecto. Asegúrese de utilizar la propiedad NativeWindow.supportsMenu para determinar si el sistema operativo admite menús de ventana. El uso de otros medios (como Capabilities.os) para determinar la compatibilidad puede producir errores de programación (si no se tienen en cuenta determinados sistemas operativos de destino).

Elementos de API relacionados

Informa sobre la configuración de minimización utilizada para crear la ventana.

No es posible modificar la configuración de minimizable una vez creada la ventana.

Nota: algunos gestores de ventanas de Linux permiten que el usuario minimice las ventanas incluso cuando la propiedad minimizable se establece en false.

Elementos de API relacionados

Tamaño mínimo de la ventana.

El límite del tamaño se especifica como coordenadas de un objeto Point. La propiedad x del punto corresponde a la anchura de la ventana y la propiedad y, a la altura de la ventana.

Al configurar minSize, cambian los límites de la ventana si están por debajo del nuevo tamaño mínimo.

La restricción minSize se fuerza para operaciones de cambio de tamaño de ventana invocadas mediante código ActionScript y a través del sistema operativo.

Nota: la anchura y la altura de cualquier fondo cromático del sistema operativo pueden imposibilitar la creación de ventanas con tamaño inferior al tamaño mínimo especificado.

Elementos de API relacionados

windowObj.minSize = new Point(200,80);

displayObject.stage.nativeWindow.minSize = new Point(120,60);

window.nativeWindow.minSize = new air.Point(80,60);

El objeto NativeWindow al que pertenece esta ventana.

La propiedad de la ventana se establece al crear la ventana y no se puede cambiar. Para crear una ventana con propietario, establezca el objeto NativeWindow como la propiedad owner del objeto NativeWindowInitOptions utilizado para crear la ventana perteneciente.

Nota: en Linux, algunos administradores de ventanas no se muestran ventanas pertenecientes delante de la ventana cuando el propietario está en modo de pantalla completa.

Elementos de API relacionados

Informa sobre el parámetro renderMode de ventana utilizado para crear la ventana.

El valor devuelto por NativeWindow.renderMode son una de las constantes definidas en la clase NativeWindowRenderMode.

No es posible modificar la configuración de renderMode una vez creada la ventana.

Elementos de API relacionados

Informa sobre la configuración de cambio de tamaño utilizada para crear la ventana.

No es posible modificar la configuración de resizable una vez creada la ventana.

Elementos de API relacionados

Objeto Stage para esta ventana. El objeto Stage es el objeto raíz de la arquitectura de la lista de visualización empleada en el contenido SWF basado en ActionScript 3.0.

El escenario es la raíz de la lista de visualización de la ventana. Para añadir objetos visuales a una ventana, basta con añadirlos al escenario o a otro objeto ya presente en la lista de visualización del escenario. Las dimensiones del escenario coinciden con las de la zona cliente de la ventana si se utiliza el fondo cromático del sistema. Las dimensiones del escenario coinciden con las de la ventana si no se utiliza el fondo cromático del sistema.

Elementos de API relacionados

import flash.display.StageAlign;

windowObj.stage.align = StageAlign.TOP_LEFT;

Indica si AIR admite menús de ventanas activas en el sistema operativo actual.

Si NativeWindow.supportsMenu es true, se muestra un menú nativo en la ventana si se asigna un objeto NativeMenu a la propiedad menu de la ventana, a no ser que la propiedad systemChrome de la ventana sea NativeWindowSystemChrome.NONE). Asegúrese de utilizar la propiedad NativeWindow.supportsMenu para determinar si el sistema operativo admite menús de ventana nativos. El uso de otros medios (como Capabilities.os) para determinar la compatibilidad puede producir errores de programación (si no se tienen en cuenta determinados sistemas operativos de destino).

Nota: está permitido asignar asigna un menú a una ventana si su propiedad NativeWindow.supportsMenu es false o si la propiedad systemChrome es NativeWindowSystemChrome.NONE, pero no produce ningún efecto.

Elementos de API relacionados

Indica si AIR admite avisos de notificación de ventana en el sistema operativo actual.

Cuando NativeWindow.supportsNotification es true, llamar al método notifyUser() de la ventana genera un aviso visual para informar al usuario de que se ha producido un evento de interés. Este aviso visual se ajusta a las convenciones del sistema operativo del sistema nativo. Por ejemplo, en Windows^®, el icono de la barra de tareas comienza a parpadear.

Nota: llamar a notifyUser() cuando NativeWindow.supportsNotification es false está permitido, pero no tiene ningún efecto.

Elementos de API relacionados

Indica si AIR admite ventanas nativas con píxeles transparentes.

Si NativeWindow.supportsTransparency es true, la proporciona transparencia en píxeles en la ventana nativa, si la propiedad transparent de la ventana está definida como true. La opacidad de todos los píxeles se establece en 1 si NativeWindow.supportsTransparency es false, independientemente del valor de la propiedad transparent de la ventana. Los píxeles totalmente transparentes se representan como puntos negros si NativeWindow.supportsTransparency es false. Asegúrese de utilizar la propiedad NativeWindow.supportsTransparency para determinar si el sistema operativo admite transparencia. El uso de otros medios (como Capabilities.os) para determinar la compatibilidad puede producir errores de programación (si no se tienen en cuenta determinados sistemas operativos de destino).

Nota: el valor de esta propiedad puede cambiar mientras se ejecuta la aplicación; depende de las preferencias que el usuario haya configurado en el sistema operativo.

Elementos de API relacionados

Informa sobre la configuración del fondo cromático del sistema utilizada para crear la ventana.

Los valores devueltos por NativeWindow.systemChrome son una de las constantes definidas en la clase NativeWindowSystemChrome.

No es posible modificar la configuración de los controles de aspecto del sistema una vez creada la ventana.

Elementos de API relacionados

var sysChromeType:String = windowObj.systemChrome;

var sysChromeType:String = displayObject.stage.nativeWindow.systemChrome;

var sysChromeType = window.nativeWindow.systemChrome;

import flash.display.NativeWindow;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowInitOptions;

public function deChromeWindow(oldWindow:NativeWindow):NativeWindow{
    if(oldWindow.systemChrome != NativeWindowSystemChrome.NONE){
        var newOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
        newOptions.systemChrome = NativeWindowSystemChrome.NONE;
        newOptions.transparent = true;
        
        var newWindow:NativeWindow = new NativeWindow(newOptions);
        newWindow.stage.stageWidth = oldWindow.stage.stageWidth;
        newWindow.stage.stageHeight = oldWindow.stage.stageHeight;
        newWindow.stage.align = oldWindow.stage.align;
        newWindow.stage.scaleMode = oldWindow.stage.scaleMode;
        
        for(var i:int = 0; i < oldWindow.stage.numChildren; i++){
            newWindow.stage.addChild(oldWindow.stage.getChildAt(i));
        }
        newWindow.activate();
        oldWindow.close();
        
        return newWindow;
    }
    return oldWindow;
}

Tamaño más grande de ventana admitido por el sistema operativo.

El límite del tamaño se especifica como coordenadas de un objeto Point. La propiedad x del punto corresponde a la anchura de la ventana y la propiedad y, a la altura de la ventana.

Además del límite de tamaño impuesto por el sistema operativo, AIR tiene un tamaño de ventana máximo de 4.095 por 4.095 píxeles (2.880 píxeles por 28.80 píxeles en AIR 1.5 y versiones anteriores). Una aplicación puede establecer un límite utilizando la propiedad maxSize del objeto NativeWindow.

Tamaño más pequeño de ventana admitido por el sistema operativo.

El límite del tamaño se especifica como coordenadas de un objeto Point. La propiedad x del punto corresponde a la anchura de la ventana y la propiedad y, a la altura de la ventana.

Título de la ventana.

El título aparece en los controles de aspecto del sistema de la ventana, en caso de mostrarse, y en otras ubicaciones que dependen del sistema (por ejemplo, la barra de tareas).

windowObj.title = "Window Title";

Informa sobre la configuración de tranparencia del sistema utilizada para crear la ventana.

No es posible modificar la propiedad transparent una vez creada la ventana. La transparencia afecta tanto a la apariencia visual como al comportamiento del ratón en la ventana. En Windows y Mac OS X, la ventana no captura los eventos de ratón si el valor de alfa del píxel está por debajo de un umbral determinado, que oscila entre 0,6 y 0,1 en función del sistema operativo. En Linux, la ventana captura eventos de ratón sobre áreas totalmente transparentes, por lo que los usuarios no pueden acceder a otras ventanas y elementos del escritorio.

Nota: no siempre se admite la transparencia de las ventanas. Si la configuración del sistema operativo del usuario no permite la transparencia, la ventana se creará sin ella. Las zonas que deberían ser transparentes se visualizan en negro. Utilice la propiedad NativeWindow.supportsTransparency para determinar si se admite la transparencia de las ventanas.

Elementos de API relacionados

Informa sobre el parámetro type de ventana utilizado para crear la ventana.

Los valores devueltos por NativeWindow.type son una de las constantes definidas en la clase NativeWindowType.

No es posible modificar la configuración de type una vez creada la ventana.

Elementos de API relacionados

Especifica si la ventana está visible.

Una ventana invisible no se muestra en el escritorio, pero todas sus propiedades y métodos conservan su validez.

De forma predeterminada, visible se establece como false. Para visualizar una ventana, establezca visible como true o llame a NativeWindow.activate().

Si la ventana tiene un propietario, el estado visible estado de dicha ventana determina si se visualiza la ventana. Si no se visualiza la ventana propietaria, no se visualizará ninguna ventana que le pertenezca, incluso si sus propiedades visible son true.

Nota: en Mac OS X, al definir visible=false en una ventana minimizada no se elimina el icono de la ventana del Dock. Si el usuario hace clic de nuevo en el icono del Dock, la ventana vuelve al estado visible y se visualiza en el escritorio.

Elementos de API relacionados

windowObj.visible = true;

displayObj.stage.nativeWindow.visible = true;

window.nativeWindow.visible = true;

Anchura de la ventana, en píxeles.

Las dimensiones de una ventana nativa incluyen los controles de aspecto de la ventana del sistema que aparece. La anchura del área de visualizacíon utilizable dentro de una ventana está disponible en la propiedad Stage.stageWidth.

Cambiar la propiedad width de una ventana equivale a cambiar la anchura mediante la propiedad bounds.

Si la anchura especificada es menor o mayor que el valor de anchura máximo permitido, la anchura de la ventana se fija en el tamaño permitido más cercano. Los factores que determinan la anchura máxima y mínima son los siguientes:

• Las propiedades minSize.y y maxSize.y del objeto NativeWindow
• Los límites máximo y mínimo del sistema operativo, que son los valores de NativeWindow.systemMinSize.y y NativeWindow.systemMaxSize.y.
• La anchura máxima de una ventana en Adobe AIR, que es 4.095 píxeles (2.880 píxeles en AIR 1.5 y versiones anteriores).

En Linux, establecer la propiedad width es una operación asíncrona.

Para detectar si se ha completado el cambio de anchura, detecte el evento resize que se distribuye en todas las plataformas.

Los valores de píxeles se redondean al entero más próximo cuando cambia el ancho de la ventana.

Elementos de API relacionados

Coordenada del eje horizontal de la esquina superior izquierda de la ventana con relación al origen del escritorio del sistema operativo.

En sistemas con más de un monitor, x puede ser un valor negativo. Si guarda el valor, tal vez para que una ventana regrese a su posición anterior, siempre debe verificar que la ventana se coloca en una ubicación válida al recolocarla. Los cambios de resolución de pantalla o la disposición de los monitores puede hacer que la ventana quede fuera de la pantalla. Utilice la clase Screen para obtener información sobre la geometría del escritorio.

Cambiar la propiedad x de una ventana equivale a cambiar la ubicación mediante la propiedad bounds.

En Linux, establecer la propiedad x es una operación asíncrona.

Para detectar si se ha completado el cambio de posición, detecte el evento move que se distribuye en todas las plataformas.

Los valores de píxeles se redondean al entero más próximo cuando cambia la coordenada x de la ventana.

Elementos de API relacionados

Coordenada del eje vertical de la esquina superior izquierda de la ventana con relación a la esquina superior izquierda del escritorio del sistema operativo.

En sistemas con más de un monitor, y puede ser un valor negativo. Si guarda el valor, tal vez para que una ventana regrese a su posición anterior, siempre debe verificar que la ventana se coloca en una ubicación válida al recolocarla. Los cambios de resolución de pantalla o la disposición de los monitores puede hacer que la ventana quede fuera de la pantalla. Utilice la clase Screen para obtener información sobre la geometría del escritorio.

Cambiar la propiedad y de una ventana equivale a cambiar la ubicación mediante la propiedad bounds.

En Linux, establecer la propiedad y es una operación asíncrona.

Para detectar si se ha completado el cambio de posición, detecte el evento move que se distribuye en todas las plataformas.

Los valores de píxeles se redondean al entero más próximo cuando cambia la coordenada y de la ventana.

Elementos de API relacionados

Crea una nueva instancia de NativeWindow y la ventana del sistema operativo correspondiente.

La configuración definida en el parámetro initOptions no se puede modificar una vez creada la ventana. Una configuración no válida de initOptions hace que se emita un error de funcionamiento no permitido. La configuración válida pero no disponible en el sistema operativo no emite ninguna excepción. Se puede detectar la funcionalidad concreta de la ventana en el sistema operativo actual, si es necesario, utilizando miembros NativeWindow estáticos como systemMaxSize.

El tamaño predeterminado de la ventana lo determina el sistema operativo, y las ventanas se crean en estado invisible. Para impedir que se realicen cambios en la ventana y deje de ser visible, no cambie la propiedad visible de la ventana a true ni llame a activate() hasta que haya finalizado los cambios en la ventana.

Elementos de API relacionados

import flash.display.NativeWindowInitOptions;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowType;
import flash.display.NativeWindow;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.geom.Rectangle;

var windowOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
windowOptions.systemChrome = NativeWindowSystemChrome.STANDARD;
windowOptions.type = NativeWindowType.NORMAL;

var newWindow:NativeWindow = new NativeWindow(windowOptions);
newWindow.stage.scaleMode = StageScaleMode.NO_SCALE;
newWindow.stage.align = StageAlign.TOP_LEFT;
newWindow.bounds = new Rectangle(100, 100, 800, 800);

newWindow.activate();

Activa la ventana.

Al activar una ventana ocurre lo siguiente:

• La ventana se hace visible
• La ventana se trae al frente
• La ventana admite selección de teclado y de ratón

En Linux, activate() es una operación asíncrona.

El objeto NativeWindow distribuye un evento activate en todas las plataformas.

Elementos de API relacionados

displayObject.stage.nativeWindow.activate();

windowObj.activate();

window.nativeWindow.activate();

Cierra la ventana.

Se distribuye un evento close justo cuando finaliza la operación de cierre. No se distribuye ningún evento closing. Si es posible cancelar la operación close, se distribuye un evento closing y se comprueba si algún detector registrado cancela el comportamiento predeterminado antes de llamar al método close().

Cuando una ventana está cerrada, las ventanas que le pertenecen también se cierran. Las ventanas que le pertenecen no distribuyen eventos closing.

Si no se hace referencia a las instancias del objeto de visualización de la pantalla, se eliminan los datos innecesarios salvo en la ventana inicial de la aplicación creada por AIR. Para que los objetos de visualización puedan eliminar los datos innecesarios, quítelos del escenario de la ventana.

Una vez cerrado, el objeto NativeWindow sigue siendo una referencia válida, pero al acceder a la mayoría de propiedades y métodos, se emite un error de funcionamiento no permitido.

Las ventanas cerradas no se pueden volver a abrir. Si la ventana ya está cerrada, no se realiza ninguna acción ni se distribuyen eventos.

Nota: para ocultar una ventana sin cerrarla, establezca la propiedad visible de la ventana como false.

Elementos de API relacionados

windowObj.close();

displayObj.stage.nativeWindow.close();

window.close(); //overriddable in HTMLHost

window.nativeWindow.close(); //not overriddable

public function closeCommand():Boolean{
    var closeEvent:Event = new Event(Event.CLOSING,true,true);
    windowObj.dispatchEvent(closeEvent);
    if(!closeEvent.isDefaultPrevented()){
        windowObj.close();
        return true;
    } else {
      return false;
    }
}

<script src="AIRAliases.js" type="text/javascript"></script>
<script type="text/javascript">
    var dirtyData = false;
    function closeWindow(){
            var closingEvent = new air.Event(air.Event.CLOSING,true,true);
            window.nativeWindow.dispatchEvent(closingEvent);
               if(!closingEvent.isDefaultPrevented()){
                   window.nativeWindow.close();
                //or use: window.close(); 
               return true;
           } else {
               return false;
        }
    }
        
    function onClosing(event){
        if(dirtyData){
            event.preventDefault();
            //Save data...
        }
    }    

    window.nativeWindow.addEventListener(air.Event.CLOSING,onClosing);        
</script>

Convierte un punto en coordenadas de píxeles relativas al origen del escenario de la ventana (un punto global, en términos de lista de visualización) en un punto del escritorio virtual.

Las coordenadas del escritorio virtual se miden en relación a la esquina superior izquierda del monitor principal.

Parámetros

Elementos de API relacionados

Devuelve una lista con los objetos NativeWindow que pertenecen a esta ventana.

No se puede cambiar propiedad de NativeWindows añadiendo o eliminando objetos de la vector devuelto. La propiedad de la ventana no se puede modificar una vez creada la ventana.

Elementos de API relacionados

Maximiza esta ventana.

Al llamar a maximize() se distribuye un evento displayStateChange y, si procede, un evento move y resize. Aunque el fondo cromático del sistema distribuye un evento displayStateChanging que se puede cancelar con un comando maximize iniciado por el usuario, la lógica de maximize debe implementar este comportamiento, si es necesario.

El método maximize() se ejecuta asíncronamente. Para saber si ha finalizado el cambio de estado, detecte el evento displayStateChange. Si la ventana ya está maximizada, no se realiza ninguna acción ni se distribuyen eventos.

Notas sobre el comportamiento del SO:

• En sistemas operativos como Mac OS X (donde al maximizar una ventana no se impide su cambio de tamaño), llamar a maximize() aumenta la ventana hasta llenar toda la pantalla, pero no evita sucesivos cambios de tamaño. Si se cambia el tamaño de una ventana ampliada, también se restaura su estado de visualización.
• En algunos sistemas operativos como Mac OS X, así como en algunos gestores de ventanas de Linux, al maximizar la ventana, ésta no va más allá de la anchura y la altura especificadas en la propiedad maxSize. En otros, la ventana se amplía para llenar toda la pantalla incluso si el tamaño de la pantalla supera el valor de maxSize.
• Algunos gestores de ventanas de Linux no permiten maximizar las ventanas de utilidades.

Elementos de API relacionados

public function maximizeWindow(nativeWin:NativeWindow):Boolean{
  if(nativeWin.displayState != NativeWindowDisplayState.MAXIMIZED){
    var beforeState:String = nativeWin.displayState;
    var afterState:String = NativeWindowDisplayState.MAXIMIZED;
    var displayStateEvent:NativeWindowDisplayStateEvent = 
        new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
    nativeWin.dispatchEvent(displayStateEvent);
    if(!displayStateEvent.isDefaultPrevented()){
        nativeWin.maximize();
        return true;
    } else {
      return false;
    }
  }
  return false;
}

function maximizeWindow(nativeWin){
    if(nativeWin.displayState != air.NativeWindowDisplayState.MAXIMIZED){
        var beforeState = nativeWin.displayState;
        var afterState = air.NativeWindowDisplayState.MAXIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.maximize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

Minimiza esta ventana.

Al llamar a minimize() se distribuye un evento displayStateChange y, si procede, un evento move y resize. El fondo cromático del sistema distribuye un evento displayStateChanging que se puede cancelar mediante un comando minimize iniciado por el usuario, pero llamar a minimize() no cumple este cometido. La lógica de minimize puede implementar este comportamiento, si es necesario.

El método minimize() se ejecuta asíncronamente. Para detectar si se ha completado el cambio de estado, detecte el evento displayStateChange que se distribuye en todas las plataformas. Si la ventana ya está minimizada, no se realiza ninguna acción ni se distribuyen eventos.

Las ventanas pertenecientes a este ventana están ocultas cuando está minimizada. Las ventanas pertenecientes no distribuyen eventos displayStateChanging, o displayStateChange.

Notas:

• En Windows, minimizar una ventana invisible (visible == false) hace que la ventana se haga visible.
• Algunos gestores de ventanas de Linux no permiten minimizar las ventanas de utilidades.

Elementos de API relacionados

public function minimizeWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.MINIMIZED){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

 
function minimizeWindow(){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.MINIMIZED){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

Activa un aviso visual a través del sistema operativo para indicar que el evento correspondiente se ha producido.

Si NativeWindow.supportsNotification es true, el aviso visual se ajusta a la convención del sistema operativo en el sistema nativo. Por ejemplo, en Windows, el icono de la barra de tareas comienza a parpadear.

El parámetro type determina la intensidad del aviso. Las constantes de los valores permitidos se definen en la clase NotificationType y pueden ser:

• NotificationType.INFORMATIONAL
• NotificationType.CRITICAL

Los avisos proporcionados para las notificaciones informativas son de corta duración; los que se facilitan para notificaciones críticas permanecen habilitados hasta que el usuario activa la ventana. No todos los gestores de ventanas de Linux admiten dos niveles de notificación. En dichos gestores, notifyUser() tendrá el mismo efecto, independientemente de la opción especificada.

Nota: llamar a notifyUser() cuando NativeWindow.supportsNotification es false está permitido, pero no tiene ningún efecto.

Parámetros

Envía este ventana directamente detrás de la ventana especificada.

No activa ni adquiere la selección para esta ventana o para la aplicación. Las ventanas minimizadas u ocultas (visible es false) no se pueden reordenar.

Una ventana perteneciente nunca se puede mover detrás de su propietaria. Si esta ventana tiene un propietario, el propietario y sus demás ventanas pertenecientes también se ordenan detrás del destino. Si la ventana de destino tiene un propietario, esta ventana se ordena detrás del propietario de la de destino.

En algunos gestores de ventanas de Linux no es posible permitir que las ventanas se ordenen detrás de las ventanas de utilidades.

Parámetros

windowBehind.orderInBackOf(windowFront);

displayObjBehind.stage.nativeWindow.orderInBackOf(displayObjectFront.stage.nativeWindow);

jsWindowObjBehind.nativeWindow.orderInBackOf(jsWindowObjFront.nativeWindow);

Pone esta ventana directamente delante de la ventana especificada.

No activa ni adquiere la selección para esta ventana o para la aplicación. Las ventanas minimizadas u ocultas (visible es false) no se pueden reordenar.

Una ventana nunca se puede mover delante de una ventana que le pertenece. Si esta ventana tiene un propietario, el propietario y sus demás ventanas pertenecientes también se ordenan delante del destino. Si la ventana de destino tiene un propietario, la ventana también se ordena por delante de cualquier otra ventana que tenga el mismo propietario que el destino.

En algunos gestores de ventanas de Linux no es posible permitir que las ventanas se ordenen delante de las ventanas de utilidades.

Parámetros

windowFront.orderInFrontOf(windowBehind);

displayObjFront.stage.nativeWindow.orderInFrontOf(displayObjectBehind.stage.nativeWindow);

jsWindowObjFront.nativeWindow.orderInFrontOf(jsWindowObjBehind.nativeWindow);

Pone esta ventana detrás de cualquier otra ventana visible.

No activa ni adquiere la selección para esta ventana o para la aplicación. Las ventanas minimizadas u ocultas (visible es false) no se pueden reordenar.

Si alwaysInFront es true, llamar a este método no pondrá la ventana detrás cualquier otra que tenga alwaysInFront como false.

Una ventana perteneciente nunca se puede mover detrás de su propietaria. Si esta ventana tiene un propietario, el propietario y sus demás ventanas pertenecientes también se ordenan en la parte inferior de la lista de visualización de la ventana. Esta ventana se moverá detrás de cualquier otra ventana perteneciente a la misma ventana. Si la ventana es propietaria de otras ventanas, esas ventanas también se mueven a la parte posterior, sin perder su orden actual con respecto a los demás.

En algunos gestores de ventanas de Linux no es posible permitir que las ventanas se ordenen detrás de las ventanas de utilidades.

windowObj.orderToBack();

displayObj.stage.nativeWindow.orderToBack();

window.nativeWindow.orderToBack();

Pone esta ventana por delante de cualquier otra ventana visible.

No activa ni adquiere la selección para esta ventana o para la aplicación. Las ventanas minimizadas u ocultas (visible es false) no se pueden reordenar.

Si alwaysInFrontes false, llamar a este método no pondrá la ventana por delante de cualquier otra que tenga alwaysInFront como true.

Una ventana nunca se puede mover delante de una ventana que le pertenece. Si la ventana es propietaria de otras ventanas, esas ventanas también se mueven a la parte delantera, sin perder su orden actual con respecto a los demás. Si esta ventana tiene un propietario, el propietario y sus demás ventanas pertenecientes también se ordenan en la parte delantera del orden de visualización de la ventana. Esta ventana se mueve delante de otras ventanas que tengan el mismo propietario.

En algunos gestores de ventanas de Linux no es posible permitir que las ventanas se ordenen delante de las ventanas de utilidades.

windowObj.orderToFront();

displayObj.stage.nativeWindow.orderToFront();

window.nativeWindow.orderToFront();

Restaura la ventana desde su estado minimizado o maximizado.

Al llamar a restore() se distribuye un evento displayStateChange y, si procede, un evento move y resize. Aunque el fondo cromático del sistema distribuye un evento displayStateChanging que se puede cancelar con un comando restore iniciado por el usuario, la lógica de restore debe implementar este comportamiento, si es necesario.

Si la ventana ya tiene el estado NativeWindowDisplayState.NORMAL, no se realiza ninguna acción ni se distribuyen eventos.

Para detectar si se ha completado el cambio de estado, detecte el evento displayStateChange que se distribuye en todas las plataformas.

Elementos de API relacionados

public function restoreWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.NORMAL){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.NORMAL;
        var displayStateChangingEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateChangingEvent);
        if(!displayStateChangingEvent.isDefaultPrevented()){
            nativeWin.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

function restoreWindow(nativeWin){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.NORMAL){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.NORMAL;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

Inicia un movimiento de la ventana controlado por el sistema.

Cuando se llama desde un evento mouseDown, este método inicia una secuencia de movimientos de ratón que continúa hasta que se produce un evento mouseUp.

Cuando se llama desde otro código, este me´todo inicia una secuencia de movimientos de ratón o de teclado según el patrón predeterminado del sistema operativo.

Durante la secuencia de movimientos, se distribuye una serie de eventos a medida que se mueve el origen de la ventana. En cada movimiento adicional, primero se distribuye un evento moving y, después, si no se cancela el evento moving, se actualiza la ubicación de la ventana y se distribuye un evento move. Si se cancela un evento moving, la secuencia de movimientos finaliza inmediatamente.

var initOpts:NativeWindowInitOptions = new NativeWindowInitOptions();
var win:NativeWindow = new NativeWindow(initOpts);
win.activate();
win.stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);

function mouseDownHandler(event:MouseEvent):void
{
    win.startMove();
}

Inicia una operación de cambio de tamaño de la ventana controlada por el sistema.

Cuando se llama desde un controlador de eventos mouseDown, este método inicia una secuencia de cambio de tamaño activada desde el ratón que continúa hasta que se produce un evento mouseUp.

Cuando se llama desde otro código, este método inicia una secuencia de cambio de tamaño activada desde el ratón o el teclado según el patrón predeterminado del sistema operativo.

Durante la secuencia de cambio de tamaño, se distribuye una serie de eventos a medida que cambian las dimensiones de la ventana. En cada cambio adicional, primero se distribuye un evento resize y, después, si no se cancela el evento resize, se actualizan las dimensiones de la ventana y se distribuye un evento resize. Si se cancela un evento resizing, la secuencia de movimientos finaliza inmediatamente.

Parámetros

Elementos de API relacionados

stage.addEventListener(MouseEvent.MOUSE_DOWN, onResizeCommand);

function onResizeCommand(event:MouseEvent):void
{
    var win:NativeWindow = event.target.nativeWindow;
    var resizeFrom:String = "";
    if (event.stageY < win.height * .33)
    {
        resizeFrom = NativeWindowResize.TOP;
    }
    else if (event.stageY > win.height * .66)
    {
        resizeFrom = NativeWindowResize.BOTTOM;
    }
    if (event.stageX < win.width * .33)
    {
        resizeFrom += NativeWindowResize.LEFT;
    }
    else if (event.stageX > win.width * .66)
    {
        resizeFrom += NativeWindowResize.RIGHT;
    }
    win.startResize(resizeFrom);    
}

Se distribuye por el objeto NativeWindow una vez activada la ventana.

Nota: este evento no tiene ni "fase de captura" ni "fase de propagación", lo que significa que los detectores de eventos deben añadirse directamente a cualquier destino potencial, se encuentre o no en la lista de visualización.

Los dispositivos de AIR para TV nunca distribuyen automáticamente este evento. El usuario puede, sin embargo, distribuirlo manualmente.

Este evento tiene las propiedades siguientes:

Se distribuye por el objeto NativeWindow una vez cerrada la ventana.

Este evento tiene las propiedades siguientes:

Se distribuye por el objeto NativeWindow inmediatamente antes de que se cierre la ventana. Este evento se puede cancelar para impedir que se cierre la ventana.

Este evento tiene las propiedades siguientes:

Se distribuye por el objeto NativeWindow una vez desactivada la ventana.

Nota: este evento no tiene ni "fase de captura" ni "fase de propagación", lo que significa que los detectores de eventos deben añadirse directamente a cualquier destino potencial, se encuentre o no en la lista de visualización.

Los dispositivos de AIR para TV nunca distribuyen automáticamente este evento. El usuario puede, sin embargo, distribuirlo manualmente.

Este evento tiene las propiedades siguientes:

Se distribuye por el objeto NativeWindow cuando la propiedad displayState de la ventana cambia.

No cambie de tamaño la ventana ni su estado de visualización en el controlador de eventos displayStateChange.

Este evento tiene las propiedades siguientes:

Distribuido por este objeto NativeWindow inmediatamente antes de que cambie su estado de visualización. Este evento se puede cancelar para impedir el cambio.

Este evento tiene las propiedades siguientes:

function displayStateChanging_handler(displayStateEvent:NativeWindowDisplayStateEvent):void
{
  //shouldStopStateChange is an application-defined Boolean indicating 
  //that display state changes should be canceled
  if (displayStateEvent.type == NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING 
                                  &&    shouldStopStateChange)
  {
    displayStateEvent.preventDefault();
  }
}

Distribiuido por el objeto NativeWindow cuando la ventana se mueve en el escritorio.

Se distribuye un evento move cada vez que cambia el origen de la ventana (propiedades x o y). Esto puede ocurrir cuando el sistema controla el movimiento de las ventanas, cuando se minimiza, maximiza o restaura una ventana, o bien cuando se cambia la ubicación de la ventana modificando las propiedades x, y o bounds.

Nota: evite acciones que puedan abrir simultáneamente cuadros de diálogo del sistema operativo en las funciones de controlador de los eventos moving y move de NativeWindow. Esto puede ocurrir, por ejemplo, si dos funciones de controlador emiten un error. Si esto ocurriese, el segundo cuadro de diálogo abierto no registra la acción del ratón y debe cerrarse con el teclado.

Este evento tiene las propiedades siguientes:

Se distribuye por el objeto NativeWindow inmediatamente antes de que se mueva la ventana en el escritorio. Este evento se puede cancelar para impedir el movimiento o modificar sus valores.

Nota: evite acciones que puedan abrir simultáneamente cuadros de diálogo del sistema operativo en las funciones de controlador de los eventos moving y move de NativeWindow. Esto puede ocurrir, por ejemplo, si dos funciones de controlador emiten un error. Si esto ocurriese, el segundo cuadro de diálogo abierto no registra la acción del ratón y debe cerrarse con el teclado.

Este evento tiene las propiedades siguientes:

Nota: en Linux, el método preventDefault() no se admite para este evento.

Se distribuye por el objeto NativeWindow una vez cambiado el tamaño de la ventana. Se distribuye un evento resize cada vez que cambia el tamaño de la ventana (propiedades width o height). Esto puede ocurrir cuando el sistema controla el cambio de tamaño de las ventanas, cuando se minimiza, maximiza o restaura una ventana, o bien cuando se cambia el tamaño de la ventana modificando las propiedades width, height o bounds. Los eventos resize de NativeWindow se distribuyen en bucles de cambio de tamaño controlados por el sistema. Por el contrario, los eventos resize del objeto Stage se distribuyen cuando el escenario está listo para el dibujo.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye por el objeto NativeWindow inmediatamente antes de que se cambie el tamaño de la ventana en el escritorio. Este evento se puede cancelar para impedir el cambio de tamaño o modificar sus valores.

Este evento tiene las propiedades siguientes:

Nota: en Linux, el método preventDefault() no se admite para este evento.

function boundsChanging_handler(boundsEvent:NativeWindowBoundsEvent):void
{
  //shouldStopResize is an application-defined Boolean indicating 
  //that resize operations should be canceled
  if (boundsEvent.type == NativeWindowBoundsEvent.RESIZING && shouldStopResize)
  {
    boundsEvent.preventDefault();
  }
}