Pakiet flash.utils 

Anuluje określone wywołanie setInterval().

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Anuluje określone wywołanie setTimeout().

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Generuje obiekt XML, który opisuje obiekt ActionScript o nazwie określonej przez parametr metody. Ta metoda implementuje pojęcie programistyczne reflection dla języka ActionScript.

Jeśli parametr value jest instancją typu, zwracany obiekt XML zawiera wszystkie właściwości instancji tego typu, ale nie zawiera żadnych właściwości statycznych. Ten warunek można sprawdzić podczas analizowania obiektu XML poprzez sprawdzenie wartości znacznika <type> (atrybut isStatic), która jest równa false, gdy parametr value jest instancją typu.

W celu uzyskania właściwości statycznych typu należy wprowadzić typ do parametru value. Zwrócony obiekt XML zawiera nie tylko właściwości statyczne typu, ale również wszystkie właściwości jego instancji. Właściwości instancji są zagnieżdżone w znaczniku o nazwie <factory>, co umożliwia ich odróżnienie od właściwości statycznych. W takim przypadku atrybut isStatic znacznika <type> ma wartość true.

Uwaga: Jeśli wymagane jest tylko przeniesienie hierarchii dziedziczenia obiektu, a pozostałe informacje udostępniane przez metodę describeType() nie są potrzebne, zamiast tej metody należy użyć funkcji getQualifiedClassName() i getQualifiedSuperclassName().

W poniższej tabeli przedstawiono niektóre znaczniki i atrybuty obiektu XML wygenerowanego przez metodę describeType() (wszystkie zwracane nazwy klas i interfejsu są podawane w formacie pełnym):

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Zwraca kopię ciągu wejściowego zakodowaną w formacie UTF-8 lub przy użyciu strony kodowej systemu (zależnie od wartości właściwości System.useCodePage). Zastosowanie właściwości System.useCodePage umożliwia dostęp w środowisku wykonawczym do starszej zawartości zakodowanej przy użyciu lokalnych stron kodowych, ale tylko w systemach, w których stosowane są te starsze strony kodowe. Przykład: do danych w języku japońskim zakodowanych jako Shift-JIS znaki zmiany znaczenia będą poprawnie dodawane i usuwane tylko w systemie operacyjnym korzystającym z domyślnej strony kodowej języka japońskiego.

Parametry

Zwraca odniesienie do obiektu klasy określonej przez parametr name.

Parametry

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Zwraca w pełni kwalifikowaną nazwę klasy obiektu.

Parametry

Powiązane elementy interfejsu API

Zwraca pełną nazwę klasy bazowej obiektu określonego przez parametr value. Funkcja umożliwia szybsze pobieranie nazwy klasy bazowej niż metoda describeType(), ale nie udostępnia wszystkich informacji, jakie zapewnia wywołanie metody describeType().

Po uzyskaniu nazwy klasy za pomocą tej funkcji można przekonwertować nazwę klasy na odwołanie do klasy — w tym celu należy użyć funkcji getDefinitionByName().

Uwaga: Stosowanie tej funkcji jest ograniczone do hierarchii instancji, a funkcja describeType() może korzystać z hierarchii obiektów klas, pod warunkiem że parametr value określa typ danych. Wywołanie funkcji describeType() dla typu danych powoduje zwrócenie klasy nadrzędnej na podstawie hierarchii obiektów klas, w której wszystkie obiekty klasy dziedziczą z klasy. Funkcja getQualifiedSuperclassName() ignoruje hierarchię obiektów klas i zwraca klasę nadrzędną na podstawie hierarchii instancji. Przykład: wywołanie funkcji getQualifiedSuperclassName(String) powoduje zwrócenie wartości Object, ale w rzeczywistości klasa String dziedziczy od klasy Class. Innymi słowy: wyniki są takie same niezależnie od tego, czy używana jest instancja typu czy sam typ.

Parametry

Powiązane elementy interfejsu API

Służy do obliczenia czasu względnego. Dla środowiska wykonawczego Flash przetwarzającego kod ActionScript 3.0, ta metoda zwraca liczbę milisekund, jaka upłynęła od czasu uruchomienia wirtualnej maszyny środowiska wykonawczego Flash dla ActionScript 3.0 (AVM2). Dla środowiska wykonawczego Flash przetwarzającego kod ActionScript 2.0 ta metoda zwraca liczbę milisekund, jaka upłynęła od początku inicjowania środowiska wykonawczego Flash. Środowiska wykonawcze Flash korzystają z dwóch maszyn wirtualnych w celu przetwarzania kodu ActionScript. AVM1 jest maszyną wirtualną ActionScript używaną w celu wykonywania kodu ActionScript 1.0 i 2.0. AVM2 jest maszyną wirtualną ActionScript używaną w celu wykonywania kodu ActionScript 3.0. Działanie metody getTimer() dla AVM1 różni się niż dla AVM2.

Informacje na temat dat kalendarzowych (znaczników czasu) zawiera opis obiektu Date.

Powiązane elementy interfejsu API

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Uruchamia funkcję w określonym przedziale czasowym (w milisekundach).

Zamiast stosowania metody setInterval() należy rozważyć utworzenie obiektu Timer z określonym przedziałem czasowym i wartością 0 dla parametru repeatCount (taka wartość sprawi, że obiekt Timer będzie powtarzany nieskończoną ilość razy).

Jeśli użytkownik zamierza użyć metody clearInterval() w celu anulowania wywołania setInterval(), należy się upewnić, że wywołanie metody setInterval() zostało przypisane do zmiennej (do której później będzie się odwoływać funkcja clearInterval()). Jeśli użytkownik nie zamierza wywoływać funkcji clearInterval() w celu anulowania wywołania setInterval(), dla obiektu zawierającego funkcję ustawiania przybliżenia limitu czasu nie zostanie przeprowadzone czyszczenie pamięci.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Uruchamia funkcję po określonym czasie (w milisekundach).

Zamiast stosowania tej metody należy rozważyć utworzenie obiektu Timer z określonym przedziałem czasowym i wartością 1 dla parametru repeatCount (taka wartość sprawi, że obiekt Timer zostanie uruchomiony tylko raz).

Jeśli użytkownik zamierza użyć metody clearTimeout() w celu anulowania wywołania setTimeout(), należy się upewnić, że wywołanie metody setTimeout() zostało przypisane do zmiennej (do której później będzie się odwoływać funkcja clearTimeout()). Jeśli użytkownik nie zamierza wywoływać funkcji clearTimeout() w celu anulowania wywołania setTimeout(), dla obiektu zawierającego funkcję ustawiania przybliżenia limitu czasu nie zostanie przeprowadzone czyszczenie pamięci.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Zwraca kopię ciągu wejściowego, która była uprzednio zakodowana w formacie UTF-8 lub przy użyciu strony kodowej systemu (zależnie od wartości właściwości System.useCodePage). Zastosowanie właściwości System.useCodePage umożliwia dostęp w środowisku wykonawczym do starszej zawartości zakodowanej przy użyciu lokalnych stron kodowych, ale tylko w systemach, w których stosowane są te starsze strony kodowe. Przykład: do danych w języku japońskim zakodowanych jako Shift-JIS znaki zmiany znaczenia będą poprawnie dodawane i usuwane tylko w systemie operacyjnym korzystającym z domyślnej strony kodowej języka japońskiego.

Parametry