Video  - AS3

사후 처리의 일부로 디코딩된 비디오에 적용되는 필터 유형을 나타냅니다. 기본값은 0이며, 이 값에서는 비디오 압축기가 디블로킹 필터를 필요한 만큼 적용합니다.

비디오 압축으로 인해 원치 않은 인위적인 요소가 나타날 수 있습니다. deblocking 속성을 사용하여 블로킹을 줄여 주는 필터를 설정할 수 있으며, On2 코덱으로 압축된 비디오의 경우에는 링잉을 줄일 수 있습니다.

블로킹이란 각 비디오 프레임을 구성하는 블록 경계선 사이에서 눈에 띄는 결함을 가리킵니다. 링잉은 비디오 이미지 내의 요소들 주변에서 나타나는 왜곡된 가장자리를 말합니다.

두 개의 디블로킹 필터인, Sorenson 코덱의 필터와 On2 VP6 코덱의 필터가 있습니다. 또한 On2 VP6 코덱을 사용할 때 디링잉 필터를 사용할 수 있습니다. 필터를 설정하려면 다음 값 중 하나를 사용합니다.

• 0 - 비디오 압축기가 디블로킹 필터를 필요한 만큼 적용하도록 합니다.
• 1 - 디블로킹 필터를 사용하지 않습니다.
• 2 - Sorenson 디블로킹 필터를 사용합니다.
• 3 - On2 비디오에 한해 On2 디블로킹 필터만 사용하고 디링잉 필터는 사용하지 않습니다.
• 4 - On2 비디오에 한해 On2 디블로킹 및 디링잉 필터를 사용합니다.
• 5 - On2 비디오에 한해 On2 디블로킹 및 고성능 On2 디링잉 필터를 사용합니다.

Sorenson 코덱을 사용할 때 비디오에 대해 2보다 큰 값을 선택하면 Sorenson 디코더는 기본값 2를 사용합니다.

디블로킹 필터는 전반적인 재생 성능에 영향을 주며, 보통 고대역폭 비디오에는 사용할 필요가 없습니다. 시스템 성능이 부족한 경우에는 디블로킹 필터를 활성화한 상태에서 비디오를 재생하기가 어려울 수 있습니다.

비디오의 크기를 조절할 때 매끄럽게 할 것인지 여부를 지정합니다. 매끄럽게 하는 기능이 동작하려면 런타임이 고품질 모드(기본값)여야 합니다. 기본값은 false(매끄럽게 하지 않음)입니다.

Flash Player 9.0.115.0 이상의 버전을 사용하여 비디오를 재생할 경우 밉매핑 이미지 최적화를 활용하려면 이 속성을 true로 설정합니다.

비디오 스트림의 높이를 픽셀 단위로 지정하는 정수입니다. 라이브 스트림의 경우, 이 값은 비디오 스트림을 캡처하는 Camera 객체의 Camera.height 속성과 동일합니다. 녹화된 비디오 파일의 경우 이 값은 비디오의 높이입니다. NetStream.Video.DimensionChange 이벤트는 녹화된 비디오에서 이 값이 변경되는 경우에 전달됩니다.

Stage에 놓인 Video 객체의 실제 크기와 관계없이 캡처된 크기와 동일하게 비디오를 표시할 때 이 속성을 사용할 수 있습니다.

관련 API 요소

비디오 스트림의 너비를 픽셀 단위로 지정하는 정수입니다. 라이브 스트림의 경우, 이 값은 비디오 스트림을 캡처하는 Camera 객체의 Camera.width 속성과 동일합니다. 녹화된 비디오 파일의 경우 이 값은 비디오의 폭입니다. NetStream.Video.DimensionChange 이벤트는 녹화된 비디오에서 이 값이 변경되는 경우에 전달됩니다.

Stage에 놓인 Video 객체의 실제 크기와 관계없이 캡처된 크기와 동일하게 비디오를 표시할 때 이 속성을 사용할 수 있습니다.

관련 API 요소

새 Video 인스턴스를 만듭니다. width 및 height 매개 변수의 값을 제공하지 않으면 기본값이 사용됩니다. 초기 구성 이후에 Video.width 및 Video.height를 사용하여 Video 객체의 폭과 높이 속성을 설정할 수도 있습니다. Video 객체를 새로 만들 때 폭 또는 높이 값으로 0을 사용할 수 없습니다. 0을 전달하면 기본값이 적용됩니다.

Video를 만든 다음 DisplayObjectContainer.addChild() 또는 DisplayObjectContainer.addChildAt() 메서드를 호출하여 Video 객체를 부모 DisplayObjectContainer 객체에 추가합니다.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

응용 프로그램에서 Video 객체의 경계선 안에 표시할 카메라의 비디오 스트림을 지정합니다.

이 메서드를 사용하여 사용자가 캡처한 실시간 비디오를 Video 객체에 연결합니다. 실시간 비디오를 캡처하는 동일한 컴퓨터 또는 장치에서 로컬로 실시간 비디오를 재생하거나 Flash Media Server로 실시간 비디오를 보내고 Flash Media Server 서버를 사용하여 다른 사용자에게 스트리밍할 수 있습니다.

참고: iOS AIR 응용 프로그램에서는 응용 프로그램이 GPU 렌더링 모드를 사용하면 카메라 비디오를 표시할 수 없습니다.

매개 변수

관련 API 요소

응용 프로그램에서 Video 객체의 경계 내에 표시할 비디오 스트림을 지정합니다. 비디오 스트림은 NetStream.play()로 재생되는 비디오 파일, Camera 객체 또는 null입니다. 비디오 파일을 사용하는 경우 로컬 파일 시스템이나 Flash Media Server에 저장할 수 있습니다. netStream 인수의 값이 null이면 Video 객체에서 더 이상 비디오가 재생되지 않습니다.

비디오 파일에 오디오만 있으면 이 메서드를 사용할 필요가 없습니다. 비디오 파일의 오디오 부분은 NetStream.play()를 호출할 때 자동으로 재생됩니다. 비디오 파일과 연관된 오디오를 제어하려면 비디오 파일을 재생하는 NetStream 객체의 soundTransform 속성을 사용합니다.

매개 변수

관련 API 요소

비디오 스트림이 아닌 Video 객체에 현재 표시된 이미지를 지웁니다. 이 메서드는 현재 이미지를 처리하는 데 유용합니다. 예를 들어 Video 객체를 숨기지 않고 마지막 이미지 또는 표시 대기 정보를 지울 수 있습니다.

관련 API 요소

이 예제에서는 Video 및 NetStream 객체를 만들고 Video.attachNetStream() 및 NetStream.play()를 호출하는 코드가 핸들러 함수 안에 배치됩니다. 핸들러는 NetConnection 객체에 대한 연결에 성공해야만 호출됩니다. 연결은 netStatus 이벤트가 성공을 나타내는 code 속성을 갖는 정보 객체를 반환하면 성공합니다. 연결에 성공할 때까지 기다렸다가 NetStream.play()를 호출하는 것이 좋습니다.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }