NetGroup  - AS3

Indique le nombre approximatif de membres du groupe, en fonction de la densité du voisinage et d’une distribution uniforme des adresses de groupe.

Eléments de l’API associés

Renvoie un objet NetGroupInfo dont les propriétés fournissent des statistiques de qualité de service (QoS) liées à la transmission de données RTMFP homologue à homologue de cet objet NetGroup.

Eléments de l’API associés

Spécifie le début de la plage d’adresses de groupe pour laquelle ce nœud est « le plus proche » et dont il est responsable. La plage est spécifiée dans le sens ascendant le long de l’anneau d’adresses de groupe mod 2²⁵⁶.

Eléments de l’API associés

Spécifie la fin de la plage d’adresses de groupe pour laquelle ce nœud est « le plus proche » et dont il est responsable. La plage est spécifiée dans le sens ascendant le long de l’anneau d’adresses de groupe mod 2²⁵⁶.

Eléments de l’API associés

Indique le nombre de membres du groupe auxquels ce nœud est directement connecté.

Eléments de l’API associés

Spécifie le mode de réception de routage de ce nœud comme étant l’une des valeurs de la classe d’énumération NetGroupReceiveMode.

Eléments de l’API associés

Spécifie la stratégie d’extraction de la réplication d’objets. La valeur est l’une des valeurs énumérées dans la classe NetGroupReplicationStrategy.

Eléments de l’API associés

Construit un objet NetGroup sur l’objet NetConnection spécifié et le joint au groupe spécifié par le groupspec.

Dans la plupart des cas, un groupspec peut utiliser la liaison montante du réseau sur le système local. Lorsqu’un objet NetStream ou NetGroup est construit avec un groupspec, Flash Player affiche une boîte de dialogue Confidentialité. Cette boîte de dialogue vous demande si Flash Player peut utiliser la connexion en vue de partager les données avec les homologues d’un utilisateur. Si l’utilisateur clique sur « Autoriser ce domaine », la boîte de dialogue n’apparaît pas la prochaine fois que l’utilisateur se connecte à cette application. Si un utilisateur n’autorise pas la mise en réseau coopérative, toutes les fonctions d’homologue dans le groupe (publication, routage direct, réplication d’objets et multidiffusion) sont désactivées. Si l’autorisation est accordée, un événement NetStatusEvent est envoyé à l’écouteur d’événement de NetConnection avec NetGroup.Connect.Success dans la propriété code de l’objet info. Si l’autorisation est refusée, la propriété code est définie sur NetGroup.Connect.Rejected. Tant qu’un événement NetGroup.Connect.Success n’est pas reçu, une exception est renvoyée si vous tentez d’appeler une méthode de l’objet NetGroup.

Remarque : lorsqu’un client s’abonne au flux en multidiffusion d’une adresse IP native, la boîte de dialogue de sécurité n’est pas affichée.

     new NetGroup(myConnection, myGroupSpecifier.groupspecWithAuthorizations());
     

Eléments de l’API associés

Ajoute des objets depuis startIndex jusqu’à endIndex au jeu d’objets qui répondent aux demandes, comme l’indique ce nœud aux voisins. Par défaut, le jeu Have est vide. Les index doivent être des nombres entiers compris entre 0 et 9 007 199 254 740 992.

Pour plus d’informations sur la réplication d’objets, voir la section "Replicate an object within a group" du guide Flash Media Server Developer’s Guide.

Cette méthode envoie un événement NetStatusEvent à l’écouteur d’événement de NetGroup avec "NetGroup.Replication.Request" dans la propriété code de l’objet info.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Ajoute manuellement un enregistrement indiquant que peerID est un membre du groupe. Une tentative de connexion immédiate est effectuée uniquement si la topologie le requiert.

Paramètres

Eléments de l’API associés

Ajoute manuellement un voisin en le connectant immédiatement au peerID spécifié, qui doit déjà se trouver dans ce groupe. Cette connexion directe peut être abandonnée ultérieurement si la topologie n’en a pas besoin.

Paramètres

Eléments de l’API associés

Ajoute des objets depuis startIndex jusqu’à endIndex au jeu d’objets à extraire. Les index doivent être des nombres entiers compris entre 0 et 9 007 199 254 740 992. Par défaut, le jeu Want est vide.

Pour plus d’informations sur la réplication d’objets, voir la section "Replicate an object within a group" du guide Flash Media Server Developer’s Guide.

Cette méthode envoie un événement NetStatusEvent à l’écouteur d’événement de NetGroup avec NetGroup.Replication.Fetch.SendNotify dans la propriété info.code. Cet événement est suivi d’un événement NetGroup.Replication.Fetch.Failed ou NetGroup.Replication.Fetch.Result.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Se déconnecte du groupe et ferme cet objet NetGroup. Il est impossible d’utiliser cet objet NetGroup après l’appel de cette méthode.

Convertit un ID homologue en une adresse de groupe pouvant être utilisée avec la méthode sendToNearest().

Paramètres

Eléments de l’API associés

Refuse une demande reçue dans l’événement NetGroup.Replication.Request d’un NetStatusEvent pour un objet précédemment annoncé avec addHaveObjects(). Le demandant peut solliciter à nouveau cet objet à moins (ou jusqu’à ce) qu’il ne soit retiré du jeu Have.

Pour plus d’informations sur la réplication d’objets, voir la section "Replicate an object within a group" du guide Flash Media Server Developer’s Guide.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Envoie un message à tous les membres d’un groupe. Pour appeler cette méthode, la propriété GroupSpecifier.postingEnabled doit être définie sur true dans le groupspec transmis au constructeur de NetGroup. Pour plus d’informations, voir la section "Post messages to a group" du guide Flash Media Server Developer’s Guide.

Tous les messages doivent être uniques. Il est impossible de transmettre un message identique à l’un des messages envoyés précédemment. Utilisez un numéro de séquence pour rendre les messages uniques.

La remise des messages n’est pas préconisée. La remise des messages n’est pas garantie.

Les messages sont sérialisés au format AMF. Le message peut être de l’un des types suivants : Object, int, Number ou String. Le message ne peut pas être un objet MovieClip.

Cette méthode envoie un événement NetStatusEvent à l’écouteur d’événement de NetGroup avec "NetGroup.Posting.Notify" dans la propriété info.code. L’événement "NetGroup.Posting.Notify" est distribué à l’objet NetGroup sur le client et sur le serveur.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

package  {

    import flash.display.Sprite;
    import flash.events.TextEvent;
    import flash.events.MouseEvent;
    import flash.events.NetStatusEvent;
    import fl.events.ComponentEvent;
    import fl.controls.Label;
    import fl.controls.Button;
    import fl.controls.TextInput;
    import fl.controls.TextArea;
    import flash.text.TextFieldAutoSize;
    import flash.net.*;

    public class NetGroupPostExample extends Sprite{

        private var connectButton:Button;
        private var disconnectButton:Button;
        private var groupNameText:TextInput;
        private var userNameText:TextInput;
        private var chatText:TextInput;
        private var statusLog:TextArea;
        private var groupLabel:Label;
        private var userLabel:Label;

        private var netConnection:NetConnection = null;
        private var netGroup:NetGroup = null;
        private var sequenceNumber:uint = 0;
        private var connected:Boolean = false;
        private var joinedGroup:Boolean = false;

        private const SERVER:String = "rtmfp://fms.example.com/someapp";

        public function NetGroupPostExample() {
            DoUI();
        }

        // Writes messages to the TextArea.
        private function StatusMessage(msg:Object):void{
            statusLog.text += msg;
            statusLog.verticalScrollPosition = statusLog.textHeight;
            statusLog.validateNow();
        }

        // Handles all NetStatusEvents for the NetConnection and the NetGroup.
        // This code includes cases it doesn't handle so you can see the cases
        // and their info objects for learning purposes.
        private function NetStatusHandler(e:NetStatusEvent):void{
            StatusMessage(e.info.code + "\n");
            switch(e.info.code){
                case "NetConnection.Connect.Success":
                    connectButton.enabled = false;
                    disconnectButton.enabled = true;
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                    OnDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;

                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }
        // Creates a NetConnection to Flash Media Server if the app isn't already connected
        // and if there's a group name in the TextInput field.
        private function DoConnect(e:MouseEvent):void{
            if(!connected && (groupNameText.length > 0)){
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                // To connect to Flash Media Server, pass the server name.
                netConnection.connect(SERVER);
            }
            else
            {
                StatusMessage("Enter a group name");
            }
        }

        // Called in the "NetConnection.Connect.Success" case in the NetStatusEvent handler.
        private function OnConnect():void{

            StatusMessage("Connected\n");
            connected = true;

            // Create a GroupSpecifier object to pass to the NetGroup constructor.
            // The GroupSpecifier determines the properties of the group
            var groupSpecifier:GroupSpecifier;
            groupSpecifier = new GroupSpecifier("aslrexample/" + groupNameText.text);
            groupSpecifier.postingEnabled = true;
            groupSpecifier.serverChannelEnabled = true;

            netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
            netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

            StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");

        }

        private function OnNetGroupConnect():void{
            joinedGroup = true;
        }

        private function DoDisconnect(e:MouseEvent):void{
            if(netConnection){
                netConnection.close();
            }
        }

        private function OnDisconnect():void{
            StatusMessage("Disconnected\n");
            netConnection = null;
            netGroup = null;
            connected = false;
            joinedGroup = false;
            connectButton.enabled = true;
            disconnectButton.enabled = false;
        }

        private function ClearChatText():void{
            chatText.text = "";
        }

        // Called when you the chatText field has focus and you press Enter.
        private function DoPost(e:ComponentEvent):void{
            if(joinedGroup){
                var message:Object = new Object;
                message.user = userNameText.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);
                StatusMessage("==> " + chatText.text + "\n");
            } else {
                StatusMessage("Click Connect before sending a chat message");
            }
            ClearChatText();
        }

        private function OnPosting(message:Object):void{
            StatusMessage("<" + message.user + "> " + message.text + "\n");
        }

        private function DoUI():void {

            groupLabel = new Label();
            groupLabel.move(20, 10);
            groupLabel.autoSize = TextFieldAutoSize.LEFT
            groupLabel.text = "Group name:"
            addChild(groupLabel);

            groupNameText = new TextInput();
            groupNameText.move(90, 10);
            groupNameText.text = "channel" + (int(Math.random() * 899) + 101);
            addChild(groupNameText);

            connectButton = new Button();
            connectButton.addEventListener(MouseEvent.CLICK, DoConnect);
            connectButton.move(205, 10);
            connectButton.label = "Connect";
            addChild(connectButton);

            disconnectButton = new Button();
            disconnectButton.addEventListener(MouseEvent.CLICK, DoDisconnect);
            disconnectButton.move(310, 10);
            disconnectButton.label = "Disconnect";
            disconnectButton.enabled = false;
            addChild(disconnectButton);

            statusLog = new TextArea();
            statusLog.move(30, 38);
            statusLog.width = 360;
            statusLog.height = 215;
            statusLog.editable = false;
            addChild(statusLog);

            userLabel = new Label();
            userLabel.move(20, 270);
            userLabel.autoSize = TextFieldAutoSize.LEFT
            userLabel.text = "User name:"
            addChild(userLabel);

            userNameText = new TextInput();
            userNameText.move(80, 270);
            userNameText.text = "user " + int(Math.random() * 65536);
            addChild(userNameText);

            chatText = new TextInput();
            chatText.addEventListener(ComponentEvent.ENTER, DoPost);
            chatText.move(185, 270);
            chatText.maxChars = 255;
            chatText.width = 215;
            addChild(chatText);

        }

        public function onPlayStatus(info:Object):void {}
        public function onMetaData(info:Object):void {}
        public function onCuePoint(info:Object):void {}
        public function onTextData(info:Object):void {}

    }

}

Supprime des objets depuis startIndex jusqu’à endIndex du jeu d’objets qui répondent aux demandes, comme l’indique ce nœud aux voisins. Les index doivent être des nombres entiers compris entre 0 et 9 007 199 254 740 992.

Pour plus d’informations sur la réplication d’objets, voir la section "Replicate an object within a group" du guide Flash Media Server Developer’s Guide.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Supprime des objets depuis startIndex jusqu’à endIndex du jeu d’objets à extraire. Les index doivent être des nombres entiers compris entre 0 et 9 007 199 254 740 992.

Pour plus d’informations sur la réplication d’objets, voir la section "Replicate an object within a group" du guide Flash Media Server Developer’s Guide.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Envoie un message à tous les voisins. Renvoie NetGroupSendResult.SENT si au moins un voisin a été sélectionné.

Pour plus d’informations sur l’acheminement des messages, voir la section "Route messages directly to a peer" du guide Flash Media Server Developer’s Guide.

Lorsqu’un nœud reçoit un message, un événement NetStatusEvent est envoyé à l’écouteur d’événement de NetGroup avec NetGroup.SendTo.Notify dans la propriété code de l’objet info.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Envoie un message au voisin (ou au nœud local) le plus proche de l’adresse de groupe spécifiée. Prend en compte les voisins de l’ensemble de l’anneau. Renvoie NetGroupSendResult.SENT si le message a été correctement envoyé vers sa destination.

Pour plus d’informations sur l’acheminement des messages, voir la section "Route messages directly to a peer" du guide Flash Media Server Developer’s Guide.

Lorsqu’un nœud reçoit un message, un événement NetStatusEvent est envoyé à l’écouteur d’événement de NetGroup avec NetGroup.SendTo.Notify dans la propriété code de l’objet info.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Envoie un message au voisin spécifié par le paramètre sendMode. Renvoie NetGroupSendResult.SENT si le message a été correctement envoyé vers la destination requise.

Pour plus d’informations sur l’acheminement des messages, voir la section "Route messages directly to a peer" du guide Flash Media Server Developer’s Guide.

Lorsqu’un nœud reçoit un message, un événement NetStatusEvent est envoyé à l’écouteur d’événement de NetGroup avec NetGroup.SendTo.Notify dans la propriété code de l’objet info.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Répond à la demande dès sa réception par NetGroup.Replication.Request de NetStatusEvent pour un objet précédemment annoncé avec la méthode addHaveObjects(). L’objet peut être de l’un des types suivants : Object, int, Number et String. L’objet ne peut pas être un objet MovieClip.

Pour plus d’informations sur la réplication d’objets, voir la section "Replicate an object within a group" du guide Flash Media Server Developer’s Guide.

REMARQUE : testez l’événement NetGroup.Neighbor.Connect avant d’appeler cette méthode.

Paramètres

Eléments de l’API associés

Distribué lorsqu’un objet NetGroup publie son état ou signale une erreur. L’événement netStatus contient une propriété info. La propriété info est un objet qui contient des informations sur l’événement, telles que la réussite ou l’échec d’une tentative de connexion.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Lorsque vous exécutez l’application, vous pouvez indiquer n’importe quel nom de groupe dans le champ de saisie de texte. La classe GroupSpecifier utilise le nom (ainsi que toutes les propriétés que vous avez définies) pour créer une chaîne qui est le nom toujours unique du groupe. Pour connecter un autre client au groupe, ce client doit utiliser le même nom de groupe. Par exemple, si le client A utilise le nom de groupe « firstmesh », les autres clients qui souhaitent communiquer avec le client A doivent également utiliser le nom de groupe « firstmesh ». Si le client B utilise le nom de groupe « kite », il parviendra à se connecter, mais il créera un nouveau groupe et ne sera pas en mesure de communiquer avec le client A ou les membres du groupe « firstmesh ».

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="100%" height="100%" applicationComplete="OnApplicationComplete()">
    <mx:Script>
        <![CDATA[
            private var netConnection:NetConnection = null;
            private var netStream:NetStream = null;
            private var netGroup:NetGroup = null;
            private var video:Video = null;
            private var sequenceNumber:uint = 0;
            private var resizeTimer:Timer = null;

            private const SERVER:String = "rtmfp://fms.example.com/someapp";

            [Bindable] private var connected:Boolean = false;
            [Bindable] private var joinedGroup:Boolean = false;

            private function OnApplicationComplete():void
            {
                userName.text = "user " + int(Math.random() * 65536);

                groupName.text = "channel" + (int(Math.random() * 899) + 101);

                resizeTimer = new Timer(2000.0);
                resizeTimer.addEventListener(TimerEvent.TIMER, DoResizeVideo);
                resizeTimer.start();
            }

            private function StatusMessage(msg:Object):void
            {
                statusLog.text += msg;
                statusLog.verticalScrollPosition = statusLog.textHeight;
                statusLog.validateNow();
            }

            private function NetStatusHandler(e:NetStatusEvent):void
            {
                StatusMessage(e.info.code);
                switch(e.info.code)
                {
                case "NetConnection.Connect.Success":
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                case "NetConnection.Connect.Failed":
                case "NetConnection.Connect.Rejected":
                case "NetConnection.Connect.AppShutdown":
                case "NetConnection.Connect.InvalidApp":
                    OnDisconnect();
                    break;

                case "NetStream.Connect.Success": // e.info.stream
                    OnNetStreamConnect();
                    break;

                case "NetStream.Connect.Rejected": // e.info.stream
                case "NetStream.Connect.Failed": // e.info.stream
                    DoDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    DoDisconnect();
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;


                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    DoResizeVideo();
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }

            private function DoConnect():void
            {
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                netConnection.connect(SERVER);
            }

            private function OnConnect():void
            {
                var groupSpecifier:GroupSpecifier;

                StatusMessage("Connected\n");
                connected = true;

                groupSpecifier = new GroupSpecifier("max2009lab/" + groupName.text);
                groupSpecifier.multicastEnabled = true;
                groupSpecifier.postingEnabled = true;
                groupSpecifier.serverChannelEnabled = true;

                netStream = new NetStream(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netStream.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");
            }

            private function OnNetStreamConnect():void
            {
                netStream.client = this;

                var mic:Microphone = Microphone.getMicrophone();
                if(mic)
                {
                    mic.codec = SoundCodec.SPEEX;
                    mic.setSilenceLevel(0);

                    netStream.attachAudio(mic);

                    StatusMessage("got microphone\n");
                }

                var camera:Camera = Camera.getCamera();
                if(camera)
                {
                    camera.setMode(320, 240, 10);
                    camera.setQuality(30000, 0);
                    camera.setKeyFrameInterval(15);

                    videoDisplay.attachCamera(camera);
                    videoDisplay.maintainAspectRatio = true;

                    netStream.attachCamera(camera);

                    StatusMessage("got camera\n");
                }

                netStream.publish("stream");
            }

            private function OnNetGroupConnect():void
            {
                joinedGroup = true;
            }

            private function DoDisconnect():void
            {
                if(netConnection)
                    netConnection.close();
                videoDisplay.attachCamera(null);
            }

            private function OnDisconnect():void
            {
                StatusMessage("Disconnected\n");
                netConnection = null;
                netStream = null;
                netGroup = null;
                connected = false;
                joinedGroup = false;
            }

            private function ClearChatText():void
            {
                chatText.text = "";
            }

            private function DoPost():void
            {
                var message:Object = new Object;

                message.user = userName.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);

                StatusMessage("==> " + chatText.text + "\n");

                chatText.callLater(ClearChatText);
            }

            private function OnPosting(message:Object):void
            {
                StatusMessage("<" + message.user + "> " + message.text + "\n");
            }

            private function DoResizeVideo(ignored:* = null):void
            {
                if(video)
                {
                    if( (0 == video.videoHeight)
                     || (0 == video.videoWidth)
                    )
                    {
                        video.height = videoDisplay.height;
                        video.width = videoDisplay.width;
                        video.x = 0;
                        video.y = 0;
                    }
                    else
                    {
                        var videoAspect:Number = Number(video.videoWidth) / Number(video.videoHeight);
                        var displayAspect:Number = Number(videoDisplay.width) / Number(videoDisplay.height);
                        var adjustFactor:Number;

                        if(videoAspect >= displayAspect) // video is wider than display
                        {
                            adjustFactor = Number(video.videoWidth) / Number(videoDisplay.width);
                            video.width = videoDisplay.width;
                            video.height = int(Number(video.videoHeight) / adjustFactor);
                            video.x = 0;
                            video.y = int((videoDisplay.height - video.height) / 2);
                        }
                        else
                        {
                            adjustFactor = Number(video.videoHeight) / Number(videoDisplay.height);
                            video.height = videoDisplay.height;
                            video.width = int(Number(video.videoWidth) / adjustFactor);
                            video.x = int((videoDisplay.width - video.width) / 2);
                            video.y = 0;
                        }
                    }
                }
            }

            public function onPlayStatus(info:Object):void {}
            public function onMetaData(info:Object):void {}
            public function onCuePoint(info:Object):void {}
            public function onTextData(info:Object):void {}

            public function ValidateConnectAllowed(isConnected:Boolean, groupNameText:String):Boolean
            {
                return (!isConnected) && (groupNameText.length > 0);
            }
        ]]>
    </mx:Script>

    <mx:VBox top="10" right="10" left="10" bottom="10" verticalGap="6">
        <mx:HBox width="100%">
            <mx:Text text="Group:"/>
            <mx:TextInput id="groupName" width="100%" text="default" enabled="{!connected}"/>
            <mx:Button label="Connect" click="DoConnect()" enabled="{ValidateConnectAllowed(connected, groupName.text)}" />
            <mx:Button label="Disconnect" click="DoDisconnect()" enabled="{connected}" />
        </mx:HBox>
        <mx:VideoDisplay id="videoDisplay" width="320" height="240" resize="DoResizeVideo()"/>
        <mx:TextArea id="statusLog" width="100%" height="100%"/>
        <mx:HBox width="100%">
            <mx:TextInput id="userName" width="160" />
            <mx:TextInput id="chatText" width="100%" enabled="{joinedGroup}" enter="DoPost()"/>
        </mx:HBox>
    </mx:VBox>

</mx:Application>