Clipboard  - AS3

この Clipboard オブジェクトで使用できるデータ形式の名前が含まれたストリングの配列です。

ClipboardFormats クラスに標準形式の名前のストリング定数が定義されます。この他の、アプリケーションで定義されたストリングは、データをオブジェクトとして転送する場合、形式名として使用することもできます。

関連する API エレメント

 var availableFormats:Array = Clipboard.generalClipboard.formats;

オペレーティングシステムクリップボードです。

システムのクリップボードにペーストされたデータは、他のアプリケーションからも利用できます。それには Web ブラウザー内で実行される保護されていないリモートコードも含まれます。

注意：Flash Player 10 アプリケーションでは、クリップボードからのペースト操作には最初に「ペースト」コマンドに対応するショートカットキーを押すかコンテキストメニューの「ペースト」コマンドをマウスでクリックするなどのユーザーイベントが必要です。Clipboard.getData() は、InteractiveObject が paste イベントを受け取り、paste イベントを実行している場合にのみクリップボードのコンテンツを返します。他の環境での Clipboard.getData() の呼び出しは失敗します。アプリケーションサンドボックスの外部にあるコンテンツには AIR で同じ制限が適用されます。

generalClipboard オブジェクトは自動的に作成されます。このプロパティには Clipboard の別のインスタンスを割り当てることはできません。その代わりに、getData() メソッドと setData() メソッドを使用して既存のオブジェクトに対してデータの読み書きを行います。

クリップボードは、新しいデータを書き込む前に必ずクリアして、すべての形式の古いデータを確実に消去する必要があります。

generalClipboard オブジェクトを AIR NativeDragManager に渡すことはできません。AIR アプリケーションでのネイティブなドラッグ＆ドロップ操作に対しては、新しい Clipboard オブジェクトを作成してください。

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

クライアントシステムでファイルプロミスのクリップボードがサポートされているかどうかを示します。

空の Clipboard オブジェクトを作成します。

Clipboard オブジェクトを作成し、Adobe AIR でのネイティブなドラッグ＆ドロップジェスチャのデータを保持します。Clipboard オブジェクトは 1 つのドラッグ＆ドロップジェスチャにのみ使用できます。再利用することはできません。

コピー＆ペースト操作用に Clipboard オブジェクトを作成しないでください。代わりに単一の Clipboard.generalClipboard オブジェクトを使用してください。

関連する API エレメント

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

この Clipboard オブジェクトからすべてのデータ表現を削除します。

 Clipboard.generalClipboard.clear();

指定された形式のデータ表現を削除します。

パラメーター

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

指定された形式のデータが存在する場合、クリップボードデータを取得します。

Flash Playerでは、getData() の呼び出しは paste イベントハンドラー内で実行する必要があります。AIR では、この制限はアプリケーションセキュリティサンドボックス外のコンテンツにのみ適用されます。

標準のデータ形式にアクセスすると、対応する Flash データタイプの新しいオブジェクトとしてデータが返されます。

アプリケーションで定義された形式にアクセスする場合、transferMode パラメーターの値によって、元のオブジェクトへの参照を返すか、元のオブジェクトの直列化されたコピーが格納された匿名オブジェクトを返すかが決まります。originalPreferred モードまたは clonePreferred モードを指定すると、適切なバージョンを使用できない場合に代わりのバージョンが返されます。originalOnly モードまたは cloneOnly モードを指定すると、要求されたバージョンを使用できない場合に null が返されます。

パラメーター

関連する API エレメント

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

指定された形式のデータがこの Clipboard オブジェクトに存在するかどうかをチェックします。

ClipboardFormats クラスの定数を使用して、標準の形式名を参照します。

パラメーター

関連する API エレメント

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

転送する情報の指定されたデータ形式の表現を追加します。

Adobe AIR のアプリケーションサンドボックスでは、いつでも setData() を呼び出すことができます。他のコンテキストでは、キー入力やマウスクリックなどのユーザー操作に応答する場合にのみ、setData() を呼び出すことができます。

同じ情報の別の表現を、異なる形式でクリップボードに追加できます。これにより、他の多くのコンポーネントまたはアプリケーションでもデータを利用できるようになります。例えば、イメージ編集アプリケーション用のビットマップデータ、URL およびネイティブファイルシステムへの転送用のエンコードされた PNG ファイルとしてイメージを追加できます。

data パラメーターは、指定された形式に適合するデータ型にする必要があります。

カスタムの形式名の先頭を "air:" または "flash:" にすることはできません。カスタムの形式を使用するときに名前が競合するのを避けるために、アプリケーション ID やパッケージ名を接頭辞として使用して、「com.example.applicationName.dataPacket」のような形式にすることができます。

アプリケーション内または AIR アプリケーション間で転送する場合、serializable パラメーターによって参照とコピーの両方を使用できるのか、オブジェクトへの参照のみを使用できるのかが決まります。serializable を true に設定すると、参照とデータオブジェクトのコピーの両方を使用できるようになります。serializable を false に設定すると、オブジェクト参照のみを使用できるようになります。オブジェクト参照は、現在のアプリケーション内でのみ有効です。そのため、serializable が false に設定されている場合、その形式のデータは、他の Flash Player または AIR アプリケーションで使用できないことも意味します。コンポーネントは、目的の形式のデータにアクセスするときに適切なクリップボード転送モードを設定することにより、参照を取得するかオブジェクトのコピーを取得するかを選択できます。

注意：標準形式は、サポートされているアプリケーションの外部にデータをペーストまたはドラッグする場合、常にネイティブ形式に変換されます。そのため、serializable パラメーターの値は、Flash ベース以外のアプリケーションによる標準形式のデータの使用に影響を与えません。

ある形式でのデータのレンダリングを遅らせるには、代わりに setDataHandler() メソッドを使用します。setData() メソッドと setDataHandler() メソッドの両方を使用して同じ形式名でデータ表現を追加すると、ハンドラー関数は呼び出されません。

注意：Mac OS で format パラメーターに ClipboardFormats.URL_FORMAT を設定した場合、URL が転送されるのは、その URL が有効である場合に限られます。それ以外の場合、Clipboard オブジェクトは空になります（getData() を呼び出すと、null が返されます）。

パラメーター

関連する API エレメント

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

転送用のデータを生成するハンドラー関数に参照を追加します。

ハンドラー関数を使用して、実際にデータにアクセスするまで、データの作成またはレンダリングを遅らせます。

ハンドラー関数は、指定された形式に適合するデータ型を返す必要があります。

指定された形式のデータを読み取る場合にのみ、ハンドラー関数が呼び出されます。場合によっては、ドロップ操作が行われる前に、オペレーティングシステムが関数を呼び出すことがあります。例えば、ハンドラー関数を使用して、AIR アプリケーションからファイルシステムにドラッグされたファイルのデータを提供する場合、オペレーティングシステムでは、ドラッグジェスチャが AIR アプリケーションを離れるとすぐに、データハンドラー関数を呼び出します。その結果、通常はファイルデータのダウンロード中または作成中に、予期せず停止する場合があります。この目的では、URLFilePromise を代わりに使用できます。

基になるデータは、アプリケーションでそのデータを保護する手順を実行しない場合、ハンドラーを追加した時点からデータを読み取る時点までの間変更できます。ハンドラー関数によって表されるクリップボード上のデータが複数回読み取られた場合の動作は保証されません。クリップボードからは、最初の関数呼び出しによって作成されたデータが返される場合もあれば、関数が再度呼び出される場合もあります。いずれの動作にも依存しないでください。

Adobe AIR のアプリケーションサンドボックスでは、いつでも setDataHandler() を呼び出すことができます。他のコンテキストでは、キー入力やマウスクリックなどのユーザー操作に応答する場合にのみ、setDataHandler() を呼び出すことができます。

この Clipboard オブジェクトにデータを直接追加するには、代わりに setData() メソッドを使用します。同じ形式名を使用して setData() メソッドと setDataHandler() メソッドの両方を呼び出すと、ハンドラー関数は呼び出されません。

注意：Mac OS で format パラメーターに ClipboardFormats.URL_FORMAT を設定した場合、URL が転送されるのは、ハンドラー関数が有効な URL を返す場合に限られます。それ以外の場合、Clipboard オブジェクトは空になります（getData() を呼び出すと、null が返されます）。

パラメーター

関連する API エレメント

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. データ（この例ではストリング）を Clipboard.generalClipboard に書き込みます。
2. Clipboard.generalClipboard からクリップボード定数を読み取ります。

注意：クリップボードのデータアクセスに対するセキュリティ上の制限により、この例は Flash Player では機能しません。Flash Player の場合、paste イベントハンドラーでは Clipboard オブジェクトの getData() メソッドのみ呼び出すことができます。

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}