Package flash.utils 

Annule un appel de setInterval() spécifié.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Annule un appel de setTimeout() spécifié.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Produit un objet XML qui décrit l’objet ActionScript identifié en tant que paramètre de la méthode. Cette méthode implémente le concept de programmation par réflexion pour le langage ActionScript.

Si le paramètre value est l’occurrence d’un type, l’objet XML renvoyé comprend toutes les propriétés d’occurrence de ce type, mais n’inclut aucune propriété statique. Pour vérifier cette condition lors de l’analyse de l’objet XML, examinez la valeur de l’attribut isStatic de la balise <type>, qui est réglée sur false lorsque le paramètre value est l’occurrence d’un type.

Pour obtenir les propriétés statiques d’un type, transmettez le type en tant que tel pour le paramètre value. L’objet XML renvoyé comprend non seulement les propriétés statiques du type, mais aussi toutes les propriétés de son occurrence. Pour les distinguer des propriétés statiques, les propriétés de l’occurrence sont imbriquées dans la balise <factory>. Dans ce cas, l’attribut isStatic de la balise <type> a la valeur true.

Remarque : s’il vous suffit de parcourir la hiérarchie d’héritage d’un objet sans avoir besoin d’accéder aux autres informations fournies par describeType(), utilisez plutôt les fonctions getQualifiedClassName() et getQualifiedSuperclassName().

Le tableau ci-dessous décrit certains attributs et certaines balises de l’objet XML généré par describeType() (tous les noms de classe et d’interface renvoyés sont au format complet) :

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Renvoie une copie contenant une séquence d’échappement de la chaîne entrée, codée au format UTF-8 ou page de codes système, selon la valeur de System.useCodePage. L’utilisation de System.useCodePage permet au moteur d’exécution d’accéder au contenu hérité codé dans les pages de codes locales, mais uniquement sur les systèmes qui utilisent la page de codes héritée. Par exemple, des données en japonais codées au format Shift-JIS ne subiront le processus de conversion escape/unescape que dans un système d’exploitation qui utilise une page de codes japonais par défaut.

Paramètres

Renvoie une référence à l’objet de la classe spécifiée par le paramètre name.

Paramètres

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Renvoie le nom de classe complet d’un objet.

Paramètres

Eléments de l’API associés

Renvoie le nom complet de la classe de base de l’objet spécifié par le paramètre value. Cette fonction permet d’extraire plus rapidement le nom de la classe de base que describeType(), mais ne fournit pas autant d’informations que describeType().

Après avoir récupéré le nom d’une classe avec cette fonction, vous pouvez le convertir en référence de classe à l’aide de la fonction getDefinitionByName().

Remarque : cette fonction se limite elle-même aux hiérarchies d’occurrences, alors que la fonction describeType() utilise les hiérarchies d’objets de classe si le paramètre value est un type de données. L’appel de describeType() sur un type de données renvoie la super-classe basée sur la hiérarchie d’objets de classe, dans laquelle tous les objets de classe héritent de Class. Cependant, la fonction getQualifiedSuperclassName() ne tient pas compte de la hiérarchie d’objets de classe et renvoie la super-classe en fonction de la hiérarchie d’occurrences, plus familière. Ainsi, un appel de getQualifiedSuperclassName(String) renvoie Object bien que, théoriquement, l’objet de classe String hérite de Class. En d’autres termes, les résultats sont identiques, que vous utilisiez l’occurrence d’un type ou le type lui-même.

Paramètres

Eléments de l’API associés

Permet de calculer le temps relatif. Pour un moteur d’exécution de Flash qui exécute ActionScript 3.0, cette méthode renvoie le nombre de millisecondes qui se sont écoulées depuis le démarrage de la machine virtuelle du moteur d’exécution de Flash pour ActionScript 3.0. Pour un moteur d’exécution de Flash qui exécute ActionScript 2.0, cette méthode renvoie le nombre de millisecondes qui se sont écoulées depuis le début de l’initialisation du moteur d’exécution de Flash. Le moteur d’exécution de Flash utilise deux machines virtuelles pour exécuter ActionScript. AVM1 désigne la machine virtuelle ActionScript qui exécute ActionScript 1.0 et 2.0. AVM2 désigne la machine virtuelle ActionScript qui exécute ActionScript 3.0. Le comportement de la méthode getTimer(), pour AVM1 est différent du comportement pour AVM2.

Pour obtenir une date de calendrier (horodatage), voir l’objet Date.

Eléments de l’API associés

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Exécute une fonction à fréquence définie (intervalle exprimé en millisecondes).

Au lieu d’utiliser la méthode setInterval(), envisagez de créer un objet Timer associé à l’intervalle spécifié, en utilisant 0 pour le paramètre repeatCount (qui règle l’horloge sur une répétition perpétuelle).

Si vous souhaitez utiliser la méthode clearInterval() pour annuler l’appel de setInterval(), veillez à affecter l’appel de setInterval() à une variable (à laquelle la méthode clearInterval() fera ultérieurement référence). Si vous n’appelez pas la fonction clearInterval() pour annuler l’appel de setInterval(), l’objet contenant la fonction de fermeture setTimeout spécifiée ne sera pas nettoyé.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Exécute une fonction spécifiée après un délai défini (exprimé en millisecondes).

Au lieu d’utiliser cette méthode, envisagez de créer un objet Timer associé à l’intervalle spécifié, en utilisant 1 en tant que paramètre repeatCount (qui règle l’horloge pour qu’elle ne s’exécute qu’une seule fois).

Si vous souhaitez utiliser la méthode clearTimeout() pour annuler l’appel de setTimeout(), veillez à affecter l’appel de setTimeout() à une variable (à laquelle la fonction clearTimeout() fera ultérieurement référence). Si vous n’appelez pas la fonction clearTimeout() pour annuler l’appel de setTimeout(), l’objet contenant la fonction de fermeture setTimeout spécifiée ne sera pas nettoyé.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Renvoie une copie de la chaîne entrée soumise au processus de conversion unescape, décodée du format UTF-8 ou page de codes système, selon la valeur de System.useCodePage. L’utilisation de System.useCodePage permet au moteur d’exécution d’accéder au contenu hérité codé dans les pages de codes locales, mais uniquement sur les systèmes qui utilisent la page de codes héritée. Par exemple, des données en japonais codées au format Shift-JIS ne subiront le processus de conversion escape/unescape que dans un système d’exploitation qui utilise une page de codes japonais par défaut.

Paramètres