ContextMenu  - AS3

Instancja klasy ContextMenuBuiltInItems z następującymi właściwościami: forwardAndBack, loop, play, print, quality, rewind, save i zoom. Ustawienie dla tych właściwości wartości false powoduje usunięcie odpowiadających elementów menu z określonego obiektu ContextMenu. Są to uporządkowane właściwości i domyślnie ustawiona jest dla nich wartość true.

Uwaga: W środowisku AIR menu kontekstowe nie mają elementów wbudowanych.

Powiązane elementy interfejsu API

Instancja klasy ContextMenuClipboardItems z następującymi właściwościami: cut, copy, paste, delete, selectAll. Ustawienie dla którejkolwiek z tych właściwości wartości false powoduje wyłączenie odpowiadającego jej elementu w menu schowka.

Powiązane elementy interfejsu API

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Określa korzystanie z menu schowka. Jeśli jest to wartość true, właściwość clipboardItems określa, które elementy są włączone, a które wyłączone w menu schowka.

Jeśli wartość właściwości link jest inna niż null, właściwość clipBoardMenu jest ignorowana.

Tablica obiektów ContextMenuItem. Każdy obiekt w tablicy przedstawia element menu kontekstowego zdefiniowany przez użytkownika. Ta właściwość służy do dodawania, usuwania lub modyfikowania tych niestandardowych elementów menu.

Aby dodać nowy element menu, należy utworzyć obiekt ContextMenuItem, a następnie dodać go do tablicy customItems (na przykład za pomocą metody Array.push(). Więcej informacji o tworzeniu elementów menu zawiera wpis do klasy ContextMenuItem.

Powiązane elementy interfejsu API

Właściwość isSupported ma wartość true, jeśli na bieżącej platformie jest obsługiwana klasa ContextMenu; w przeciwnym razie ma wartość false.

Tablica własnych elementów w tym menu.

Użycie tej właściwości jest równoważne użyciu właściwości customItems. Tablica jest posortowana w kolejności wyświetlania.

Właściwość URLRequest odsyłacza. Jeśli ta właściwość jest równa null, wyświetlane jest zwykłe menu kontekstowe. Jeśli ta właściwość ma wartość inną niż null, wyświetlane jest menu kontekstowe łącza, które działa w odniesieniu do podanego adresu URL.

Jeśli została określona właściwość link, właściwość clipboardMenu jest ignorowana.

Wartością domyślną jest null.

Liczba elementów w tym menu.

Tworzy nowy obiekt ContextMenu.

Powiązane elementy interfejsu API

Dodaje element menu na dół tego menu.

Podczas tworzenia menu kontekstowego można dodawać do niego obiekty NativeMenuItem albo ContextMenuItem. Jednak zaleca się stosowane w danym menu kontekstowym tylko jednego typu obiektów, tak aby wszystkie pozycje w menu miały te same właściwości.

Parametry

Tworzy kopię podanego obiektu ContextMenu. Kopia dziedziczy wszystkie właściwości oryginalnego obiektu menu.

Informuje, czy menu zawiera określoną pozycję.

Parametry

Wyświetla to menu w określonym miejscu.

Uwaga: W programie Flash Player ta metoda nie jest obsługiwana.

Parametry

Pobiera pozycję menu o podanym indeksie.

Parametry

Pobiera położenie określonego elementu.

Parametry

Ukrywa wszystkie wbudowane elementy menu (poza opcją Ustawienia) w określonym obiekcie ContextMenu. Jeśli uruchomiona jest wersja debugera programu Flash Player, zostanie wyświetlony element menu debugera. Będzie on jednak zaciemniony dla plików SWF bez włączonego zdalnego debugowania.

Za pomocą tej metody ukryte zostaną wyłącznie te elementy menu, które pojawiają się w standardowym menu kontekstowym; nie ma ona wpływu na elementy pojawiające się w menu edytowania i błędów.

Działanie tej metody wymaga ustawienia dla wszystkich elementów logicznych my_cm.builtInItems wartości false. Można wybiórczo wyświetlić wbudowane elementy poprzez ustawienie dla odpowiadającego elementu my_cm.builtInItems wartości true.

Uwaga: W środowisku AIR menu kontekstowe nie mają elementów wbudowanych. Wywołanie tej metody nie odniesie żadnego skutku.

Powiązane elementy interfejsu API

Usuwa z menu wszystkie elementy.

Usuwa i zwraca pozycję menu o określonym indeksie.

Parametry

Dysponowana, gdy użytkownik po raz pierwszy generuje menu kontekstowe, ale jeszcze przed wyświetleniem zawartości menu. Umożliwia to modyfikację zestawu elementów menu kontekstowego przed wyświetleniem menu. Użytkownik generuje menu kontekstowe, klikając prawym przyciskiem myszy urządzenie wskazujące.

To zdarzenie ma następujące właściwości:

1. Deklarowana jest właściwość myContextMenu, która następnie jest przypisywana do nowego obiektu ContextMenu. Następnie deklarowana jest właściwość redRectangle (typu Sprite).
2. Wywołana zostaje metoda removeDefaultItems(), za pomocą której usuwane są wszystkie wbudowane elementy menu kontekstowego, z wyjątkiem polecenia Drukuj.
3. Wywoływana jest metoda addCustomMenuItems(), która powoduje umieszczenie wybranego z menu elementu o nazwie Red to Black w tablicy defaultItems za pomocą metody push() obiektu Array. Do obiektu ContextMenuItem jest dodawany detektor zdarzeń menuItemSelect i wywoływana jest skojarzona metoda menuItemSelectHandler(). Za pomocą tej metody drukowane są niektóre instrukcje trace() za każdym razem, po przejsciu do menu kontekstowego i wybraniu elementu Red to Black. Czerwony kwadrat zostaje również usunięty i zastąpiony czarnym.
4. Dodawany jest detektor zdarzeń typu menuSelect wraz ze skojarzoną metodą menuSelectHandler(), która po prostu drukuje trzy instrukcje trace() za każdym razem, gdy wybrany jest jakikolwiek element z menu kontekstowego.
5. Następnie za pomocą metody addChildren() rysowany jest czerwony kwadrat i dodawany do listy wyświetlania, gdzie zostaje natychmiast wyświetlony.
6. Na koniec właściwość myContextMenu jest przypisywana do menu kontekstowego ikonki redRectangle, przez co niestandardowe menu kontekstowe jest wyświetlane tylko wtedy, gdy wskaźnik myszy znajduje się nad kwadratem.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}