ContextMenu  - AS3

Una instancia de la clase ContextMenuBuiltInItems con las siguientes propiedades: forwardAndBack, loop, play, print, quality, rewind, save y zoom. La configuración de estas propiedades con el valor false quita los elementos de menú correspondientes del objeto ContextMenu especificado. Estas propiedades son enumerables y están configuradas con el valor true de manera predeterminada.

Nota: en AIR, los menús contextuales no incluyen opciones incorporadas.

Elementos de API relacionados

Una instancia de la clase ContextMenuClipboardItems con las siguientes propiedades: cut, copy, paste, delete, selectAll. Si establece una de estas propiedades como false, se desactiva el elemento correspondiente del menú del portapapeles.

Elementos de API relacionados

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Especifica si se debe utilizar o no el menú del portapapeles. Si este valor es true, la propiedad clipboardItems determina qué elementos se activan y se desactivan en el menú del portapapeles.

Si la propiedad link no es null, se omite esta propiedad clipBoardMenu.

Un conjunto de objetos ContextMenuItem. Cada objeto del conjunto representa un elemento del menú contextual que ha definido. Utilice esta propiedad para añadir, quitar o modificar estos elementos de menú personalizados.

Para añadir nuevos elementos al menú, cree un objeto ContextMenuItem y luego añádalo al conjunto customItems (por ejemplo, utilizando Array.push()). Para más información sobre la creación de elementos de menú, consulte la entrada de la clase ContextMenuItem.

Elementos de API relacionados

La propiedad isSupported se establece en true si la clase ContextMenu se admite en la plataforma actual; en caso contrario, se establece en false.

Conjunto de elementos personalizados de este menú.

Utilizar esta propiedad equivale a utilizar la propiedad customItems. El conjunto se ordena según su orden de visualización.

Objeto URLRequest del vínculo. Si esta propiedad es null, se muestra un menú contextual normal. Si esta propiedad no es null, se muestra el vínculo del menú contextual y se activa la dirección URL especificada.

Si se especifica una propiedad link, la propiedad clipboardMenu se omite.

El valor predeterminado es null.

Número de elementos en este menú.

Crea un objeto ContextMenu.

Elementos de API relacionados

Añade un elemento de menú al final de un menú.

Cuando se crea un menú contextual, es posible añadir objetos NativeMenuItem o ContextMenuItem. Sin embargo, se recomienda utilizar sólo un tipo de objeto en un menú contextual para que todos los elementos del menú tengan las mismas propiedades.

Parámetros

Crea una copia del objeto ContextMenu. La copia hereda todas las propiedades del objeto de menú original.

Indica si el menú contiene el elemento de menú especificado.

Parámetros

El menú emerge en la ubicación especificada.

Nota: este método no se admite en Flash Player.

Parámetros

Obtiene el elemento de menú en el índice especificado.

Parámetros

Obtiene la posición del elemento especificado.

Parámetros

Oculta todos los elementos de menú incorporados (salvo Configuración) del objeto ContextMenu especificado. Si se está en ejecución la versión del depurador de Flash Player, se mostrará el elemento de menú Depuración, aunque éste estará atenuado para archivos SWF que no tengan activada la depuración remota.

Este método oculta sólo los elementos de menú que aparecen en el menú contextual estándar; no afecta a los elementos que aparecen en los menús de edición y de error.

Este método funciona configurando todos los miembros booleanos de my_cm.builtInItems como false. Puede seleccionar los elementos incorporados que deben estar visibles configurando su correspondiente miembro en my_cm.builtInItems como true.

Nota: en AIR, los menús contextuales no incluyen opciones incorporadas. Llamar a este método no produce ningún efecto.

Elementos de API relacionados

Elimina todos los elementos de la lista.

Elimina y devuelve el elemento de menú en el índice especificado.

Parámetros

Se distribuye cuando el usuario genera por primera vez un menú contextual, pero antes de que se muestre su contenido. De este modo, el programa puede modificar la definición de los elementos del menú contextual antes de mostrarlo. El usuario genera el menú contextual al hacer clic con el botón derecho del dispositivo de señalización.

Este evento tiene las propiedades siguientes:

1. Se declara una propiedad myContextMenu y, a continuación, se asigna a un objeto ContextMenu nuevo y se declara una propiedad redRectangle de tipo Sprite.
2. Se llama al método removeDefaultItems(), que elimina todos los elementos incorporados en el menú contextual salvo Print.
3. Se llama al método addCustomMenuItems(), que coloca el elemento de menú de selección de menú Red to Black en el conjunto defaultItems a través del método push() de la clase Array. Se añade un detector de eventos menuItemSelect al objeto ContextMenuItem y se llama al método asociado menuItemSelectHandler(). Este método imprime determinadas sentencias mediante trace() siempre que se accede al menú contextual y se selecciona Red to Black. Asimismo, se elimina el cuadrado de color rojo y se sustituye por uno de color negro.
4. Se añade un detector de eventos de tipo menuSelect, junto con el método asociado menuSelectHandler, que simplemente imprime tres sentencias a través de trace() siempre que se abre un elemento del menú contextual.
5. A continuación, addChildren() dibuja un cuadrado de color rojo y lo añade a la lista de visualización, donde aparece inmediatamente.
6. Por último, myContextMenu se asigna al menú contextual del elemento sprite redRectangle, de modo que el menú contextual personalizado sólo aparezca cuando el puntero del ratón se encuentre sobre el cuadrado.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}