TextFormat  - AS3

Gibt die Ausrichtung des Absatzes an. Gültige Werte sind TextFormatAlign-Konstanten.

Der Standardwert ist TextFormatAlign.LEFT.

Verwandte API-Elemente

Gibt den Blockeinzug in Pixeln an. Der Blockeinzug gilt für den gesamten Textblock, d. h. für alle Textzeilen. Im Gegensatz dazu wirkt sich der normale Einzug (TextFormat.indent) nur auf die erste Zeile in einem Absatz aus. Wenn diese Eigenschaft auf null gesetzt ist, wird in diesem TextFormat-Objekt kein Blockeinzug angegeben (Blockeinzug = 0).

Gibt an, ob der Text fett formatiert wird. Der Standardwert null bedeutet, dass keine Fettformatierung erfolgt. Wenn der Wert true ist, ist der Text fett formatiert.

Gibt an, dass der Text Bestandteil einer Aufzählung ist. In einer Aufzählung ist jeder Textabsatz eingerückt. Vor der ersten Zeile in einem Absatz wird ein Aufzählungszeichen angezeigt. Der Standardwert null bedeutet, dass keine Aufzählung verwendet wird.

Gibt die Textfarbe an. Eine Zahl mit drei 8-Bit-RGB-Komponenten. 0xFF0000 ist beispielsweise Rot und 0x00FF00 Grün. Der Standardwert null bedeutet, dass in Flash Player die Farbe Schwarz (0x000000) verwendet wird.

Ein String mit dem Namen der Schriftart für Text in diesem Textformat. Der Standardwert null bedeutet, dass in Flash Player Times New Roman für den Text verwendet wird.

Gibt den Einzug vom linken Rand bis zum ersten Zeichen im Absatz an. Der Standardwert ist null, d. h., es erfolgt kein Einzug.

Verwandte API-Elemente

Gibt an, ob Text in diesem Textformat kursiv formatiert wird. Der Standardwert null bedeutet, dass keine Kursivformatierung erfolgt.

Ein boolescher Wert, der angibt, ob Kerning aktiviert (true) oder deaktiviert (false) ist. Der Begriff „Kerning“ bezeichnet die Anpassung der Pixel zwischen bestimmten Zeichenpaaren zur Verbesserung der Lesbarkeit. Diese Funktion sollte nur verwendet werden, wenn sie unbedingt erforderlich ist, beispielsweise bei Überschriften in großen Schriftarten. Kerning wird nur für eingebettete Schriftarten unterstützt.

Bestimmte Schriftarten wie Verdana und Schriftarten mit fester Breite wie Courier New unterstützen Kerning nicht.

Der Standardwert null bedeutet, dass Kerning deaktiviert ist.

Eine Ganzzahl, die den Abstand zwischen den Zeilen (leading) angibt. Der Standardwert ist null, d. h., es wird kein Zeilenabstand verwendet.

Der linke Rand des Absatzes in Pixel. Der Standardwert ist null, d. h., der linke Rand ist 0 Pixel breit.

Eine Zahl für den insgesamt verfügbaren Platz, der gleichmäßig zwischen den Zeichen aufgeteilt wird. Der Wert gibt an, wie viele Pixel Leerraum hinter jedem Zeichen einzufügen sind. Der Standardwert null bedeutet, dass ein Zeichenabstand von 0 Pixel verwendet wird. Sie können Dezimalwerte verwenden, zum Beispiel 1.75.

Der rechte Rand des Absatzes in Pixel. Der Standardwert ist null, d. h., der rechte Rand ist 0 Pixel breit.

Die Größe des Texts in diesem Textformat in Pixeln. Der Standardwert ist null, was bedeutet, das als Größe 12 verwendet wird.

Gibt benutzerdefinierte Tabstopps als Array aus nicht negativen Ganzzahlen an. Jeder Tabstopp wird in Pixeln angegeben. Wenn keine benutzerdefinierten Tabstopps definiert werden (null), wird als Standardtabstopp 4 verwendet (durchschnittliche Zeichenbreite).

Gibt das Zielfenster an, in dem der Hyperlink angezeigt werden soll. Wenn als Zielfenster ein leerer String angegeben wird, erscheint der Text im Standardzielfenster (_self). Sie können einen benutzerdefinierten Namen oder einen der folgenden vier Namen auswählen: Mit der Option _self wird der aktuelle Frame im aktuellen Fenster angegeben, mit _blank ein neues Fenster, mit _parent der dem aktuellen Frame übergeordnete Frame und mit _top der Frame der obersten Stufe im aktuellen Fenster. Wenn die Eigenschaft TextFormat.url ein leerer String oder null ist, kann sie zwar abgerufen und gesetzt werden, hat aber keine Auswirkung.

Verwandte API-Elemente

Gibt an, ob der Text mit diesem Textformat unterstrichen ist (true) oder nicht (false). Dieser Unterstreichungseffekt ähnelt dem, der mit dem <U>-Tag erzielt wird. Hierbei handelt es sich jedoch nicht um eine echte Unterstreichung, da Unterlängen nicht korrekt übersprungen werden. Der Standardwert null bedeutet, dass keine Unterstreichung verwendet wird.

Gibt die Ziel-URL für den Text in diesem Textformat an. Wenn für die Eigenschaft url ein leerer String angegeben wird, weist der Text keinen Hyperlink auf. Der Standardwert ist null, d. h., der Text weist keinen Hyperlink auf.

Hinweis: Damit der Hyperlink funktioniert, muss für den Text mit dem zugewiesenen Textformat die Eigenschaft htmlText festgelegt werden.

Verwandte API-Elemente

Erstellt ein TextFormat-Objekt mit den angegebenen Eigenschaften. Später können Sie die Eigenschaften des TextFormat-Objekts ändern, um die Formatierung von Textfeldern zu modifizieren.

Jeder Parameter kann auf den Wert null gesetzt werden, wenn er nicht definiert werden soll. Alle Parameter sind optional. Ein weggelassener Parameter wird wie ein Parameter mit dem Wert null behandelt.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Es wird eine label-Eigenschaft vom Typ „TextField“ erstellt.
2. Der Klassenkonstruktor ruft die Funktion configureLabel() auf.
3. Mit der Funktion configureLabel() wird zuerst ein neues TextField-Objekt erstellt, das anschließend der Eigenschaft label zugewiesen wird. Danach werden die Parameter wie folgt eingestellt:
   • Textfeld links ausrichten
   • Hintergrundfüllung aktivieren
   • Rahmen aktivieren.
4. Anschließend erstellt configureLabel() die lokale Variable, format und weist sie einer neuer TextFormat-Instanz mit Parametern zu, die wie folgt definiert sind:
   • Schriftart = Verdana
   • Schriftfarbe = reines Rot
   • Schriftgröße = 10
   • Unterstreichung = true.
5. Die Eigenschaft defaultTextFormat von „label“ ist auf format gesetzt, und die label-Instanz wird der Anzeigeliste hinzugefügt. In dieser wird zuerst ein Textfeld ohne Text (als kleines Feld mit weißem Hintergrund) angezeigt.
6. Zum Schluss (im Konstruktor) wird durch den Aufruf von setLabel() der label-Text auf „Hello World and welcome to the show“ gesetzt, und als Koordinaten werden x = 0 und y = 0 festgelegt.

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}