ContextMenuItem  - AS3

Pakiet	flash.ui
Klasa	public final class ContextMenuItem
Dziedziczenie	ContextMenuItem NativeMenuItem EventDispatcher Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 1.0, Flash Player 9

Klasa ContextMenuItem reprezentuje element w menu kontekstowym. Każdy objekt ContextMenuItem zawiera napis (tekst) wyświetlony w menu kontekstowym. Aby dodać nowy element do menu kontekstowego, należy dodać go do tablicy customItems obiektu ContextMenu.

Za pomocą właściwości klasy ContextMenuItem można włączać lub wyłączać określone elementy menu oraz powodować, że będą one widoczne lub niewidoczne.

Poprzez zapisanie modułu obsługi zdarzeń dla zdarzenia menuItemSelect realizuje się dodawanie funkcjonalności do elemenu menu po wybraniu go przez użytkownika.

Niestandardowe elementy menu pojawiają się w górnej części menu kontekstowego powyżej wbudowanych elementów. Pasek separatora oddziela niestandardowe elementy menu od elementów wbudowanych. W środowisku AIR nie ma wbudowanych elementów i poniższe ograniczenia nie dotyczą treści w obszarze izolowanym aplikacji AIR.

Ograniczenia:

• Do menu kontekstowego można dodać maksymalnie 15 elementów niestandardowych.
• Każdy napis musi zawierać co najmniej jeden widoczny znak.
• Znaki elementów sterujących, nowe linie oraz inne puste znaki są ignorowane.
• Napis nie może być dłuższy niż 100 znaków.
• Napisy identyczne z wbudowanymi lub niestandardowymi elementami menu są ignorowane, bez względu na to, czy element zgodny jest widoczny. Napisy menu są podobne do wbudowanych napisów lub istniejących napisów niestandardowych i nie rozróżniają wielkości liter, interpunkcji i pustych znaków.
• Następujące napisy są zabronione, jednak można stosować same wyrazy w połączeniu z innymi wyrazami w celu utworzenia napisu niestandardowego (na przykład, wyraz „Wklej" jest niedozwolony, ale wyrażenie „Wklej obrazek do albumu” jest dopuszczalne).

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• Żaden z poniższych wyrazów nie może pojawić się w niestandardowym napisie samodzielnie lub w połączeniu z innymi wyrazami:

   Adobe
   Macromedia
   Flash Player
   Settings
   

Uwaga: Jeśli użytkownik korzysta z systemu innego niż angielski, ciągi znaków napisu są porównane do listy angielskiej oraz przetłumaczonej listy.

Wyświetl przykłady

Powiązane elementy interfejsu API

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}