TextLine  - AS3

Gibt die Anzahl der Pixel von der Grundlinie zur Spitze des höchsten Zeichens in der Zeile an. Für eine TextLine, die nur ein Grafikelement enthält, wird ascent auf 0 gesetzt.

Die Anzahl der Atome in der Zeile, die der Anzahl der nicht weiter teilbaren Elemente einschließlich Leerzeichen und Grafikelemente entspricht.

Gibt die Anzahl der Pixel von der Grundlinie zum unteren Rand der längsten Unterlänge in der Zeile an. Für eine TextLine, die nur ein Grafikelement enthält, wird descent auf 0 gesetzt.

Gibt an, ob die Textzeile Grafikelemente enthält.

Verwandte API-Elemente

Gibt an, ob die Textzeile Tabulatoren enthält.

Ein Vektor, der die TextLineMirrorRegion-Objekte enthält, oder null, wenn keine vorhanden sind.

Verwandte API-Elemente

Die nächste TextLine im TextBlock oder null, wenn die aktuelle Zeile die letzte Zeile im Block ist oder die „validity“ der Zeile TextLineValidity.STATIC ist.

Verwandte API-Elemente

Die vorherige TextLine im TextBlock oder null, wenn dies die erste Zeile im Block ist oder die „validity“ der Zeile TextLineValidity.STATIC ist.

Verwandte API-Elemente

Die Länge des unformatierten Texts im Textblock, der zur Zeile wurde, einschließlich der U+FDEF-Zeichen, die Grafikelemente repräsentieren, und der nachgestellten Leerzeichen, die Teil der Zeile sind, aber nicht angezeigt werden.

Verwandte API-Elemente

Die Breite, die für die TextBlock.createTextLine()-Methode angegeben wurde, als diese die Zeile erstellt hat. Dieser Wert ist hilfreich, wenn eine Änderung einen neuen Zeilenumbruch erfordert.

Verwandte API-Elemente

Der TextBlock, der diese Textzeile enthält, oder null, falls die Gültigkeit der Zeile TextLineValidity.STATIC ist, was bedeutet, dass die Verbindung zwischen der Zeile und dem TextBlock getrennt wurde.

Verwandte API-Elemente

Der Index des ersten Zeichens der Zeile im unformatierten Text des Textblocks.

Verwandte API-Elemente

Die logische Höhe der Textzeile, die der Summe von ascent + descent entspricht. Um die Inked-Höhe zu erhalten, greifen Sie auf die vererbte height-Eigenschaft zu.

Der Wert wird berechnet aus dem Unterschied zwischen den Grundlinien, die die Zeile eingrenzen, entweder ideo top/bottom oder ascent/descent, je nachdem, ob TextBlock.baselineZero ideo ist oder nicht. Grafikelemente werden beim Berechnen dieser Grundlinien nicht berücksichtigt.

Verwandte API-Elemente

Die logische Breite der Textzeile; dies ist die Breite, die die Text-Engine für das Zeilenlayout verwendet. Durch den Zugriff auf die vererbte width-Eigenschaft wird die tatsächliche Breite des Begrenzungsrahmens aller gezeichneten Pixel abgerufen.

Verwandte API-Elemente

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Legt die Anzahl der Pixel von der Grundlinie bis zum oberen Rand des höchsten Zeichens bzw. der höchsten Grafik auf der Zeile fest.

Legt die Anzahl der Pixel von der Grundlinie bis zur Unterseite des längsten Unterlängenzeichens oder der Grafik auf der Zeile fest.

Die logische Gesamthöhe der Textzeile, die der Summe von totalAscent + totalDescent entspricht.

Die Breite der Zeile, wenn dieser kein Blocksatz zugewiesen wäre. Bei Text ohne Blocksatz stimmt dieser Wert mit textWidth überein. Bei Text im Blocksatz gibt dieser Wert an, welche Länge der Text ohne Blocksatz hätte, und textWidth stellt die tatsächliche Zeilenbreite dar. Wenn beispielsweise der folgende String im Blocksatz steht und mit der Breite 500 an TextBlock.createTextLine() übergeben wird, hat er eine tatsächliche Breite von 500, aber die Breite ohne Blocksatz beträgt 268,9921875.

Verwandte API-Elemente

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Ermöglicht der Anwendung, beliebige Daten mit der Textzeile zu verknüpfen.

Gibt die aktuelle Gültigkeit der Textzeile an. Werte für diese Eigenschaft sind in der TextLineValidity-Klasse enthalten. Die Regeln für das Einstellen dieser Eigenschaft lauten:

Eine Zeile gilt als USER_INVALID, wenn die Gültigkeit auf einen String eingestellt ist, der kein Mitglied von TextLineValidity ist. USER_INVALID ist hier eine Abstraktion, um jeden derartigen Wert darzustellen.

Wenn der Inhalt des TextBlock geändert wird, kennzeichnet die Flash-Laufzeitumgebung die betroffenen Textzeilen, die vorherige Zeile und alle folgenden Zeilen als INVALID. Die vorherige Zeile muss als ungültig gekennzeichnet werden, wenn eine Änderung zulässt, dass die vorherige Zeile einen Teil des Inhalts aufnimmt, der sich ursprünglich in der ersten betroffenen Zeile befand.

Neu umbrochene Zeilen sind immer VALID. Die Flash-Laufzeitumgebung kann nachfolgende Zeilen von VALID zu POSSIBLY_INVALID oder INVALID ändern. Zeilen mit der Gültigkeit POSSIBLY_INVALID können zu VALID geändert werden, falls die Zeilenumbrüche übereinstimmen, oder zu INVALID, falls dies nicht der Fall ist.

Anwendungscode kann Zeilen mit der Gültigkeit VALID zu INVALID oder USER_INVALID ändern und Zeilen mit der Gültigkeit USER_INVALID als VALID kennzeichnen. Anwendungscode kann Zeilen nicht als POSSIBLY_INVALID kennzeichnen.

Anwendungscode kann beliebige Zeilen als STATIC kennzeichnen. Dadurch wird das block-Mitglied null. Alle Grafikelemente in einer STATIC-Textzeile werden entfernt und erhalten neue übergeordnete Elemente, wenn sie Teil einer Textzeile sind, die aus dem Textblock umbrochen wurde, aus dem die STATIC-Textzeile ursprünglich stammt.

Verwandte API-Elemente

Gibt den zugrundeliegenden Inhalt der TextLine als XML-String aus. Dies kann beim automatischen Testen hilfreich sein. Informationen zu Text, Formatierung und Layout sind enthalten.

Nachstehend wird die Ausgabe beschrieben:

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Hinweis: Inhalt und Format der Ausgabe dieser Methode können in der Zukunft geändert werden. Adobe garantiert nicht die Abwärtskompatibilität dieser Methode.

Verwandte API-Elemente

Diese Methode ist veraltet und hat keine Auswirkungen. Atomdaten sind komprimiert und spielen deshalb beim Verwalten der Speichereffizienz keine Rolle.

Verwandte API-Elemente

Ruft die bidirektionale Ebene des Atoms an der angegebenen Indexposition ab. Der Wert wird anhand einer Kombination der Eigenschaft TextBlock.bidiLevel und der bidirektionalen Unicode-Eigenschaften der Zeichen, aus denen sich die Zeile zusammensetzt, bestimmt.

Wenn beispielsweise ein Textblock mit hebräischem Text beginnt, setzen Sie TextBlock.bidiLevel auf 1, womit „von rechts nach links“ als Standard festgesetzt wird. Enthält der Text ein Zitat in Englisch (von links nach rechts), hat dieser Text die AtomBidiLevel-Einstellung 2. Kommt im englischen Text eine arabische Textstelle vor (von rechts nach links), lautet die AtomBidiLevel-Einstellung für diese Stelle 3. Wenn im arabischen Text eine Zahl (von links nach rechts) genannt wird, lautet die AtomBidiLevel-Einstellung für diese Zahl 4. Es ist nicht von Bedeutung, in welcher Zeile die Atome letztendlich auftreten. Die hebräischen Atome haben die AtomBidiLevel-Einstellung 1, die englischen Atome haben die AtomBidiLevel-Einstellung 2, die arabischen Atome haben die AtomBidiLevel-Einstellung 3 und die Zahlenatome haben die AtomBidiLevel-Einstellung 4.

Parameter

Verwandte API-Elemente

Ruft die Grenzen des Atoms beim angegebenen Index in Relation zur Textzeile ab. Die Grenzen des angegebenen Atoms bestehen aus dessen horizontaler Position (x) in der Zeile, seiner vertikalen Position in der Zeile (y), seiner Breite (w) und seiner Höhe (h). Alle Werte werden in Pixeln angegeben.

Parameter

Ruft die Mitte des Atoms gemessen entlang der Grundlinie beim angegebenen Index ab.

Parameter

Ruft die Grafik des Atoms beim angegebenen Index ab, oder null, wenn es sich bei dem Atom um ein Zeichen handelt.

Parameter

Gibt den Index des Atoms zurück, das das durch den charIndex-Parameter angegebene Zeichen enthält, oder -1, wenn das Zeichen zu keinem Atom in der Zeile gehört. Der charIndex ist relativ zum gesamten Inhalt des Textblocks, der die Zeile enthält.

Parameter

Gibt den Index des Atoms bei dem durch den x- und yParameter angegebenen Punkt zurück, oder -1, wenn sich an diesem Punkt kein Atom befindet.

Diese Methode verwendet globale Koordinaten und kann somit leicht mit den Eigenschaften MouseEvent.stageX und der MouseEvent.stageY kombiniert werden.

Parameter

Ruft den Textblock-Anfangsindex des Atoms beim angegebenen Index ab.

Parameter

Ruft den Textblock-Endindex des Atoms beim angegebenen Index ab.

Parameter

Ruft die Drehung des Atoms beim angegebenen Index ab. Für diese Eigenschaft werden TextRotation-Konstanten verwendet. Die Drehung des Atoms ergibt sich aus den kumulativen Drehungen des Elements und der Zeile. Dies dient hauptsächlich zur Einstellung der Orientierung der Einfügemarke bei der Interaktion mit einer TextLine.

Parameter

Verwandte API-Elemente

Gibt an, ob es links neben dem Atom beim angegebenen Index eine Wortgrenze gibt. Wortgrenzen werden anhand der Unicode-Eigenschaften der Zeichen, aus denen die Zeile besteht, bestimmt.

Parameter

Ruft die Position der angegebenen Grundlinie in Relation zu TextBlock.baselineZero ab.

Parameter

Verwandte API-Elemente

Gibt die erste TextLineMirrorRegion in der Zeile zurück, deren mirror-Eigenschaft mit der des vom mirror-Parameter angegebenen übereinstimmt, oder null, falls es keine Übereinstimmung gibt.

Auch ein einzelnes TextElement kann je nach bidirektionaler Ebene und Zeilenumbruch mehrere TextLineMirrorRegion-Objekte in einer oder mehreren Zeilen produzieren. Die nextRegion- und previousRegion-Eigenschaft verknüpfen alle Spiegelbereiche, die aus einem Textelement erstellt wurden.

Parameter

Verwandte API-Elemente

Der Höchstwert der angeforderten Breite einer Textzeile in Pixel. Die TextBlock.createTextLine()-Methode verwendet diese Konstante als Standardwert für den width-Parameter, sofern kein Wert angegeben wird.

Verwandte API-Elemente

1. Fügen Sie die NumericStepper-Komponente zur Bibliothek hinzu.
2. Speichern Sie diesen Code unter „TextLineExample.as“ im gleichen Verzeichnis wie die FLA-Datei.
3. Setzen Sie die Klasse im Eigenschaftenfenster der FLA-Datei auf „TextLineExample“.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}