XML

Pakiet	Najwyższy poziom
Klasa	public final dynamic class XML
Dziedziczenie	XML Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9, Flash Lite 4

Klasa XML zawiera metody i właściwości dotyczące pracy z obiektami XML. Klasa XML (wraz z klasami XMLList, Namespace oraz QName) implementuje zaawansowane standardy obsługi kodu XML określone w specyfikacji ECMAScript for XML (E4X) (ECMA-357, wydanie 2).

Należy użyć metody toXMLString(), aby zwrócić ciąg znaków reprezentujący obiekt XML, bez względu na to czy obiekt XML zawiera elementy proste czy złożone.

Uwaga: Nazwa klasy XML (wraz z klasami powiązanymi) udostępnionej w narzędziu ActionScript 2.0 została zmieniona na XMLDocument i umieszczona w pakiecie flash.xml. Jest również udostępniona w narzędziu ActionScript 3.0 w celu zapewnienia zgodności z wersjami wcześniejszymi.

Wyświetl przykłady

Więcej informacji

Specyfikacja ECMAScript for XML (E4X) (ECMA-357, wydanie 2)

Powiązane elementy interfejsu API

Przestrzeń nazw
QName
XMLList
XML.toXMLString()

Właściwości publiczne

Ukryj dziedziczone właściwości publiczne

Pokaż dziedziczone właściwości publiczne

	Właściwość		Zdefiniowane przez
		constructor : Object Odwołanie do obiektu klasy lub funkcji konstruktora, dotyczące danej instancji obiektu.	Object
		ignoreComments : Boolean [statyczny] Określa, czy podczas analizy składniowej danych źródłowych XML komentarze XML mają być pomijane.	XML
		ignoreProcessingInstructions : Boolean [statyczny] Określa, czy podczas analizy składniowej danych źródłowych XML przez obiekty XML instrukcje XML są pomijane.	XML
		ignoreWhitespace : Boolean [statyczny] Określa, czy w trakcie analizy składniowej białe znaki na początku i końcu węzłów tekstowych mają być pomijane.	XML
		prettyIndent : int [statyczny] Określa wielkość wcięć stosowanych w ramach metod toString() oraz toXMLString(), gdy właściwość XML.prettyPrinting ma wartość prawda.	XML
		prettyPrinting : Boolean [statyczny] Określa, czy metody String() oraz toXMLString() mają normalizować białe znaki między niektórymi znacznikami.	XML

Metody publiczne

Ukryj dziedziczone metody publiczne

Pokaż dziedziczone metody publiczne

	Metoda		Zdefiniowane przez
		XML(value:Object) Tworzy nowy obiekt XML.	XML
		addNamespace(ns:Object):XML Dodaje przestrzeń nazw do zbioru przestrzeni nazw dotyczących obiektu XML.	XML
		appendChild(child:Object):XML Dołącza dany element podrzędny na końcu właściwości obiektu XML.	XML
		attribute(attributeName:*):XMLList Zwraca wartość XML atrybutu o tej samej nazwie, którą określa parametr attributeName.	XML
		attributes():XMLList Zwraca listę wartości atrybutów danego obiektu XML.	XML
		child(propertyName:Object):XMLList Wyświetla listę obiektów podrzędnych obiektu XML.	XML
		childIndex():int Identyfikuje obiekt o zerowym indeksie w obiekcie XML (w kontekście obiektu macierzystego).	XML
		children():XMLList Zawiera listę elementów podrzędnych obiektu XML w kolejności ich wyświetlania.	XML
		comments():XMLList Zawiera listę właściwości obiektu XML z komentarzami XML.	XML
		contains(value:XML):Boolean Porównuje obiekt XML z danym parametrem.	XML
		copy():XML Zwraca kopię danego obiektu XML.	XML
		defaultSettings():Object [statyczny] Zwraca obiekt, którego następujące właściwości są ustawione na wartości domyślne: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent oraz prettyPrinting.	XML
		descendants(name:Object = *):XMLList Zwraca wszystkie elementy podrzędne (bezpośrednio podrzędne, podrzędne wobec obiektów podrzędnych itd.) obiektu XML o danym parametrze name.	XML
		elements(name:Object = *):XMLList Wyświetla listę elementów obiektu XML.	XML
		hasComplexContent():Boolean Sprawdza, czy obiekt XML zawiera elementy złożone.	XML
		hasOwnProperty(p:String):Boolean Sprawdza, czy obiekt ma właściwość określoną przez parametr p.	XML
		hasSimpleContent():Boolean Sprawdza, czy obiekt XML zawiera elementy proste.	XML
		inScopeNamespaces():Array Tworzy listę przestrzeni nazw dla obiektu XML na podstawie obiektu nadrzędnego.	XML
		insertChildAfter(child1:Object, child2:Object):* W obiekcie XML parametr potomek2 jest wstawiany po parametrze potomek1, a jest zwracany obiekt wynikowy.	XML
		insertChildBefore(child1:Object, child2:Object):* W obiekcie XML parametr potomek2 jest wstawiany przed parametrem potomek1, a jest zwracany obiekt wynikowy.	XML
		isPrototypeOf(theClass:Object):Boolean Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr.	Object
		length():int W przypadku obiektów XML ta metoda zawsze zwraca liczbę całkowitą 1.	XML
		localName():Object Zwraca nazwę lokalną zawartą w pełnej nazwie obiektu XML.	XML
		name():Object Zwraca pełną, kwalifikowaną nazwę obiektu XML.	XML
		namespace(prefix:String = null):* Jeśli nie został dostarczony żaden parametr, zwraca przestrzeń nazw skojarzoną z pełną (kwalifikowaną) nazwą tego obiektu XML.	XML
		namespaceDeclarations():Array Zwraca listę deklaracji przestrzeni nazw skojarzonych z obiektem XML (w kontekście obiektu macierzystego).	XML
		nodeKind():String Określa typ węzła: tekst, komentarz, instrukcja, atrybut lub element.	XML
		normalize():XML W przypadku obiektów XML i wszystkich jego obiektów potomnych scala sąsiednie i eliminuje puste węzły tekstowe.	XML
		parent():* Zwraca obiekt macierzysty obiektu XML.	XML
		prependChild(value:Object):XML Wstawia kopię udostępnionego obiektu child do elementu XML przed wszystkimi istniejącymi właściwościami XML tego elementu.	XML
		processingInstructions(name:String = "*"):XMLList W przypadku udostępnienia parametru name zwraca listę wszystkich elementów podrzędnych obiektu XML, które zawierają instrukcje związane z tym parametrem name.	XML
		propertyIsEnumerable(p:String):Boolean Sprawdza, czy właściwość p stanowi zbiór właściwości, które można iterować za pomocą instrukcji for..in zastosowanej do obiektu XML.	XML
		removeNamespace(ns:Namespace):XML Usuwa daną przestrzeń nazw z tego obiektu i wszystkich jego obiektów potomnych.	XML
		replace(propertyName:Object, value:XML):XML Zamienia właściwości określone przez parametr propertyName na dany parametr value.	XML
		setChildren(value:Object):XML Zamienia właściwości podrzędne obiektu XML określonym zbiorem właściwości XML (zgodnie z parametrem value).	XML
		setLocalName(name:String):void Zmienia lokalną nazwę obiektu XML zgodnie z danym parametrem name.	XML
		setName(name:String):void Ustawia nazwę obiektu XML jako podaną pełną nazwę lub nazwę atrybutu.	XML
		setNamespace(ns:Namespace):void Ustawia przestrzeń nazw skojarzoną z obiektem XML.	XML
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Ustawia dostępność właściwości dynamicznej używanej w pętlach.	Object
		setSettings(... rest):void [statyczny] Ustawia właściwości następujących właściwości XML: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent oraz prettyPrinting.	XML
		settings():Object [statyczny] Pobiera następujące właściwości: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent oraz prettyPrinting.	XML
		text():XMLList Zwraca obiekt XMLList zawierający wszystkie właściwości XML obiektu XML, który reprezentuje węzły tekstowe XML.	XML
		toJSON(k:String):* Dostarcza możliwą do przesłonięcia metodę, która pozwala na dostosowywanie kodowania JSON wartości w obiekcie XML.	XML
		toLocaleString():String Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych.	Object
		toString():String Zwraca ciąg znaków reprezentujący obiekt XML.	XML
		toXMLString():String Zwraca ciąg znaków reprezentujący obiekt XML.	XML
		valueOf():XML Zwraca obiekt XML.	XML

Szczegół właściwości

ignoreComments

właściwość

ignoreComments:Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Określa, czy podczas analizy składniowej danych źródłowych XML są ignorowane komentarze XML. Komentarze są domyślnie pomijane (wartość true). Aby uwzględnić komentarze XML, tę właściwość należy ustawić na wartość false. Właściwości ignoreComments używa się tylko podczas analizy składniowej obiektu XML, a nie podczas wywoływania metody, jak np. myXMLObject.child(*).toXMLString(). Jeśli źródłowy obiekt XML zawiera węzły komentarza, można je uwzględnić lub pominąć podczas analizy składniowej obiektu XML.

Implementacja
public static function get ignoreComments():Boolean
public static function set ignoreComments(value:Boolean):void

Powiązane elementy interfejsu API

XML.child()
XML.toXMLString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje rezultat ustawienia właściwości XML.ignoreComments na wartość false, a następnie na wartość true:

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreProcessingInstructions

właściwość

ignoreProcessingInstructions:Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Określa, czy podczas analizy składniowej danych źródłowych XML są ignorowane instrukcje XML. Instrukcje są domyślnie pomijane (wartość true). Aby uwzględnić instrukcje XML, tę właściwość należy ustawić na wartość false. Właściwości ignoreProcessingInstructions używa się wyłącznie podczas analizy składniowej obiektu XML, a nie podczas wywołania metody, jak np. myXMLObject.child(*).toXMLString(). Jeśli źródłowy obiekt XML zawiera węzły instrukcji, można je uwzględnić lub pominąć podczas analizy składniowej obiektu XML.

Implementacja
public static function get ignoreProcessingInstructions():Boolean
public static function set ignoreProcessingInstructions(value:Boolean):void

Powiązane elementy interfejsu API

XML.child()
XML.toXMLString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje rezultat ustawienia właściwości XML.ignoreProcessingInstructions na wartość false, a następnie na wartość true:

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreWhitespace

właściwość

ignoreWhitespace:Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Określa, czy w trakcie analizy składniowej mają być ignorowane spacje na początku i końcu węzłów tekstowych. Białe znaki są domyślnie pomijane (wartość true). Jeśli węzeł tekstowy składa się w 100% z białych znaków, a właściwość ignoreWhitespace jest ustawiona na wartość true, wówczas węzeł nie zostanie utworzony. Aby w węźle tekstowym wyświetlić białe znaki, należy właściwość ignoreWhitespace ustawić na wartość false.

Nowy obiekt XML buforuje w pamięci podręcznej obowiązującą w momencie tworzenia go wartość właściwości ignoreWhitespace. Zmiana właściwości ignoreWhitespace nie zmienia zachowania istniejących obiektów XML.

Implementacja
public static function get ignoreWhitespace():Boolean
public static function set ignoreWhitespace(value:Boolean):void

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje rezultat ustawienia właściwości XML.ignoreWhitespace na wartość false, a następnie na wartość true:

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

prettyIndent

właściwość

prettyIndent:int

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Określa wielkość wcięcia stosowanego w ramach metod toString() i toXMLString(), gdy właściwość XML.prettyPrinting jest ustawiona na wartość true. Wcięcia tworzy się za pomocą spacji, a nie tabulacji. Wartość domyślna to 2.

Implementacja
public static function get prettyIndent():int
public static function set prettyIndent(value:int):void

Powiązane elementy interfejsu API

prettyPrinting
toString()
toXMLString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje rezultat ustawienia statycznej właściwości XML.prettyIndent:

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

prettyPrinting

właściwość

prettyPrinting:Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Określa, czy metody toString() i toXMLString() mają normalizować białe znaki między niektórymi znacznikami. Wartością domyślną jest true.

Implementacja
public static function get prettyPrinting():Boolean
public static function set prettyPrinting(value:Boolean):void

Powiązane elementy interfejsu API

prettyIndent
toString()
toXMLString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje rezultat ustawienia statycznej właściwości XML.prettyPrinting:

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Konstruktor Szczegół

()

Konstruktor

public function XML(value:Object)

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Tworzy nowy obiekt XML. Przed wywołaniem którejkolwiek metody klasy XML należy za pomocą konstruktora utworzyć obiekt XML.

Należy użyć metody toXMLString(), aby zwrócić ciąg reprezentujący obiekt XML, bez względu na to czy obiekt XML zawiera elementy proste czy złożone.

Parametry

value:Object — Dowolny obiekt, który można skonwertować na obiekt XML za pomocą funkcji najwyższego poziomu XML().

Powiązane elementy interfejsu API

Funkcja globalna XML()
XML.toXMLString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład przedstawia sposób ładowania zdalnego dokumentu XML (napisanego w języku ActionScript 3.0) za pomocą klasy URLLoader w programie Flash Professional. Przykład pochodzi z witryny ActionScriptExamples.com.

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

Oto inny wariant przy użyciu kodu ActionScript. Przykład pochodzi z witryny ActionScriptExamples.com.

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Szczegół metody

addNamespace

()

metoda

AS3 function addNamespace(ns:Object):XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Dodaje przestrzeń nazw do zbioru przestrzeni nazw dotyczących obiektu XML. Jeśli w zbiorze przestrzeni nazw dla obiektu XML istnieje już przestrzeń nazw (z przedrostkiem zgodnym z przedrostkiem danego parametru), wówczas przedrostek istniejącej przestrzeni nazw zostaje ustawiony na wartość undefined. Jeśli parametr wejściowy to obiekt Namespace, jest on bezpośrednio użyty. Jeśli jest to obiekt QName, identyfikator URI z parametru wejściowego zostanie użyty w celu utworzenia nowej przestrzeni nazw. W przeciwnym razie zostanie przekonwertowany na ciąg znaków, a przestrzeń nazw tworzona jest z ciągu znaków.

Parametry

ns:Object — Przestrzeń nazw dodawana do obiektu XML.

Zwraca

XML — Nowy obiekt XML z dodaną przestrzenią nazw.

Przykład ( Sposób korzystania z tego przykładu )

W tym przykładzie pokazano użycie przestrzeni nazw określonej dla jednego obiektu XML i zastosowanie jej do innego obiektu XML:

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

appendChild

()

metoda

AS3 function appendChild(child:Object):XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Dołącza dany element podrzędny na końcu właściwości obiektu XML. Metoda appendChild() pobiera obiekt XML, obiekt XMLList lub obiekt innego typu, który jest następnie konwertowany na ciąg znaków typu String.

Za pomocą operatora delete (XML) można usunąć węzły XML.

Parametry

child:Object — Dołączany obiekt XML.

Zwraca

XML — Wynikowy obiekt XML.

Powiązane elementy interfejsu API

Operator delete (XML)

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje załączanie nowego elementu na końcu listy elementów podrzędnych obiektu XML:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

attribute

()

metoda

AS3 function attribute(attributeName:*):XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca wartość XML atrybutu o nazwie zgodnej z parametrem attributeName. Atrybuty znajdują się w elementach XML. W poniższym przykładzie pokazano element posiadający atrybut o nazwie „gender” i wartości „boy”: <first gender="boy">John</first>.

Parametr attributeName może stanowić dowolny typ danych. Jednakże najczęściej używanym typem danych jest String. W przypadku przekazywania obiektu innego niż obiekt QName parametr attributeName jest konwertowany na ciąg znaków za pomocą metody toString().

W razie konieczności utworzenia odwołania nazwy kwalifikowanej można przekazać obiekt QName. Za pomocą obiektu QName można definiować przestrzeń nazw oraz nazwę lokalną, której można użyć do definiowania kwalifikowanej nazwy atrybutu. Z tego względu wywołanie metody attribute(qname) nie jest równoważne z wywołaniem metody attribute(qname.toString()).

Parametry

attributeName:* — Nazwa atrybutu.

Zwraca

XMLList — Obiekt XMLList lub pusty obiekt XMLList. Jeśli wartość atrybutu nie została zdefiniowana, zwraca pusty obiekt XMLList.

Powiązane elementy interfejsu API

XML.attributes()
QName
Namespace
XML.elements()
operator identyfikatora atrybutu (@)

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje przekazanie obiektu QName do metody attribute(). Właściwość localName jest określana jako attr, a właściwość namespace jako ns.

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

Aby uzyskać zwrot atrybutu o nazwie zgodnej ze słowem zastrzeżonym w programie ActionScript, należy skorzystać z metody attribute() zamiast operatora identyfikatora atrybutu (@), jak pokazano w poniższym przykładzie:

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));

attributes

()

metoda

AS3 function attributes():XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca listę wartości atrybutów danego obiektu XML. Aby uzyskać zwrot nazwy atrybutu, należy użyć metody name() wraz z metodą attributes(). Użycie metody xml.attributes() jest równoważne użyciu operatora xml.@*.

Zwraca

XMLList — Lista wartości atrybutu.

Powiązane elementy interfejsu API

XML.attribute()
XML.name()
operator @

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje zwrot nazwy atrybutu:

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

Poniższy przykład ilustruje zwrot nazw wszystkich atrybutów:

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
}

child

()

metoda

AS3 function child(propertyName:Object):XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Wyświetla listę obiektów podrzędnych obiektu XML. Element potomny obiektu XML to element XML, węzeł tekstowy, komentarz lub instrukcja.

Za pomocą parametru propertyName można utworzyć listę zawartości określonego potomnego obiektu XML. Aby na przykład zwrócić zawartość elementu potomnego o nazwie <first>, należy wywołać metodę child("first") dla obiektu XML. Taki sam wynik można wygenerować, korzystając z indeksu obiektu potomnego. Indeks określa położenie obiektu podrzędnego na liście innych obiektów potomnych XML. Na przykład metoda child(0) zwraca pierwszy element potomny na liście.

Za pomocą znaku gwiazdki (*) można zwrócić wszystkie elementy potomne w dokumencie XML. Na przykład za pomocą metody doc.child("*").

Za pomocą metody length() z parametrem gwiazdki (*) metody child() można uzyskać zwrot wszystkich elementów potomnych. Na przykład: numChildren = doc.child("*").length().

Parametry

propertyName:Object — Nazwa elementu lub liczba całkowita podrzędnego obiektu XML.

Zwraca

XMLList — Obiekt XMLList zawierający węzły podrzędne zgodne z parametrem wejściowym.

Powiązane elementy interfejsu API

XML.elements()
klasa XMLList
XML.length()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody child() do identyfikacji elementów potomnych o określonej nazwie:

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

childIndex

()

metoda

AS3 function childIndex():int

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Identyfikuje obiekt o zerowym indeksie w obiekcie XML (w kontekście obiektu nadrzędnego).

Zwraca

int — Położenie obiektu. Zwraca wartość -1, jak również dodatnie liczby całkowite.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody childIndex():

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

children

()

metoda

AS3 function children():XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zawiera listę elementów podrzędnych obiektu XML w kolejności ich wyświetlania. Element podrzędny obiektu XML to element XML, węzeł tekstowy, komentarz lub instrukcja.

Zwraca

XMLList — Obiekt XMLList zawierający elementy podrzędne obiektu XML.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody children():

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

comments

()

metoda

AS3 function comments():XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zawiera listę właściwości obiektu XML z komentarzami XML.

Zwraca

XMLList — Obiekt XMLList zawierający właściwości z komentarzami.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody comments():

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

contains

()

metoda

AS3 function contains(value:XML):Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Porównuje obiekt XML z danym parametrem value.

Parametry

value:XML — Wartość służąca do porównania z bieżącym obiektem XML.

Zwraca

Boolean — Jeśli obiekt XML jest zgodny z parametrem value, wówczas przyjęta zostaje wartość true. W przeciwnym przypadku — wartość false.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody contains():

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

copy

()

metoda

AS3 function copy():XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca kopię danego obiektu XML. Kopia stanowi duplikat wszystkich trzech węzłów. Jeśli skopiowany obiekt XML nie posiada elementu nadrzędnego, wówczas w przypadku wywołania metody parent() zwrócona zostanie wartość będzie null.

Zwraca

XML — Kopia obiektu

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje utworzenie nowej instancji obiektu XML za pomocą metody copy(). W przypadku modyfikacji kopii, obiekt oryginalny nie zmienia się:

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

defaultSettings

()

metoda

AS3 static function defaultSettings():Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca obiekt, którego następujące właściwości zostały ustawione na wartości domyślne: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent orazprettyPrinting. Wartości domyślne są następujące:

ignoreComments = true
ignoreProcessingInstructions = true
ignoreWhitespace = true
prettyIndent = 2
prettyPrinting = true

Uwaga: Tej metody nie stosuje się bezpośrednio do instancji klasy XML. Do klasy XML można ją zastosować za pomocą następującego kodu: var df:Object = XML.defaultSettings().

Zwraca

Object — Obiekt, którego właściwości zostały ustawione na wartości domyślne.

Powiązane elementy interfejsu API

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.setSettings()
XML.settings()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje sposób zastosowania niektórych ustawień własnych (na potrzeby komentarzy i instrukcji) przed ustawieniami obiektu XML, przywrócenia ustawień domyślnych przed ustawieniem kolejnego obiektu XML oraz ponownego określenia ustawień własnych (na potrzeby konfigurowania kolejnych obiektów XML):

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

descendants

()

metoda

AS3 function descendants(name:Object = *):XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca wszystkie elementy podrzędne (bezpośrednio podrzędne, podrzędne wobec obiektów podrzędnych itd.) obiektu XML o danym parametrze name. Parametr name jest opcjonalny. Parametr name może stanowić obiekt QName, dane typu String lub dane innego typu, które są następnie konwertowane na dane typu String.

Aby uzyskać zwrot wszystkich obiektów potomnych, należy użyć parametru „*” Jeśli żaden parametr nie zostanie przekazany, wówczas przekazany zostaje ciąg „*”, za pomocą którego zwracane są wszystkie elementy podrzędne obiektu XML.

Parametry

name:Object (default = *) — Nazwa zgodnego elementu.

Zwraca

XMLList — Obiekt XMLList zawierający obiekty podrzędne. W przypadku braku obiektów potomnych zwrócony obiekt XMLList jest pusty.

Powiązane elementy interfejsu API

operator dostępu do potomków (..) operator

Przykład ( Sposób korzystania z tego przykładu )

Aby zwrócić wszystkie obiekty podrzędne o nazwach zgodnych z wyrazem zastrzeżonym w narzędziu ActionScript, należy użyć metody descendants() zamiast operatora descendant (..), jak pokazano w poniższym przykładzie:

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class"));

Poniższy przykład ilustruje, jak za pomocą metody descendants() można uzyskać obiekt XMLList, który zawiera wszystkie obiekty podrzędne (bezpośrednio i niebezpośrednio):

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

elements

()

metoda

AS3 function elements(name:Object = *):XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Wyświetla listę elementów obiektu XML. Element składa się ze znacznika początkowego i końcowego, na przykład: <first></first>. Parametr name jest opcjonalny. Parametr name może stanowić obiekt QName, dane typu String lub inny typ danych, który będzie konwertowany na dane typu String. Za pomocą parametru name można umieścić na liście dany element. W tym przykładzie dla elementu „first” zwracany jest ciąg „John”: <first>John</first>.

Aby wyświetlić wszystkie elementy na liście, należy jako parametru użyć symbolu gwiazdki (*). Symbol gwiazdki stanowi również parametr domyślny.

Za pomocą metody length() z parametrem gwiazdki można uzyskać zwrot całkowitej liczby elementów. Na przykład, numElement = addressbook.elements("*").length().

Parametry

name:Object (default = *) — Nazwa elementu. Nazwa elementu jest ujęta w nawiasy ostre. W tym przykładzie „first” stanowi parametr name: <first></first>.

Zwraca

XMLList — Obiekt XMLList składający się z zawartości elementów. Zawartość elementów oddzielana jest znacznikiem początkowym i końcowym. W przypadku użycia symbolu gwiazdki (*) do wywołania wszystkich elementów zwracana są zarówno znaczniki elementów jak i zawartość.

Powiązane elementy interfejsu API

XML.child()
klasa XMLList
XML.length()
XML.attribute()
operator XML dot (.) operator

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje, jak przy użyciu metody elements() można otrzymać zwrot listy samych elementów — nie komentarzy, właściwości tekstu czy instrukcji:

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

Aby uzyskać zwrot elementów, których nazwy są zgodne z wyrazami zastrzeżonymi w narzędziu ActionScript, należy użyć metody elements() zamiast operatora XML dot (.), jak pokazano w poniższym przykładzie:

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class"));

hasComplexContent

()

metoda

AS3 function hasComplexContent():Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Sprawdza, czy obiekt XML zawiera elementy złożone. Obiekt XML posiada elementy złożone, jeśli jego zawartość stanowią elementy podrzędne. Obiekty XML reprezentujące atrybuty, komentarze, instrukcje oraz węzły tekstowe nie posiadają elementów złożonych. Obiekt zawierający powyższe elementy można jednak uznać za obiekt o elementach złożonych, jeśli istnieją dla niego obiekty podrzędne).

Zwraca

Boolean — Jeśli obiekt XML zawiera elementy złożone, wówczas zwrócona zostaje wartość true. W przeciwnym razie — wartość false.

Powiązane elementy interfejsu API

XML.hasSimpleContent()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład przedstawia obiekt XML posiadający jedną właściwość o nazwie a, która zawiera elementy proste oraz jedną właściwość o nazwie a, która zawiera elementy złożone:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

hasOwnProperty

()

metoda

AS3 function hasOwnProperty(p:String):Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Sprawdza, czy obiekt posiada właściwość określoną przez parametr p.

Parametry

p:String — Zgodna właściwość.

Zwraca

Boolean — Jeśli ta właściwość istnieje, true; w przeciwnym wypadku false.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody hasOwnProperty() w celu upewnienia się, że właściwość (b) istnieje zanim nastąpi analiza wyrażenia (b == "11"), które korzysta z tej właściwości:

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11"));

W przypadku gdy w tym przykładzie ostatni wiersz wyglądałby jak poniżej, program Flash Player wygenerowałby wyjątek, ponieważ pierwszy element o nazwie a nie posiada właściwości o nazwie b:

trace(xml.a.(b == "11"));

Poniższy przykład ilustruje użycie metody hasOwnProperty() w celu upewnienia się, że właściwość (item) istnieje zanim nastąpi analiza wyrażenia (item.contains("toothbrush")), które korzysta z tej właściwości:

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));

hasSimpleContent

()

metoda

AS3 function hasSimpleContent():Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Sprawdza, czy obiekt XML zawiera elementy proste. Obiekt XML zawiera elementy proste, jeśli reprezentuje węzeł tekstowy, węzeł atrybutów lub element XML, który nie posiada elementów podrzędnych. Obiekt XML, który reprezentuje komentarze i instrukcje nie zawiera elementów prostych.

Zwraca

Boolean — Jeśli obiekt XML zawiera elementy proste, wówczas zwrócona zostaje wartość true. W przeciwnym razie — wartość false.

Powiązane elementy interfejsu API

XML.hasComplexContent()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład przedstawia obiekt XML mający jedną właściwość o nazwie a, która zawiera elementy proste, oraz jedną właściwość o nazwie a, która zawiera elementy złożone.

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

inScopeNamespaces

()

metoda

AS3 function inScopeNamespaces():Array

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Tworzy listę przestrzeni nazw dla obiektu XML na podstawie obiektu macierzystego.

Zwraca

Array — Tablica obiektów Namespace.

insertChildAfter

()

metoda

AS3 function insertChildAfter(child1:Object, child2:Object):*

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Wstawia w obiekcie XML dany parametr child2 po parametrze child1 i zwraca obiekt wynikowy. Jeśli parametr child1 ma wartość null, metoda wstawia zawartość parametru child2 przed wszystkimi elementami potomnymi obiektu XML (innymi słowy po wartości none). Jeśli parametr child1 został udostępniony, ale nie istnieje w obiekcie XML, obiekt XML nie zostanie modyfikowany i zostanie zwrócona wartość undefined.

W przypadku wywołania tej metody dla obiektu podrzędnego XML, który nie jest elementem (tekstem, atrybutem, komentarzem, wartością pi itd.) zwracana jest wartość undefined.

Za pomocą operatora delete (XML) można usunąć węzły XML.

Parametry

	`child1:Object` — Obiekt to obiekt źródłowy wstawiany przed parametrem `child2`.

	`child2:Object` — Obiekt do wstawienia.

Zwraca

* — Wynikowy obiekt XML lub wartość undefined.

Powiązane elementy interfejsu API

XML.insertChildBefore()
operator delete (XML)

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje dołączanie elementu na końcu listy elementów podrzędnych obiektu XML:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

Rezultat wywołania metody trace() jest następujący:

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

insertChildBefore

()

metoda

AS3 function insertChildBefore(child1:Object, child2:Object):*

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Wstawia w tym obiekcie XML parametr child2 przed parametrem child1 i zwraca obiekt wynikowy. Jeśli parametr child1 posiada wartość null, metoda wstawia zawartość parametru child2 po wszystkich elementach potomnych obiektu XML (innymi słowy przed wartością none). Jeśli parametr child1 został udostępniony, ale nie istnieje w obiekcie XML, obiekt XML nie zostanie modyfikowany i zostanie zwrócona wartość undefined.

W przypadku wywołania tej metody dla obiektu podrzędnego XML, który nie jest elementem (tekstem, atrybutem, komentarzem, wartością pi itd.) zwracana jest wartość undefined.

Za pomocą operatora delete (XML) można usunąć węzły XML.

Parametry

	`child1:Object` — Obiekt w obiekcie źródłowym wstawiony po parametrze `child2`.

	`child2:Object` — Obiekt do wstawienia.

Zwraca

* — Wynikowy obiekt XML lub wartość undefined.

Powiązane elementy interfejsu API

XML.insertChildAfter()
Operator delete (XML)

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje dołączanie elementu na końcu listy elementów podrzędnych obiektu XML:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

Rezultat wywołania metody trace() jest następujący:

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

length

()

metoda

AS3 function length():int

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Dla obiektu XML ta metoda zawsze zwraca liczbę całkowitą 1. Metoda length() klasy XMLList zwraca wartość 1 dla obiektu XMLList, który zawiera tylko jedną wartość.

Zwraca

int — Dla dowolnego obiektu XML zawsze zwraca wartość 1.

localName

()

metoda

AS3 function localName():Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca nazwę lokalną zawartą w pełnej nazwie obiektu XML.

Zwraca

Object — Dla nazwy lokalnej zwracany jest ciąg znaków, albo wartość null.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody localName():

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

name

()

metoda

AS3 function name():Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca pełną, kwalifikowaną nazwę obiektu XML.

Zwraca

Object — Pełna nazwa to albo QName albo wartość null.

Powiązane elementy interfejsu API

XML.attributes()
identyfikator atrybutu

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody name() w celu uzyskania pełnej nazwy obiektu XML:

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

Poniższy przykład ilustruje użycie metody name() wywołanej dla właściwości XML, elementu tekstowego i atrybutu:

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

namespace

()

metoda

AS3 function namespace(prefix:String = null):*

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Jeśli żaden parametr nie został przekazany, zwraca przestrzeń nazw skojarzoną z pełną nazwą tego obiektu XML. Jeśli parametr prefix został określony, wówczas metoda zwraca przestrzeń nazw zgodną z parametremprefix znajdującą się w zakresie obiektu XML. W przypadku braku przestrzeni nazw metoda zwraca wartość undefined.

Parametry

prefix:String (default = null) — Zgodny przedrostek.

Zwraca

* — Zwraca wartość null, undefined lub przestrzeń nazw.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody namespace() w celu pobrania przestrzeni nazw obiektu XML i przypisania jej do obiektu Namespace o nazwie soap, za pomocą którego można następnie zidentyfikować właściwość obiektu xml (xml.soap::Body[0]):

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

Poniższy przykład ilustruje użycie metody namespace() w celu pobrania domyślnej przestrzeni nazw dla węzła oraz przestrzeni nazw dla określonego przedrostka („dc”):

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

namespaceDeclarations

()

metoda

AS3 function namespaceDeclarations():Array

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca listę deklaracji przestrzeni nazw skojarzonych z obiektem XML (w kontekście obiektu macierzystego).

Zwraca

Array — Tablica obiektów Namespace.

Powiązane elementy interfejsu API

XML.namespace()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje zwrot listy deklaracji przestrzeni nazw dla obiektu XML:

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

Rezultat wywołania metody trace() jest następujący:

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

nodeKind

()

metoda

AS3 function nodeKind():String

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Określa typ węzła: tekst, komentarz, instrukcja, atrybut lub element.

Zwraca

String — Typ użytego węzła.

Powiązane elementy interfejsu API

Identyfikator atrybutu

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje śledzenie wszystkich pięciu typów węzłów:

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

normalize

()

metoda

AS3 function normalize():XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

W przypadku obiektów XML i wszystkich jego obiektów potomnych scala sąsiednie i eliminuje puste węzły tekstowe.

Zwraca

XML — Wynikowy, znormalizowany obiekt XML.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje rezultat wywołania metody normalize():

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

parent

()

metoda

AS3 function parent():*

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca obiekt macierzysty obiektu XML. Jeśli dla obiektu XML nie istnieje obiekt macierzysty, metoda zwraca wartość undefined.

Zwraca

* — Odwołanie do obiektu XML węzła nadrzędnego lub wartość undefined, jeśli obiekt XML nie ma obiektu nadrzędnego.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody parent() w celu identyfikacji elementów macierzystych dla określonego elementu w strukturze XML:

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

prependChild

()

metoda

AS3 function prependChild(value:Object):XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Wstawia kopię udostępnionego obiektu child do elementu XML przed wszystkimi istniejącymi właściwościami XML tego elementu.

Za pomocą operatora delete (XML) można usunąć węzły XML.

Parametry

value:Object — Obiekt do wstawienia.

Zwraca

XML — Wynikowy obiekt XML.

Powiązane elementy interfejsu API

Operator delete (XML)

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody prependChild() w celu dodania elementu na początku listy elementów podrzędnych obiektu XML:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

processingInstructions

()

metoda

AS3 function processingInstructions(name:String = "*"):XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

W przypadku udostępnienia parametru name zwraca listę wszystkich elementów potomnych obiektu XML, które zawierają instrukcje z tym parametrem name. W przypadku braku parametru metoda zwraca listę wszystkich elementów potomnych obiektu XML zawierających dowolne instrukcje.

Parametry

name:String (default = "*") — Nazwa zgodnych instrukcji.

Zwraca

XMLList — Lista zgodnych obiektów podrzędnych.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody processingInstructions() w celu uzyskania tablicy instrukcji dla obiektu XML:

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

propertyIsEnumerable

()

metoda

AS3 function propertyIsEnumerable(p:String):Boolean

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Sprawdza, czy właściwość p stanowi zbiór właściwości, które można iterować za pomocą instrukcji for..in zastosowanej do obiektu XML. Zwraca wartość true tylko w przypadku gdy toString(p) == "0".

Parametry

p:String — Sprawdzana właściwość.

Zwraca

Boolean — Jeśli właściwość można iterować za pomocą instrukcji for..in, zwrócona zostaje wartość true. W przeciwnym razie — wartość false.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje, że dla obiektu XML metoda propertyNameIsEnumerable() zwraca wartość true tylko w przypadku wartości 0, podczas gdy dla obiektu XMLList zwracana jest wartość true dla każdego poprawnego indeksu obiektu XMLList:

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

removeNamespace

()

metoda

AS3 function removeNamespace(ns:Namespace):XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Usuwa daną przestrzeń nazw dla określonego obiektu i wszystkich jego obiektów potomnych. Jeśli odwołanie do metody removeNamespaces() nastąpi przy wykorzystaniu pełnej nazwy obiektu, lub pełnej nazwy jego atrybutów, wówczas metoda nie usunie przestrzeni nazw.

Parametry

ns:Namespace — Przestrzeń nazw do usunięcia.

Zwraca

XML — Kopia wynikowego obiektu XML.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje sposób usuwania deklaracji przestrzeni nazw z obiektu XML:

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

replace

()

metoda

AS3 function replace(propertyName:Object, value:XML):XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zamienia właściwości określone przez parametr propertyName na dany parametr value. W przypadku braku właściwości zgodnych z parametrem propertyName obiekt XML nie zostaje zmodyfikowany.

Parametry

	`propertyName:Object` — Może to być wartość liczbowa, niepełna nazwa zbioru elementów XML, pełna nazwa zbioru elementów XML lub wieloznaczny symbol gwiazdki („*”). Nazwa niepełna służy do identyfikacji elementów XML w domyślnej przestrzeni nazw.

	`value:XML` — Wartość zamienna. Może to być obiekt XML, obiekt XMLList lub dowolna wartość, którą można konwertować za pomocą metody `toString()`.

Zwraca

XML — Wynikowy obiekt XML zawierający zamienione zgodne właściwości.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje wywołanie metody replace() zawierającej w miejscu pierwszego parametru liczbę całkowitą:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

Rezultat wywołania metody trace() jest następujący:


 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>

Poniższy przykład ilustruje wywołanie metody replace() zawierającej w miejscu pierwszego parametru ciąg znaków:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

Rezultat wywołania metody trace() jest następujący:


 <body>
     <p>Hi</p>
     <hr/>
 </body>;

Poniższy przykład ilustruje wywołanie metody replace() zawierającej w miejscu pierwszego parametru obiekt QName:

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

Rezultat wywołania metody trace() jest następujący:


 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>

Poniższy przykład ilustruje wywołanie metody replace() zawierającej w miejscu pierwszego parametru ciąg znaków "*":

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

Rezultat wywołania metody trace() jest następujący:


 <body>
     <img src="hello.jpg"/>
 </body>

setChildren

()

metoda

AS3 function setChildren(value:Object):XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zamienia właściwości podrzędne obiektu XML określonym zbiorem właściwości XML (zgodnie z parametrem value).

Parametry

value:Object — Zamienne właściwości XML. Mogą stanowić pojedynczy obiekt XML lub XMLList.

Zwraca

XML — Wynikowy obiekt XML.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje wywołanie metody setChildren() najpierw przy użyciu jako parametru obiektu XML, a następnie obiektu XMLList:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

setLocalName

()

metoda

AS3 function setLocalName(name:String):void

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zmienia nazwę lokalna obiektu XML zgodnie z danym parametrem name.

Parametry

name:String — Nazwa zamienna dla nazwy lokalnej.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody setLocalName() w celu zmiany nazwy lokalnej elementu XML:

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

setName

()

metoda

AS3 function setName(name:String):void

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Ustawia nazwę obiektu XML jako podaną pełną nazwę lub nazwę atrybutu.

Parametry

name:String — Nowa nazwa obiektu.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody setName() w celu zmiany nazwy elementu XML:

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

setNamespace

()

metoda

AS3 function setNamespace(ns:Namespace):void

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Ustawia przestrzeń nazw skojarzoną z obiektem XML.

Parametry

ns:Namespace — Nowa przestrzeń nazw.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie przestrzeni nazw soap określonej w jednym obiekcie XML i jej zastosowanie do przestrzeni nazw innego obiektu XML (xml2):

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

setSettings

()

metoda

AS3 static function setSettings(... rest):void

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Ustawia wartości dla następujących właściwości XML: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent oraz prettyPrinting. Poniższe ustawienia domyślne mają zastosowane w przypadku braku udostępnienia parametru setObj:

XML.ignoreComments = true
XML.ignoreProcessingInstructions = true
XML.ignoreWhitespace = true
XML.prettyIndent = 2
XML.prettyPrinting = true

Uwaga: Tej metody nie stosuje się bezpośrednio do instancji klasy XML. Do klasy XML można ją stosować za pomocą następującego kodu: XML.setSettings().

Parametry

... rest — Obiekt zawierający każdą z poniższych właściwości:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Powiązane elementy interfejsu API

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting
defaultSettings()
settings()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje sposób zastosowania niektórych niestandardowych ustawień (na potrzeby komentarzy i instrukcji) przed ustawieniami obiektu XML, przywrócenia ustawień domyślnych przed ustawieniem kolejnego obiektu XML oraz ponownego określenia ustawień niestandardowych (na potrzeby ustawień kolejnych obiektów XML):

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

settings

()

metoda

AS3 static function settings():Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Pobiera następujące właściwości: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent oraz prettyPrinting.

Zwraca

Object — Obiekt zawierający poniższe właściwości XML:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Powiązane elementy interfejsu API

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.defaultSettings()
XML.setSettings()

Przykład ( Sposób korzystania z tego przykładu )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

text

()

metoda

AS3 function text():XMLList

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca obiekt XMLList zawierający wszystkie właściwości XML obiektu XML, który reprezentuje węzły tekstowe XML.

Zwraca

XMLList — Lista właściwości.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje użycie metody text() w celu pobrania węzłów tekstowych obiektu XML:

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

toJSON

()

metoda

AS3 function toJSON(k:String):*

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

Flash Player 11, AIR 3, Flash Lite 4

Dostarcza możliwą do przesłonięcia metodę, która pozwala na dostosowywanie kodowania JSON wartości w obiekcie XML.

Metoda JSON.stringify() szuka metody toJSON() w każdym obiekcie, który przegląda. Jeżeli metoda toJSON() zostanie odnaleziona, metoda JSON.stringify() wywołuję ją dla każdej wartości, którą napotka, przekazując klucz będący w parze z tą wartością.

Obiekt XML dostarcza domyślną implementację metody toJSON() zwracającą po prostu nazwę klasy. Klienci, którzy chcą eksportować obiekty XML do formatu JSON, muszą zapewnić własną implementację. Można to zrobić, ponownie definiując metodę toJSON() prototypu klasy.

Metoda toJSON() może zwracać wartość dowolnego typu. W przypadku zwrócenia obiektu metoda stringify() przeszukuje rekurencyjnie ten obiekt. Jeżeli metoda toJSON() zwraca ciąg, to metoda stringify() nie działania rekurencyjnie i kontynuuje przeglądanie.

Parametry

k:String — Klucz z pary klucz-wartość napotkany przez metodę JSON.stringify() podczas przeglądania tego obiektu.

Zwraca

* — Ciąg nazwy klasy.

Powiązane elementy interfejsu API

Object
Object.prototype

toString

()

metoda

AS3 function toString():String

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca ciąg znaków reprezentujący obiekt XML. Reguły tej konwersji zależą od tego, czy elementy zawarte w obiekcie XML są proste czy złożone:

Jeśli obiekt XML zawiera treść prostą, metodatoString() zwraca zawartość obiektu XML w postaci ciągu znaków i usuwa następujące elementy: znacznik początkowy, atrybuty, deklaracje przestrzeni nazw oraz znacznik końcowy.

Jeśli obiekt XML zawiera elementy złożone, metoda toString() zwraca w formie ciągu znaków zawartość XML reprezentującą cały obiekt XML wraz ze znacznikiem początkowym, atrybutami, deklaracjami przestrzeni nazw oraz znacznikiem końcowym.

Aby za każdym razem uzyskać zwrot całego obiektu XML, należy użyć metody toXMLString().

Zwraca

String — Ciąg znaków reprezentujący obiekt XML.

Powiązane elementy interfejsu API

XML.hasSimpleContent()
XML.hasComplexContent()
XML.toXMLString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje wyniki zwrócone przez metodę toString() w przypadku obiektu XML zawierającego elementy proste:

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

Poniższy przykład ilustruje wyniki zwrócone przez metodę toString() w przypadku obiektu XML zawierającego elementy złożone:

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type>

toXMLString

()

metoda

AS3 function toXMLString():String

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca ciąg znaków reprezentujący obiekt XML. W przeciwieństwie do metody toString(), metoda toXMLString() zawsze zwraca znacznik początkowy, atrybuty oraz znacznik końcowy obiektu XML bez względu na to, czy elementy zawarte w obiekcie XML są proste czy złożone. (Metoda toString() usuwa te elementy z obiektów XML, które zawierają treść prostą).

Zwraca

String — Ciąg znaków reprezentujący obiekt XML.

Powiązane elementy interfejsu API

XML.toString()

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje różnicę w wykorzystaniu metody toString() (która domyślnie ma zastosowanie do wszystkich parametrów metody trace()), a użyciem metody toXMLString():

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

valueOf

()

metoda

AS3 function valueOf():XML

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Zwraca obiekt XML.

Zwraca

XML — Pierwotna wartość instancji XML.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład pokazuje, że wartość zwrócona przez metodę valueOf() jest taka sama jak źródłowego obiektu XML:

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true

Przykłady Sposób korzystania z tego przykładu

XMLExample.as

Poniższy przykład ilustruje tworzenie zmiennej XML, a następnie dodawanie do niej węzłów. Wówczas właściwości XML zostają użyte do wyszukania i wydruku węzłów XML. Należy pamiętać, że symbolu „małpy” (@) używa się przy kilku wywołaniach metody trace() w celu lokalizacji informacji według nazwy atrybutu.

package {
    import flash.display.Sprite;

    public class XmlExample extends Sprite {        
        public function XmlExample() {
            var employees:XML =
                <employees>
                    <employee ssn="123-123-1234">
                        <name first="John" last="Doe"/>
                        <address>
                            <street>11 Main St.</street>
                            <city>San Francisco</city>
                            <state>CA</state>
                            <zip>98765</zip>
                        </address>
                    </employee>
                    <employee ssn="789-789-7890">
                        <name first="Mary" last="Roe"/>
                        <address>
                            <street>99 Broad St.</street>
                            <city>Newton</city>
                            <state>MA</state>
                            <zip>01234</zip>
                        </address>
                    </employee>
                </employees>;

            trace(employees.employee[0].address.zip);   // 98765

            trace(employees.employee[1].@ssn);          // 789-789-7890

            trace(employees.employee.name);             // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees..zip[0]);                   // 98765

            trace(employees..@ssn[1]);                  // 789-789-7890

            trace(employees..name);                     // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees.employee[0].address.*);     // <street>11 Main St.</street>    
                                                        // <city>San Francisco</city>
                                                        // <state>CA</state>
                                                        // <zip>98765</zip>
            var node:String = "zip";
            trace(employees.employee[0].address[node]); // 98765
            
            var attribute:String = "ssn";
            trace(employees.employee[1].@[attribute]);  // 789-789-7890
            
            for each (var num:XML in employees..@ssn) {
                trace(num);                             // 123-123-1234
            }                                           // 789-789-7890
            
            var ssnToFind:String = "789-789-7890";
            trace(employees.employee.(@ssn == ssnToFind).toXMLString());
                                                        // <employee ssn="789-789-7890">
                                                        // <name first="Mary" last="Roe"/>
                                                        // <address>
                                                        // <street>99 Broad St.</street>
                                                        // <city>Newton</city>
                                                        // <state>MA</state>
                                                        // <zip>01234</zip>
                                                        // </address>
                                                        // </employee>
        }
    }
}

Informacje prawne | Zasady prywatności online

XML - AS3

Pakietyx

Elementy językowe

Dodatki

Klasy x

ignoreComments

ignoreProcessingInstructions

ignoreWhitespace

prettyIndent

prettyPrinting

XML

addNamespace

appendChild

attribute

attributes

child

childIndex

children

comments

contains

copy

defaultSettings

descendants

elements

hasComplexContent

hasOwnProperty

hasSimpleContent

inScopeNamespaces

insertChildAfter

insertChildBefore

length

localName

name

namespace

namespaceDeclarations

nodeKind

normalize

parent

prependChild

processingInstructions

propertyIsEnumerable

removeNamespace

replace

setChildren

setLocalName

setName

setNamespace

setSettings

settings

text

toJSON

toString

toXMLString

valueOf