Package | fl.controls.dataGridClasses |
Classe | public class DataGridColumn |
Héritage | DataGridColumn Object |
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Vous pouvez spécifier le type de composant qui affiche les données d’un objet DataGridColumn. Vous pouvez définir plusieurs caractéristiques, notamment le texte qui s’affiche dans l’en-tête de colonne et si la colonne peut être modifiée, triée ou redimensionnée.
Eléments de l’API associés
Propriété | Défini par | ||
---|---|---|---|
cellRenderer : Object
Classe utilisée pour le rendu des éléments dans cette colonne. | DataGridColumn | ||
constructor : Object
Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet. | Object | ||
dataField : String
Identifie le nom du champ ou de la propriété de l’élément fournisseur de données associé à la colonne. | DataGridColumn | ||
editable : Boolean = true
Indique si les éléments de la colonne peuvent être modifiés. | DataGridColumn | ||
editorDataField : String = "text"
Identifie le nom de la propriété de l’éditeur d’élément contenant les nouvelles données de l’élément de liste. | DataGridColumn | ||
headerRenderer : Object
Classe utilisée pour le rendu de l’en-tête de cette colonne. | DataGridColumn | ||
headerText : String
Nom de colonne à afficher dans l’en-tête de colonne. | DataGridColumn | ||
imeMode : String
Mode de l’éditeur de méthode d’entrée (IME). | DataGridColumn | ||
itemEditor : Object = fl.controls.dataGridClasses.DataGridCellEditor
Indique la classe des occurrences de l’éditeur d’élément à utiliser pour la colonne lorsqu’elle est modifiable. | DataGridColumn | ||
labelFunction : Function
Fonction qui détermine le texte à afficher dans cette colonne. | DataGridColumn | ||
minWidth : Number
Largeur minimale de la colonne, en pixels. | DataGridColumn | ||
resizable : Boolean = true
Indique si l’utilisateur est autorisé à modifier la largeur de la colonne. | DataGridColumn | ||
sortable : Boolean = true
Indique si l’utilisateur peut cliquer sur l’en-tête de la colonne active pour trier le fournisseur de données. | DataGridColumn | ||
sortCompareFunction : Function
Fonction de rappel appelée lors du tri des données de la colonne. | DataGridColumn | ||
sortDescending : Boolean = false
Indique si l’objet DataGridColumn doit être trié par ordre croissant ou décroissant. | DataGridColumn | ||
sortOptions : uint = 0
Une ou plusieurs constantes définies, identifiées par un nom ou un numéro et séparées par l’opérateur OR (|) au niveau du bit. | DataGridColumn | ||
visible : Boolean
Indique si la colonne est visible. | DataGridColumn | ||
width : Number
Largeur de la colonne, en pixels. | DataGridColumn |
Méthode | Défini par | ||
---|---|---|---|
DataGridColumn(columnName:String = null)
Crée une nouvelle occurrence de DataGridColumn. | DataGridColumn | ||
Indique si la propriété spécifiée d’un objet est définie. | Object | ||
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre. | Object | ||
Renvoie la chaîne que le rendu d’élément affiche pour l’objet de données spécifié. | DataGridColumn | ||
Indique si la propriété spécifiée existe et est énumérable. | Object | ||
Définit la disponibilité d’une propriété dynamique pour les opérations en boucle. | Object | ||
Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur. | Object | ||
Renvoie une représentation sous forme de chaîne de l’objet DataGridColumn. | DataGridColumn | ||
Renvoie la valeur primitive de l’objet spécifié. | Object |
cellRenderer | propriété |
cellRenderer:Object
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Classe utilisée pour le rendu des éléments dans cette colonne. Cette propriété peut être de type Class, Sprite ou String. Si la propriété est de type String, la valeur de chaîne doit être un nom de classe complet.
La valeur par défaut est null.
Implémentation
public function get cellRenderer():Object
public function set cellRenderer(value:Object):void
Eléments de l’API associés
Exemple ( Comment utiliser cet exemple )
import fl.controls.dataGridClasses.DataGridColumn; var dgc:DataGridColumn = new DataGridColumn("Field"); dgc.cellRenderer = "MyCustomCellRendererClass"; dg.addColumn(dgc);
dataField | propriété |
public var dataField:String
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Identifie le nom du champ ou de la propriété de l’élément fournisseur de données associé à la colonne.
editable | propriété |
public var editable:Boolean = true
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Indique si les éléments de la colonne peuvent être modifiés. La valeur true
indique que les éléments de la colonne peuvent être modifiés ; la valeur false
indique qu’ils ne peuvent pas l’être.
Si cette propriété a la valeur true
et que la propriété editable
de l’objet DataGrid a également la valeur true
, les éléments d’une colonne sont modifiables et peuvent être modifiés individuellement en cliquant sur leur entrée ou en naviguant jusqu’à eux à l’aide des touches de direction et de tabulation.
La valeur par défaut est true.
editorDataField | propriété |
public var editorDataField:String = "text"
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Identifie le nom de la propriété de l’éditeur d’élément contenant les nouvelles données de l’élément de liste.
Par exemple, la valeur par défaut de itemEditor
étant TextInput, la valeur par défaut de la propriété editorDataField
est "text"
. Cette valeur spécifie la propriété text
du composant TextInput.
La valeur par défaut est "text".
headerRenderer | propriété |
headerRenderer:Object
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Classe utilisée pour le rendu de l’en-tête de cette colonne.
Cette propriété peut être de type Class, Sprite ou String. Si la propriété est de type String, la valeur de chaîne doit être un nom de classe complet.
La valeur par défaut est null.
Implémentation
public function get headerRenderer():Object
public function set headerRenderer(value:Object):void
Eléments de l’API associés
headerText | propriété |
headerText:String
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Nom de colonne à afficher dans l’en-tête de colonne. Par défaut, le composant DataGrid utilise la valeur de la propriété dataField
comme nom de colonne.
Implémentation
public function get headerText():String
public function set headerText(value:String):void
Exemple ( Comment utiliser cet exemple )
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var dp:DataProvider = new DataProvider(); dp.addItem({name:"Person A", sales:13453}); dp.addItem({name:"Person B", sales:23432}); dp.addItem({name:"Person C", sales:9454}); var nameCol:DataGridColumn = new DataGridColumn("name"); nameCol.headerText = "Employee:"; var salesCol:DataGridColumn = new DataGridColumn("sales"); salesCol.headerText = "Sales:"; salesCol.labelFunction = currencyFormatter; salesCol.sortOptions = Array.NUMERIC; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(nameCol); myDataGrid.addColumn(salesCol); myDataGrid.dataProvider = dp; myDataGrid.move(10, 10); myDataGrid.setSize(320, 240); addChild(myDataGrid); function currencyFormatter(item:Object):String { return "$" + item.sales.toFixed(0); }
imeMode | propriété |
imeMode:String
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Mode de l’éditeur de méthode d’entrée (IME). L’éditeur IME permet aux utilisateurs d’entrer du texte en chinois, japonais et coréen. La classe flash.system.IMEConversionMode définit les constantes à utiliser comme valeurs valides de cette propriété.
Si cette propriété est de valeur null
, le mode de l’éditeur IME est défini selon la valeur de la propriété imeMode
du composant DataGrid.
La valeur par défaut est null.
Implémentation
public function get imeMode():String
public function set imeMode(value:String):void
Eléments de l’API associés
itemEditor | propriété |
public var itemEditor:Object = fl.controls.dataGridClasses.DataGridCellEditor
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Indique la classe des occurrences de l’éditeur d’élément à utiliser pour la colonne lorsqu’elle est modifiable. Cette propriété peut être de type Class, Sprite ou String. Si la propriété est de type String, la valeur de chaîne doit être un nom de classe complet.
La valeur par défaut est "fl.controls.dataGridClasses.DataGridCellEditor".
Exemple ( Comment utiliser cet exemple )
import fl.controls.dataGridClasses.DataGridColumn; var dgc:DataGridColumn = new DataGridColumn("Field"); dgc.itemEditor = "MyCustomItemEditorClass"; dg.addColumn(dgc);
labelFunction | propriété |
labelFunction:Function
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Fonction qui détermine le texte à afficher dans cette colonne. Par défaut, la colonne affiche le texte du champ de données qui correspond au nom de la colonne. Toutefois, une colonne peut également servir à afficher le texte de plusieurs champs de données ou à afficher du contenu qui n’est pas dans un format correct. Pour ce faire, il convient d’utiliser la propriété labelFunction
pour spécifier une fonction de rappel.
Si les propriétés labelFunction
et labelField
sont toutes deux définies, la propriété labelFunction
est prioritaire.
La valeur par défaut est null.
Implémentation
public function get labelFunction():Function
public function set labelFunction(value:Function):void
Exemple ( Comment utiliser cet exemple )
import fl.controls.DataGrid; import fl.controls.ScrollPolicy; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var i:uint; var totalRows:uint = 16; var dp:DataProvider = new DataProvider(); for (i = 0; i < totalRows; i++) { dp.addItem({col1:getRandomNumber(), col2:getRandomNumber(), col3:getRandomNumber(), col4:getRandomNumber()}); } var c1:DataGridColumn = new DataGridColumn("col1"); c1.sortOptions = Array.NUMERIC; var c2:DataGridColumn = new DataGridColumn("col2"); c2.sortOptions = Array.NUMERIC; var c3:DataGridColumn = new DataGridColumn("col3"); c3.sortOptions = Array.NUMERIC; c3.labelFunction = currencyFormatter; var dg:DataGrid = new DataGrid(); dg.setSize(200, 300); dg.addColumn(c1); dg.addColumn(c2); dg.addColumn(c3); dg.dataProvider = dp; addChild(dg); function getRandomNumber():Number { return Math.random() * 100; } function currencyFormatter(data:Object):String { var value:Number = Number(data.col3); return "$" + value.toFixed(2); }
labelFunction
et sortCompareFunction
:
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var data:XML = <data> <item name="Employee A" isManager="1" /> <item name="Employee B" isManager="0" /> <item name="Employee C" isManager="1" /> </data>; var dp:DataProvider = new DataProvider(data); var nameDGC:DataGridColumn = new DataGridColumn("name"); nameDGC.sortCompareFunction = isManager; nameDGC.labelFunction = nameLabelFunction; var myDataGrid:DataGrid = new DataGrid() myDataGrid.addColumn(nameDGC); myDataGrid.dataProvider = dp; myDataGrid.width = 200; myDataGrid.rowCount = myDataGrid.length; myDataGrid.move(10, 10); addChild(myDataGrid); function nameLabelFunction(item:Object):String { var managerString:String = ""; if (item.isManager == "1") { managerString = " (Manager)"; } return item.name + managerString; } function isManager(itemA:Object, itemB:Object):int { if (itemA.isManager > itemB.isManager) { return -1; } else if (itemA.isManager < itemB.isManager) { return 1; } else { return 0; } }
minWidth | propriété |
minWidth:Number
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Largeur minimale de la colonne, en pixels.
La valeur par défaut est 20.
Implémentation
public function get minWidth():Number
public function set minWidth(value:Number):void
Eléments de l’API associés
Exemple ( Comment utiliser cet exemple )
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; import fl.events.DataGridEvent; var data:XML = <data> <row col1="item 1.A" col2="item 1.B" col3="item 1.C" /> <row col1="item 2.A" col2="item 2.B" col3="item 2.C" /> <row col1="item 3.A" col2="item 3.B" col3="item 3.C" /> </data>; var dp:DataProvider = new DataProvider(data); var c1:DataGridColumn = new DataGridColumn("col1"); c1.minWidth = 100; var c2:DataGridColumn = new DataGridColumn("col2"); var c3:DataGridColumn = new DataGridColumn("col3"); var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(c1); myDataGrid.addColumn(c2); myDataGrid.addColumn(c3); myDataGrid.dataProvider = dp; myDataGrid.move(10, 10); myDataGrid.setSize(300, 200); myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler); addChild(myDataGrid); function columnStretchHandler(event:DataGridEvent):void { var column:DataGridColumn; for each (column in myDataGrid.columns) { trace(column.dataField, "width:" + column.width, "minWidth:" + column.minWidth); } trace("---"); }
resizable | propriété |
public var resizable:Boolean = true
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Indique si l’utilisateur est autorisé à modifier la largeur de la colonne. La valeur true
indique que l’utilisateur peut modifier la largeur de la colonne ; la valeur false
indique que l’utilisateur ne peut pas modifier la largeur de la colonne.
La valeur par défaut est true.
sortable | propriété |
public var sortable:Boolean = true
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Indique si l’utilisateur peut cliquer sur l’en-tête de la colonne active pour trier le fournisseur de données. La valeur true
indique que la colonne peut être triée par un clic sur son en-tête ; la valeur false
indique qu’elle ne peut pas être triée de cette façon.
La valeur par défaut est true.
Exemple ( Comment utiliser cet exemple )
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; import fl.events.DataGridEvent; var data:XML = <dataProvider> <data col1="Person A" col2="11.383" /> <data col1="Person B" col2="3.399" /> <data col1="Person C" col2="25.624" /> </dataProvider> var dp:DataProvider = new DataProvider(data); var c1:DataGridColumn = new DataGridColumn("col1"); var c2:DataGridColumn = new DataGridColumn("col2"); c2.sortable = false; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(c1); myDataGrid.addColumn(c2); myDataGrid.dataProvider = dp; myDataGrid.move(10, 10); myDataGrid.setSize(160, 120); addChild(myDataGrid);
sortable
sur false
:
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; import fl.events.DataGridEvent; var xmlDP:XML = <items> <item name="Person 1" bio="Person 1 bio" /> <item name="Person 2" bio="Person 2 bio" /> </items>; var dp:DataProvider = new DataProvider(xmlDP); var nameCol:DataGridColumn = new DataGridColumn("name"); nameCol.headerText = "Name:"; var bioCol:DataGridColumn = new DataGridColumn("bio"); bioCol.headerText = "Bio:"; bioCol.sortable = false; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(nameCol); myDataGrid.addColumn(bioCol); myDataGrid.dataProvider = dp; myDataGrid.rowCount = dp.length; myDataGrid.width = 200; myDataGrid.move(10, 10); myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler); addChild(myDataGrid); function headerReleaseHandler(event:DataGridEvent):void { var myDG:DataGrid = event.currentTarget as DataGrid; trace("dataField:" + event.dataField); trace("columnIndex:" + event.columnIndex); trace("{DataGrid}.sortDescending:" + myDG.sortDescending); trace("{DataGridColumn}.sortDescending:" + myDG.getColumnAt(event.columnIndex).sortDescending); trace(""); }
sortCompareFunction | propriété |
sortCompareFunction:Function
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Fonction de rappel appelée lors du tri des données de la colonne. Si cette propriété n’est pas spécifiée, le tri des données s’effectue selon un critère numérique ou alphanumérique, en fonction de la propriété sortOptions
. Lorsqu’elle est spécifiée, la propriété sortCompareFunction
vous permet de créer votre propre méthode de tri personnalisée pour la colonne de grille de données active.
La valeur par défaut est null.
Implémentation
public function get sortCompareFunction():Function
public function set sortCompareFunction(value:Function):void
Eléments de l’API associés
Exemple ( Comment utiliser cet exemple )
labelFunction
et sortCompareFunction
:
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var data:XML = <data> <item name="Employee A" isManager="1" /> <item name="Employee B" isManager="0" /> <item name="Employee C" isManager="1" /> </data>; var dp:DataProvider = new DataProvider(data); var nameDGC:DataGridColumn = new DataGridColumn("name"); nameDGC.sortCompareFunction = isManager; nameDGC.labelFunction = nameLabelFunction; var myDataGrid:DataGrid = new DataGrid() myDataGrid.addColumn(nameDGC); myDataGrid.dataProvider = dp; myDataGrid.width = 200; myDataGrid.rowCount = myDataGrid.length; myDataGrid.move(10, 10); addChild(myDataGrid); function nameLabelFunction(item:Object):String { var managerString:String = ""; if (item.isManager == "1") { managerString = " (Manager)"; } return item.name + managerString; } function isManager(itemA:Object, itemB:Object):int { if (itemA.isManager > itemB.isManager) { return -1; } else if (itemA.isManager < itemB.isManager) { return 1; } else { return 0; } }
sortDescending | propriété |
public var sortDescending:Boolean = false
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Indique si l’objet DataGridColumn doit être trié par ordre croissant ou décroissant. La valeur true
indique que l’objet DataGridColumn est trié par ordre décroissant ; la valeur false
indique que l’objet DataGridColumn est trié par ordre croissant.
La valeur par défaut est false.
sortOptions | propriété |
public var sortOptions:uint = 0
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Une ou plusieurs constantes définies, identifiées par un nom ou un numéro et séparées par l’opérateur OR (|) au niveau du bit. Ces constantes sont utilisées pour spécifier l’opération de tri.
La valeur par défaut est 0.
Eléments de l’API associés
Exemple ( Comment utiliser cet exemple )
sortOptions
pour spécifier qu’une colonne de grille de données doit être triée numériquement :
import fl.data.DataProvider; import fl.controls.dataGridClasses.DataGridColumn; var data:XML = <players> <player name="Player 1" score="1234" /> <player name="Player 2" score="198" /> <player name="Player 3" score="987" /> </players>; var dp:DataProvider = new DataProvider(data); var nameDGC:DataGridColumn = new DataGridColumn("name"); var scoreDGC:DataGridColumn = new DataGridColumn("score"); scoreDGC.sortOptions = Array.NUMERIC; dg.addColumn(nameDGC); dg.addColumn(scoreDGC); dg.dataProvider = dp;
visible | propriété |
visible:Boolean
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Indique si la colonne est visible. La valeur true
indique que la colonne est visible ; la valeur false
indique qu’elle ne l’est pas.
La valeur par défaut est true.
Implémentation
public function get visible():Boolean
public function set visible(value:Boolean):void
Exemple ( Comment utiliser cet exemple )
visible
de chacune de ces colonnes en cliquant sur l’occurrence du composant Button correspondant sur la scène.
import fl.controls.Button; import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var dp:DataProvider = new DataProvider(); dp.addItem({name:"Person A", average:0.297}); dp.addItem({name:"Person B", average:0.288}); dp.addItem({name:"Person C", average:0.310}); var nameCol:DataGridColumn = new DataGridColumn("name"); nameCol.headerText = "Name:"; var averageCol:DataGridColumn = new DataGridColumn("average"); averageCol.headerText = "Average:"; averageCol.labelFunction = numberFormatter; averageCol.sortOptions = Array.NUMERIC; averageCol.visible = false; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(nameCol); myDataGrid.addColumn(averageCol); myDataGrid.dataProvider = dp; myDataGrid.rowCount = dp.length; myDataGrid.width = 320; myDataGrid.move(10, 10); addChild(myDataGrid); var nameButton:Button = new Button(); nameButton.label = "Toggle name"; nameButton.toggle = true; nameButton.selected = nameCol.visible; nameButton.move(myDataGrid.x, myDataGrid.y + myDataGrid.height + 10); nameButton.addEventListener(Event.CHANGE, changeHandler); addChild(nameButton); var averageButton:Button = new Button(); averageButton.label = "Toggle average"; averageButton.toggle = true; averageButton.selected = averageCol.visible; averageButton.move(nameButton.x + nameButton.width + 10, nameButton.y); averageButton.addEventListener(Event.CHANGE, changeHandler); addChild(averageButton); function numberFormatter(item:Object):String { return Number(item.average).toFixed(3); } function changeHandler(event:Event):void { var colIndex:int = -2; var col:DataGridColumn; switch (event.currentTarget) { case nameButton: colIndex = myDataGrid.getColumnIndex("name"); break; case averageButton: colIndex = myDataGrid.getColumnIndex("average"); break; default: return; } if (colIndex > -1) { col = myDataGrid.getColumnAt(colIndex); col.visible = !col.visible; myDataGrid.removeColumnAt(colIndex); myDataGrid.addColumnAt(col, colIndex); } myDataGrid.spaceColumnsEqually(); }
width | propriété |
width:Number
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Largeur de la colonne, en pixels.
La valeur par défaut est 100.
Implémentation
public function get width():Number
public function set width(value:Number):void
Eléments de l’API associés
DataGridColumn | () | Constructeur |
public function DataGridColumn(columnName:String = null)
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Crée une nouvelle occurrence de DataGridColumn.
ParamètrescolumnName:String (default = null ) — Nom de colonne à afficher dans l’en-tête de colonne. Si aucun nom n’est spécifié, la valeur dataField est utilisée.
|
Eléments de l’API associés
itemToLabel | () | méthode |
public function itemToLabel(data:Object):String
Version du langage: | ActionScript 3.0 |
Version du produit: | Flash CS3 |
Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Renvoie la chaîne que le rendu d’élément affiche pour l’objet de données spécifié. Si l’objet DataGridColumn ou son composant DataGrid présente une propriété labelFunction
non null, la fonction est appliquée à l’objet de données. Sinon, la méthode extrait le contenu du champ spécifié par la propriété dataField
ou obtient la valeur de chaîne de l’objet de données. Si la méthode ne peut pas convertir le paramètre en chaîne, elle retourne un espace unique.
Paramètres
data:Object — Objet à rendre.
|
String — Chaîne affichable qui dépend de l’objet data spécifié.
|
toString | () | méthode |
- Ajoutez les composants DataGrid et Button à la bibliothèque.
- Enregistrez ce code sous le nom DataGridColumnExample.as dans le même répertoire que votre fichier FLA.
- Dans le fichier FLA, définissez DocumentClass sur DataGridColumnExample.
package { import flash.display.Sprite; import flash.events.MouseEvent; import fl.data.DataProvider; import fl.events.DataChangeEvent; import fl.controls.DataGrid; import fl.controls.Button; import fl.controls.dataGridClasses.DataGridColumn; public class DataGridColumnExample extends Sprite { private var dg:DataGrid; private var dp:DataProvider; private var names:Array = [ "Mary", "Bob", "Sue", "Joe" ]; public function DataGridColumnExample() { dp = new DataProvider(); dp.addEventListener(DataChangeEvent.DATA_CHANGE,dataChanged); dg = new DataGrid(); addChild(dg); dg.move(10,45); dg.setSize(450,300); dg.addColumn(new DataGridColumn("name")); dg.addColumn(new DataGridColumn("phone")); dg.addColumn(new DataGridColumn("email")); var firstColumn = dg.columns[0]; firstColumn.resizable = false; var secondColumn = dg.columns[1]; secondColumn.sortable = false; var thirdColumn = dg.columns[2]; thirdColumn.sortable = false; var addContactBtn:Button = new Button(); addContactBtn.label = "Add Contact"; addContactBtn.move(10,10); addContactBtn.addEventListener(MouseEvent.CLICK, addContact); addChild(addContactBtn); } private function getRandomPhone():String { return randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+randomDigit(); } private function randomDigit():String { return String(Math.round(Math.random()*10)%10); } private function getRandomName():String { return names[Math.round(Math.random()*names.length)%names.length]; } private function addContact(e:MouseEvent):void { var randomName:String = getRandomName() dp.addItem( { name: randomName, phone: getRandomPhone(), email: randomName + "@fictitious.com" } ); } private function dataChanged(e:DataChangeEvent):void { var changedItems:Array = e.items; dg.addItem(changedItems[0]); } } }
Tue Jun 12 2018, 09:30 AM Z