ContextMenuBuiltInItems  - AS3

Gör att användaren kan flytta framåt och bakåt i en SWF-fil vid körning (visas inte för SWF-filer med en bildruta).

Gör att användaren kan ställa in en SWF-fil så att den börjar om automatiskt när den kommer till sista bildrutan (visas inte för SWF-filer med en bildruta).

Gör att användaren kan starta en pausad SWF-fil (visas inte för SWF-filer med en bildruta).

Gör att användaren kan skicka den bildruta som visas till en skrivare.

Gör att användaren kan ställa in SWF-filens upplösning vid körning.

Gör att användaren kan ställa in en SWF-fil så att den spelas upp från första bildrutan när som helst när den markeras (visas inte för SWF-filer med en bildruta).

Gör att användare som har Shockmachine installerat spara en SWF-fil.

Gör att användaren kan zooma in och ut på en SWF-fil vid körning.

Skapar ett nytt ContextMenuBuiltInItems-objekt så att du kan ställa in egenskaperna för Flash Player på att visa eller dölja varje menyalternativ.

1. En myContextMenu-egenskap deklareras och kopplas sedan till ett nytt ContextMenu-objekt.
2. Metoden removeDefaultItems() anropas och alla inbyggda snabbmenyalternativ tas bort utom Skriv ut.
3. Metoden addCustomMenuItems() anropas vilket placerar ett menyalternativ med namnet Hello World i customItems-arrayen med hjälp av push()-metoden.
4. Menyalternativet Hello World läggs sedan till i scenens lista över snabbmenyalternativ.
5. Ett TextField-objekt med texten "Right Click" läggs till i mitten av scenen med hjälp av addChild() via createLabel().

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuBuiltInItemsExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuBuiltInItemsExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click";
            txtField.x = this.stage.stageWidth/2 - txtField.width/2;
            txtField.y = this.stage.stageHeight/2 - txtField.height/2;
            return txtField;
        }
    }
}