FocusEvent  - AS3

Spécifie la direction du focus pour un événement focusIn.

Eléments de l’API associés

Si la valeur est true, la propriété relatedObject est définie sur null pour des raisons liées aux sandbox de sécurité. Si la valeur nominale de relatedObject est une référence à un DisplayObject se trouvant dans un autre sandbox, relatedObject est défini sur null, à moins qu’il existe une autorisation dans les deux sens dans les limites de ce sandbox. L’autorisation est établie en appelant la méthode Security.allowDomain() à partir d’un fichier SWF ou en fournissant un fichier de régulation depuis le serveur d’un fichier image, puis en définissant la propriété LoaderContext.checkPolicyFile lors du chargement de l’image.

Eléments de l’API associés

Valeur de code correspondant à la touche utilisée pour déclencher un événement keyFocusChange.

Référence à l’occurrence complémentaire d’InteractiveObject affectée par le déplacement du focus. Lorsqu’un événement focusOut se produit, par exemple, relatedObject représente l’occurrence d’InteractiveObject qui a obtenu le focus.

La valeur de cette propriété peut être null dans deux cas : s’il n’existe aucun objet associé ou s’il existe un objet associé se trouvant dans un sandbox de sécurité auquel vous n’avez pas accès. Pour savoir dans quel cas vous vous trouvez, utilisez la propriété isRelatedObjectInaccessible().

Eléments de l’API associés

Indique si la touche de modification Maj est activée, auquel cas la valeur est true. Sinon, elle correspond à false. Cette propriété n’est utilisée que si l’événement FocusEvent est de type keyFocusChange.

Crée un objet Event à l’aide d’informations spécifiques relatives aux événements Focus. Les objets Event sont transmis en tant que paramètres aux écouteurs d’événements.

Eléments de l’API associés

Crée une copie de l’objet FocusEvent et définit la valeur de chaque propriété de sorte qu’elle corresponde à la valeur d’origine.

Renvoie une chaîne répertoriant toutes les propriétés de l’objet FocusEvent. La chaîne est écrite au format suivant :

[FocusEvent type=valeur bubbles=valeur cancelable=valeur relatedObject=valeur shiftKey=valeur] keyCode=valeur]

Définit la valeur de la propriété type d’un objet événement focusIn.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Définit la valeur de la propriété type d’un objet événement focusOut.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Définit la valeur de la propriété type d’un objet événement keyFocusChange.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Définit la valeur de la propriété type d’un objet événement mouseFocusChange.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

1. il déclare les propriétés child (de type Sprite) et childCount (de type uint).
2. Une boucle for crée cinq carrés bleu clair aux coordonnées (0,0). Elle commence par affecter child à une nouvelle occurrence de CustomSprite. Chaque fois qu’un objet CustomSprite est créé, il arrive ce qui suit :
   • La propriété size de type uint est définie sur 50 pixels et bgColor est définie sur la couleur bleu clair.
   • Les propriétés buttonMode et useHandCursor de la classe Sprite sont définies sur true dans le constructeur.
   • Un écouteur d’événements de type click est instancié, avec l’abonné associé clickHandler(). La méthode d’abonné crée une variable locale target de type Sprite et l’affecte à chaque clic de l’utilisateur sur une zone quelconque. Le focus de la scène est ensuite attribué à target.
   • La méthode draw() est appelée et crée un carré de 50x50 pixels via un appel aux méthodes beginFill(), drawRect() et endFill() de la classe Graphics et aux propriétés de l’occurrence.
3. Dans la boucle for, la méthode configureListeners() est appelée et instancie trois écouteurs/abonnés d’événements :
   • focusIn / focusInHandler() est distribué après l’événement click chaque fois que l’utilisateur clique sur un objet de liste d’affichage (champ).
   • focusOut / focusOutHandler() est distribué lorsque l’utilisateur clique sur un autre champ ou que le focus quitte la scène (par exemple, en cliquant à l’extérieur de Flash Player).
   • keyFocusChange / keyFocusChangeHandler() est distribué si l’utilisateur utilise la touche Tab ou les touches de direction gauche ou droite pour sélectionner un objet de liste d’affichage. La méthode keyFocusChangeHandler() piège les touches de direction droite et gauche et appelle la méthode preventDefault() pour les désactiver.
4. Dans la boucle for, chaque carré est ajouté dans la liste d’affichage et affiché (tous dans la même zone) par le biais de addChild().
5. Le constructeur appelle ensuite refreshLayout(), qui distribue les carrés orange en haut de l’écran (y = 0) en séparant chaque carré par 5 pixels.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}