Socket  - AS3

El número de bytes de datos disponibles para su lectura en el búfer de entrada.

El código debe poder acceder a bytesAvailable para garantizar que hay datos suficientes disponibles antes de intentar leerlos con uno de los métodos read.

Indica el número de bytes restantes en el búfer de escritura.

Utilice esta propiedad en combinación con el evento OutputProgressEvent. Se emite un evento OutputProgressEvent cada vez que se escriben datos en la red desde el búfer de lectura. En el controlador de eventos, puede comprobar bytesPending para ver cuántos datos quedan aún en el búfer esperando para su escritura. Si bytesPending devuelve 0, significa que todos los datos se han transferido desde el búfer de lectura a la red, y que es seguro realizar ciertas acciones como eliminar controladores de eventos, activar las referencias a sockets, iniciar la siguiente carga en la cola, etc.

Elementos de API relacionados

Indica si este objeto Socket está conectado actualmente. Una llamada a esta propiedad devuelve un valor true si el socket está conectado en ese momento; en caso contrario, devuelve false.

Indica el orden de bytes de los datos. Los valores posibles son constantes de la clase flash.utils.Endian, Endian.BIG_ENDIAN o Endian.LITTLE_ENDIAN.

El valor predeterminado es Endian.BIG_ENDIAN.

Elementos de API relacionados

La dirección IP a la que este socket está vinculado en el equipo local.

Elementos de API relacionados

El puerto al que este socket está vinculado en el equipo local.

Elementos de API relacionados

Controla la versión del AMF utilizado al escribir o leer un objeto.

Elementos de API relacionados

La dirección IP del equipo remoto a la que este socket está conectado.

Puede utilizar esta propiedad para determinar la dirección IP de un socket de cliente distribuido en un evento ServerSocketConnectEvent por un objeto ServerSocket. Utilice la clase DNSResolver para convertir una dirección IP en un nombre de dominio, si lo desea.

Elementos de API relacionados

El puerto del equipo remoto al que este socket está conectado.

Puede utilizar esta propiedad para determinar el número de puerto de un socket de cliente distribuido en un evento ServerSocketConnectEvent por un objeto ServerSocket.

Elementos de API relacionados

Indica el número de milisegundos para esperar una conexión.

Si la conexión no se realiza en el tiempo especificado, se produce un error de conexión. El valor predeterminado es 20,000 (veinte segundos).

Crea un nuevo objeto Socket. Si no se especifica ningún parámetro, se crea un socket desconectado inicialmente. Si se especifican parámetros, se intenta realizar la conexión con el host y el puerto especificados.

Nota: se recomienda encarecidamente el uso del formulario constructor sin parámetros, posteriormente la adición de todos los detectores de eventos y, a continuación, la llamada al método connect con los parámetros host y port. Esta secuencia garantiza que todos los detectores de eventos funcionen correctamente.

Cierra el socket. No es posible leer ni escribir datos tras llamar al método close().

El evento close sólo se distribuye si el servidor cierra la conexión; no se distribuye al llamar al método close().

Puede reutilizar el objeto Socket si llama de nuevo al método connect().

Realiza la conexión del socket con el host y el puerto especificados.

Si la conexión falla inmediatamente, o bien se ha distribuido un evento o se ha emitido una excepción: se distribuye un evento de error si se especificó un host y se emite una excepción si no se especificó ningún host. En caso contrario, un evento informa sobre el estado de la conexión. Si el socket ya está conectado, primero se cierra la conexión existente.

Parámetros

Alinea los datos acumulados en el búfer de salida del socket.

En algunos sistemas operativos se llama a flush() automáticamente entre los fotogramas de ejecución, pero en otros sistemas operativos como Windows, los datos no se envían nunca a no ser que se llame a flush() de forma explícita. Para garantizar que la aplicación es estable en todos los sistemas operativos, se recomienda llamar al método flush() después de escribir cada mensaje (o grupo relacionado de datos) en el socket.

Lee un valor booleano del socket. Tras leer un solo byte, el método devuelve true si el byte es distinto de cero; en caso contrario, devuelve false.

Lee un byte con signo del socket.

Lee el número de bytes de datos especificado por el parámetro length desde el socket. Los bytes se leen en el conjunto de bytes especificado, comenzando por la posición indicada mediante offset.

Parámetros

Lee un número de coma flotante con precisión doble IEEE 754 del socket.

Lee un número de coma flotante con precisión simple IEEE 754 del socket.

Lee un entero de 32 bits con signo del socket.

Lee una cadena multibyte desde el flujo de bytes mediante el juego de caracteres especificado.

Parámetros

Lee un objeto del socket, codificado en formato serializado AMF.

Elementos de API relacionados

Lee un entero de 16 bits con signo del socket.

Lee un byte sin signo del socket.

Lee un entero de 32 bits sin signo del socket.

Lee un entero de 16 bits sin signo del socket.

Lee una cadena UTF-8 del socket. Se da por hecho que la cadena tiene un prefijo de declaración de entero corto sin signo que indica la longitud en bytes.

Lee el número de bytes de datos UTF-8 especificado por el parámetro length desde el socket y devuelve una cadena.

Parámetros

Escribe un valor booleano en el socket. Este método escribe un solo byte con el valor 1 (true) ó 0 (false).

Parámetros

Elementos de API relacionados

Escribe un byte en el socket.

Parámetros

Elementos de API relacionados

Escribe una secuencia de bytes desde el conjunto de bytes especificado. La operación de escritura comienza en la posición especificada por offset.

Si omite el parámetro length, la longitud predeterminada de 0 hará que el método escriba en todo el búfer, comenzando por offset.

Si también omite el parámetro offset, se escribirá en todo el búfer.

Parámetros

Elementos de API relacionados

Escribe un número de coma flotante con precisión doble IEEE 754 en el socket.

Parámetros

Elementos de API relacionados

Escribe un número de coma flotante con precisión simple IEEE 754 en el socket.

Parámetros

Elementos de API relacionados

Escribe un entero de 32 bits con signo en el socket.

Parámetros

Elementos de API relacionados

Escribe una cadena multibyte desde la transmisión de bytes mediante el juego de caracteres especificado.

Parámetros

Elementos de API relacionados

Escribe un objeto en el socket en formato serializado AMF.

Parámetros

Elementos de API relacionados

Escribe un entero de 16 bits en el socket. Los bytes escritos son los siguientes:

(v >> 8) & 0xff v & 0xff

Se utilizan los 16 bits más bajos del parámetro; los 16 bits altos se omiten.

Parámetros

Elementos de API relacionados

Escribe un entero de 32 bits sin signo en el socket.

Parámetros

Elementos de API relacionados

Escribe los datos siguientes en el socket: un entero de 16 bits sin signo, que indica la longitud de la cadena UTF-8 especificada en bytes, seguido de la propia cadena.

Antes de escribir la cadena, el método calcula el número de bytes necesarios para representar todos los caracteres de la cadena.

Parámetros

Elementos de API relacionados

Escribe una cadena UTF-8 en el socket.

Parámetros

Elementos de API relacionados

Se distribuye cuando el servidor cierra la conexión de socket.

El evento close sólo se distribuye si el servidor cierra la conexión; no se distribuye al llamar al método Socket.close().

Este evento tiene las propiedades siguientes:

Se distribuye cuando se establece una conexión de red.

Este evento tiene las propiedades siguientes:

Se distribuye cuando se produce un error de entrada o salida que provoca que una operación de carga o de envío se realice incorrectamente.

Este evento tiene las propiedades siguientes:

Se distribuye cuando un socket mueve datos de su búfer de escritura a la capa de transporte de redes

Distribuye si una llamada a Socket.connect() intenta conectar con un servidor prohibido del entorno limitado de seguridad del elemento que realiza la llamada o con un puerto inferior al 1024 y no existe ningún archivo de política de socket para permitir dicha conexión.

Nota: en una aplicación de AIR, el contenido que se ejecuta en el entorno limitado de seguridad de la aplicación puede conectar cualquier ningún servidor y número de puerto sin un archivo de política de socket.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando el socket ha recibido datos.

Los datos recibidos por el socket permanecen en el socket hasta que se lee. No tiene que leer todos los datos disponibles durante el controlador de este evento.

Los eventos de tipo socketData no utilizan la propiedad ProgressEvent.bytesTotal.

Este evento tiene las propiedades siguientes:

1. El constructor crea una instancia de CustomSocket denominada socket y transfiere el nombre de host localhost y el puerto 80 como argumentos. Debido a que CustomSocket amplía Socket, con una llamada a super() se llama al constructor de Socket.
2. A continuación, el ejemplo llama al método configureListeners(), que añade detectores para eventos Socket.
3. Finalmente, el método de socket connect() se llama conlocalhost como nombre de host y 80 como número de puerto.

Nota: para ejecutar el ejemplo, necesita un servidor que se ejecute en el mismo dominio en el que reside el archivo SWF (en el ejemplo, localhost) y que detecte en el puerto 80.

package {
    import flash.display.Sprite;

    public class SocketExample extends Sprite {
        private var socket:CustomSocket;
        
        public function SocketExample() {
            socket = new CustomSocket("localhost", 80);
        }
    }
}

import flash.errors.*;
import flash.events.*;
import flash.net.Socket;

class CustomSocket extends Socket {
    private var response:String;

    public function CustomSocket(host:String = null, port:uint = 0) {
        super();
        configureListeners();
        if (host && port)  {
            super.connect(host, port);
        }
    }

    private function configureListeners():void {
        addEventListener(Event.CLOSE, closeHandler);
        addEventListener(Event.CONNECT, connectHandler);
        addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);
    }

    private function writeln(str:String):void {
        str += "\n";
        try {
            writeUTFBytes(str);
        }
        catch(e:IOError) {
            trace(e);
        }
    }

    private function sendRequest():void {
        trace("sendRequest");
        response = "";
        writeln("GET /");
        flush();
    }

    private function readResponse():void {
        var str:String = readUTFBytes(bytesAvailable);
        response += str;
    }

    private function closeHandler(event:Event):void {
        trace("closeHandler: " + event);
        trace(response.toString());
    }

    private function connectHandler(event:Event):void {
        trace("connectHandler: " + event);
        sendRequest();
    }

    private function ioErrorHandler(event:IOErrorEvent):void {
        trace("ioErrorHandler: " + event);
    }

    private function securityErrorHandler(event:SecurityErrorEvent):void {
        trace("securityErrorHandler: " + event);
    }

    private function socketDataHandler(event:ProgressEvent):void {
        trace("socketDataHandler: " + event);
        readResponse();
    }
}