Pacchetto flash.utils 

Annulla una chiamata setInterval() specifica.

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Annulla una chiamata setTimeout() specifica.

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Produce un oggetto XML che descrive l'oggetto ActionScript specificato come parametro del metodo. Questo metodo implementa il concetto di programmazione Reflection del linguaggio ActionScript.

Se il parametro value è un'istanza di un tipo, l'oggetto XML restituito include tutte le proprietà di istanza di quel tipo ma non le proprietà statiche. È possibile verificare la presenza di questa condizione quando si analizza l'oggetto XML, esaminando il valore dell'attributo isStatic del tag <type>, che è false quando il parametro value è un'istanza di un tipo.

Per ottenere le proprietà statiche di un tipo, passare il tipo stesso come parametro value. L'oggetto XML restituito include non solo le proprietà statiche del tipo, ma anche tutte le relative proprietà di istanza. Queste ultime sono nidificate all'interno di un tag <factory>, per distinguerle dalle proprietà statiche. In questo caso, l'attributo isStatic del tag <type> è true.

Nota: se occorre solo leggere la gerarchia di ereditarietà di un oggetto e non sono necessarie le altre informazioni fornite da describeType(), utilizzate invece le funzioni getQualifiedClassName() e getQualifiedSuperclassName().

Nella seguente tabella sono descritti alcuni tag e attributi dell'oggetto XML generato da describeType() (tutti i nomi di classe e di interfaccia restituiti sono in formato completo):

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Restituisce una copia con caratteri di escape della stringa di input, codificata in UTF-8 o nella tabella codici di sistema, a seconda del valore di System.useCodePage. L'uso di System.useCodePage consente di rendere accessibile al runtime contenuti preesistenti codificati nella tabella codici locale, ma solo sui sistemi che utilizzano la stessa tabella codici di origine. Ad esempio, dati giapponesi codificati in Shift-JIS vengono elaborati correttamente con e senza caratteri di escape su un sistema operativo che utilizza una tabella codici predefinita.

Parametri

Restituisce un riferimento all'oggetto classe della classe specificata dal parametro name.

Parametri

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Restituisce il nome completo della classe di un oggetto.

Parametri

Elementi API correlati

Restituisce il nome di classe completo della classe base dell'oggetto specificato dal parametro value. Questa funzione consente di recuperare più rapidamente il nome della classe base rispetto a describeType(), ma non restituisce tutte le informazioni fornite da describeType().

Dopo aver recuperato il nome di una classe con questa funzione, è possibile convertirlo in un riferimento di classe con la funzione getDefinitionByName().

Nota: questa funzione è limitata alle gerarchie di istanza, mentre la funzione describeType() utilizza le gerarchie di oggetto classe se il parametro value è un tipo di dati. Una chiamata a describeType() su un tipo di dati restituisce la superclasse in base alla gerarchia di oggetto classe, nella quale tutti gli oggetti ereditano da Class. La funzione getQualifiedSuperclassName(), tuttavia, ignora la gerarchia di oggetti classe e restituisce la superclasse in base alla gerarchia di istanza, più familiare. Ad esempio, una chiamata a getQualifiedSuperclassName(String) restituisce Object anche se tecnicamente l'oggetto classe String eredita da Class. In altre parole, i risultati sono uguali indipendentemente dal fatto che venga utilizzata un'istanza di un tipo oppure il tipo stesso.

Parametri

Elementi API correlati

Utilizzata per calcolare il tempo relativo. Per un runtime Flash che elabora ActionScript 3.0, questo metodo restituisce il numero di millisecondi trascorsi dall'avvio della macchina virtuale del runtime Flash per ActionScript 3.0 (AVM2). Per un runtime Flash che elabora ActionScript 2.0, questo metodo restituisce il numero di millisecondi trascorsi dall'inizio dell'inizializzazione del runtime Flash. I runtime Flash utilizzano due macchine virtuali per l'elaborazione di ActionScript. AVM1 è la macchina virtuale ActionScript utilizzata per eseguire codice 1.0 and 2.0. AVM2 è quella utilizzata per eseguire codice ActionScript 3.0. Il comportamento del metodo getTimer() per AVM1 è diverso dal comportamento per AVM2.

Per una data di calendario (indicatore orario), vedete l'oggetto Date.

Elementi API correlati

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Esegue una funzione a un intervallo specificato (in millisecondi).

Anziché utilizzare il metodo setInterval(), valutate come alternativa la creazione di un oggetto Timer, con l'intervallo specificato, utilizzando 0 come parametro repeatCount (che imposta la ripetizione indefinita del timer).

Se intendete utilizzare il metodo clearInterval() per annullare la chiamata a setInterval(), assicuratevi di assegnare la chiamata a setInterval() a una variabile (alla quale il metodo clearInterval() farà riferimento successivamente). Se non chiamate la funzione clearInterval() per annullare la chiamata a setInterval(), l'oggetto che contiene la funzione di chiusura di impostazione del timeout non viene sottoposto al processo di garbage collection.

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Esegue una funzione specifica dopo un ritardo prestabilito (in millisecondi).

Anziché utilizzare questo metodo, valutare come alternativa la creazione di un oggetto Timer, con l'intervallo specificato, utilizzando 1 come parametro repeatCount (che imposta un'unica esecuzione del timer).

Se intendete utilizzare il metodo clearTimeout() per annullare la chiamata a setTimeout(), assicuratevi di assegnare la chiamata a setTimeout() a una variabile (alla quale il metodo clearTimeout() farà riferimento successivamente). Se non chiamate la funzione clearTimeout() per annullare la chiamata a setTimeout(), l'oggetto che contiene la funzione di chiusura del timeout impostato non viene sottoposto al processo di garbage collection.

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Restituisce una copia senza caratteri di escape della stringa di input, decodificata dalla tabella codici di sistema o da UTF-8 a seconda del valore di System.useCodePage. L'uso di System.useCodePage consente di rendere accessibile al runtime contenuti preesistenti codificati nella tabella codici locale, ma solo sui sistemi che utilizzano la stessa tabella codici di origine. Ad esempio, dati giapponesi codificati in Shift-JIS vengono elaborati correttamente con e senza caratteri di escape su un sistema operativo che utilizza una tabella codici predefinita.

Parametri