FlowGroupElement

套件	flashx.textLayout.elements
類別	public class FlowGroupElement
繼承	FlowGroupElement FlowElement Object
子類別	ParagraphFormattedElement, SubParagraphGroupElementBase

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

FlowGroupElement 類別是具有子系陣列之 FlowElement 物件的基底類別。這些類別包含 TextFlow、ParagraphElement、DivElement 及 LinkElement。

您無法直接建立 FlowGroupElement 物件。叫用新的 FlowGroupElement() 時擲出錯誤例外。

預設 MXML 屬性mxmlChildren

公用屬性

隱藏繼承公用屬性

顯示繼承公用屬性

	屬性		定義自
		alignmentBaseline : * TextLayoutFormat：指定主基線對齊的基線。	FlowElement
		backgroundAlpha : * TextLayoutFormat：背景的 Alpha (透明度) 值 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		backgroundColor : * TextLayoutFormat：文字的背景色彩 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		baselineShift : * TextLayoutFormat：從 dominantBaseline 值位移基線的量。	FlowElement
		blockProgression : * TextLayoutFormat：指定行位置為垂直或水平走向。	FlowElement
		breakOpportunity : * TextLayoutFormat：將換行文字斷行時，控制斷行的位置。	FlowElement
		cffHinting : * TextLayoutFormat：用於此文字的 CFF 提示類型。	FlowElement
		clearFloats : * TextLayoutFormat：控制文字包圍在浮動物件四周的方式。	FlowElement
		color : * TextLayoutFormat：文字的色彩。	FlowElement
		columnCount : * TextLayoutFormat：文字欄的數目 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		columnGap : * TextLayoutFormat：以像素為單位，指定欄之間所留間距空間的量 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		columnWidth : * TextLayoutFormat：以像素為單位的欄寬 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		computedFormat : flashx.textLayout.formats:ITextLayoutFormat [唯讀] 傳回對此元素使用的計算格式特質。	FlowElement
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		coreStyles : Object [唯讀] 傳回此 FlowElement 的 coreStyles。	FlowElement
		digitCase : * TextLayoutFormat：用於此文字的數字大小寫類型。	FlowElement
		digitWidth : * TextLayoutFormat：用於此文字的數字寬度類型。	FlowElement
		direction : * TextLayoutFormat：指定文字區塊內文字的預設雙向內嵌層級。	FlowElement
		dominantBaseline : * TextLayoutFormat：指定貼齊 alignmentBaseline 的元素基線，以決定行上元素的垂直位置。	FlowElement
		firstBaselineOffset : * TextLayoutFormat：指定容器中第一行的基線位置。	FlowElement
		fontFamily : * TextLayoutFormat：要使用的字體名稱，或是以逗號分隔的字體名稱清單。	FlowElement
		fontLookup : * TextLayoutFormat：要使用字體查詢。	FlowElement
		fontSize : * TextLayoutFormat：以像素為單位的文字大小。	FlowElement
		fontStyle : * TextLayoutFormat：文字樣式。	FlowElement
		fontWeight : * TextLayoutFormat：字體粗細。	FlowElement
		format : flashx.textLayout.formats:ITextLayoutFormat 直接套用至此元素的 TextLayoutFormat 屬性。	FlowElement
		id : String 指定元素的識別名稱，如此只要參照此 id 就可以設定元素的樣式。	FlowElement
		justificationRule : * TextLayoutFormat：對齊段落中文字所使用的規則。	FlowElement
		justificationStyle : * TextLayoutFormat：段落對齊所用的樣式。	FlowElement
		kerning : * TextLayoutFormat：字距微調會調整某些字元組之間的像素，以改善可讀性。	FlowElement
		leadingModel : * TextLayoutFormat：指定行距模型，它結合了行距基礎及行距方向。	FlowElement
		ligatureLevel : * TextLayoutFormat：控制字體中定義的哪些連字可用於文字。	FlowElement
		lineBreak : * TextLayoutFormat：控制容器內的文字換行 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		lineHeight : * TextLayoutFormat：文字的行距控制。	FlowElement
		lineThrough : * TextLayoutFormat：若為 true，將套用刪除線，亦即通過文字中間的線。	FlowElement
		linkActiveFormat : * TextLayoutFormat：定義正常狀態下的連結格式化特質。	FlowElement
		linkHoverFormat : * TextLayoutFormat：定義滑鼠位於連結範圍 (滑入) 時，停留狀態連結的格式化特質。	FlowElement
		linkNormalFormat : * TextLayoutFormat：定義正常狀態下的連結格式化特質。	FlowElement
		listAutoPadding : * TextLayoutFormat：當清單開始邊緣該側的邊框距離值設為 auto 時，這會將清單的開始邊緣指定為自動縮排。	FlowElement
		listMarkerFormat : * TextLayoutFormat：定義格式化特質清單標記。	FlowElement
		listStylePosition : * TextLayoutFormat：有效值為 ListStylePosition.INSIDE、ListStylePosition.OUTSIDE、FormatValue.INHERIT。若未定義預設值，則表示未設定。如果重疊顯示時未定義此屬性，則此屬性將繼承祖系的值。	FlowElement
		listStyleType : * TextLayoutFormat：有效值為 ListStyleType.UPPER_ALPHA、ListStyleType.LOWER_ALPHA、ListStyleType.UPPER_ROMAN、ListStyleType.LOWER_ROMAN、ListStyleType.NONE、ListStyleType.DISC、ListStyleType.CIRCLE、ListStyleType.SQUARE、ListStyleType.BOX、ListStyleType.CHECK、ListStyleType.DIAMOND、ListStyleType.HYPHEN、ListStyleType.ARABIC_INDIC、ListStyleType.BENGALI、ListStyleType.DECIMAL、ListStyleType.DECIMAL_LEADING_ZERO、ListStyleType.DEVANAGARI、ListStyleType.GUJARATI、ListStyleType.GURMUKHI、ListStyleType.KANNADA、ListStyleType.PERSIAN、ListStyleType.THAI、ListStyleType.URDU、ListStyleType.CJK_EARTHLY_BRANCH、ListStyleType.CJK_HEAVENLY_STEM、ListStyleType.HANGUL、ListStyleType.HANGUL_CONSTANT、ListStyleType.HIRAGANA、ListStyleType.HIRAGANA_IROHA、ListStyleType.KATAKANA、ListStyleType.KATAKANA_IROHA、ListStyleType.LOWER_ALPHA、ListStyleType.LOWER_GREEK、ListStyleType.LOWER_LATIN、ListStyleType.UPPER_ALPHA、ListStyleType.UPPER_GREEK、ListStyleType.UPPER_LATIN、FormatValue.INHERIT。若未定義預設值，則表示未設定。如果重疊顯示時未定義此屬性，則此屬性將繼承祖系的值。	FlowElement
		locale : * TextLayoutFormat：文字的地區設定。	FlowElement
		mxmlChildren : Array 將子系的陣列附加至此物件。	FlowGroupElement
		numChildren : int [唯讀] 傳回此 FlowGroupElement 物件所具有的 FlowElement 子系數目。	FlowGroupElement
		paddingBottom : * TextLayoutFormat：下方內移距 (像素)。	FlowElement
		paddingLeft : * TextLayoutFormat：左方內移距 (像素)。	FlowElement
		paddingRight : * TextLayoutFormat：右方內移距 (像素)。	FlowElement
		paddingTop : * TextLayoutFormat：上方內移距 (像素)。	FlowElement
		paragraphEndIndent : * TextLayoutFormat：指定段落結尾邊緣縮排量的數字 (以像素為單位)。	FlowElement
		paragraphSpaceAfter : * TextLayoutFormat：一個數字，指定段落後面要保留的空間量 (像素)。	FlowElement
		paragraphSpaceBefore : * TextLayoutFormat：一個數字，指定段落前面要保留的空間量 (像素)。	FlowElement
		paragraphStartIndent : * TextLayoutFormat：指定段落開頭邊緣縮排量的數字 (以像素為單位)。	FlowElement
		parent : FlowGroupElement [唯讀] 傳回此 FlowElement 物件的父輩。	FlowElement
		parentRelativeEnd : int [唯讀] 傳回父輩中此 FlowElement 物件的相對結尾。	FlowElement
		parentRelativeStart : int [唯讀] 傳回父輩中此 FlowElement 物件的相對開頭。	FlowElement
		renderingMode : * TextLayoutFormat：用於此文字的顯示模式。	FlowElement
		styleName : * TextLayoutFormat：指定元素的識別類別，如此只要參照此 styleName 就可以設定元素的樣式。	FlowElement
		styles : Object [唯讀] 傳回此 FlowElement 的樣式。	FlowElement
		tabStops : * TextLayoutFormat：指定段落關聯的定位停駐點。	FlowElement
		textAlign : * TextLayoutFormat：段落中各行相對於容器的對齊方式。	FlowElement
		textAlignLast : * TextLayoutFormat：段落中最後 (或唯一的) 一行相對於齊行文字中之容器的對齊方式。	FlowElement
		textAlpha : * TextLayoutFormat：文字的 Alpha (透明) 值。	FlowElement
		textDecoration : * TextLayoutFormat：文字上的裝飾。	FlowElement
		textIndent : * TextLayoutFormat：以像素為單位，指定段落中第一行縮排量的數字。	FlowElement
		textJustify : * TextLayoutFormat：指定對齊文字的選項。	FlowElement
		textLength : int [唯讀] 傳回此 FlowElement 物件及其子系所擁有的文字總長度。	FlowElement
		textRotation : * TextLayoutFormat：決定此文字要旋轉的度數。	FlowElement
		tracking : Object [唯寫] 設定字距調整，且與 trackingRight 屬性的意義相同。	FlowElement
		trackingLeft : * TextLayoutFormat：以像素為單位代表要套用至每個字元左側字距調整 (手動字距微調) 量的數字 (或 fontSize 的百分比，例如，120%)。	FlowElement
		trackingRight : * TextLayoutFormat：以像素為單位代表要套用至每個字元右側字距調整 (手動字距微調) 量的數字 (或 fontSize 的百分比，例如，120%)。	FlowElement
		typeName : String 每個 FlowElement 都有 typeName。	FlowElement
		typographicCase : * TextLayoutFormat：用於此文字的印刷大小寫類型。	FlowElement
		userStyles : Object 可讓您讀寫 FlowElement 物件上的使用者樣式。	FlowElement
		verticalAlign : * TextLayoutFormat：垂直對齊或齊行 (如果重疊顯示時未定義，則採用預設值)。	FlowElement
		whiteSpaceCollapse : * TextLayoutFormat：將文字匯入 TextFlow 時捨去或保留空格。	FlowElement
		wordSpacing : * TextLayoutFormat：指定對齊時要使用之文字間的最佳、最小及最大間距 (標準間距寬度的倍數)。	FlowElement

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		FlowGroupElement() 基底類別 - 叫用新的 FlowGroupElement() 時擲出錯誤例外。	FlowGroupElement
		addChild(child:FlowElement):FlowElement 附加子系 FlowElement 物件。	FlowGroupElement
		addChildAt(index:uint, child:FlowElement):FlowElement 在指定的索引位置新增子系 FlowElement 物件。	FlowGroupElement
		clearStyle(styleProp:String):void 清除此 FlowElement 物件中由 styleProp 參數所指定的樣式。	FlowElement
		deepCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement 製作此 FlowElement 物件 (包含任何子系) 的深層複本，這會複製兩個指定字元位置之間的內容，並傳回複本做為 FlowElement 物件。	FlowElement
		equalUserStyles(otherElement:FlowElement):Boolean 將這一個的 userStyles 與 otherElement 的 userStyles 進行比較。	FlowElement
		findChildIndexAtPosition(relativePosition:int):int 指定相對文字位置，尋找第一個內含相對位置的子系 FlowElement 的索引。	FlowGroupElement
		findLeaf(relativePosition:int):FlowLeafElement 指定相對文字位置，尋找內含位置的分葉元素。	FlowGroupElement
		getAbsoluteStart():int 傳回文字流排中的元素開始位置做為絕對索引。	FlowElement
		getCharAtPosition(relativePosition:int):String 傳回指定位置的字元 (與此 FlowElement 物件相對的位置)。	FlowElement
		getCharCodeAtPosition(relativePosition:int):int 傳回指定位置的字元碼 (與此 FlowElement 相對的位置)。	FlowElement
		getChildAt(index:int):FlowElement 傳回指定索引位置的 FlowElement 子系。	FlowGroupElement
		getChildIndex(child:FlowElement):int 搜尋子系以找出指定的 FlowElement 物件，並傳回其索引位置。	FlowGroupElement
		getElementRelativeStart(ancestorElement:FlowElement):int 傳回此元素的開頭 (與祖系元素相對的位置)。	FlowElement
		getFirstLeaf():FlowLeafElement 傳回此群組的第一個 FlowLeafElement 子系。	FlowGroupElement
		getLastLeaf():FlowLeafElement 傳回此群組的最後一個 FlowLeafElement 子系。	FlowGroupElement
		getNextSibling():FlowElement 傳回文字流排階層中的下一個 FlowElement 同級項目。	FlowElement
		getParagraph():ParagraphElement 傳回與此元素相關的 ParagraphElement 物件。	FlowElement
		getPreviousSibling():FlowElement 傳回文字流排階層中的上一個 FlowElement 同級項目。	FlowElement
		getStyle(styleProp:String):* 傳回 styleProp 參數所指定的樣式值，此參數會指定樣式名稱，而且可以包含任何使用者樣式名稱。	FlowElement
		getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String [覆寫]	FlowGroupElement
		getTextFlow():flashx.textLayout.elements:TextFlow 往上瀏覽文字流排階層，以傳回元素的根 TextFlow 物件。	FlowElement
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		initialized(document:Object, id:String):void 實作物件已經建立而且在 MXML 標籤上指定的所有組件屬性已經初始化後，為 MXML 物件進行呼叫。	FlowElement
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		removeChild(child:FlowElement):FlowElement 從群組中移除指定的子系 FlowElement 物件。	FlowGroupElement
		removeChildAt(index:uint):FlowElement 移除指定索引位置的子系 FlowElement 物件。	FlowGroupElement
		replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void 將群組中的子元素取代為指定的新元素。	FlowGroupElement
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		setStyle(styleProp:String, newValue:*):void 將 styleProp 參數所指定的樣式設為 newValue 參數所指定的值。	FlowElement
		shallowCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement 製作此 FlowElement 物件的複本，這會複製兩個指定字元位置之間的內容。	FlowElement
		splitAtIndex(childIndex:int):FlowGroupElement 在 childIndex 參數指定的位置分割此物件。	FlowGroupElement
		splitAtPosition(relativePosition:int):FlowElement 在 relativePosition 參數指定的位置分割此 FlowElement 物件，而此參數是此元素在文字中的相對位置。	FlowElement
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回指定之物件的字串形式。	Object
		valueOf():Object 會傳回指定之物件的基本值。	Object

屬性詳細資訊

mxmlChildren

屬性

mxmlChildren:Array

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

將子系的陣列附加至此物件。使用 replaceChildren() 方法，將每個元素附加至陣列。專供 mxml 編譯匯入期間使用。

實作
public function get mxmlChildren():Array
public function set mxmlChildren(value:Array):void

擲回值

TypeError — 如果陣列元素不是 FlowElement 或 String

相關 API 元素

FlowGroupElement.replaceChildren()

numChildren

屬性

numChildren:int [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

傳回此 FlowGroupElement 物件所具有的 FlowElement 子系數目。

實作
public function get numChildren():int

建構函式詳細資料

()

建構函式

public function FlowGroupElement()

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

基底類別 - 叫用新的 FlowGroupElement() 時擲出錯誤例外。

方法詳細資訊

addChild

()

方法

public function addChild(child:FlowElement):FlowElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

附加子系 FlowElement 物件。新的子系會新增至子清單的結尾。

參數

child:FlowElement — 要附加的子元素。

傳回值

FlowElement — 新增的子系 FlowElement

範例 ( 如何使用本範例 )

這個範例會呼叫 addChild()，以便將範圍新增至段落以及將段落新增至文字方向。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildExample extends Sprite
    {        
        public function FlowGroupElement_addChildExample()
        {
            // create string for text flow
            var simpleText:String = "It was a dark and stormy night.";        
                    
            // define TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span:SpanElement = new SpanElement;
            span.text = simpleText;
            // add span to paragraph and add paragraph to text flow
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

addChildAt

()

方法

public function addChildAt(index:uint, child:FlowElement):FlowElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

在指定的索引位置新增子系 FlowElement 物件。

參數

	`index:uint` — 要新增子元素之位置的索引，第一個位置是 0。

	`child:FlowElement` — 要新增的子元素。

傳回值

FlowElement — 新增的子系 FlowElement

擲回值

RangeError — index 超出範圍。

範例 ( 如何使用本範例 )

這個範例會呼叫 addChildAt，以便將三個範圍新增至段落。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildAtExample extends Sprite
    {        
        public function FlowGroupElement_addChildAtExample()
        {
            // define text strings for the contents of the text flow
            var textA:String = "It was a dark and stormy night. ";
            var textB:String = "The quick red fox jumped over the lazy brown dog. ";
            var textC:String = "Mary had a little lamb. ";
            // define TextFlow, ParagraphElement and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            span1.text = textA;
            span2.text = textB;
            span3.text = textC;
            // add spans at specified positions
            paragraph.addChildAt(0, span2);
            paragraph.addChildAt(0, span1);
            paragraph.addChildAt(1, span3);
            textFlow.addChild(paragraph);
            // assign composer, controller, and update to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findChildIndexAtPosition

()

方法

public function findChildIndexAtPosition(relativePosition:int):int

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

指定相對文字位置，尋找第一個內含相對位置的子系 FlowElement 的索引。多個子系可以包含相對位置，因為 FlowElement 的長度是零。

檢查子系，尋找內含相對位置的 FlowElement。提供的相對位置是與此 FlowElement 相對的位置。

參數

relativePosition:int — 與此元素相對的位置

傳回值

int — 第一個內含 relativePosition 之子元素的索引

範例 ( 如何使用本範例 )

這個範例會尋找文字相對位置的子系索引以及將它的顏色設為紅色。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findChildIndexAtPositionExample extends Sprite
    {        
        public function FlowGroupElement_findChildIndexAtPositionExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the index of the child containing relative offset 21; set color to red
            var index:int = textFlow.findChildIndexAtPosition(21);
            textFlow.getChildAt(index).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findLeaf

()

方法

public function findLeaf(relativePosition:int):FlowLeafElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

指定相對文字位置，尋找內含位置的分葉元素。

往下尋找流排元素階層，尋找內含指定位置的 FlowLeafElement。指定的位置是與此 FlowElement 物件相對的位置。

參數

relativePosition:int — 要查閱的相對文字索引。

傳回值

FlowLeafElement — 內含相對位置的分葉元素。

範例 ( 如何使用本範例 )

這個範例會建立兩個段落、尋找相對位置 55 的 FlowLeafElement，並將它的顏色設為紅色。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findLeafExample extends Sprite
    {        
        public function FlowGroupElement_findLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the FlowLeafElement object containing relative offset 55; set color to red
            var leaf:SpanElement = textFlow.findLeaf(55) as SpanElement;
            leaf.color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildAt

()

方法

public function getChildAt(index:int):FlowElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

傳回指定索引位置的 FlowElement 子系。

參數

index:int — 尋找 FlowElement 物件的位置。

傳回值

FlowElement — 位於指定位置的子系 FlowElement 物件。

範例 ( 如何使用本範例 )

這個範例會使用 getChildAt() 方法來存取文字方向中的段落以及將其中一個範圍的顏色變成紅色。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getChildAtExample extends Sprite
    {        
        public function FlowGroupElement_getChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the paragraph at index position 1
            var para:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
            // find the span at index position 1 of the paragraph and color it red
            para.getChildAt(1).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildIndex

()

方法

public function getChildIndex(child:FlowElement):int

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

搜尋子系以找出指定的 FlowElement 物件，並傳回其索引位置。

參數

child:FlowElement — 在其中尋找子系的 FlowElement 物件項目。

傳回值

int — 指定子項的索引位置。如果找不到 child，則傳回 -1。

getFirstLeaf

()

方法

public function getFirstLeaf():FlowLeafElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

傳回此群組的第一個 FlowLeafElement 子系。

傳回值

FlowLeafElement — 第一個 FlowLeafElement 物件。

範例 ( 如何使用本範例 )

這個範例會建立兩個段落、尋找第一個 FlowLeafElement 物件，然後將它的顏色變成紅色。

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getFirstLeafExample extends Sprite
    {        
        public function FlowGroupElement_getFirstLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a </flow:span>"+
                        "<flow:span fontStyle=\"italic\">dark and stormy</flow:span>"+
                        "<flow:span> night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // get first FlowLeafElement object and set its color to red
            var leaf:SpanElement = textFlow.getFirstLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            // add composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getLastLeaf

()

方法

public function getLastLeaf():FlowLeafElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

傳回此群組的最後一個 FlowLeafElement 子系。

傳回值

FlowLeafElement — 最後一個 FlowLeafElement 物件。

範例 ( 如何使用本範例 )

這個範例會建立兩個段落、尋找最後一個 FlowLeafElement 物件，然後將它的顏色變成紅色。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getLastLeafExample extends Sprite
    {        
        public function FlowGroupElement_getLastLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            //find last leaf, set its color to red and display text
            var leaf:SpanElement = textFlow.getLastLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getText

()

方法

override public function getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String

參數

	`relativeStart:int` (default = `0`)

	`relativeEnd:int` (default = `-1`)

	`paragraphSeparator:String` (default = " ")

傳回值

String

removeChild

()

方法

public function removeChild(child:FlowElement):FlowElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

從群組中移除指定的子系 FlowElement 物件。

參數

child:FlowElement — 要移除的子元素。

傳回值

FlowElement — 已移除的子系 FlowElement 物件

擲回值

ArgumentError — 找不到 child。

範例 ( 如何使用本範例 )

這個範例會移除文字方向中第二個段落的第三個範圍。

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildExample extends Sprite
    {        
        public function FlowGroupElement_removeChildExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            // get paragraph with ID = 'para2' and remove its child with name = 'span4'
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.removeChild(textFlow.getElementByID("span4"));
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

removeChildAt

()

方法

public function removeChildAt(index:uint):FlowElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

移除指定索引位置的子系 FlowElement 物件。

參數

index:uint — 要移除的子元素的位置。

傳回值

FlowElement — 從指定位置移除的子系 FlowElement 物件。

擲回值

RangeError — index 超出範圍。

範例 ( 如何使用本範例 )

這個範例會呼叫 removeChildAt()，以便移除三個段落中的第二個。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildAtExample extends Sprite
    {        
        public function FlowGroupElement_removeChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Mary had a little lamb. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow, import text, add composer and controller 
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // remove child at index position 1 (with first position = 0); display text
            textFlow.removeChildAt(1);
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

replaceChildren

()

方法

public function replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

將群組中的子元素取代為指定的新元素。使用 beginChildIndex 及 endChildIndex 參數，可以如下控管作業：

若要刪除元素，請不要傳遞任何取代元素。
若要插入元素，請將相同的值傳遞給 beginChildIndex 及 endChildIndex。新的元素會插入指定索引的前面。
若要附加元素，請將 numChildren 傳遞給 beginChildIndex 及 endChildIndex。

否則，此方法會取代指定的元素，從元素的 beginChildIndex 開始，最多可到但不含 endChildIndex。

參數

	`beginChildIndex:int` — 子陣列中取代範圍開始位置的索引值。

	`endChildIndex:int` — 子陣列中取代範圍結束位置之後的索引值。

	`... rest` — 取代指定元素範圍的元素。可以是內含流排元素或陣列或其向量的序列。

擲回值

RangeError — 指定的 beginChildIndex 或 endChildIndex 超出範圍。

範例 ( 如何使用本範例 )

這個範例會將第二個段落中的三個範圍取代成兩個新的範圍。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_replaceChildrenExample extends Sprite
    {        
        public function FlowGroupElement_replaceChildrenExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
            
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // define two new SpanElement objects
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            span1.text = "Mary had a little lamb. ";
            span2.text = "And this little pig stayed home. ";
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,600));
            // get paragraph with ID = 'para2' and replace its children with span1 and span2
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.replaceChildren(0, 3, [span1, span2]);
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

splitAtIndex

()

方法

public function splitAtIndex(childIndex:int):FlowGroupElement

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10, AIR 1.5

在 childIndex 參數指定的位置分割此物件。如果此群組元素具有父輩，請建立此物件的淺層複本，並將它的子系取代為最高到此索引的元素。將 childIndex 後面的元素移至複本。

參數

childIndex:int

傳回值

FlowGroupElement — 新的 FlowGroupElement 物件。

擲回值

RangeError — 如果 childIndex 大於子系的長度。

法律聲明 | 線上隱私權政策

FlowGroupElement - AS3

類別 x

mxmlChildren

numChildren