ContextMenuEvent  - AS3

El objeto de la lista de visualización al que se asocia el menú. Podría ser el destino del ratón (mouseTarget) o uno de sus ascendientes de la lista de visualización.

Indica si la propiedad mouseTarget se ha establecido en null por motivos de seguridad. Si el valor nominal de menuTarget afecta a una referencia a DisplayObject en otro entorno limitado de seguridad, menuTarget se establece en null a no ser que existan permisos en ambas direcciones en los límites del entorno limitado. Puede establecer los permisos llamando a Security.allowDomain() desde un archivo SWF, o bien proporcionando un archivo de política desde el servidor de un archivo de imagen y estableciendo la propiedad LoaderContext.checkPolicyFile al cargar la imagen.

Elementos de API relacionados

El objeto de la lista de visualización en el que el usuario hace clic con el botón derecho para mostrar el menú contextual. Podría ser el objeto de la lista de visualización al que se asocia el menú (contextMenuOwner) o uno de sus descendientes de la lista de visualización.

El valor de esta propiedad puede ser null en dos casos: si no hay destino del ratón, por ejemplo, cuando pasa el ratón por encima de algún objeto sobre el fondo, o si existe el destino del ratón, pero se encuentra en un entorno limitado de seguridad para el que no tiene acceso. Utilice la propiedad isMouseTargetInaccessible() para determinar qué motivo es pertinente.

Elementos de API relacionados

Crea un objeto de evento que contiene información específica sobre eventos de menú. Los objetos de evento se transfieren como parámetros a los detectores de eventos.

Elementos de API relacionados

Crea una copia del objeto ContextMenuEvent y define el valor de cada propiedad para que coincida con el del objeto original.

Devuelve una cadena con todas las propiedades del objeto ContextMenuEvent. La cadena tiene el siguiente formato:

[tipo ContextMenuEvent= valor bubbles= valor cancelable= valor ... contextMenuOwner= valor]

Define el valor de la propiedad type de un objeto de evento menuItemSelect.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento menuSelect.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

1. Se declara una propiedad myContextMenu y, a continuación, se asigna a un objeto ContextMenu nuevo y se declara una propiedad redRectangle de tipo Sprite.
2. Se llama al método removeDefaultItems(). Este método elimina todos los elementos incorporados en el menú contextual excepto Print.
3. Se llama al método addCustomMenuItems(). Este método coloca un elemento de menú Reverse Colors en el conjunto defaultItems utilizando el método push() de Array. Se añade un detector de eventos menuItemSelect al objeto ContextMenuItem y se llama al método asociado menuItemSelectHandler(). Este método imprime algunas sentencias trace() cuando el usuario selecciona Reverse Colors en el menú contextual. Además, el cuadrado rojo pasa a ser negro y el texto negro se muestra en rojo.
4. De nuevo en el constructor, se añade un detector de eventos menuSelect, junto con el método asociado menuSelectHandler(), que simplemente imprime tres sentencias trace() siempre que se selecciona un elemento del menú contextual.
5. El constructor llama a addChildren(), que dibuja un cuadrado de color rojo y lo añade a la lista de visualización, donde aparece inmediatamente.
6. Por último, myContextMenu se asigna al menú contextual de la propiedad redRectangle, de modo que el menú contextual personalizado sólo aparezca cuando el puntero del ratón se encuentre sobre el cuadrado.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}