TextBlock  - AS3

Gibt an, dass Sie das Bildschirmerscheinungsbild auf Kosten der WYSIWYG-Drucktreue verbessern möchten (WYSIWYG = What you see is what you get, engl. für Was Sie sehen, ist das, was Sie bekommen). Für Plattformen und Schriftarten, die die Subpixel-Glyphpositionierung während des Rendering nicht unterstützen, aber nicht-lineares Skalieren unterstützen, wird die Verwendung dieser Metriken auf Kosten der WYSIWYG-Drucktreue, besonders für kleine Schriften, aktiviert, wenn diese Eigenschaft auf den Wert true eingestellt wird. Die nicht-lineare Schriftskalierung wird durch selektives Skalieren der Breite einzelner Glyphen erzielt, um unansehnliche Lücken, die durch Ausrichten an Pixeln entstehen, auszugleichen.

Auf Plattformen, die die Subpixel-Glyphpositionierung unterstützen, wird dieser Kennzeichner ignoriert.

Dieser Kennzeichner hat keine Auswirkungen auf das Rendering eingebetteter Schriftarten

Der Standardwert ist true.

Die Schriftart, die verwendet wird, um die Grundlinie für alle im Block erstellten Zeilen festzulegen, unabhängig von ihrem Inhalt. Grundlinien sind von der Schriftart und der Schriftgröße abhängig.

Der Standardwert ist null. Wenn die Grundlinienschriftart null ist, wird die Grundlinienschriftgröße ignoriert und die Grundlinie für jede gegebene Zeile basiert auf der Schriftart und -größe des größten Texts in der Zeile. Wenn Sie sowohl baselineFontDescription als auch baselineFontSize, angeben, bestimmen sie die Grundlinien für alle Zeilen im Textblock, unabhängig von ihrem Inhalt. Diese Kombination ist meistens in der asiatischen Typografie hilfreich.

Verwandte API-Elemente

Die Schriftgröße wird verwendet, um die Grundlinien der im Block erstellten Zeilen zu berechnen. Grundlinien sind von der Schriftart und der Schriftgröße abhängig.

Der Standardwert ist 12. Wenn die Grundlinienschriftart null ist, wird die Grundlinienschriftgröße ignoriert und die Grundlinie für jede gegebene Zeile basiert auf der Schriftart und -größe des größten Texts in der Zeile.

Verwandte API-Elemente

Gibt an, welche Grundlinie sich für Zeilen, die in diesem Block erstellt werden, bei y=0 befindet. Gültige Werte für diese Eigenschaft enthalten die Mitglieder der TextBaseline-Klasse.

Der Standardwert ist TextBaseline.ROMAN.

Wenn Sie Werte für diese Eigenschaft definieren möchten, verwenden Sie die folgenden Stringwerte:

Verwandte API-Elemente

Gibt die bidirektionale Absatzeinbettungsebene des Textblocks an. Im Allgemeinen sollten Sie 0 für LTR-Absätze (von links nach rechts; Englisch, Japanisch usw.) und 1 für RTL-Absätze (von rechts nach links; Arabisch, Hebräisch usw.) verwenden. Die Verwendung von anderen Werten als 0 oder 1 ist für Sonderfälle reserviert - siehe UAX#9, "Unicode Bidirectional Algorithm" (http://www.unicode.org/reports/tr9/).

Der Standardwert ist 0.

Wenn Sie die bidiLevel-Eigenschaft ändern, ändert sich die Gültigkeit aller zuvor umbrochener Zeilen zu TextLineValidity.INVALID. Nachdem bidiLevel geändert wurde, entspricht die firstInvalidLine-Eigenschaft der firstLine-Eigenschaft und Sie müssen alle Zeilen im TextBlock neu umbrechen.

Verwandte API-Elemente

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Enthält den Inhalt des Textblocks. Da ContentElement eine Basisklasse ist, weisen Sie content eine Instanz einer ContentElement-Unterklasse zu: TextElement, GraphicElement oder GroupElement. Ein TextElement enthält einen String, ein GraphicElement enthält ein DisplayObject und ein GroupElement enthält ein Vektor-Objekt, das ein oder mehrere TextElement-, GraphicElement- oder andere GroupElement-Objekte enthält. Verwenden Sie ein TextElement für einen Absatz mit homogenem Text, ein GraphicElement für eine Grafik und ein GroupElement für eine Kombination aus Text- und Grafikelemente oder mehreren Instanzen desselben Elements sowie anderen GroupElement-Objekten.

Der Standardwert ist null.

Wenn Sie die content-Eigenschaft ändern, ändert sich die Gültigkeit aller zuvor erstellten Zeilen zu TextLineValidity.INVALID. Nachdem content geändert wurde, entspricht die firstInvalidLine-Eigenschaft der firstLine-Eigenschaft und Sie müssen alle Zeilen im TextBlock neu umbrechen.

Verwandte API-Elemente

Identifiziert die erste Zeile im Textblock, in der TextLine.validity nicht TextLineValidity.VALID entspricht.

Der Standardwert ist null.

Verwandte API-Elemente

Die erste TextLine im TextBlock, falls vorhanden.

Der Standardwert ist null.

Verwandte API-Elemente

Die letzte TextLine im TextBlock, falls vorhanden.

Der Standardwert ist null.

Verwandte API-Elemente

Dreht die Textzeilen im Textblock als eine Einheit. Rufen Sie die createTextLine()-Methode auf, nachdem Sie lineRotation eingestellt haben, damit dies wirksam wird. Der Standardwert ist TextRotation.ROTATE_0.

Die endgültige Drehung einer Glyphe richtet sich nach den Werten für ElementFormat.textRotation, ContentElement.textRotation und TextBlock.lineRotation.

TextBlock.lineRotation wird normalerweise für asiatischen Text verwendet. Um einen Absatz mit senkrechtem japanischen Text zu erstellen, gehen Sie folgendermaßen vor:

1. Setzen Sie die TextBlock.lineRotation-Eigenschaft auf TextRotation.ROTATE_90.
2. Übernehmen Sie für die ElementFormat.textRotation-Eigenschaft des Inhalts die Standardeinstellung TextRotation.AUTO.

Verwenden Sie die folgenden Konstanten, die in der TextRotation-Klasse definiert sind, um den Wert für diese Eigenschaft einzustellen:

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Gibt die Tabstopps für den Text im Textblock in Form eines Vektors von TabStop-Objekten an.

Der Standardwert ist null, was bedeutet, dass keine Tabstopps angegeben wurden. Wenn keine Tabstopps angegeben wurden (oder der Einfügepunkt hinter dem letzten angegebenen Tabstopp liegt), erstellt die Laufzeitumgebung automatisch Halbzoll-Tabs.

Wenn die tabStops-Eigenschaft eingestellt ist, fertigt der TextBlock eine Kopie des Vektors zur internen Verwendung an. Änderungen am ursprünglichen Vektor oder seinem Inhalt wirken sich nicht auf den TextBlock aus. Bei einer Abfrage der tabStops-Eigenschaft wird eine Kopie des internen Vektors zurückgegeben. Auch hier gilt, dass sich Änderungen am zurückgegebenen Vektor oder seinem Inhalt nicht auf den TextBlock auswirken.

Verwandte API-Elemente

Gibt den TextJustifier an, der bei der Zeilenerstellung verwendet werden soll.

Der Standardwert ist ein konstruiertes TextJustifier-Standardobjekt.

Wenn die textJustifier-Eigenschaft eingestellt ist, fertigt der TextBlock eine Kopie des Objekts zur internen Verwendung an. Änderungen am Originalobjekt wirken sich nicht auf den TextBlock aus. Bei einer Abfrage der textJustifier-Eigenschaft wird eine Kopie des internen Objekts zurückgegeben. Auch hier gilt, dass sich Änderungen am zurückgegebenen Objekt nicht auf den TextBlock auswirken.

Verwandte API-Elemente

Gibt das Ergebnis einer createTextLine()-Methode an. Beim Ändern des Blockinhalts werden zuvor umbrochene Zeilen ungültig und diese Eigenschaft wird auf null zurückgesetzt.

Der Standardwert ist null.

Werte für diese Eigenschaft sind in TextLineCreationResult enthalten.

Verwandte API-Elemente

Ermöglicht der Anwendung, beliebige Daten mit dem Textblock zu verknüpfen. Bei den Daten kann es sich um Informationen zum Inhalt handeln (z. B. Änderungsdatum, Name des Verfassers) oder um zwischengespeicherte Daten, die bei der Verarbeitung benötigt werden.

Erstellt ein TextBlock-Objekt.

Verwandte API-Elemente

Weist den Textblock an, eine Textzeile aus dem Inhalt zu erstellen, die beim durch den previousLine-Parameter angegebenen Punkt beginnt und am vom width-Parameter angegebenen Punkt umbrochen wird. Die Textzeile ist ein TextLine-Objekt, das Sie der Anzeigeliste hinzufügen können.

Zeilenumbrüche in einem Bereich eines Textblocks, auf den bereits Zeilenumbrüche angewendet wurden, kann die Gültigkeit der Zeilen in und hinter dem Bereich mit den Zeilenumbrüchen ändern. Der Status der Zeilen kann sich von VALID zu INVALID oder POSSIBLY_INVALID ändern. Wenn eine neu umbrochene Zeile genau an einer zuvor umbrochenen Zeile ausgerichtet wird, die den Status POSSIBLY_INVALID hat, ändern sich diese zuvor umbrochene und alle folgenden Zeilen mit dem Status POSSIBLY_INVALID wieder zurück zum Status VALID. Die Gültigkeit von Zeilen mit Werten, die nicht TextLineValidity angehören, ändert sich nicht in VALID, kann sich allerdings in INVALID ändern. Überprüfen Sie die firstInvalidLine-Eigenschaft, nachdem der Textblock geändert wurde, um zu sehen, wo mit dem Neu-Umbruch von Textzeilen zu beginnen oder fortzufahren ist.

Sie können künstliche Wortumbrüche erstellen, indem Sie das ZWSP-Zeichen (Unicode Zero Width Space) in den Text einfügen. Dies kann hilfreich sein für Sprachen wie zum Beispiel Thai, für die ein Wörterbuch für richtige Zeilenumbrüche erforderlich ist. Die Flash-Laufzeitumgebung enthält kein derartiges Wörterbuch.

Sofern nach dem Erstellen aller gewünschten Zeilen nicht damit zu rechnen ist, dass die Zeilen, zum Beispiel wegen der Größenänderung des Containers, wiederholt neu umbrochen werden müssen, sollte der Benutzer zum Verringern der Speicherlast die releaseLineCreationData()-Methode aufrufen, damit der Textblock die temporären Daten, die mit Zeilenumbrüchen verknüpft sind, löschen kann.

Parameter

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Gibt den zugrundeliegenden Inhalt des TextBlock als XML-String aus. Dies kann beim automatischen Testen hilfreich sein. Informationen zu Text, Formatierung und Layout sind enthalten.

Nachstehend wird die Ausgabe beschrieben:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Eine Beschreibung der Ausgabe jeder Zeile finden Sie im Abschnitt zur TextLine.dump()-Methode.

Hinweis: Inhalt und Format der Ausgabe können in der Zukunft geändert werden. Adobe garantiert nicht die Abwärtskompatibilität dieser Methode.

Verwandte API-Elemente

Sucht den Index der nächsten Atomgrenze ab dem angegebenen Zeichenindex, wobei das Zeichen beim angegebenen Index nicht eingeschlossen wird. Die Zeichen zwischen Atomgrenzen verbinden sich, um ein Atom in einer TextLine zu bilden, zum Beispiel ein „e“ mit einem dazugehörigen Akut-Zeichen.

Parameter

Verwandte API-Elemente

Sucht den Index der nächsten Wortgrenze ab dem angegebenen Zeichenindex, wobei das Zeichen beim angegebenen Index nicht eingeschlossen wird. Wortgrenzen werden aufgrund der Unicode-Eigenschaften der Zeichen bestimmt.

Parameter

Sucht den Index der vorherigen Atomgrenze bis zum angegebenen Zeichenindex, wobei das Zeichen beim angegebenen Index nicht eingeschlossen wird. Die Zeichen zwischen Atomgrenzen verbinden sich, um ein Atom in einer TextLine zu bilden, zum Beispiel ein „e“ mit einem dazugehörigen Akut-Zeichen.

Parameter

Verwandte API-Elemente

Sucht den Index der vorherigen Wortgrenze bis zum angegebenen Zeichenindex, wobei das Zeichen beim angegebenen Index nicht eingeschlossen wird. Wortgrenzen werden aufgrund der Unicode-Eigenschaften der Zeichen bestimmt.

Parameter

Gibt die TextLine zurück, die das vom charIndex-Parameter angegebene Zeichen enthält.

Parameter

Weist den Textblock an, eine vorhandene Textzeile zu verwenden, um eine Textzeile aus dem Inhalt zu erstellen, die beim durch den previousLine-Parameter angegebenen Punkt beginnt und am vom width-Parameter angegebenen Punkt umbrochen wird. Die Textzeile ist ein TextLine-Objekt, das Sie der Anzeigeliste hinzufügen können. Beim Wiederverwenden einer vorhandenen TextLine wird die Leistung verbessert, da weniger Objekte erstellt werden müssen.

Die neu erstellte textLine wird ggf. vom Textblock, in dem sie sich befindet, gelöst. Außerdem werden alle Eigenschaften, einschließlich vererbte Eigenschaften von DisplayObjectContainer, InteractiveObject und DisplayObject, auf ihre Standardwerte zurückgesetzt. Zum Schluss werden alle untergeordneten Elemente der Zeile, einschließlich Grafikelemente und andere Verzierungen, sowie alle Ereignis-Listener für die Zeile entfernt. Um die Leistung zu verbessern, wird als einzige Ausnahme von diesem vollständigen Zurücksetzen die Zeile selbst nicht von ihrem übergeordneten Element entfernt.

Zeilenumbrüche in einem Bereich eines Textblocks, auf den bereits Zeilenumbrüche angewendet wurden, kann die Gültigkeit der Zeilen in und hinter dem Bereich mit den Zeilenumbrüchen ändern. Der Status der Zeilen kann sich von VALID zu INVALID oder POSSIBLY_INVALID ändern. Wenn eine neu umbrochene Zeile genau an einer zuvor umbrochenen Zeile ausgerichtet wird, die den Status POSSIBLY_INVALID hat, ändern sich diese zuvor umbrochene und alle folgenden Zeilen mit dem Status POSSIBLY_INVALID wieder zurück zum Status VALID. Die Gültigkeit von Zeilen mit Werten, die nicht TextLineValidity angehören, ändert sich nicht in VALID, kann sich allerdings in INVALID ändern. Überprüfen Sie die firstInvalidLine-Eigenschaft, nachdem der Textblock geändert wurde, um zu sehen, wo mit dem Neu-Umbruch von Textzeilen zu beginnen oder fortzufahren ist.

Sie können künstliche Wortumbrüche erstellen, indem Sie das ZWSP-Zeichen (Unicode Zero Width Space) in den Text einfügen. Dies kann hilfreich sein für Sprachen wie zum Beispiel Thai, für die ein Wörterbuch für richtige Zeilenumbrüche erforderlich ist. Die Flash-Laufzeitumgebung enthält kein derartiges Wörterbuch.

Sofern nach dem Erstellen aller gewünschten Zeilen nicht damit zu rechnen ist, dass die Zeilen, zum Beispiel wegen der Größenänderung des Containers, wiederholt neu umbrochen werden müssen, sollte der Benutzer zum Verringern der Speicherlast die releaseLineCreationData()-Methode aufrufen, damit der Textblock die temporären Daten, die mit Zeilenumbrüchen verknüpft sind, löschen kann.

Parameter

Verwandte API-Elemente

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Weist den Textblock an, alle temporären Daten, die mit dem Erstellen von Textzeilen verknüpft sind, freizugeben. Um den von einer Anwendung belegten Arbeitsspeicher zu verringern, sollten Sie die releaseLineCreationData()-Methode aufrufen, wenn Sie mit dem Erstellen von Textzeilen in einem Textblock fertig sind. Um die Leistung beim neuen Umbrechen der Zeilen zu verbessern (zum Beispiel, wenn die Containergröße geändert wird), sollte jedoch nicht die releaseLineCreationData()-Methode aufgerufen werden. Die Anwendung ist dafür zuständig, Arbeitsspeicherlast und Leistung ins Gleichgewicht zu bringen.

Die empfohlene Vorgehensweise für Text, der wahrscheinlich nicht geändert wird, ist folgende: initialisieren Sie einen Textblock, rufen Sie die createTextLine()-Methode so oft wie möglich auf, um die gewünschte Ausgabe zu erzielen, und rufen Sie dann die releaseLineCreationData()-Methode auf.

Verwandte API-Elemente

Entfernt einen Bereich von Textzeilen aus der Liste der vom TextBlock verwalteten Zeilen. Auf diese Weise können die Zeilen aus dem Speicher entfernt werden (Garbage-Kollektor), wenn keine weiteren Verweise darauf vorhanden sind.

Setzt die textBlock-, nextLine- und previousLine-Mitglieder der entfernten Zeilen auf null. Setzt die validity der entfernten Zeilen und aller anderen Zeilen, die auf die entfernten Zeilen im TextBlock folgen, auf TextLineValidity.INVALID.

Parameter

Verwandte API-Elemente