MouseEvent  - AS3

指出 Alt 鍵為作用中 (true) 或停用 (false)。 只支援 Windows。在其他作業系統上，這個屬性一定會設定為 false。

指出已按下主要滑鼠按鈕 (true) 或未按下 (false)。

指出此滑鼠按下事件是否為多次按下動作序列的一部分。對於 MouseEvent.mouseDown、MouseEvent.mouseUp、MouseEvent.middleMouseDown、MouseEvent.middleMouseUp、MouseEvent.rightMouseDown 和 MouseEvent.rightMouseUp 以外的所有滑鼠事件，此參數都將是零。搭配 clickCount 參數，您就可以偵聽按一下、按兩下或多次按下動作序列。例如在按兩下動作序列中，第一個 MouseEvent.mouseDown 和 MouseEvent.mouseUp 的 clickCount 將為 1，而第二個 MouseEvent.mouseDown 和 MouseEvent.mouseUp 的 clickCount 將為 2。如果滑鼠已完成移動，或者多次按下動作序列基於某些原因而中斷，則下一個 MouseEvent.mouseDown 的 clickCount 將為 1。doubleClick 事件將如預期般觸發。

指出 Command 鍵是否已啟用 (僅限 Mac)。

在 Mac 中，commandKey 屬性的值將與 ctrlKey 屬性的值相同。在 Windows 或 Linux 中一律為 false。

指出是否已啟用 Control 鍵 (在 Mac 中) 以及是否已啟用 Ctrl 鍵 (在 Windows 或 Linux 中)。

在 Windows 或 Linux 中，指出 Ctrl 鍵為作用中 (true) 或已停用 (false)。在 Macintosh 中，指出 Control 鍵或 Command 鍵是否已啟用。

指出當使用者滾動滑鼠滾輪時，每滾動一個單位 (一格) 所代表的捲動行數。 delta 值若為正值，表示向上捲動；負值則表示向下捲動。 一般的值是介於 1 到 3 之間，但更快速的滾動可能會產生更大的值。 此設定會依裝置和作業系統而有所不同，並且通常是由使用者進行設定。 這個屬性只適用於 MouseEvent.mouseWheel 事件。

如果是 true，則 relatedObject 屬性會因為安全執行程序的因素而設定為 null。如果 relatedObject 的名目值是另一個安全執行程序中 DisplayObject 的參考，則 relatedObject 會設定為 null，除非跨越安全執行程序邊界的兩個方向都有權限。建立權限的方法包括：從 SWF 檔呼叫 Security.allowDomain()、提供來自影像檔伺服器的原則檔案，以及於載入影像時設定 LoaderContext.checkPolicyFile 屬性。

相關 API 元素

滑鼠鎖定停用時，則為相對於包含的 Sprite，事件發生的水平座標。將 Stage.mouseLock 設定為 false 即可停用滑鼠鎖定。

當滑鼠鎖定啟用時，localX 和 localY 為 0。請在滑鼠鎖定啟用時，使用 movementX 和 movementY 判斷滑鼠位置的變更。

相關 API 元素

滑鼠鎖定停用時，則為相對於包含的 Sprite，事件發生的垂直座標。將 Stage.mouseLock 設定為 false 即可停用滑鼠鎖定。

當滑鼠鎖定啟用時，localX 和 localY 為 0。請在滑鼠鎖定啟用時，使用 movementX 和 movementY 判斷滑鼠位置的變更。

相關 API 元素

滑鼠鎖定啟用時，則為自上次滑鼠事件以來滑鼠位置在 X 方向的變更。將 Stage.mouseLock 設定為 true 即可啟用滑鼠鎖定。

當滑鼠鎖定啟用時：

• localX 和 localY 包含 0。
• movementX 和 movementY 包含 delta 值。
• movementX 和 movementY 絕不會根據舞台變形而轉換。也就是說，它們會永遠保留螢幕座標。

當 Stage.mouseLock 為 false 時，movementX 和 movementY 為 0。

相關 API 元素

滑鼠鎖定啟用時，則為自上次滑鼠事件以來滑鼠位置在 Y 方向的變更。將 Stage.mouseLock 設定為 true 即可啟用滑鼠鎖定。

當滑鼠鎖定啟用時：

• localX 和 localY 包含 0。
• movementX 和 movementY 包含 delta 值。
• movementX 和 movementY 絕不會根據舞台變形而轉換。也就是說，它們會永遠保留螢幕座標。

當 Stage.mouseLock 為 false 時，movementX 和 movementY 為 0。

相關 API 元素

與事件相關的顯示清單物件的參照。 例如，當發生 mouseOut 事件時，relatedObject 代表指標裝置目前指向的顯示清單物件。 這個屬性會套用至 mouseOut、mouseOver、rollOut 和 rollOver 事件。

在下列兩種情況下，這個屬性的值可能是 null：沒有相關物件，或是有相關物件但它位在您無法存取的安全執行程序中。使用 isRelatedObjectInaccessible() 屬性可判斷哪個原因適用於此情況。

相關 API 元素

指出 Shift 鍵為作用中 (true) 或停用 (false)。

在全域舞台座標上，事件發生的水平座標。 每次設定 localX 屬性時，就會計算這個屬性。

在全域舞台座標上，事件發生的垂直座標。 每次設定 localY 屬性時，就會計算這個屬性。

建立包含滑鼠事件相關資訊的 Event 物件。 Event 物件會當做參數傳遞至事件偵聽程式。

建立 MouseEvent 物件的副本，並將每個屬性的值設為符合原始物件的屬性值。

傳回包含 MouseEvent 物件所有屬性的字串。 此字串的格式如下：

[MouseEvent type= value bubbles= value cancelable= value ... delta= value ]

如果已經修改顯示清單，則指示 Flash Player 或 Adobe AIR 在此事件處理完畢後再顯示。

定義 type 屬性值 (click 事件物件)。

這個事件具有下列屬性：

相關 API 元素

MouseEvent.CONTEXT_MENU 常數會定義 contextMenu 事件物件的 type 屬性值。

這個事件具有下列屬性：

定義 doubleClick 事件物件的 type 屬性值。doubleClickEnabled 屬性必須為 true，才能讓物件產生 doubleClick 事件。

這個事件具有下列屬性：

相關 API 元素

定義 middleClick 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 middleMouseDown 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 middleMouseUp 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 mouseDown 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 mouseMove 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

定義 type 屬性值 (mouseOut 事件物件)。

這個事件具有下列屬性：

相關 API 元素

定義 type 屬性值 (mouseOver 事件物件)。

這個事件具有下列屬性：

相關 API 元素

定義 type 屬性值 (mouseUp 事件物件)。

這個事件具有下列屬性：

相關 API 元素

定義 type 屬性值 (mouseWheel 事件物件)。

這個事件具有下列屬性：

相關 API 元素

定義 releaseOutside 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 rightClick 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 rightMouseDown 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 rightMouseUp 事件物件的 type 屬性值。

這個事件具有下列屬性：

相關 API 元素

定義 type 屬性值 (rollOut 事件物件)。

這個事件具有下列屬性：

相關 API 元素

定義 type 屬性值 (rollOver 事件物件)。

這個事件具有下列屬性：

相關 API 元素

1. 首先會宣告大小 (100 x 100 像素) 和背景顏色 (橘黃色) 的屬性，以供稍後繪製正方形時使用。
2. 建構函式會建立新的 ChildSprite 物件 child。 建議函式會呼叫其 draw() 方法，在座標 (0,0) 繪出橘色的正方形 (100 x 100 像素)，然後再新增七個事件偵聽程式/訂閱者。
   • click / clickHandler()：當使用者用滑鼠左鍵在正方形上按一下時傳送。
   • doubleClick / doubleClickHandler()：當使用者用滑鼠左鍵在正方形上按兩下時傳送。
   • mouseDown / mouseDownHandler()：當按下 ChildSprite 物件 (橘色正方形) 時傳送，此時會在螢幕上印出 trace() 訊息，然後呼叫 ChildSprite.draw()，接著會繪出深黃色的方形取代以 mouseOverHandler() 繪出的淺藍色方形。 mouseDownHandler() 方法也會新增一個處理滑鼠事件的 mouseMove 事件偵聽程式和 mouseMoveHandler() 訂閱者 (如下說明)。 然後呼叫 startDrag() 方法，允許使用者拖曳這個 Sprite 物件。
   • mouseOut / mouseOutHandler()：只要指標離開正方形區域時就傳送。 draw() 方法，讓正方形回復其正常大小和顏色。
   • mouseOver / mouseOverHandler()：當滑鼠指標滑入方形上方時傳送。 此方法會重新繪製正方形，將它的大小放大，而其背景顏色為深黃色。
   • mouseUp / mouseUpHandler()：當使用者放開滑鼠按鈕時會移動 mouseMove 事件偵聽程式，並呼叫 stopDrag，將方形固定在位置上。
   • mouseMove/mouseMoveHandler()：會當做 mouseDownHandler() 函式的一部分來呼叫，而且會在使用者按下滑鼠左鍵並拖曳正方形時傳送。
   • mouseWheel / mouseWheelHandler()：當使用者滾動滑鼠滾輪到正方形上方時傳送。
3. ChildSprite 實體 child 接著會使用 addChild() 新增至顯示清單，以立即繪出橘色的方形。

注意：

• MouseEventExample 類別應該是文件根。
• 以上列出的某些事件方法會宣告一個區域變數 sprite，該區域變數會指定 event.target，以列出 Sprite。

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}