QName  - AS3

Lokalna nazwa obiektu QName.

Identyfikator URI (Uniform Resource Identifier) obiektu QName.

Tworzy obiekt QName będący kopią innego obiektu QName. Jeśli przekazany do konstruktora parametr to obiekt QName, tworzona jest kopia tego obiektu. Jeśli parametr nie jest obiektem QName, zostaje on przekonwertowany na ciąg znaków i przypisany właściwości localName nowej instancji QName. Jeśli parametr posiada wartość undefined lub nie został określony, tworzony jest nowy obiekt QName z właściwością localName, której wartość zostaje ustawiona na pusty ciąg znaków.

Uwaga: Ta klasa zawiera dwa wpisy konstruktora, ponieważ każdy formularz wymaga różnych parametrów. Zachowanie konstruktora może być różne w zależności o typu i liczby przekazanych parametrów określonych w każdym wpisie. Język ActionScript 3.0 nie obsługuje przeciążania metod i konstruktorów.

Tworzy z obiektu Namespace obiekt QName z identyfikatorem URI, a także obiekt localName z obiektu QName. Jeśli którykolwiek z tych dwóch parametrów nie jest zgodny z oczekiwanym typem danych, zostaje przekonwertowany na ciąg znaków i przypisany odpowiedniej właściwości obiektu QName. Na przykład, jeśli obydwa parametry to ciąg znaków, nowy obiekt QName jest zwracany z właściwością uri ustawioną na pierwszy parametr, a właściwość localName zostaje ustawiona na drugi parametr. Innymi słowy, poniższe permutacje (jak i wiele innych) stanowią poprawne formularze dla konstruktora:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Jeśli parametrowi uri zostanie nadana wartość null, właściwość uri nowego obiektu QName zostanie ustawiona na wartość null.

Uwaga: Ta klasa zawiera dwa wpisy konstruktora, ponieważ każdy formularz wymaga różnych parametrów. Zachowanie konstruktora może być różne w zależności o typu i liczby przekazanych parametrów określonych w każdym wpisie. Język ActionScript 3.0 nie obsługuje przeciążania metod i konstruktorów.

Zwraca ciąg złożony z identyfikatora URI oraz lokalnej nazwy obiektu QName, oddzielone znakami „::”.

Formularz zależy od właściwości uri obiektu QName:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Zwraca obiekt QName.

1. Tworzenie instancji Namespace i wprowadzenie jej do konstruktora QName. Ten sposób umożliwia późniejsze wykorzystanie właściwości Namespace.prefix do innych celów.
2. Tworzenie instancji QName za pomocą prostego ciągu wartości dla parametru uri w konstruktorze QName.

Rezultaty zastosowania tego kodu:

1. Określenie zmiennej XML o nazwie rssXML.
2. Utworzenie nowego obiektu Namespace z przedrostkiem dc.
3. Utworzenie nowego obiektu QName przy użyciu obiektu Namespace oraz nazwy lokalnej creator.
4. Wywołanie metody showDescendants(), która wykorzystuje metodę XML.descendants() do pobrania instancji XMLList zawierającej wszystkie elementy potomne, której pełna nazwa jest zgodna z daną instancja QName.
5. Wyświetlenie pełnej nazwy i wartości tekstowej dla każdego elementu z listy za pomocą pętli for each.
6. Utworzenie kolejnego obiektu QName za pomocą ciągu wartości parametru uri i nazwy lokalnej date.
7. Ponowne wywołanie metody showDescendants() w celu wyświetlenia nazwy i wartości tekstowej elementów podrzędnych.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}