ContextMenuEvent  - AS3

Obiekt listy wyświetlania, z którym jest skojarzone menu. Może to być cel myszy (mouseTarget) lub jeden z jego przodków na liście wyświetlania.

Określa, czy ze względów bezpieczeństwa właściwość mouseTarget została ustawiona na null. Jeśli nominalną wartością właściwości menuTarget byłoby odwołanie do obiektu DisplayObject w innym obszarze izolowanym, wówczas właściwości menuTarget przypisywana jest wartość null, chyba że ustanowiono uprawnienia w obu kierunkach przez granice obszaru izolowanego. Uprawnienie ustanawiane jest przez wywołanie metody Security.allowDomain() z pliku SWF lub przez dostarczenie pliku reguł z serwera pliku obrazu i ustawienie flagi LoaderContext.checkPolicyFile podczas ładowania obrazu.

Powiązane elementy interfejsu API

Obiekt listy wyświetlania, którego kliknięcie prawym przyciskiem myszy powoduje wyświetlenie menu kontekstowego. Może to być obiekt listy wyświetlania, z którym skojarzone jest menu (contextMenuOwner) lub jeden z jego potomków na liście wyświetlania.

Ta właściwość może mieć wartość null w dwóch przypadkach: jeśli nie istnieje cel myszy (np. gdy mysz zostanie przesunięta z tła nad inny element) lub jeśli istnieje cel myszy, ale znajduje się on w obszarze izolowanym, do którego program nie ma dostępu. Aby wskazać, który z tych powodów znajduje zastosowanie, należy użyć właściwości isMouseTargetInaccessible().

Powiązane elementy interfejsu API

Tworzy obiekt Event, który zawiera określone informacje o zdarzeniach dotyczących menu. Obiekty Event są przekazywane jako parametry do detektorów zdarzeń.

Powiązane elementy interfejsu API

Tworzy kopię obiektu ContextMenuEvent i ustawia wartości poszczególnych właściwości zgodnie z właściwościami oryginału.

Zwraca ciąg znaków, który zawiera wszystkie właściwości obiektu ContextMenuEvent. Format ciągu znaków jest następujący:

[ContextMenuEvent type=wartość bubbles=wartość cancelable=wartość ... contextMenuOwner=wartość]

Definiuje wartość właściwości type obiektu zdarzenia menuItemSelect.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia menuSelect.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

1. Deklarowana jest właściwość myContextMenu, która następnie jest przypisywana do nowego obiektu ContextMenu. Następnie deklarowana jest właściwość redRectangle (typu Sprite).
2. Wywoływana jest metoda removeDefaultItems(). Ta metoda usuwa wszystkie wbudowane pozycje menu kontekstowego, z wyjątkiem polecenia Drukuj.
3. Wywoływana jest metoda addCustomMenuItems(). Ta metoda umieszcza element menu Reverse Colors (Odwróć kolory) w tablicy defaultItems, korzystając z metody push() obiektu Array. Do obiektu ContextMenuItem jest dodawany detektor zdarzeń menuItemSelect i wywoływana jest skojarzona metoda menuItemSelectHandler(). Ta metoda drukuje instrukcje trace() za każdym razem, gdy użytkownik wybierze polecenie Reverse Colors z menu kontekstowego Ponadto czerwony kwadrat staje się czarny, a czarny tekst staje się czerwony.
4. Po powrocie do konstruktora dodawany jest detektor zdarzeń menuSelect wraz ze skojarzoną metodą menuSelectHandler(), która po prostu drukuje trzy instrukcje trace() za każdym razem, gdy wybrany jest jakikolwiek element z menu kontekstowego.
5. Konstruktor wywołuje metodę addChildren(), która rysuje czerwony kwadrat i dodaje go do listy wyświetlania, co powoduje natychmiastowe wyświetlenie kwadratu.
6. Na koniec właściwość myContextMenu jest przypisywana do menu kontekstowego właściwości redRectangle, przez co niestandardowe menu kontekstowe jest wyświetlane tylko wtedy, gdy wskaźnik myszy znajduje się nad kwadratem.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}