Label  - AS3 Flash

Ruft einen String ab bzw. legt einen String fest, der angibt, wie die Größe und Ausrichtung der Beschriftung an den Wert der Eigenschaft text angepasst werden. Folgende Werte sind gültig:

• TextFieldAutoSize.NONE: Größe und Ausrichtung der Bezeichnung werden nicht an den Text angepasst.
• TextFieldAutoSize.LEFT: Die Bezeichnung wird am rechten und unteren Rand an den Text angepasst. Linker und oberer Rand werden nicht verändert.
• TextFieldAutoSize.CENTER: Die Bezeichnung wird am linken und rechten Rand an den Text angepasst. Die horizontale Mitte der Bezeichnung bleibt an der Position der ursprünglichen horizontalen Mitte verankert.
• TextFieldAutoSize.RIGHT: Die Bezeichnung wird am linken und unteren Rand an den Text angepasst. Oberer und rechter Rand werden nicht verändert.

Der Standardwert ist TextFieldAutoSize.NONE.

Verwandte API-Elemente

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Ruft einen Wert ab, der angibt, ob zusätzliche Leerraumzeichen wie Leerzeichen oder Zeilenumbrüche aus einer HTML-Text enthaltenen Label-Komponente entfernt werden, oder legt diesen fest. Der Wert true gibt an, dass Leerräume entfernt werden, der Wert false, dass diese beibehalten werden.

Die Eigenschaft condenseWhite betrifft nur Text mit der Eigenschaft htmlText, nicht mit der Eigenschaft text. Wenn Sie die Eigenschaft text zum Einrichten von Text verwenden, wird die Eigenschaft condenseWhite ignoriert.

Wenn Sie die Eigenschaft condenseWhite auf true setzen, müssen Sie HTML-Standardbefehle verwenden, beispielsweise <br> und <p>, um im Textfeld Zeilenumbrüche zu setzen.

Der Standardwert ist false.

Verwandte API-Elemente

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Ruft die Höhe der Komponente in Pixeln ab oder legt diese fest.

Durch Festlegen dieser Eigenschaft wird ein resize-Ereignis ausgelöst. Weitere Informationen dazu, wann dieses Ereignis ausgelöst wird, finden Sie im Abschnitt zum resize-Ereignis.

Falls die Eigenschaft scaleY der Komponente nicht 1.0 beträgt, stimmt die auf Basis der internen Koordinaten erhaltene Höhe der Komponente nicht mit dem Höhenwert der übergeordneten Koordinaten überein. Beispiel: Eine Komponente mit einer Höhe von 100 Pixeln und einer scaleY-Eigenschaft von 2 weist für die übergeordneten Koordinaten einen Wert von 100 Pixeln auf, speichert jedoch einen Höhenwert von 50 Pixeln.

Verwandte API-Elemente

Ruft den von der Label-Komponente angezeigten Text einschließlich HTML-Markups ab, mit denen der Textstil angegeben wird, oder legt diesen fest. Sie können bei dieser Eigenschaft HTML-Text angeben, indem Sie eine Untermenge von HTML-Tags verwenden, die vom TextField-Objekt unterstützt wird.

Wenn Sie den Standardwert der Eigenschaft text im Eigenschafteninspektor ändern, hat dieser geänderte Wert Vorrang vor dem Wert der Eigenschaft htmlText im Eigenschafteninspektor. Um die Eigenschaft htmlText im Eigenschafteninspektor zu verwenden, muss das Eigenschaftenfeld text den Wert Label genau wie dargestellt enthalten. Beim Schreiben von ActionScript-Code brauchen Sie den Wert der Eigenschaft text nicht festzulegen; der Standardwert ist Label.

Der Standardwert ist "".

Verwandte API-Elemente

Ruft einen Wert ab bzw. legt einen Wert fest, der angibt, ob Text ausgewählt werden kann. Der Wert true gibt an, dass Text ausgewählt werden kann, der Wert false, dass kein Text ausgewählt werden kann.

Auswählbarer Text kann vom Benutzer aus der Label-Komponente kopiert werden.

Der Standardwert ist false.

Ruft den Nur-Text ab bzw. legt den Nur-Text fest, der von der Label-Komponente angezeigt wird.

Hinweis: Die HTML-Markup-Zeichen haben in der Zeichenfolge keine besondere Bedeutung und werden wie eingegeben angezeigt.

Verwenden Sie die Eigenschaft htmlText, um Text mit HTML-Tags anzuzeigen. Text, den Sie unter Verwendung der Eigenschaft htmlText eingeben, wird im HTML-Format angezeigt. Wenn Sie die Eigenschaft text verwenden, wird eine Nur-Text-Version des HTML-Textes ohne HMTL-Tags angezeigt.

Wenn Sie die standardmäßig im Eigenschafteninspektor vorgegebene Eigenschaft text ändern, hat diese Vorrang vor der Eigenschaft htmlText im Eigenschafteninspektor.

Der Standardwert ist "Label".

Verwandte API-Elemente

Ein Verweis auf das interne Textfeld der Label-Komponente.

Ruft die Breite der Komponente in Pixeln ab oder legt diese fest.

Durch Festlegen dieser Eigenschaft wird ein resize-Ereignis ausgelöst. Weitere Informationen dazu, wann dieses Ereignis ausgelöst wird, finden Sie im Abschnitt zum resize-Ereignis.

Falls die Eigenschaft scaleX der Komponente nicht 1.0 beträgt, stimmt die auf Basis der internen Koordinaten erhaltene Breite der Komponente nicht mit dem Breitenwert der übergeordneten Koordinaten überein. Beispiel: Eine Komponente mit einer Breite von 100 Pixeln und einer scaleX-Eigenschaft von 2 weist für die übergeordneten Koordinaten einen Wert von 100 Pixeln auf, speichert jedoch einen Breitenwert von 50 Pixeln.

Verwandte API-Elemente

Ruft einen Wert ab bzw. legt einen Wert fest, der angibt, ob das Textfeld Zeilenumbrüche unterstützt. Der Wert true gibt an, dass Zeilenumbrüche unterstützt werden, der Wert false, dass diese nicht unterstützt werden.

Der Standardwert ist false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Erstellt eine neue Instanz der Label-Komponente.

Ruft die Standardstilmatrix der aktuellen Komponente ab. Die Stilmatrix enthält den für die Komponente geeigneten Typ und hängt von dem Stil ab, der von der Komponente verwendet wird. Der Stil disabledTextFormat enthält beispielsweise den Wert null oder ein TextFormat-Objekt. Sie können diese Stile verwenden und setStyle() für die aktuelle Komponente aufrufen. Mit folgendem Code wird der Standardstil disabledTextFormat der angegebenen Komponente überschrieben:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Verwandte API-Elemente

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Wird ausgelöst, wenn sich die Breite oder Höhe einer Komponente ändert.

Hinweis: Dieses Ereignis tritt nicht ein, wenn für die Änderung des Beschriftungstextes der ActionScript-Code verwendet wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Fügen Sie die Label- und Button-Komponenten Ihrer Bibliothek hinzu.
2. Speichern Sie diesen Code unter „LabelExample.as“ im gleichen Verzeichnis wie die FLA-Datei.
3. Legen Sie für „DocumentClass“ in der FLA-Datei „LabelExample“ fest.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}