NetStatusEvent  - AS3

Objet associé à des propriétés décrivant son état ou indiquant une erreur.

L’objet d’informations peut avoir une propriété code contenant une chaîne représentant un événement spécifique ou une propriété level contenant une chaîne "status" ou "error".

L’objet d’informations peut également être différent. Les propriétés code et level peuvent ne pas fonctionner pour certaines implémentations et certains serveurs peuvent envoyer des objets différents.

Les connexions P2P envoient des messages à un objet NetConnection avec un paramètre stream dans l’objet d’informations désignant l’objet NetStream auquel le message appartient.

Par exemple, Flex Data Services envoie des objets Message qui provoquent des erreurs de forçage de type si vous tentez d’accéder au code ou à la propriété level.

Le tableau suivant répertorie les valeurs possibles des propriétés code et level.

Si vous recevez systématiquement des erreurs concernant la mémoire tampon, tentez de modifier celle-ci à l’aide de la propriété NetStream.bufferTime.

Eléments de l’API associés

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Crée un objet d’événement contenant des informations sur les événements netStatus. Les objets Event sont transmis en tant que paramètres aux écouteurs d’événements.

Eléments de l’API associés

Crée une copie de l’objet NetStatusEvent et définit la valeur de chaque propriété de sorte qu’elle corresponde à la valeur d’origine.

Renvoie une chaîne répertoriant toutes les propriétés de l’objet NetStatusEvent. La chaîne est écrite au format suivant :

[NetStatusEvent type=valeur bubbles=valeur cancelable=valeur info=valeur]

Définit la valeur de la propriété type d’un objet d’événement netStatus.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Dans cet exemple, la méthode netStatusHandler est enregistrée en tant qu’écouteur de l’événement NetStatusEvent NetConnection.netStatus. Lorsque l’état (réussite ou échec) de la tentative de NetConnection.connect() est connu, l’événement netStatus déclenche cette méthode. Si la tentative de connexion à l’objet NetConnection aboutit (en d’autres termes, si la propriété info de l’objet NetStatusEvent distribué par l’événement netStatus possède une propriété code indiquant un succès), le code crée les objets Video et NetStream et appelle les méthodes Video.attachNetStream() et NetStream.play().

Remarque : pour exécuter cet exemple, vous devez disposer d’un fichier FLV dont le nom et l’emplacement correspondent à la variable transmise à videoURL ; dans ce cas, un fichier FLV nommé Video.flv et situé dans le même répertoire que le fichier SWF.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }