ContextMenuEvent  - AS3

Visningslisteobjektet som menyn är kopplad till. Det här kan vara musmålet (mouseTarget) eller en av dess underordnade i visningslistan.

Anger om egenskapen mouseTarget sattes till null av säkerhetsskäl. Om det nominella värdet för menuTarget är en referens till ett DisplayObject i en annan säkerhetssandlåda, är menuTarget satt till null om det inte finns behörighet i båda riktningar över den här sandlådegränsen. Behörighet etableras genom att anropa Security.allowDomain() från en SWF-fil, eller genom att tillhandahålla en principfil för en server för en bildfil och ställa in flaggan LoaderContext.checkPolicyFile under inläsning av bilden.

Relaterade API-element

Visningslisteobjektet som användaren högerklickade på för att visa snabbmenyn. Det här kan vara det visningslisteobjekt som menyn är kopplad till (contextMenuOwner) eller en av dess underordnade i visningslistan.

Värdet för den här egenskapen kan vara null under två förhållanden: Om det inte finns något musmål, om du till exempel för musen över något från bakgrunden, eller om det finns ett musmål, men det finns i en säkerhetssandlåda som du inte har åtkomst till. Använd egenskapen isMouseTargetInaccessible() för att avgöra vilken av dessa orsaker det är som gäller.

Relaterade API-element

Skapar ett nytt Event-objekt som innehåller specifik information om menyhändelser. Event-objekt skickas som parametrar till händelseavlyssnare.

Relaterade API-element

Skapar en kopia av ContextMenuEvent-objektet och ställer in värdet för alla egenskaper så att de matchar originalets egenskaper.

Returnerar en sträng som innehåller alla egenskaper i ContextMenuEvent-objektet. Strängen är i följande format:

[ContextMenuEvent type=värde bubbles=värde cancelable=värde ... contextMenuOwner=värde]

Definierar värdet för ett menuItemSelect-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett menuSelect-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

1. Egenskapen myContextMenu deklareras och tilldelas sedan till ett nytt ContextMenu-objekt och egenskapen redRectangle (av typen Sprite) deklareras.
2. Metoden removeDefaultItems() anropas. Med den här metoden tas alla inbyggda kontextmenyposter bort utom Print.
3. Metoden addCustomMenuItems() anropas. Med den här metoden sätts en Reverse Colors-menypost i arrayen defaultItems med push()-metoden för Array. En menuItemSelect-händelseavlyssnare läggs till ContextMenuItem-objektet och den kopplade metoden anropas menuItemSelectHandler(). Den här metoden skriver ut några trace()-satser när användaren väljer Reverse Colors från kontextmenyn. Dessutom blir den röda fyrkanten svart, och den svarta texten blir röd.
4. Tillbaka i konstruktorn läggs en menuSelect-händelseavlyssnare till, tillsammans med den kopplade metoden menuSelectHandler(), som enkelt skriver ut tre trace()-satser varje gång användaren väljer en post i kontextmenyn.
5. Konstruktorn anropar addChildren() som ritar en röd fyrkant och lägger till den i visningslistan, som i sin tur omedelbart visar fyrkanten.
6. Till sist tilldelas myContextMenu till kontextmenyn för egenskapen redRectangle så att den anpassade kontextmenyn bara visas när muspekaren är över fyrkanten.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}