DropShadowFilter  - AS3

Valeur de transparence alpha de la couleur d’ombre. Les valeurs valides sont comprises entre 0.0 et 1.0. Par exemple, 0,25 définit une valeur de transparence de 25 %. La valeur par défaut est 1.0.

Angle de l’ombre. Les valeurs valides sont comprises entre 0 et 360 degrés (virgule flottante). La valeur par défaut est 45.

Quantité de flou horizontal. Les valeurs possibles sont comprises entre 0 et 255.0 (virgule flottante). La valeur par défaut est 4.0.

Quantité de flou vertical. Les valeurs possibles sont comprises entre 0 et 255.0 (virgule flottante). La valeur par défaut est 4.0.

Couleur de l’ombre. Les valeurs valides sont au format hexadécimal 0xRRGGBB. La valeur par défaut est 0x000000.

Distance de décalage de l’ombre, en pixels. La valeur par défaut est 4,0 (virgule flottante).

Indique si l’objet est caché ou non. Une valeur true indique que l’objet lui-même n’est pas tracé et que seule l’ombre est visible. La valeur par défaut est false, soit montrer l’objet.

Indique si l’ombre est intérieure ou non. La valeur true indique une ombre intérieure. La valeur par défaut est false, renvoyant une ombre extérieure au niveau des bords extérieurs de l’objet.

Applique un effet de masquage (true) qui, en réalité, rend le remplissage de l’objet transparent et révèle la couleur d’arrière-plan du document. La valeur par défaut est false (pas de masquage).

Nombre d’applications du filtre. La valeur par défaut est BitmapFilterQuality.LOW, ce qui revient à appliquer le filtre une seule fois. La valeur BitmapFilterQuality.MEDIUM applique le filtre deux fois. La valeur BitmapFilterQuality.HIGH l’applique trois fois. Les rendus des filtres de valeurs faibles sont obtenus plus rapidement.

Pour la plupart des applications, une valeur de qualité faible, moyenne ou élevée est suffisante. Il est possible d’utiliser des valeurs numériques allant jusqu’à 15 pour obtenir différents effets, mais le rendu des valeurs les plus élevées est moins rapide. Sans augmenter la valeur de quality, vous pouvez généralement obtenir un effet similaire, avec un rendu plus rapide, en augmentant simplement les valeurs des propriétés blurX et blurY.

Eléments de l’API associés

Intensité de l’empreinte ou recouvrement. Plus la valeur est élevée, plus le recouvrement est intense et plus le contraste est important entre l’ombre et l’arrière-plan. Les valeurs valides sont comprises entre 0 et 255.0. La valeur par défaut est de 1.0.

Crée une occurrence de DropShadowFilter avec les paramètres spécifiés.

Eléments de l’API associés

Renvoie une copie de cet objet filtre.

1. Déclaration des trois propriétés qui sont utilisées pour dessiner le carré auquel le filtre est appliqué.
2. Création de la fonction constructeur. Le constructeur appelle la méthode draw() qui utilise des méthodes de la classe Graphics, accessibles par le biais de la propriété graphics de Sprite, pour dessiner un carré orange.
3. Dans le constructeur, déclaration d’une variable filter comme objet BitmapFilter et attribution de celui-ci à la valeur renvoyée d’un appel à getBitmapFilter(). La méthode getBitmapFilter() définit le filtre d’ombre portée utilisé.
4. Création d’un nouvel objet Array myFilters et ajout de filter au tableau. Attribution du tableau myFilters à la propriété filters de l’objet DropShadowFilterExample. Ceci a pour effet d’appliquer tous les filtres trouvés dans myFilters, en l’occurrence filter uniquement.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.DropShadowFilter;

    public class DropShadowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function DropShadowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x000000;
            var angle:Number = 45;
            var alpha:Number = 0.8;
            var blurX:Number = 8;
            var blurY:Number = 8;
            var distance:Number = 15;
            var strength:Number = 0.65;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;
            return new DropShadowFilter(distance,
                                        angle,
                                        color,
                                        alpha,
                                        blurX,
                                        blurY,
                                        strength,
                                        quality,
                                        inner,
                                        knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}