TextFormat

パッケージ	flash.text
クラス	public class TextFormat
継承	TextFormat Object
サブクラス	UITextFormat

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

TextFormat クラスは、文字フォーマット情報を表します。TextFormat クラスを使用して、テキストフィールドに特定のテキストフォーマットを作成します。静止テキストフィールドおよびダイナミックテキストフィールドの両方にテキストフォーマットを適用できます。TextFormat クラスのプロパティは、デバイスフォントおよび埋めこみフォントに適用されます。ただし、埋め込みフォントの場合、ボールドとイタリックのテキストには、実際に特定のフォントが必要です。埋め込みフォントでボールドまたはイタリックのテキストを表示する場合は、そのフォントのボールド体およびイタリック体を埋め込む必要があります。

TextFormat オブジェクトのプロパティを設定する前に、コンストラクター new TextFormat() を使用して TextFormat オブジェクトを作成する必要があります。TextFormat オブジェクトを TextField.defaultTextFormat プロパティまたは TextField.setTextFormat() メソッドを使用してテキストフィールドに適用する場合、それらに定義されたプロパティのみが適用されます。TextField.defaultTextFormat プロパティを使用して、テキストを TextField に追加する前にフォーマットを適用し、setTextFormat() メソッドを使用して、テキストを TextField に追加した後でフォーマットを追加します。TextFormat プロパティに値を設定しない場合は Flash Player 固有のデフォルトフォーマットが使用されるので、TextFormat プロパティはデフォルトでは null です。Flash Player が各プロパティに対して使用するデフォルトのフォーマットは（プロパティの値が null の場合）、次のとおりです。

align = "left"

blockIndent = 0

bold = false

bullet = false

color = 0x000000

font = "Times New Roman"（Mac OS X でのデフォルトフォントは Times）

indent = 0

italic = false

kerning = false

leading = 0

leftMargin = 0

letterSpacing = 0

rightMargin = 0

size = 12

tabStops = []（空の配列）

target = ""（空のストリング）

underline = false

url = ""（空のストリング）

各プロパティのデフォルトのフォーマットについては、各プロパティの説明でも説明します。

例を表示

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		align : String 段落の行揃えの設定を示します。	TextFormat
		blockIndent : Object ブロックのインデントをピクセル単位で示します。	TextFormat
		bold : Object テキストをボールドにするかどうかを指定します。	TextFormat
		bullet : Object テキストが箇条書きリストの一部かどうかを示します。	TextFormat
		color : Object テキストの色を示します。	TextFormat
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		font : String このテキストフォーマットでのテキストフォント名を示すストリングです。	TextFormat
		indent : Object 左インデントから段落の先頭文字までのインデントを示します。	TextFormat
		italic : Object このテキストフォーマットのテキストをイタリックにするかどうかを示します。	TextFormat
		kerning : Object カーニングが有効（true）か無効（false）かを示すブール値です。	TextFormat
		leading : Object 行間の垂直の行送りを示す整数です。	TextFormat
		leftMargin : Object 段落の左インデントをピクセル単位で示します。	TextFormat
		letterSpacing : Object すべての文字の間に均等に配分されるスペースの量を表す数値です。	TextFormat
		rightMargin : Object 段落の右インデントをピクセル単位で示します。	TextFormat
		size : Object このテキストフォーマットのテキストのサイズ（ピクセル単位）です。	TextFormat
		tabStops : Array カスタムタブストップを負以外の整数の配列として指定します。	TextFormat
		target : String ハイパーリンクを表示するターゲットウィンドウを示します。	TextFormat
		underline : Object このテキストフォーマットを使用するテキストにアンダーラインを表示する（true）か、表示しない（false）かを示します。	TextFormat
		url : String このテキストフォーマットのテキストの対象 URL を示します。	TextFormat

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		TextFormat(font:String = null, size:Object = null, color:Object = null, bold:Object = null, italic:Object = null, underline:Object = null, url:String = null, target:String = null, align:String = null, leftMargin:Object = null, rightMargin:Object = null, indent:Object = null, leading:Object = null) 指定されたプロパティを使用して TextFormat オブジェクトを作成します。	TextFormat
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

プロパティの詳細

align

プロパティ

align:String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

段落の行揃えの設定を示します。指定できる値は TextFormatAlign 定数です。

デフォルト値： TextFormatAlign.LEFT。

実装
public function get align():String
public function set align(value:String):void

例外

ArgumentError — 指定された align は、flash.text.TextFormatAlign のメンバーではありません。

関連する API エレメント

flash.text.TextFormatAlign

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

blockIndent

プロパティ

blockIndent:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

ブロックのインデントをピクセル単位で示します。ブロックのインデントは、テキストのブロック全体、つまりテキストのすべての行に適用されます。一方、通常のインデント（TextFormat.indent）は各段落の先頭行にのみ影響します。このプロパティが null である場合、TextFormat オブジェクトはブロックのインデントを指定しません。ブロックのインデントは 0 です。

実装
public function get blockIndent():Object
public function set blockIndent(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

bold

プロパティ

bold:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

テキストをボールドにするかどうかを指定します。デフォルト値は null です。この場合、ボールド体は使用されません。値が true の場合は、テキストがボールド体になります。

実装
public function get bold():Object
public function set bold(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

bullet

プロパティ

bullet:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

テキストが箇条書きリストの一部かどうかを示します。箇条書きリストでは、テキストの各段落がインデントされます。各段落の先頭行の左に箇条書きシンボルが表示されます。デフォルト値は null です。この場合、箇条書きリストは使用されません。

実装
public function get bullet():Object
public function set bullet(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

color

プロパティ

color:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

テキストの色を示します。3 つの 8 bit RGB コンポーネントを示す数値（0xFF0000 は赤、0x00FF00 は緑など）です。デフォルト値は null で、Flash Player では黒（0x000000）が使用されます。

実装
public function get color():Object
public function set color(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

font

プロパティ

font:String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

このテキストフォーマットでのテキストフォント名を示すストリングです。デフォルト値は null で、Flash Player ではテキストに Times New Roman フォントが使用されます。

実装
public function get font():String
public function set font(value:String):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

indent

プロパティ

indent:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

左インデントから段落の先頭文字までのインデントを示します。デフォルト値は null で、インデントは使用されないことを示します。

実装
public function get indent():Object
public function set indent(value:Object):void

関連する API エレメント

flash.text.TextFormat.blockIndent

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

italic

プロパティ

italic:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

このテキストフォーマットのテキストをイタリックにするかどうかを示します。デフォルト値は null です。この場合、イタリックは使用されません。

実装
public function get italic():Object
public function set italic(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

kerning

プロパティ

kerning:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9.

カーニングが有効（true) か無効（false）かを示すブール値です。カーニングでは、読みやすくするために、特定の文字ペア間でピクセルを調整します。大きなフォントの見出しを使用する場合など、必要な場合にのみ使用する必要があります。カーニングは、埋め込みフォントに対してのみサポートされています。

Verdana や、Courier New などの等幅フォントなど、特定のフォントではカーニングはサポートされていません。

デフォルト値 null はカーニングを無効にします。

実装
public function get kerning():Object
public function set kerning(value:Object):void

leading

プロパティ

leading:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

行間の垂直の行送りを示す整数です。デフォルト値は null で、使用される行送りは 0 であることを示します。

実装
public function get leading():Object
public function set leading(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

leftMargin

プロパティ

leftMargin:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

段落の左インデントをピクセル単位で示します。デフォルト値は null です。この場合、左インデントは 0 ピクセルです。

実装
public function get leftMargin():Object
public function set leftMargin(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

letterSpacing

プロパティ

letterSpacing:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9.

すべての文字の間に均等に配分されるスペースの量を表す数値です。この値は、各文字の後の送りに追加されるピクセル数を示します。デフォルト値は null です。この場合、0 ピクセルの文字間隔が使用されます。1.75 などの小数点を含む数値を使用することができます。

実装
public function get letterSpacing():Object
public function set letterSpacing(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

rightMargin

プロパティ

rightMargin:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

段落の右インデントをピクセル単位で示します。デフォルト値は null です。この場合、右インデントは 0 ピクセルです。

実装
public function get rightMargin():Object
public function set rightMargin(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

size

プロパティ

size:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

このテキストフォーマットのテキストのサイズ（ピクセル単位）です。デフォルト値は null です。この場合、サイズ 12 が使用されます。

実装
public function get size():Object
public function set size(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

tabStops

プロパティ

tabStops:Array

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

カスタムタブストップを負以外の整数の配列として指定します。各タブストップはピクセル単位で指定します。カスタムタブストップを指定しないと（null）、タブストップはデフォルトの 4（平均文字幅）になります。

実装
public function get tabStops():Array
public function set tabStops(value:Array):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

target

プロパティ

target:String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

ハイパーリンクを表示するターゲットウィンドウを示します。ターゲットウィンドウが空のストリングである場合、テキストはデフォルトのターゲットウィンドウ _self に表示されます。カスタム名を選択することも、次の 4 つの名前のいずれかを選択することもできます。_self は現在のウィンドウ内の現在のフレームを指定します。_blank は新しいウィンドウを指定します。_parent は現在のフレームの親を指定します。_top は現在のウィンドウ内のトップレベルのフレームを指定します。TextFormat.url プロパティが空のストリングまたは null の場合は、このプロパティを取得および設定することはできますが、プロパティは何の影響も及ぼしません。

実装
public function get target():String
public function set target(value:String):void

関連する API エレメント

flash.text.TextFormat.url

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

underline

プロパティ

underline:Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

このテキストフォーマットを使用するテキストにアンダーラインを表示する（true）か、表示しない（false）かを示します。これは、<U> タグによって設定されるアンダーラインと似ていますが、このタグの場合はディセンダが正しくスキップされないので、本物のアンダーラインではありません。デフォルト値は null です。この場合、アンダーラインは使用されません。

実装
public function get underline():Object
public function set underline(value:Object):void

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

url

プロパティ

url:String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

このテキストフォーマットのテキストの対象 URL を示します。url プロパティが空のストリングである場合、テキストにはハイパーリンクがありません。デフォルト値は null です。この場合、テキストにはハイパーリンクがありません。

注意：ハイパーリンクを機能させるには、テキストフォーマットが割り当てられたテキストを htmlText プロパティで設定する必要があります。

実装
public function get url():String
public function set url(value:String):void

関連する API エレメント

flash.text.TextField.htmlText

例
この例の使用方法
このプロパティの使用方法の詳細については、TextFormat() コンストラクターの例を参照してください。

コンストラクターの詳細

()

コンストラクター

public function TextFormat(font:String = null, size:Object = null, color:Object = null, bold:Object = null, italic:Object = null, underline:Object = null, url:String = null, target:String = null, align:String = null, leftMargin:Object = null, rightMargin:Object = null, indent:Object = null, leading:Object = null)

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9., Flash Lite 4

指定されたプロパティを使用して TextFormat オブジェクトを作成します。この TextFormat オブジェクトのプロパティを変更して、テキストフィールドのフォーマットを変更できます。

null 値を設定したパラメーターは未設定になります。すべてのパラメーターはオプションです。省略したパラメーターは null として扱われます。

パラメーター

	`font:String` (default = `null`) — テキストのフォント名を示すストリングです。

	`size:Object` (default = `null`) — サイズをピクセル単位で示す整数です。

	`color:Object` (default = `null`) — このテキストフォーマットを使用するテキストの色です。3 つの 8 bit RGB コンポーネントを示す数値（0xFF0000 は赤、0x00FF00 は緑など）です。

	`bold:Object` (default = `null`) — テキストがボールド体であるかどうかを示すブール値です。

	`italic:Object` (default = `null`) — テキストがイタリック体であるかどうかを示すブール値です。

	`underline:Object` (default = `null`) — テキストが下線付きであるかどうかを示すブール値です。

	`url:String` (default = `null`) — このテキストフォーマットのテキストのハイパーリンク先である URL です。`url` が空のストリングである場合、テキストにはハイパーリンクがありません。

	`target:String` (default = `null`) — ハイパーリンクを表示するターゲットウィンドウです。ターゲットウィンドウが空のストリングである場合、テキストはデフォルトのターゲットウィンドウ `_self` に表示されます。`url` パラメーターに空のストリングまたは `null` 値を指定した場合は、このプロパティを取得または設定することはできますが、プロパティには何の影響もありません。

	`align:String` (default = `null`) — 段落の行揃えの設定を示す TextFormatAlign 値です。

	`leftMargin:Object` (default = `null`) — 段落の左インデントをピクセル単位で示します。

	`rightMargin:Object` (default = `null`) — 段落の右インデントをピクセル単位で示します。

	`indent:Object` (default = `null`) — 左インデントから段落の先頭文字までの一行目インデントを示す整数です。

	`leading:Object` (default = `null`) — 行間の垂直の行送りを示す数値です。

例 ( この例の使用方法 )

次の例では、ユーザーは、別のテキストフィールドのコンテンツに適用されるリストから、様々なテキストフォーマットオプションを選択できます。ユーザーがテキストフィールドのコンテンツをクリックすると、フォーマットがデフォルト（元の）フォーマットに戻ります。

formatTextField テキストフィールドには、すべての TextField クラスのプロパティ（kerning を除く）が別々の行に表示されます。ユーザーが formatTextField テキストフィールドの行をクリックすると、formatTextFieldClickHandler() メソッドがトリガーされます。

formatTextFieldClickHandler() メソッドが TextField.getLineIndexAtPoint() メソッドを呼び出して、クリックされた行のインデックスを取得し、TextField.getLineText() メソッドを呼び出して、行のコンテンツを取得します。switch ステートメントが行のコンテンツをチェックし、それに応じて newformat TextFormat オブジェクトのプロパティを設定します。次に、setTextFormat() メソッドが contentTextField テキストフィールドのテキストフォーマットを新しいフォーマットに設定します。様々な formatTextField 行をクリックすることで、ユーザーは、異なるフォーマットを contentTextField テキストフィールドに適用することができます。（タブ設定は、行のタブごとに別個のタブストップを定義する配列です。）url または target 行を選択した場合、ユーザーは contentTextField テキストフィールドをクリックしてリンクをアクティブにし、ターゲット URL（Flex のホームページ）のコンテンツを表示する必要があります。 target プロパティのデフォルト値は "_self" です。この場合、ユーザーが url 行を選択すると、コンテンツが現在のウィンドウに表示されます。 target プロパティが機能するには、url プロパティに URL が設定済みになっている必要があります。

ユーザーが contentTextField テキストフィールドをクリックすると、contentTextFieldClickHandler() メソッドがトリガーされ、フィールドのフォーマットと newFormat TextFormat オブジェクトがテキストフィールドのデフォルト（元の）フォーマットに設定されます。これにより、ユーザーが行ったすべてのフォーマット変更がクリアされます。

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

例この例の使用方法

TextFormatExample.as

次の例は TextFieldExample クラスを作成して、テキストメッセージをデフォルト位置（x = 0, y = 0）に表示します。ここでは以下の手順を実行します。

タイプが TextField のプロパティ label が作成されます。
クラスコンストラクターは、関数 configureLabel() を呼び出します。
configureLabel() 関数はまず、新しい TextField オブジェクトを作成し、これを label に割り当てます。次に、そのパラメーターを次のように設定します。
- テキストフィールドを左揃えにします。
- 背景の塗りを有効にします。
- 境界線を有効にします。
次に、configureLable() は、ローカル変数 format を作成し、これを新しい TextFormat インスタンスに割り当て、そのパラメーターを次のように設定します。
- Font type = Verdana
- Font Color = solid red
- Font size = 10
- Font underline = true
label の defaultTextFormat プロパティが format に設定され、label インスタンスが表示リストに追加されます。最初は、ステージに表示されるテキストフィールドにテキストが表示されません。白い背景の小さなボックスが表示されるだけです。
最後に、コンストラクターでは、"Hello World and welcome to the show" と座標 x = 0、y = 0 に表示するように label のテキストが設定されます。これは setLabel() を呼び出すことによって実行されます。

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}

法律上の注意 | プライバシーポリシー

TextFormat - AS3

パッケージx

言語エレメント

付録

パッケージ flash.text

align

blockIndent

bold

bullet

color

font

indent

italic

kerning

leading

leftMargin

letterSpacing

rightMargin

size

tabStops

target

underline

url

TextFormat