ContextMenu  - AS3

En instans av ContextMenuBuiltInItems-klassen med följande egenskaper: forwardAndBack, loop, play, print, quality, rewind, save och zoom. Om egenskaperna ställs in på false tas motsvarande menyalternativ bort från det angivna ContextMenu-objektet. Egenskaperna är uppräkningsbara och inställda på true som standard.

Obs! I AIR finns det inga inbyggda alternativ för snabbmenyer.

Relaterade API-element

En instans av ContextMenuClipboardItems-klassen med följande egenskaper: cut, copy, paste, delete, selectAll. Om en av dessa egenskaper ställs in på false inaktiveras motsvarande alternativ på urklippsmenyn.

Relaterade API-element

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Indikerar om urklippsmenyn ska användas eller inte. Om detta värde är true avgör egenskapen clipboardItems vilka alternativ som är aktiverade eller inaktiverade på urklippsmenyn.

Om link-egenskapen inte är null ignoreras den här clipBoardMenu-egenskapen.

En array med ContextMenuItem-objekt. Varje objekt i arrayen motsvarar ett snabbmenyalternativ som du har definierat. Använd egenskapen för att lägga till, ta bort eller ändra dessa anpassade menyalternativ.

Lägg till nya menyalternativ genom att först skapa ett ContextMenuItem-objekt och sedan lägga till det i arrayen customItems (till exempel genom att använda Array.push()). Mer information om hur du skapar menyalternativ finns i beskrivningen av klassen ContextMenuItem.

Relaterade API-element

Egenskapen isSupported är true om klassen ContextMenu stöds på den aktuella plattformen, och i annat fall är värdet false.

Arrayen för egna alternativ på denna meny.

Att använda den här egenskapen motsvarar att använda egenskapen customItems. Arrayen sorteras i visningsordning.

Länkens URLRequest. Om denna egenskap är null visas en normal snabbmeny. Om denna egenskap inte är null visas länksnabbmenyn, och den används på den angivna URL-adressen.

Om en link anges ignoreras clipboardMenu-egenskapen.

Standardvärdet är null.

Antalet alternativ på denna meny.

Skapar ett ContextMenu-objekt.

Relaterade API-element

Lägger till ett menyobjekt längst ned på menyn.

När du skapar en snabbmeny kan du lägga till NativeMenuItem- eller ContextMenuItem-objekt. Du bör emellertid bara använda en typ av objekt på en snabbmeny så att alla objekt på menyn har samma egenskaper.

Parametrar

Skapar en kopia av det angivna ContextMenu-objektet. Kopian ärver det ursprungliga menyobjektets alla egenskaper.

Rapporterar om denna meny innehåller det angivna menyobjektet.

Parametrar

Poppar upp denna meny vid den angivna placeringen.

Obs! Den här metoden stöds inte i Flash Player.

Parametrar

Hämtar meyobjektet vid det angivna indexvärdet.

Parametrar

Hämtar positionen för det angivna objektet.

Parametrar

Döljer alla inbyggda menyalternativ (utom Inställningar) i det angivna ContextMenu-objektet. Om felsökningsversionen av Flash Player körs, visas menyalternativet Felsökning, men det är nedtonat för SWF-filer som inte har fjärrfelsökning aktiverad.

Metoden döljer bara menyalternativ som visas på standardsnabbmenyn. Alternativ som visas på Redigera-menyn och felmenyn påverkas inte.

Metoden fungerar genom att alla booleska medlemmar i my_cm.builtInItems ställs in påfalse. Du kan göra ett specifikt inbyggt alternativ synligt genom att ställa in motsvarande medlem i my_cm.builtInItems på true

Obs! I AIR finns det inga inbyggda alternativ för snabbmenyer. Att anropa den här metoden har ingen effekt.

Relaterade API-element

Tar bort alla objekt från menyn.

Tar bort och returnerar menyobjektet vid det angivna indexvärdet.

Parametrar

Skickas när användaren först genererar en snabbmeny men innan innehållet i snabbmenyn visas. På det sättet kan programmet ändra uppsättningen med snabbmenyalternativ innan menyn visas. Användaren genererar snabbmenyn genom att högerklicka på pekenheten.

Den här händelsen har följande egenskaper:

1. En myContextMenu-egenskap deklareras och kopplas sedan till ett nytt ContextMenu-objekt och en redRectangle-egenskap av typen Sprite deklareras.
2. Metoden removeDefaultItems() anropas och alla inbyggda snabbmenyalternativ tas bort utom Skriv ut.
3. Metoden addCustomMenuItems() anropas vilket placerar ett menyalternativ med namnet Red to Black i defaultItems-arrayen med hjälp av push()-metoden. En menuItemSelect-händelseavlyssnare läggs till ContextMenuItem-objektet och den kopplade metoden anropas menuItemSelectHandler(). Med den här metoden skrivs vissa programsatser ut med hjälp av trace() varje gång snabbmenyn öppnas och Red to Black markeras. Den röda fyrkanten tas också bort och ersätts av en svart.
4. En händelseavlyssnare av typen menuSelect läggs till, tillsammans med tillhörande menuSelectHandler-metod som skriver ut tre programsatser med hjälp av trace() varje gång ett alternativ i snabbmenyn öppnas.
5. Sedan ritar addChildren() en röd fyrkant och lägger till den i visningslistan där den visas direkt.
6. Slutligen kopplas myContextMenu till snabbmenyn i redRectangle-spriten så att den anpassade snabbmenyn bara visas när muspekaren placeras över fyrkanten.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}