Guide de référence ActionScript® 3.0 pour la plate-forme Adobe® Flash®
Accueil  |  Masquer la liste des packages et des classes |  Packages  |  Classes  |  Nouveautés  |  Index  |  Annexes  |  Pourquoi existe-t-il du contenu en anglais ?
Filtres : Récupération des données du serveur...
Récupération des données du serveur...
flash.text 

TextField  - AS3

Packageflash.text
Classepublic class TextField
HéritageTextField Inheritance InteractiveObject Inheritance DisplayObject Inheritance EventDispatcher Inheritance Object
Sous-classes FlexTextField

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

La classe TextField permet de créer des objets d’affichage et de saisie de texte. Vous pouvez donner un nom d’occurrence à un champ de texte dans l’inspecteur des propriétés, puis utiliser les méthodes et les propriétés de la classe TextField pour la modifier avec ActionScript. Les noms d’occurrence de TextField s’affichent dans l’explorateur d’animations et dans la boîte de dialogue Insérer un chemin cible du panneau Actions.

Pour créer un champ de texte de façon dynamique, utilisez le constructeur TextField().

Les méthodes de la classe TextField permettent de définir, sélectionner et manipuler du texte dans un champ de texte dynamique ou de saisie que vous créez en cours de création ou à l’exécution.

ActionScript offre différentes manières de formater vos textes à l’exécution. La classe TextFormat permet de définir le formatage des caractères et des paragraphes pour les objets TextField. Vous pouvez appliquer des feuilles de style en cascade (CSS) aux champs de texte à l’aide de la propriété TextField.styleSheet et de la classe StyleSheet. Vous pouvez utiliser les feuilles de style en cascade pour les appliquer aux balises HTML intégrées, définir de nouvelles balises de format ou appliquer des styles. Vous pouvez affecter du texte au format HTML, qui utilise éventuellement des feuilles de style en cascade, directement à un champ de texte. Le texte HTML que vous affectez à un champ de texte peut contenir des supports intégrés (clips, fichiers SWF, GIF, PNG et JPEG). Le texte entoure le média intégré comme dans un document HTML dans un navigateur Web.

Flash Player prend en charge un sous-ensemble de balises HTML à utiliser pour formater le texte. Vous trouverez la liste des balises HTML prises en charge dans la description de la propriété htmlText.

Consulter les exemples

Plus d’exemples

Informations complémentaires

Eléments de l’API associés



Propriétés publiques
 PropriétéDéfini par
 InheritedaccessibilityImplementation : AccessibilityImplementation
Implémentation d’accessibilité (AccessibilityImplementation) actuelle pour cette occurrence d’InteractiveObject.
InteractiveObject
 InheritedaccessibilityProperties : AccessibilityProperties
Options d’accessibilité actuelles de l’objet d’affichage.
DisplayObject
 Inheritedalpha : Number
Indique la valeur de transparence alpha de l’objet spécifié.
DisplayObject
  alwaysShowSelection : Boolean
Lorsque défini sur true et si le champ de texte n’a pas le focus, Flash Player sélectionne le contenu du champ de texte en gris.
TextField
  antiAliasType : String
Type d’anticrènelage appliqué à ce champ de texte.
TextField
  autoSize : String
Commande le dimensionnement et l’alignement automatiques des champs de texte.
TextField
  background : Boolean
Spécifie si le champ de texte a un remplissage d’arrière-plan.
TextField
  backgroundColor : uint
Couleur de l’arrière-plan du champ de texte.
TextField
 InheritedblendMode : String
Valeur de la classe BlendMode qui spécifie le mode de fusion à utiliser.
DisplayObject
 InheritedblendShader : Shader
[écriture seule] Définit un shader utilisé pour la fusion de l’arrière-plan et du premier plan.
DisplayObject
  border : Boolean
Spécifie si le champ de texte comporte une bordure.
TextField
  borderColor : uint
Couleur de la bordure du champ de texte.
TextField
  bottomScrollV : int
[lecture seule] Entier (index basé sur 1) qui indique la ligne la plus basse visible dans le champ de texte spécifié.
TextField
 InheritedcacheAsBitmap : Boolean
Si la valeur true est définie, les moteurs d’exécution de Flash placent en mémoire cache une version bitmap interne de l’objet d’affichage.
DisplayObject
 Inherited    cacheAsBitmapMatrix : Matrix
S’il n’est pas nul, cet objet Matrix définit le mode de rendu d’un objet d’affichage lorsque cacheAsBitmap est définie sur true.
DisplayObject
  caretIndex : int
[lecture seule] L’index de la position du point d’insertion (caret).
TextField
  condenseWhite : Boolean
Valeur booléenne qui indique si l’espace blanc supplémentaire (espaces, saut de ligne, etc.) est supprimé dans un champ de texte HTML.
TextField
 Inheritedconstructor : Object
Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.
Object
 InheritedcontextMenu : NativeMenu
Spécifie le menu contextuel associé à l’objet.
InteractiveObject
  defaultTextFormat : flash.text:TextFormat
Spécifie le format appliqué au texte qui vient d’être inséré, notamment au texte saisi par un utilisateur ou inséré à l’aide de la méthode replaceSelectedText().
TextField
  displayAsPassword : Boolean
Indique si le champ de texte est un champ de texte de mot de passe.
TextField
 InheriteddoubleClickEnabled : Boolean
Spécifie si l’objet reçoit les événements doubleClick.
InteractiveObject
  embedFonts : Boolean
Spécifie si le rendu doit utiliser des polices vectorielles incorporées.
TextField
 Inheritedfilters : Array
Tableau indexé contenant tous les objets filtre actuellement associés à l’objet d’affichage.
DisplayObject
 InheritedfocusRect : Object
Spécifie si l’objet affiche un rectangle de focus.
InteractiveObject
  gridFitType : String
Type d’adaptation à la grille appliqué à ce champ de texte.
TextField
 Inheritedheight : Number
Indique la hauteur de l’objet d’affichage, en pixels.
DisplayObject
  htmlText : String
Contient la représentation HTML du contenu du champ de texte.
TextField
  length : int
[lecture seule] Nombre de caractères d’un champ de texte.
TextField
 InheritedloaderInfo : LoaderInfo
[lecture seule] Renvoie un objet LoaderInfo qui contient des informations relatives au chargement du fichier auquel appartient cet objet d’affichage.
DisplayObject
 Inheritedmask : DisplayObject
L’objet d’affichage appelant est masqué par l’objet mask spécifié.
DisplayObject
  maxChars : int
Le nombre maximum de caractères que le champ de texte peut contenir, tels que saisis par un utilisateur.
TextField
  maxScrollH : int
[lecture seule] Valeur maximale de scrollH.
TextField
  maxScrollV : int
[lecture seule] Valeur maximale de scrollV.
TextField
 InheritedmetaData : Object
Obtient les données d’objet de métadonnées de l’occurrence DisplayObject si les données d’meta a été stockée près de la l’occurrence de cette DisplayObject dans le fichier SWF à l’aide d’une balise de4 PlaceObject.
DisplayObject
 InheritedmouseEnabled : Boolean
Spécifie si l’objet reçoit des messages de la souris ou d’un autre périphérique de saisie utilisateur.
InteractiveObject
  mouseWheelEnabled : Boolean
Valeur booléenne qui indique si Flash Player fait automatiquement défiler les champs de texte multiligne lorsque l’utilisateur clique sur le champ de texte et actionne la molette de sa souris.
TextField
 InheritedmouseX : Number
[lecture seule] Indique la coordonnée x de la souris ou ou la position du périphérique de saisie utilisateur, en pixels.
DisplayObject
 InheritedmouseY : Number
[lecture seule] Indique la coordonnée y de la souris ou la position du périphérique de saisie utilisateur, en pixels.
DisplayObject
  multiline : Boolean
Indique si le champ est un champ de texte multiligne.
TextField
 Inheritedname : String
Indique le nom d’occurrence de DisplayObject.
DisplayObject
 InheritedneedsSoftKeyboard : Boolean
Indique si un clavier virtuel (clavier logiciel à l’écran) doit s’afficher lorsque cette occurrence d’InteractiveObject reçoit le focus.
InteractiveObject
  numLines : int
[lecture seule] Définit le nombre de lignes de texte d’un champ multiligne.
TextField
 InheritedopaqueBackground : Object
Indique si l’objet d’affichage est opaque avec une couleur d’arrière-plan spécifique.
DisplayObject
 Inheritedparent : DisplayObjectContainer
[lecture seule] Indique l’objet DisplayObjectContainer qui contient l’objet d’affichage.
DisplayObject
  restrict : String
Indique le jeu de caractères qu’un utilisateur peut rentrer dans le champ de texte.
TextField
 Inheritedroot : DisplayObject
[lecture seule] Pour un objet d’affichage résidant dans un fichier SWF chargé, la propriété root correspond à l’objet d’affichage de premier niveau dans la partie de la structure arborescente de la liste d’affichage représentée par ce fichier.
DisplayObject
 Inheritedrotation : Number
Indique la rotation de l’occurrence de DisplayObject, en degrés, à partir de son orientation d’origine.
DisplayObject
 InheritedrotationX : Number
Indique la rotation de l’axe des x de l’occurrence DisplayObject, en degrés, à partir de son orientation d’origine par rapport au conteneur 3D parent.
DisplayObject
 InheritedrotationY : Number
Indique la rotation de l’axe des y de l’occurrence DisplayObject, en degrés, à partir de son orientation d’origine par rapport au conteneur 3D parent.
DisplayObject
 InheritedrotationZ : Number
Indique la rotation de l’axe des z de l’occurrence DisplayObject, en degrés, à partir de son orientation d’origine par rapport au conteneur 3D parent.
DisplayObject
 Inheritedscale9Grid : Rectangle
Grille de mise à l’échelle en vigueur.
DisplayObject
 InheritedscaleX : Number
Indique l’échelle horizontale (pourcentage) de l’objet telle qu’elle est appliquée à partir du point d’alignement.
DisplayObject
 InheritedscaleY : Number
Indique l’échelle verticale (pourcentage) de l’objet telle qu’elle est appliquée à partir du point d’alignement.
DisplayObject
 InheritedscaleZ : Number
Indique l’échelle de profondeur (pourcentage) de l’objet tel qu’elle est appliquée à partir du point d’alignement.
DisplayObject
  scrollH : int
Position de défilement horizontal actuelle.
TextField
 InheritedscrollRect : Rectangle
Cadre de sélection du défilement de l’objet d’affichage.
DisplayObject
  scrollV : int
La position verticale du texte dans un champ de texte.
TextField
  selectable : Boolean
Une valeur booléenne qui indique si le champ de texte peut être sélectionné.
TextField
  selectionBeginIndex : int
[lecture seule] Valeur d’index de base zéro du premier caractère de la sélection actuelle.
TextField
  selectionEndIndex : int
[lecture seule] Valeur d’index de base zéro du dernier caractère de la sélection actuelle.
TextField
  sharpness : Number
Netteté des bords du glyphe dans ce champ de texte.
TextField
 Inherited    softKeyboard : String
Contrôle l’aspect du clavier logiciel.
InteractiveObject
 InheritedsoftKeyboardInputAreaOfInterest : Rectangle
Définit la zone qui doit rester à l’écran lorsqu’un clavier logiciel s’affiche (non disponible sur iOS)
InteractiveObject
 Inheritedstage : Stage
[lecture seule] Scène de l’objet d’affichage.
DisplayObject
  styleSheet : StyleSheet
Associe une feuille de style au champ de texte.
TextField
 InheritedtabEnabled : Boolean
Indique si cet objet est spécifié dans l’ordre de tabulation.
InteractiveObject
 InheritedtabIndex : int
Spécifie l’ordre de tabulation des objets dans un fichier SWF.
InteractiveObject
  text : String
Une chaîne qui correspond au texte du champ de texte.
TextField
  textColor : uint
Couleur du texte dans un champ de texte, au format hexadécimal.
TextField
  textHeight : Number
[lecture seule] Hauteur du texte en pixels.
TextField
  textInteractionMode : String
[lecture seule] Propriété du mode d’interaction ; la valeur par défaut est TextInteractionMode.NORMAL.
TextField
  textWidth : Number
[lecture seule] Largeur du texte en pixels.
TextField
  thickness : Number
Epaisseur des bords du glyphe dans ce champ de texte.
TextField
 Inheritedtransform : flash.geom:Transform
Objet dont les propriétés se rapportent à la matrice, à la transformation des couleurs et aux limites des pixels d’un objet d’affichage.
DisplayObject
  type : String
Type du champ de texte.
TextField
  useRichTextClipboard : Boolean
Spécifie si le formatage du texte peut être copié et collé en même temps que le corps du texte.
TextField
 Inheritedvisible : Boolean
Indique si l’objet d’affichage est visible ou non.
DisplayObject
 Inheritedwidth : Number
Indique la largeur de l’objet d’affichage, en pixels.
DisplayObject
  wordWrap : Boolean
Valeur booléenne indiquant si le champ de texte comporte un retour à la ligne.
TextField
 Inheritedx : Number
Indique la coordonnée x de l’occurrence de DisplayObject par rapport aux coordonnées locales de l’objet DisplayObjectContainer parent.
DisplayObject
 Inheritedy : Number
Indique la coordonnée y de l’occurrence de DisplayObject par rapport aux coordonnées locales de l’objet DisplayObjectContainer parent.
DisplayObject
 Inheritedz : Number
Indique la position de coordonnée z le long de l’axe des z de l’occurrence DisplayObject par rapport au conteneur 3D parent.
DisplayObject
Méthodes publiques
 MéthodeDéfini par
  
Crée une occurrence de TextField.
TextField
 Inherited
addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Enregistre un objet écouteur d’événement auprès d’un objet EventDispatcher afin que l’écouteur soit averti d’un événement.
EventDispatcher
  
Ajoute la chaîne spécifiée par le paramètre newText à la fin du texte du champ de texte.
TextField
 Inherited
Distribue un événement dans le flux d’événements.
EventDispatcher
 Inherited
getBounds(targetCoordinateSpace:DisplayObject):Rectangle
Renvoie un rectangle qui définit la zone de l’objet d’affichage relativement au système de coordonnées de l’objet targetCoordinateSpace.
DisplayObject
  
Renvoie un rectangle représentant le cadre de sélection du caractère.
TextField
  
Renvoie la valeur d’index de base zéro du caractère au point spécifié par les paramètres x et y.
TextField
  
En fonction d’un caractère d’index, renvoie l’index du premier caractère dans le même paragraphe.
TextField
  
Renvoie une référence DisplayObject pour l’ID donné, pour une image ou un fichier SWF qui a été ajouté à un champ de texte qui applique le format HTML à l’aide de la balise <img>.
TextField
  
Renvoie la valeur d’index de base zéro de la ligne au point spécifié par les paramètres x et y.
TextField
  
Renvoie la valeur d’index de base zéro de la ligne qui contient le caractère spécifié par le paramètre charIndex.
TextField
  
getLineLength(lineIndex:int):int
Renvoie le nombre de caractères d’une ligne de texte donnée.
TextField
  
Renvoie les informations métriques relatives à une ligne de texte donnée.
TextField
  
getLineOffset(lineIndex:int):int
Renvoie le caractère d’index du premier caractère de la ligne spécifiée par le paramètre lineIndex.
TextField
  
Renvoie le texte de la ligne spécifiée par le paramètre lineIndex.
TextField
  
En fonction d’un caractère d’index, renvoie la longueur du paragraphe qui contient le caractère donné.
TextField
 Inherited
getRect(targetCoordinateSpace:DisplayObject):Rectangle
Renvoie un rectangle qui définit les limites de l’objet d’affichage, en se basant sur le système de coordonnées défini par le paramètre targetCoordinateSpace, moins tout trait appliqué aux formes.
DisplayObject
  
getTextFormat(beginIndex:int = -1, endIndex:int = -1):flash.text:TextFormat
Renvoie un objet TextFormat qui contient des informations de formatage pour la plage de texte délimitée par les paramètres beginIndex et endIndex.
TextField
 Inherited
Convertit l’objet point des coordonnées de scène (globales) vers les coordonnées de l’objet d’affichage (locales).
DisplayObject
 Inherited
Convertit un point bidimensionnel à partir des coordonnées de scène (globales) vers les coordonnées d’un objet d’affichage tridimensionnel (locales).
DisplayObject
 Inherited
Vérifie si des écouteurs sont enregistrés auprès de l’objet EventDispatcher pour un type spécifique d’événement.
EventDispatcher
 Inherited
Indique si la propriété spécifiée d’un objet est définie.
Object
 Inherited
Evalue le cadre de sélection de l’objet d’affichage pour savoir s’il recouvre ou recoupe le cadre de sélection de l’objet d’affichage obj.
DisplayObject
 Inherited
hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean
Evalue l’objet d’affichage pour savoir s’il recouvre ou recoupe le point spécifié par les paramètres x et y.
DisplayObject
  
isFontCompatible(fontName:String, fontStyle:String):Boolean
[statique] Renvoie true si une police incorporée est disponible avec les paramètres fontName et fontStyle spécifiés, où Font.fontType est flash.text.FontType.EMBEDDED.
TextField
 Inherited
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.
Object
 Inherited
Convertit un point tridimensionnel des coordonnées de l’objet d’affichage tridimensionnel (locales) vers un point bidimensionnel dans les coordonnées de scène (globales).
DisplayObject
 Inherited
Convertit l’objet point des coordonnées de l’objet d’affichage (locales) vers les coordonnées de la scène (globales).
DisplayObject
 Inherited
Indique si la propriété spécifiée existe et est énumérable.
Object
 Inherited
removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void
Supprime un écouteur de l’objet EventDispatcher.
EventDispatcher
  
Remplace la sélection actuelle par le contenu du paramètre value.
TextField
  
replaceText(beginIndex:int, endIndex:int, newText:String):void
Remplace la plage de caractères que les paramètres beginIndex et endIndex spécifient par le contenu du paramètre newText.
TextField
 Inherited
Affiche un clavier virtuel.
InteractiveObject
 Inherited
Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.
Object
  
setSelection(beginIndex:int, endIndex:int):void
Définit comme sélectionné le texte désigné par les valeurs d’index des premier et dernier caractères, spécifiés par les paramètres beginIndex et endIndex.
TextField
  
setTextFormat(format:flash.text:TextFormat, beginIndex:int = -1, endIndex:int = -1):void
Applique à la partie sélectionnée d’un champ de texte le format spécifié par le paramètre format.
TextField
 Inherited
Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.
Object
 Inherited
Renvoie la représentation sous forme de chaîne de l’objet spécifié.
Object
 Inherited
Renvoie la valeur primitive de l’objet spécifié.
Object
 Inherited
Vérifie si un écouteur d’événement est enregistré auprès de cet objet EventDispatcher ou de ses ancêtres pour le type d’événement spécifié.
EventDispatcher
Evénements
 Evénement Synthèse Défini par
 Inherited[Evénement de diffusion] Distribué lorsque l’application Flash Player obtient le focus du système d’exploitation et devient active.EventDispatcher
 InheritedDistribué lorsqu’un objet d’affichage est ajouté à la liste d’affichage.DisplayObject
 InheritedEnvoyé lorsqu’un objet d’affichage est ajouté dans la liste d’affichage de la scène, directement ou par l’intermédiaire d’une arborescence secondaire qui contient l’objet d’affichage.DisplayObject
  Distribué après la modification d’une valeur de contrôle, contrairement à l’événement textInput, qui est distribué avant la modification de la valeur.TextField
 InheritedDistribué lorsque l’utilisateur sélectionne ’Effacer’ (ou ’Supprimer’) dans le menu contextuel.InteractiveObject
 InheritedDistribué lorsque l’utilisateur appuie sur le bouton principal de son périphérique de pointage et le relâche sur la même occurrence de InteractiveObject.InteractiveObject
 Inherited
    contextMenu
Distribué lorsque l’action d’un utilisateur active le menu contextuel associé à cet objet interactif dans une application AIR.InteractiveObject
 InheritedDistribué lorsque l’utilisateur active la combinaison de touches de raccourci propre à la plate-forme pour une opération de copie ou sélectionne "Copier" dans le menu contextuel.InteractiveObject
 InheritedDistribué lorsque l’utilisateur active la combinaison de touches de raccourci propre à la plate-forme pour une opération de coupage ou sélectionne "Couper" dans le menu contextuel.InteractiveObject
 Inherited[Evénement de diffusion] Distribué lorsque l’application Flash Player ou AIR perd le focus du système d’exploitation et devient inactive.EventDispatcher
 InheritedDistribué lorsque l’utilisateur appuie sur le bouton principal d’un périphérique de pointage et le relâche deux fois de suite sur la même occurrence d’InteractiveObject si l’indicateur doubleClickEnabled de cet objet est réglé sur true.InteractiveObject
 Inherited[événement de diffusion] Distribué lorsque la tête de lecture est placée sur une nouvelle image.DisplayObject
 Inherited[événement de diffusion] Distribué lorsque la tête de lecture quitte l’image en cours.DisplayObject
 InheritedDistribué après la prise de focus par un objet d’affichage.InteractiveObject
 InheritedDistribué après la perte de focus par un objet d’affichage.InteractiveObject
 Inherited[événement de diffusion] Distribué après l’exécution des constructeurs des objets d’affichage d’image, mais avant celle des scripts d’image.DisplayObject
 InheritedDistribué lorsque l’utilisateur crée un point de contact le long du bord de la surface tactile à l’aide d’une occurrence InteractiveObject (par exemple, en appuyant le long du bord de la surface tactile sur la télécommande Siri Remote pour l’Apple TV). Certains périphériques peuvent également interpréter ce contact comme une combinaison de plusieurs événements tactiles.InteractiveObject
 InheritedDistribué lorsque l’utilisateur appuie sur deux points de contact sur la même occurrence d’InteractiveObject sur un périphérique tactile (notamment lorsque l’utilisateur appuie avec deux doigts sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile, puis les retire).InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace un point de contact sur l’occurrence d’InteractiveObject d’un périphérique tactile (notamment lorsqu’il déplace un doigt de gauche à droite sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur effectue un mouvement de rotation sur un point de contact à l’aide d’une occurrence d’InteractiveObject (par exemple, lorsqu’il pose deux doigts sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile, puis les fait pivoter).InteractiveObject
 InheritedDistribué lorsque l’utilisateur effectue un mouvement de glissement sur un point de contact à l’aide d’une occurrence d’InteractiveObject (par exemple, lorsqu’il pose trois doigts puis les déplace parallèlement sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur crée un point de contact à l’aide d’une occurrence d’InteractiveObject, puis appuie brièvement sur un périphérique tactile (notamment lorsqu’il place plusieurs doigts sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile pour ouvrir un menu, puis appuie brièvement avec un doigt pour sélectionner une option de menu).InteractiveObject
 InheritedDistribué lorsque l’utilisateur effectue un mouvement de zoom sur un point de contact à l’aide d’une occurrence d’InteractiveObject (par exemple, lorsqu’il pose deux doigts, puis les écarte rapidement sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile).InteractiveObject
 InheritedCet événement est distribué à une application cliente prenant en charge la saisie en ligne avec un éditeur IME.InteractiveObject
 InheritedDistribué lorsque l’utilisateur appuie sur une touche.InteractiveObject
 InheritedDistribué lorsque l’utilisateur tente de déplacer le focus à l’aide du clavier.InteractiveObject
 InheritedDistribué lorsque l’utilisateur relâche une touche.InteractiveObject
  Distribué lorsqu’un utilisateur clique sur un lien hypertexte dans un champ de texte HTML dont l’URL commence par « event: ».TextField
 InheritedDistribué lorsque l’utilisateur appuie sur le bouton central de son périphérique de pointage et le relâche sur la même occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un utilisateur appuie sur le bouton du périphérique de pointage central sur une occurrence InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un utilisateur relâche le bouton du périphérique de pointage sur une occurrence InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un utilisateur appuie sur le bouton du périphérique de pointage sur une occurrence InteractiveObject.InteractiveObject
 InheritedDistribué lorsque l’utilisateur tente de déplacer le focus à l’aide d’un périphérique de pointage.InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace le périphérique de pointage placé sur une occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué lorsque l’utilisateur éloigne un périphérique de pointage d’une occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué lorsque l’utilisateur place un périphérique de pointage sur une occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un utilisateur relâche le bouton du périphérique de pointage sur une occurrence InteractiveObject.InteractiveObject
 InheritedDistribué lorsque la molette d’une souris est actionnée sur une occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué par l’initiateur glisser InteractiveObject lorsque l’utilisateur arrête l’opération glisser.InteractiveObject
 InheritedDistribué par l’objet InteractiveObject cible lorsqu’un objet glissé est déposé dessus et que l’opération déposer a été acceptée avec un appel à DragManager.acceptDragDrop().InteractiveObject
 InheritedDistribué par un InteractiveObject lorsqu’une opération glisser entre dans ses limites.InteractiveObject
 InheritedDistribué par un InteractiveObject lorsqu’une opération glisser sort des limites.InteractiveObject
 InheritedDistribué par un objet InteractiveObject de façon continue lorsqu’une opération glisser reste dans ses limites.InteractiveObject
 InheritedDistribué au début d’une opération glisser par l’objet InteractiveObject spécifié comme initiateur de l’action glisser dans l’appel DragManager.doDrag().InteractiveObject
 InheritedDistribué lors d’une opération glisser par l’objet InteractiveObject spécifié comme initiateur de l’action glisser dans l’appel DragManager.doDrag().InteractiveObject
 InheritedDistribué lorsque l’utilisateur active la combinaison de touches de raccourci propre à la plate-forme pour une opération de collage ou sélectionne "Coller" dans le menu contextuel.InteractiveObject
 InheritedDistribué lorsque l’utilisateur approche un stylet actif de l’écran après le seuil de détection de proximité de l’écran.InteractiveObject
 Inherited
    proximityEnd
Distribué lorsque l’utilisateur soulève un stylet actif au-dessus du seuil de détection de proximité de l’écran.InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace un stylet actif sur l’écran tout en respectant le seuil de détection de proximité.InteractiveObject
 Inherited
    proximityOut
Distribué lorsque l’utilisateur déplace un stylet actif en dehors de cet objet InteractiveObject, tout en respectant le seuil de détection de proximité de l’écran.InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace un stylet actif directement au-dessus de cet objet InteractiveObject, tout en respectant le seuil de détection de proximité de l’écran.InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace un stylet actif hors de cet objet InteractiveObject et de l’un de ses enfants, tout en respectant le seuil de détection de proximité de l’écran.InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace un stylet actif sur cet objet InteractiveObject de l’extérieur de l’arborescence d’objets de descendants dans la liste d’affichage (tout en respectant le seuil de détection de proximité de l’écran).InteractiveObject
 InheritedDistribué lorsqu’un utilisateur relâche le bouton du périphérique de pointage après avoir appuyé sur le bouton sur une occurrence d’InteractiveObject, puis après avoir déplacé le périphérique de pointage hors de l’occurrence d’InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un objet d’affichage est sur le point d’être supprimé de la liste d’affichage.DisplayObject
 InheritedDistribué lorsqu’un objet d’affichage est sur le point d’être supprimé de la liste d’affichage de la scène, directement ou par l’intermédiaire de la suppression d’une arborescence secondaire qui contient l’objet d’affichage.DisplayObject
 Inherited[événement de diffusion] Distribué lorsque la liste d’affichage est sur le point d’être mise à jour et restituée.DisplayObject
 InheritedDistribué lorsque l’utilisateur appuie sur le bouton droit de son périphérique de pointage et le relâche sur la même occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un utilisateur appuie sur le bouton du périphérique de pointage sur une occurrence InteractiveObject.InteractiveObject
 InheritedDistribué lorsqu’un utilisateur relâche le bouton du périphérique de pointage sur une occurrence InteractiveObject.InteractiveObject
 InheritedDistribué lorsque l’utilisateur éloigne un périphérique de pointage d’une occurrence de InteractiveObject.InteractiveObject
 InheritedDistribué lorsque l’utilisateur place un périphérique de pointage sur une occurrence de InteractiveObject.InteractiveObject
  Distribué par un objet TextField après une opération de défilement effectuée par l’utilisateur.TextField
 InheritedDistribué lorsque l’utilisateur active la combinaison de touches de raccourci propre à la plate-forme pour tout sélectionner ou choisit "Sélectionner tout" dans le menu contextuel.InteractiveObject
 InheritedDistribué immédiatement après l’affichage du clavier logiciel.InteractiveObject
 InheritedDistribué immédiatement avant l’affichage du clavier logiciel.InteractiveObject
 InheritedDistribué immédiatement après la disparition du clavier logiciel.InteractiveObject
 InheritedDistribué lorsque la valeur de l’indicateur tabChildren de l’objet change.InteractiveObject
 InheritedDistribué lorsque l’indicateur tabEnabled de l’objet change.InteractiveObject
 InheritedDistribué lorsque la valeur de la propriété tabIndex de l’objet change.InteractiveObject
  Flash Player distribue l’événement textInput lorsqu’un utilisateur entre un ou plusieurs caractères de texte.TextField
  Flash Player distribue l’événement textInteractionModeChange lorsqu’un utilisateur modifie le mode d’interaction d’un champ de texte.TextField
 InheritedDistribué lorsque l’utilisateur touche pour la première fois un périphérique tactile (notamment lorsqu’il pose un doigt sur un téléphone portable ou une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur cesse le contact avec un périphérique tactile (notamment lorsqu’il retire le doigt d’un téléphone portable ou d’une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur appuie sur le périphérique, et est continuellement distribué jusqu’au retrait du point de contact.InteractiveObject
 InheritedDistribué lorsque l’utilisateur retire le point de contact d’une occurrence d’InteractiveObject sur un périphérique tactile (notamment lorsqu’il fait glisser un doigt d’un objet d’affichage vers un autre sur un téléphone portable ou une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace le point de contact sur une occurrence d’InteractiveObject sur un périphérique tactile (notamment lorsqu’il fait glisser un doigt d’un point se trouvant en dehors d’un objet d’affichage vers un point sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur retire le point de contact d’une occurrence d’InteractiveObject sur un périphérique tactile (notamment lorsqu’il fait glisser un doigt d’un se trouvant sur l’objet d’affichage d’un téléphone portable ou une tablette munis d’un écran tactile vers un point se trouvant en dehors de cet objet).InteractiveObject
 InheritedDistribué lorsque l’utilisateur déplace le point de contact sur une occurrence d’InteractiveObject sur un périphérique tactile (notamment lorsqu’il fait glisser un doigt d’un point se trouvant en dehors d’un objet d’affichage vers un point sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile).InteractiveObject
 InheritedDistribué lorsque l’utilisateur lève le point de contact sur la même occurrence d’InteractiveObject sur laquelle le contact a été lancé sur un périphérique tactile (notamment lorsqu’il appuie avec un doigt à partir d’un point de contact unique sur l’objet d’affichage d’un téléphone portable ou d’une tablette munis d’un écran tactile, puis le retire).InteractiveObject
Détails de la propriété

alwaysShowSelection

propriété
alwaysShowSelection:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Lorsque défini sur true et si le champ de texte n’a pas le focus, Flash Player sélectionne le contenu du champ de texte en gris. Lorsque défini sur false et si le champ de texte n’a pas le focus, Flash Player ne sélectionne pas le contenu du champ de texte.

La valeur par défaut est false.



Implémentation
    public function get alwaysShowSelection():Boolean
    public function set alwaysShowSelection(value:Boolean):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
Compile et exécute le fichier suivant. Lorsque vous exécutez le fichier, faites glisser pour sélectionner le texte dans chacun des deux champs de texte et remarquez les différentes sélections obtenues lorsque vous sélectionnez du texte dans les deux champs (changement de focus) :
    package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_alwaysShowSelection extends Sprite {
        public function TextField_alwaysShowSelection() {
            var label1:TextField = createCustomTextField(0, 20, 200, 20);
            label1.text = "This text is selected.";
            label1.setSelection(0, 9);
            label1.alwaysShowSelection = true;

            var label2:TextField = createCustomTextField(0, 50, 200, 20);
            label2.text = "Drag to select some of this text.";
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x; result.y = y;
            result.width = width; result.height = height;
            addChild(result);
            return result;
        }
    }
}

antiAliasType

propriété 
antiAliasType:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9

Type d’anticrènelage appliqué à ce champ de texte. Utilisez les constantes flash.text.AntiAliasType pour cette propriété. Vous ne pouvez contrôler cette définition que si la police est intégrée (avec la propriété embedFonts définie sur true). Le paramètre par défaut est flash.text.AntiAliasType.NORMAL.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Valeur de chaîneDescription
flash.text.AntiAliasType.NORMALApplique un anticrènelage ordinaire au texte. Cette valeur correspond au type d’anticrènelage utilisé par Flash Player 7 et les versions précédentes.
flash.text.AntiAliasType.ADVANCEDApplique un anticrènelage avancé qui rend le texte plus lisible (cette fonctionnalité est devenue disponible dans Flash Player 8). Anticrènelage avancé permet d’obtenir une qualité du rendu des polices de petite taille. Cette option convient particulièrement aux applications comportant beaucoup de texte de petite taille. L’anticrènelage avancé n’est pas recommandé pour les polices de plus de 48 points.



Implémentation
    public function get antiAliasType():String
    public function set antiAliasType(value:String):void

Eléments de l’API associés

autoSize

propriété 
autoSize:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Commande le dimensionnement et l’alignement automatiques des champs de texte. Les valeurs acceptables pour les constantes TextFieldAutoSize sont : TextFieldAutoSize.NONE (par défaut), TextFieldAutoSize.LEFT, TextFieldAutoSize.RIGHT et TextFieldAutoSize.CENTER.

Si autoSize est défini sur TextFieldAutoSize.NONE (par défaut), aucun redimensionnement n’a lieu.

Si autoSize est défini sur TextFieldAutoSize.LEFT, le texte est alors traité comme du texte cadré à gauche, ce qui signifie que la marge gauche du champ de texte reste fixe et tout redimensionnement d’un champ de texte sur une seule ligne se fera dans la marge de droite. Si le texte contient un saut de ligne (par exemple "\n" ou "\r") le bas est alors également redimensionné pour s’adapter à la ligne suivante du texte. Si wordWrap est également défini sur true, seul le bas du champ de texte est redimensionné et le côté droit reste fixe.

Si autoSize est défini sur TextFieldAutoSize.RIGHT, le texte est alors traité comme du texte cadré à droite, ce qui signifie que la marge droite du champ de texte reste fixe et tout redimensionnement d’un champ de texte sur une seule ligne se fera dans la marge de gauche. Si le texte contient un saut de ligne (par exemple "\n" ou "\r") le bas est alors également redimensionné pour s’adapter à la ligne suivante du texte. Si wordWrap est également défini sur true, seul le bas du champ de texte est redimensionné et le côté gauche reste fixe.

Si autoSize est défini sur TextFieldAutoSize.CENTER, le texte est traité comme du texte centré, ce qui signifie que tout redimensionnement d’un champ de texte sur une seule ligne est uniformément réparti sur les marges droite et gauche. Si le texte contient un saut de ligne (par exemple "\n" ou "\r") le bas est alors également redimensionné pour s’adapter à la ligne suivante du texte. Si wordWrap est également défini sur true, seul le bas du champ de texte est redimensionné et les côtés gauche et droit restent fixe.



Implémentation
    public function get autoSize():String
    public function set autoSize(value:String):void

Valeur émise
ArgumentError — Le paramètre autoSize spécifié n’appartient pas à flash.text.TextFieldAutoSize.

Eléments de l’API associés

background

propriété 
background:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Spécifie si le champ de texte a un remplissage d’arrière-plan. Si true, le champ de texte a un remplissage d’arrière-plan. Si false, le champ de texte n’a pas de remplissage d’arrière-plan. La propriété backgroundColor permet de définir la couleur d’arrière-plan d’un champ de texte.

La valeur par défaut est false.



Implémentation
    public function get background():Boolean
    public function set background(value:Boolean):void

Eléments de l’API associés

backgroundColor

propriété 
backgroundColor:uint

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Couleur de l’arrière-plan du champ de texte. La valeur par défaut est 0xFFFFFF (blanc). Cette propriété peut être extraite ou définie, même s’il n’y a pas encore d’arrière-plan, mais la couleur n’est visible que si la propriété background du champ de texte est définie sur true.



Implémentation
    public function get backgroundColor():uint
    public function set backgroundColor(value:uint):void

Eléments de l’API associés

border

propriété 
border:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Spécifie si le champ de texte comporte une bordure. Si true, le champ de texte comporte une bordure. Si false, le champ de texte ne comporte pas de bordure. La propriété borderColor permet de définir la couleur de la bordure.

La valeur par défaut est false.



Implémentation
    public function get border():Boolean
    public function set border(value:Boolean):void

Eléments de l’API associés

borderColor

propriété 
borderColor:uint

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Couleur de la bordure du champ de texte. La valeur par défaut est 0x000000 (noir). Cette propriété peut être extraite ou définie, même s’il n’y a pas encore de bordure, mais la couleur n’est visible que si la propriété border du champ de texte est définie sur true.



Implémentation
    public function get borderColor():uint
    public function set borderColor(value:uint):void

Eléments de l’API associés

bottomScrollV

propriété 
bottomScrollV:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Entier (index basé sur 1) qui indique la ligne la plus basse visible dans le champ de texte spécifié. Considérez le champ de texte comme une fenêtre sur un bloc de texte. La propriété scrollV est l’index basé sur 1 de la ligne la plus haute et visible dans la fenêtre.

Tout le texte situé entre les lignes désignées par scrollV et bottomScrollV est visible dans le champ de texte.



Implémentation
    public function get bottomScrollV():int

Eléments de l’API associés

caretIndex

propriété 
caretIndex:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

L’index de la position du point d’insertion (caret). Si aucun point d’insertion ne s’affiche, cette valeur correspond à la position du point d’insertion en cas de restauration du focus sur le champ (il s’agit généralement du dernier emplacement du point d’insertion, ou 0 si le champ n’a pas eu le focus).

Les index de plages de sélection sont de base zéro (par exemple, la première position est 0, la deuxième position est 1, etc.).



Implémentation
    public function get caretIndex():int

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
Dans cet exemple, une occurrence TextField est créée et remplie avec du texte. Un écouteur d’événement est affecté de façon à ce que l’utilisateur clique sur TextField, la méthode printCursorPosition est appelée. Dans ce cas, les valeurs des propriétés caretIndex, selectionBeginIndex et selectionEndIndex sont renvoyées.

Exécutez cet exemple, puis essayez de cliquer dans TextField pour sélectionner le texte. Cliquez ensuite dans le champ sans sélectionner de texte. Lorsque vous cliquez sur le texte sans faire de sélection, la propriété caretIndex indique l’emplacement du point d’insertion et les propriétés selectionBeginIndex et selectionEndIndex sont égales à la valeur de la propriété caretIndex.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createCustomTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field. Compare the difference between clicking without selecting versus clicking and selecting text.";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent):void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

condenseWhite

propriété 
condenseWhite:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Valeur booléenne qui indique si l’espace blanc supplémentaire (espaces, saut de ligne, etc.) est supprimé dans un champ de texte HTML. La valeur par défaut est false. La propriété condenseWhite n’affecte que le texte défini avec la propriété htmlText, pas la propriété text. Si vous définissez du texte avec la propriété text, la propriété condenseWhite est ignorée.

Si la propriété condenseWhite est définie sur true, utilisez les commandes HTML classiques, telles que <BR> et <P>, pour placer des sauts de ligne dans le champ de texte.

Définissez la propriété condenseWhite avant de définir la propriété htmlText.



Implémentation
    public function get condenseWhite():Boolean
    public function set condenseWhite(value:Boolean):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant révèle la différence entre la définition du paramètre condenseWhite sur false et sa définition sur true :
package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_condenseWhite extends Sprite {
        public function TextField_condenseWhite() {
            var tf1:TextField = createCustomTextField(0, 0, 200, 50);
            tf1.condenseWhite = false;
            tf1.htmlText = "keep    on\n\ttruckin'";
            
            var tf2:TextField = createCustomTextField(0, 120, 200, 50);
            tf2.condenseWhite = true;
            tf2.htmlText = "keep    on\n\ttruckin'";
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

defaultTextFormat

propriété 
defaultTextFormat:flash.text:TextFormat

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Spécifie le format appliqué au texte qui vient d’être inséré, notamment au texte saisi par un utilisateur ou inséré à l’aide de la méthode replaceSelectedText().

Remarque : lorsque vous sélectionnez des caractères en vue de les remplacer à l’aide des méthodes setSelection() et replaceSelectedText(), la propriété defaultTextFormat est appliquée uniquement si la totalité du texte (y compris le dernier caractère) a été sélectionnée. Voici un exemple :

     var my_txt:TextField new TextField();
     my_txt.text = "Flash Macintosh version";
     var my_fmt:TextFormat = new TextFormat();
     my_fmt.color = 0xFF0000;
     my_txt.defaultTextFormat = my_fmt;
     my_txt.setSelection(6,15); // partial text selected - defaultTextFormat not applied
     my_txt.setSelection(6,23); // text selected to end - defaultTextFormat applied
     my_txt.replaceSelectedText("Windows version");
     

Lorsque vous accédez à la propriété defaultTextFormat, l’objet TextFormat renvoyé voit toutes ses propriétés définies. Aucune propriété n’a la valeur null.

Remarque : vous ne pouvez pas définir cette propriété lorsqu’une feuille de style est appliquée au champ de texte.



Implémentation
    public function get defaultTextFormat():flash.text:TextFormat
    public function set defaultTextFormat(value:flash.text:TextFormat):void

Valeur émise
Error — Cette méthode ne peut pas être appliquée à un champ de texte associé à une feuille de style.

Eléments de l’API associés

displayAsPassword

propriété 
displayAsPassword:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Indique si le champ de texte est un champ de texte de mot de passe. Si la valeur de cette propriété est true, le champ de texte est traité en tant que mot de passe et masque les caractères d’entrée en utilisant les astérisques à la place des caractères. Si false, le champ de texte n’est pas traité comme un mot de passe. Lorsque le mode mot de passe est activé, les commandes Couper et Copier et leurs raccourcis clavier ne fonctionnent pas. Ce mécanisme de sécurité empêche un utilisateur malhonnête d’utiliser les raccourcis pour découvrir le mot de passe d’un ordinateur sans surveillance.

La valeur par défaut est false.



Implémentation
    public function get displayAsPassword():Boolean
    public function set displayAsPassword(value:Boolean):void

embedFonts

propriété 
embedFonts:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Spécifie si le rendu doit utiliser des polices vectorielles incorporées. Si false, Flash Player restitue le champ de texte à l’aide de polices de périphérique.

Si vous définissez la propriété embedFonts sur true pour un champ de texte, vous devez spécifier la police du texte par l’intermédiaire de la propriété font d’un objet TextFormat appliqué au champ de texte. Si la police spécifiée n’est pas intégrée dans le fichier SWF, le texte ne s’affiche pas.

La valeur par défaut est false.



Implémentation
    public function get embedFonts():Boolean
    public function set embedFonts(value:Boolean):void

Eléments de l’API associés

gridFitType

propriété 
gridFitType:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9

Type d’adaptation à la grille appliqué à ce champ de texte. Cette propriété s’applique uniquement si la propriété flash.text.AntiAliasType du champ de texte est définie sur flash.text.AntiAliasType.ADVANCED.

Le type d’adaptation à la grille utilisé détermine si Flash Player force les lignes horizontales et verticales fortes à s’aligner sur une grille de pixels ou sous-pixels, ou pas du tout.

Pour la propriété flash.text.GridFitType, vous pouvez utiliser les valeurs de chaînes suivantes :

Valeur de chaîneDescription
flash.text.GridFitType.NONENe spécifie pas d’adaptation à la grille. Les lignes horizontales et verticales des glyphes ne sont pas alignées sur la grille de pixels. Ce paramètre est conseillé pour les animations ou les grandes polices.
flash.text.GridFitType.PIXELSpécifie que les lignes horizontales et verticales fortes sont adaptées à la grille de pixels. Ce paramètre convient uniquement aux champs de texte alignés à gauche. Pour utiliser ce paramètre, la propriété flash.display.AntiAliasType du champ de texte doit être définie sur flash.text.AntiAliasType.ADVANCED. Ce paramètre rend généralement le texte justifié à gauche plus lisible.
flash.text.GridFitType.SUBPIXELSpécifie que les lignes horizontales et verticales fortes sont adaptées à la grille de sous-pixels sur les écrans à cristaux liquides. Pour utiliser ce paramètre, la propriété flash.text.AntiAliasType du champ de texte doit être défini sur flash.text.AntiAliasType.ADVANCED. Le paramètre flash.text.GridFitType.SUBPIXEL est généralement préférable pour le texte dynamique aligné à droite ou centré et permet parfois d’établir un bon compromis entre la qualité d’animation et la qualité du texte.

La valeur par défaut est pixel.



Implémentation
    public function get gridFitType():String
    public function set gridFitType(value:String):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant montre trois champs de texte avec des paramètres différents pour la propriété gridFitType. Lorsque vous utilisez cet exemple, notez la différence de netteté des deux premières lignes. Remarquez également l’utilisation optimale de GridFitType.PIXEL pour le texte aligné à gauche et de GridFitType.SUBPIXEL pour le texte aligné à droite.
package
{
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.text.AntiAliasType;
    import flash.text.GridFitType;

    public class gridFitTypeExample extends Sprite
    {
        public function gridFitTypeExample()
        {
    var format1:TextFormat = new TextFormat();
    format1.font="Arial";
    format1.size=12;

    var tf1:TextField = createCustomTextField(0,0,format1,"NONE",TextFieldAutoSize.LEFT,GridFitType.NONE);
    
    var tf2:TextField = createCustomTextField(0,30,format1,"PIXEL",TextFieldAutoSize.LEFT,GridFitType.PIXEL);

    var tf3:TextField = createCustomTextField(300,60,format1,"SUBPIXEL",TextFieldAutoSize.RIGHT,GridFitType.SUBPIXEL);

        }
        private function createCustomTextField(x:Number,y:Number,fm:TextFormat,tl:String,tfs:String,gft:String):TextField 
        {
            var result:TextField = new TextField();
            result.x=x;
            result.y=y;
            result.embedFonts=true;
            result.antiAliasType=AntiAliasType.ADVANCED;
            result.text="This text uses a gridFitType of " + tl;
            result.autoSize=tfs;
        result.gridFitType=gft;
            result.setTextFormat(fm);
            addChild(result);
            return result;
        }
    }
}

htmlText

propriété 
htmlText:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Contient la représentation HTML du contenu du champ de texte.

Flash Player prend en charge les balises HTML suivantes :

Balise Description
Balise d’ancrage La balise <a> crée un lien hypertexte et prend en charge les attributs suivants :
  • target : Désigne le nom de la fenêtre cible dans laquelle vous chargez la page. Les options incluent _self, _blank, _parent et _top. L’option _selfspécifie l’image active dans la fenêtre actuelle, _blank spécifie une nouvelle fenêtre, _parent spécifie le parent de l’image active et _top spécifie l’image de plus haut niveau dans la fenêtre active.
  • href : spécifie une URL ou un événement link ActionScript. L’URL peut être absolue ou relative à l’emplacement du fichier SWF qui charge la page. Par exemple, l’URL http://www.adobe.com constitue une référence absolue, alors que /index.html est une référence relative. Les URL absolues doivent être précédées du préfixe http:// ; dans le cas contraire, Flash ou AIR les considère comme des URL relatives. Vous pouvez utiliser l’événement link pour que le lien exécute une fonction ActionScript dans un fichier SWF au lieu d’ouvrir une URL. Pour spécifier un événement link, utilisez le modèle d’événement plutôt que le modèle http dans votre attribut href. href="event:myText" au lieu de href="http://myURL" en est un exemple ; lorsque l’utilisateur clique sur un lien hypertexte contenant le modèle d’événement, le champ de texte distribue un TextEvent link avec sa propriété text définie sur "myText". Vous pouvez alors créer une fonction ActionScript qui s’exécute chaque fois que le lien TextEvent est distribué. Vous pouvez également définir des styles a:link, a:hover et a:active pour les balises d’ancrage en utilisant les feuilles de style.
Balise Bold La balise <b> met le texte en gras. Des caractères en gras doivent être disponibles dans la police utilisée.
Balise Break La balise <br> introduit un saut de ligne dans le champ de texte. Spécifie que le champ de texte doit être multiligne pour utiliser cette balise.
Balise Font La balise <font> spécifie une police ou une liste de polices pour afficher le texte. La balise font prend en charge les attributs suivants :
  • color : Seules les valeurs de couleur hexadécimales (#FFFFFF) sont prises en charge.
  • face : Désigne le nom de la police à utiliser. Comme indiqué dans l’exemple suivant, vous pouvez spécifier des noms de police séparés par des virgules, auquel cas Flash Player sélectionne la première balise disponible. Si la police spécifiée n’est pas installée sur le système informatique local ou si elle n’est pas intégrée dans le fichier SWF, Flash Player sélectionne une police de remplacement.
  • size : Désigne la taille de la police. Vous pouvez appliquer des tailles de pixel absolues, telles que 16 ou 18, ou relatives, telles que +2 ou -4.
Balise Image  La balise <img> vous permet d’intégrer des fichiers image (JPEG, GIF, PNG), des fichiers SWF et des clips externes à l’intérieur des champs de texte et des occurrences au sein des champs de texte. Le texte se déroule automatiquement autour des images intégrées dans les champs de texte. Vous devez définir le champ de texte sur multiligne pour placer un texte autour d’une image.

La balise <img> prend en charge les attributs suivants :

  • src : Spécifie l’URL vers un fichier image ou SWF, ou l’identifiant de liaison pour un symbole de clip dans la bibliothèque. Cet attribut est requis ; tous les autres attributs sont facultatifs. Les fichiers externes (JPEG, GIF, PNG et SWF) ne s’affichent pas tant qu’ils ne sont pas entièrement téléchargés.
  • width : Largeur de l’image, du fichier SWF ou du clip inséré, en pixels.
  • height : Hauteur de l’image, du fichier SWF ou du clip inséré, en pixels.
  • align : Spécifie l’alignement horizontal de l’image intégrée dans le champ de texte. Les valeur valides sont left et right. La valeur par défaut est left.
  • hspace : Spécifie l’espace horizontal qui entoure l’image là où aucun texte n’apparaît. La valeur par défaut est 8.
  • vspace : Spécifie l’espace vertical qui entoure l’image là où aucun texte n’apparaît. La valeur par défaut est 8.
  • id : Spécifie le nom d’une occurrence de clip (créée par Flash Player) contenant l’élément intégré (fichier image, SWF ou clip). Cette approche est utilisée pour contrôler le contenu intégré avec ActionScript.
  • checkPolicyFile : spécifie que Flash Player doit rechercher un fichier de régulation d’URL sur le serveur associé au domaine de l’image. En présence d’un fichier de régulation, les fichiers SWF figurant dans les domaines identifiés par ce fichier de régulation peuvent accéder aux données de l’image chargée, par exemple en appelant la méthode BitmapData.draw() avec cette image en tant que paramètre source. Pour plus d’informations concernant la sécurité, voir la rubrique du Pôle de développement Flash Player : Sécurité (disponible en anglais uniquement).

Flash affiche le média intégré dans un champ de texte, à sa taille normale. Pour spécifier les dimensions du média à intégrer, utilisez les attributs height et width de la balise <img>.

En général, une image intégrée dans un champ de texte apparaît sur la ligne qui suit la balise <img>. Cependant, lorsque la balise <img> est le premier caractère dans le champ de texte, l’image apparaît sur la première ligne du champ de texte.

Pour le contenu AIR dans le sandbox de sécurité de l’application, AIR ignore les balises img dans le contenu HTML des objets TextField ActionScript, afin d’éviter les tentatives d’hameçonnage,

Balise Italic La balise <i> affiche le texte entre balises en italiques. Des caractères italiques doivent être disponibles dans la police utilisée.
Balise List item La balise <li> insère une puce juste avant le texte sur lequel elle porte. Remarque : dans la mesure où Flash Player et AIR ne permettent pas d’identifier les balises de liste triées ou non triées (<ol> et <ul>), ces dernières n’ont aucun effet sur le rendu de la liste. Toutes les listes restent non triées et tous les éléments de la liste sont précédés par des puces.
Balise Paragraphe La balise <p> crée un paragraphe. Le champ de texte doit être défini sur multiligne pour utiliser cette balise. La balise <p> prend en charge les attributs suivants :
  • align : Détermine l’alignement du texte au sein du paragraphe ; les valeurs valides sont left, right, justify et center.
  • class : Spécifie la classe de style CSS définie par un objet flash.text.StyleSheet.
Balise Span La balise <span> peut uniquement être utilisée avec les styles de texte CSS. Elle prend en charge l’attribut suivant :
  • class : Spécifie la classe de style CSS définie par un objet flash.text.StyleSheet.
Balise Text format

La balise <textformat> permet d’utiliser un sous-ensemble de propriétés de formatage des paragraphes de la classe TextFormat dans les champs de texte, dont l’interlignage, le retrait, les marges et les taquets de tabulation. Vous pouvez associer des balises <textformat> aux balises HTML intégrées.

La balise <textformat> dispose des attributs suivants :

  • blockindent : Spécifie l’indentation d’un bloc, en points. Correspond à TextFormat.blockIndent.
  • indent : Spécifie l’indentation, de la marge gauche au premier caractère du paragraphe. Correspond à TextFormat.indent. Les nombres positifs et négatifs sont acceptables.
  • leading : Spécifie l’espace séparant les lignes (espace vertical). Correspond à TextFormat.leading. Les nombres positifs et négatifs sont acceptables.
  • leftmargin : Spécifie la marge gauche du paragraphe, en points. Correspond à TextFormat.leftMargin.
  • rightmargin : Spécifie la marge gauche du paragraphe, en points. Correspond à TextFormat.rightMargin.
  • tabstops : Spécifie des taquets de tabulation personnalisés, sous forme d’un tableau d’entiers non négatifs. Correspond à TextFormat.tabStops.
Balise Underline La balise <u> souligne le texte placé entre les balises.

Flash Player et AIR prennent en charge les entités HTML suivantes :

Entité Description
&lt; < (Inférieur à)
&gt; > (Supérieur à)
&amp; & (esperluette)
&quot; " (guillemets doubles)
&apos; ’ (apostrophe, guillemet simple)

Flash Player et AIR prennent également en charge les codes de caractères explicites, tels que &#38; (esperluette ASCII) et &#x20AC; (symbole € Unicode).



Implémentation
    public function get htmlText():String
    public function set htmlText(value:String):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant crée un objet TextField appelé tf1 et affecte une chaîne au format HTML à sa propriété text. Lorsque la propriété htmlText est suivie, une chaîne au format HTML est renvoyée avec des balises supplémentaires (telles que <P> et <FONT>) qui sont ajoutées de façon automatique par Flash Player. Lorsque la valeur de la propriété text est suivie, la chaîne non formatée et sans balises HTML s’affiche.

Par comparaison, les mêmes opérations sont exécutées sur un autre objet TextField appelé tf2 et un objet StyleSheet est alors affecté à la propriété styleSheet de tf2 avant la définition de sa propriété htmlText. Dans ce cas, lorsque la propriété htmlText est suivie, elle inclut uniquement le texte HTML qui a été affecté à l’origine à la propriété htmlText, ce qui indique qu’aucune balise supplémentaire n’a été ajoutée par Flash Player.

package {
    import flash.display.Sprite;
    import flash.text.StyleSheet;
    import flash.text.TextField;

    public class TextField_text extends Sprite {
        public function TextField_text() {
            var tf1:TextField = createCustomTextField(10, 10, 400, 22);
            tf1.htmlText = "<b>Lorem ipsum dolor sit amet.</b>";

            // htmlText: <P ALIGN="LEFT"><FONT FACE="Times New Roman" SIZE="12" COLOR="#000000" LETTERSPACING="0" KERNING="0"><b>Lorem ipsum dolor sit amet.</b></FONT></P>
            trace("htmlText: " + tf1.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf1.text);
            
            var tf2:TextField = createCustomTextField(10, 50, 400, 22);
            tf2.styleSheet = new StyleSheet();
            tf2.htmlText = "<b>Lorem ipsum dolor sit amet.</b>";
            // htmlText: <b>Lorem ipsum dolor sit amet.</b>
            trace("htmlText: " + tf2.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf2.text);
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

length

propriété 
length:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Nombre de caractères d’un champ de texte. Un caractère tel qu’une marque de tabulation (\t) compte comme un seul caractère.



Implémentation
    public function get length():int

maxChars

propriété 
maxChars:int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Le nombre maximum de caractères que le champ de texte peut contenir, tels que saisis par un utilisateur. Un script peut insérer plus de texte que maxChars ne le permet ; la propriété maxChars n’indique que la quantité de texte qu’un utilisateur peut entrer. Si la valeur de la propriété est égale à 0, l’utilisateur peut entrer autant de texte que nécessaire.

La valeur par défaut est 0.



Implémentation
    public function get maxChars():int
    public function set maxChars(value:int):void

maxScrollH

propriété 
maxScrollH:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Valeur maximale de scrollH.



Implémentation
    public function get maxScrollH():int

Eléments de l’API associés

maxScrollV

propriété 
maxScrollV:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Valeur maximale de scrollV.



Implémentation
    public function get maxScrollV():int

Eléments de l’API associés

mouseWheelEnabled

propriété 
mouseWheelEnabled:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9

Valeur booléenne qui indique si Flash Player fait automatiquement défiler les champs de texte multiligne lorsque l’utilisateur clique sur le champ de texte et actionne la molette de sa souris. Par défaut, cette valeur est true. Cette propriété est utile si vous souhaitez empêcher le défilement des champs de texte en actionnant la molette de la souris, ou implémenter votre propre défilement de champs de texte.



Implémentation
    public function get mouseWheelEnabled():Boolean
    public function set mouseWheelEnabled(value:Boolean):void

multiline

propriété 
multiline:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Indique si le champ est un champ de texte multiligne. Si la valeur est true, le champ de texte est multiligne ; si la valeur est false, le champ de texte est un champ de texte sur une seule ligne. Dans un champ de type TextFieldType.INPUT, la valeur multiline détermine si la touche Entrée créé une nouvelle ligne (valeur false et la touche Entrée est ignorée). Si vous collez du texte dans un objet TextField avec une valeur multiline false, les nouvelles lignes sont éliminées du texte.

La valeur par défaut est false.



Implémentation
    public function get multiline():Boolean
    public function set multiline(value:Boolean):void

Eléments de l’API associés

numLines

propriété 
numLines:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Définit le nombre de lignes de texte d’un champ multiligne. Si la propriété wordWrap est définie sur true, le nombre de lignes augmente lorsque le texte contient des sauts de ligne.



Implémentation
    public function get numLines():int

Eléments de l’API associés

restrict

propriété 
restrict:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Indique le jeu de caractères qu’un utilisateur peut rentrer dans le champ de texte. Si la valeur de la propriété restrict est null, vous pouvez entrer n’importe quel caractère. Si la valeur de la propriété restrict est une chaîne vide, aucun caractère ne peut être entré. Si la valeur de la propriété restrict est une chaîne de caractères, vous ne pouvez entrer que les caractères dans la chaîne du champ de texte. La chaîne est lue de gauche à droite. Vous pouvez spécifier une plage à l’aide du caractère (-). Seule l’interaction de l’utilisateur est limitée ; un script peut mettre n’importe quel texte dans le champ de texte. Cette propriété ne se synchronise pas avec les options de polices incorporées de l’inspecteur des propriétés.

Si la chaîne commence par un caret (^), tous les caractères sont initialement acceptés et les caractères suivants de la chaîne sont exclus du jeu de caractères acceptés. Si la chaîne ne commence pas par un caret (^), aucun caractère n’est initialement accepté et les caractères suivants de la chaîne sont inclus dans le jeu de caractères acceptés.

L’exemple suivant autorise uniquement les caractères en majuscules, les espaces et les nombres dans le champ de texte :

     my_txt.restrict = "A-Z 0-9";
     

L’exemple suivant exclut uniquement les caractères en minuscules :

     my_txt.restrict = "^a-z";
     

Insérez une barre oblique pour saisir un ^ ou un -. Les séquences acceptables sont \-, \^ ou \\. Si la barre oblique doit être un caractère réel dans la chaîne, vous devez également la faire précéder d’une autre barre oblique dans le code ActionScript. Par exemple, le code suivant inclut uniquement le tiret (-) et le signe circonflexe (^) :

     my_txt.restrict = "\\-\\^";
     

Le caractère ^ peut être utilisé n’importe où dans la chaîne pour faire alterner l’inclusion et l’exclusion des caractères. Le code suivant inclut uniquement des lettres en majuscules, mais exclut la lettre Q en majuscules :

     my_txt.restrict = "A-Z^Q";
     

Vous pouvez utiliser la séquence d’échappement \u pour créer des chaînes restrict. Le code suivant inclut uniquement les caractères ASCII allant de 32 à 126 (tilde).

     my_txt.restrict = "\u0020-\u007E";
     

La valeur par défaut est null.



Implémentation
    public function get restrict():String
    public function set restrict(value:String):void

scrollH

propriété 
scrollH:int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Position de défilement horizontal actuelle. Si la propriété scrollH est 0, le texte ne défile pas horizontalement. Cette valeur de propriété est un entier qui représente la position horizontale en pixels.

Les unités du défilement horizontal sont les pixels, alors que les unités du défilement vertical sont les lignes. Le défilement horizontal est mesuré en pixels étant donné que la plupart des polices que vous utilisez sont généralement espacées de façon proportionnelle, c’est-à-dire que les caractères peuvent avoir différentes largeurs. Flash Player procède au défilement vertical par ligne dans la mesure où les utilisateurs préfèrent généralement consulter une ligne entière de texte. Même s’il existe plusieurs polices sur une ligne, la hauteur de la ligne s’adapte à la plus grande police utilisée.

Remarque : la propriété scrollH est de base zéro, contrairement à la propriété de défilement vertical scrollV qui est de base 1.



Implémentation
    public function get scrollH():int
    public function set scrollH(value:int):void

Eléments de l’API associés

scrollV

propriété 
scrollV:int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

La position verticale du texte dans un champ de texte. La propriété scrollV est utile pour diriger les utilisateurs vers un paragraphe spécifique dans un long passage ou pour créer des champs de texte avec défilement.

Les unités du défilement vertical sont des lignes, alors que les unités du défilement horizontal sont des pixels. Si la première ligne qui s’affiche correspond à la première ligne du champ de texte, scrollV est défini sur 1 (non pas sur 0). Le défilement horizontal est mesuré en pixels étant donné que la plupart des polices que vous utilisez sont généralement espacées de façon proportionnelle et les caractères peuvent donc avoir différentes largeurs. Flash procède au défilement vertical par ligne dans la mesure où les utilisateurs préfèrent généralement consulter une ligne entière de texte. Même s’il existe plusieurs polices sur une ligne, la hauteur de la ligne s’adapte à la plus grande police utilisée.



Implémentation
    public function get scrollV():int
    public function set scrollV(value:int):void

Eléments de l’API associés

selectable

propriété 
selectable:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Une valeur booléenne qui indique si le champ de texte peut être sélectionné. La valeur true indique que le texte est sélectionnable. La propriété selectable détermine si un champ de texte peut être sélectionné et non pas s’il peut être modifié. Un champ de texte dynamique peut être sélectionné, même s’il ne peut pas être modifié. Lorsqu’un champ de texte n’est pas sélectionnable, vous ne pouvez pas sélectionner son texte.

Si selectable est défini sur false, le texte du champ de texte ne répond pas aux commandes de sélection de la souris ou du clavier, et le texte ne peut pas être copié à l’aide de la commande Copier. Si selectable est défini sur true, le texte du champ de texte peut être sélectionné avec la souris ou le clavier, et le texte peut être copié à l’aide de la commande Copier. Vous pouvez sélectionner le texte de cette manière même si le champ de texte est un champ de texte dynamique et non un champ de texte de saisie.

La valeur par défaut est true.



Implémentation
    public function get selectable():Boolean
    public function set selectable(value:Boolean):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant crée deux champs de texte dynamiques : un champ de texte avec la propriété selectable définie sur true et l’autre avec la propriété selectable définie sur false. Lorsque vous utilisez cet exemple, essayez de sélectionner le texte de ces champs avec la souris ou le clavier.
package
{
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class selectableExample extends Sprite
    {
        public function selectableExample()
        {
    var tf1:TextField = createCustomTextField(10, 10);
    tf1.text="This text can be selected";
    tf1.selectable=true;

    var tf2:TextField = createCustomTextField(10, 30);
    tf2.text="This text cannot be selected";
    tf2.selectable=false;
        }

        private function createCustomTextField(x:Number, y:Number):TextField 
       {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.autoSize=TextFieldAutoSize.LEFT;
            addChild(result);
            return result;
        }
    }
}

selectionBeginIndex

propriété 
selectionBeginIndex:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Valeur d’index basée sur zéro du premier caractère de la sélection actuelle. Par exemple, le premier caractère est 0, le deuxième est 1, etc. Si aucun texte n’est sélectionné, cette propriété reprend la valeur de caretIndex.



Implémentation
    public function get selectionBeginIndex():int

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
Dans cet exemple, une occurrence TextField est créée et remplie avec du texte. Un écouteur d’événement est affecté de façon à ce que l’utilisateur clique sur TextField, la méthode printCursorPosition est appelée. Dans ce cas, les valeurs des propriétés caretIndex, selectionBeginIndex et selectionEndIndex sont renvoyées.

Exécutez cet exemple, puis essayez de cliquer dans TextField pour sélectionner le texte. Cliquez ensuite dans le champ sans sélectionner de texte. Lorsque vous cliquez sur le texte sans faire de sélection, la propriété caretIndex indique l’emplacement du point d’insertion et les propriétés selectionBeginIndex et selectionEndIndex sont égales à la valeur de la propriété caretIndex.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createCustomTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field. Compare the difference between clicking without selecting versus clicking and selecting text.";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent):void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

selectionEndIndex

propriété 
selectionEndIndex:int  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Valeur d’index de base zéro du dernier caractère de la sélection actuelle. Par exemple, le premier caractère est 0, le deuxième est 1, etc. Si aucun texte n’est sélectionné, cette propriété reprend la valeur de caretIndex.



Implémentation
    public function get selectionEndIndex():int

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
Dans cet exemple, une occurrence TextField est créée et remplie avec du texte. Un écouteur d’événement est affecté de façon à ce que l’utilisateur clique sur TextField, la méthode printCursorPosition est appelée. Dans ce cas, les valeurs des propriétés caretIndex, selectionBeginIndex et selectionEndIndex sont renvoyées.

Exécutez cet exemple, puis essayez de cliquer dans TextField pour sélectionner le texte. Cliquez ensuite dans le champ sans sélectionner de texte. Lorsque vous cliquez sur le texte sans faire de sélection, la propriété caretIndex indique l’emplacement du point d’insertion et les propriétés selectionBeginIndex et selectionEndIndex sont égales à la valeur de la propriété caretIndex.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createCustomTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field. Compare the difference between clicking without selecting versus clicking and selecting text.";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent):void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

sharpness

propriété 
sharpness:Number

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9

Netteté des bords du glyphe dans ce champ de texte. Cette propriété s’applique uniquement si la propriété flash.text.AntiAliasType du champ de texte est définie sur flash.text.AntiAliasType.ADVANCED. La plage de sharpness est comprise entre -400 et 400. Si vous tentez de définir sharpness sur une valeur en dehors de cette plage, Flash définit cette propriété sur la valeur valide la plus proche, soit -400 ou 400.

La valeur par défaut est 0.



Implémentation
    public function get sharpness():Number
    public function set sharpness(value:Number):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant montre l’effet de la modification de la propriété sharpness d’un objet TextField. Vous devez intégrer la police et définir la propriété antiAliasType sur ADVANCED.
package
{
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.AntiAliasType;
    import flash.text.GridFitType;
    import flash.text.TextFormat;

    public class sharpnessExample extends Sprite
    {
        public function sharpnessExample()
        {
    var format1:TextFormat = new TextFormat();
    format1.font="Arial";
    format1.size=24;
    var lTxt:String = "The quick brown fox";

    var tf1:TextField=createCustomTextField(0,lTxt,format1,-400);
    var tf2:TextField=createCustomTextField(30,lTxt,format1,0);
    var tf3:TextField=createCustomTextField(60,lTxt,format1,400);
        }

        private function createCustomTextField(y:Number,fldTxt:String,format:TextFormat,fldSharpness:Number):TextField 
       {
            var result:TextField = new TextField();
            result.y=y;
            result.text=fldTxt;
            result.embedFonts=true;
            result.autoSize=TextFieldAutoSize.LEFT;
            result.antiAliasType=AntiAliasType.ADVANCED;
            result.gridFitType=GridFitType.PIXEL;
            result.sharpness=fldSharpness;
            result..setTextFormat(format);
            addChild(result);
            return result;
        }
    }
}

styleSheet

propriété 
styleSheet:StyleSheet

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Associe une feuille de style au champ de texte. Pour plus d’informations sur la création de feuilles de style, voir la classe StyleSheet et le Guide du développeur d’ActionScript 3.0.

Vous pouvez modifier la feuille de style associée à un champ de texte à la demande. Si vous modifiez la feuille de style en cours d’utilisation, le champ de texte est redessiné avec la nouvelle feuille de style. Vous pouvez définir la feuille de style sur null ou undefined pour ne pas en utiliser. Si la feuille de style en cours d’utilisation est supprimée, le champ de texte est redessiné sans feuille de style.

Remarque : lorsque la feuille de style est supprimée, le contenu de TextField.text et TextField.htmlText se modifie pour intégrer le formatage qui a été appliqué auparavant par la feuille de style. Pour préserver le contenu d’origine de TextField.htmlText sans le formatage, enregistrez la valeur dans une variable avant de supprimer la feuille de style.



Implémentation
    public function get styleSheet():StyleSheet
    public function set styleSheet(value:StyleSheet):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant définit un simple objet StyleSheet et l’affecte à un champ de texte avec contenu HTML. Définissez la propriété stylesheet avant de définir le contenu.
package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.StyleSheet;

    public class TextStylesheetExample extends Sprite {
        var myLabel:TextField = new TextField();
        var labelText:String = "Hello world.";
        var newStyle:StyleSheet = new StyleSheet();

        public function TextStylesheetExample()
       {
            var styleObj:Object = new Object();
            styleObj.fontWeight = "bold";
            styleObj.color = "#660066";
            newStyle.setStyle(".defStyle", styleObj);

            myLabel.styleSheet=newStyle;
            myLabel.htmlText=labelText;
            addChild(myLabel);
        }
    }
}

text

propriété 
text:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Une chaîne qui correspond au texte du champ de texte. Les lignes sont séparées par le caractère de retour chariot (’\r’, ASCII 13). Cette propriété contient du texte non formaté dans le champ de texte, sans balises HTML.

Pour obtenir le texte du formulaire HTML, utilisez la propriété htmlText.

Remarque : si une feuille de style est appliquée au champ de texte, le contenu de la propriété text est interprété au format HTML.



Implémentation
    public function get text():String
    public function set text(value:String):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant crée un objet TextField appelé tf1 et affecte une chaîne au format HTML à sa propriété text. Lorsque la propriété htmlText est suivie, une chaîne au format HTML est renvoyée avec des balises supplémentaires (telles que <P> et <FONT>) qui sont ajoutées de façon automatique par Flash Player. Lorsque la valeur de la propriété text est suivie, la chaîne non formatée et sans balises HTML s’affiche.

Par comparaison, les mêmes opérations sont exécutées sur un autre objet TextField appelé tf2 et un objet StyleSheet est alors affecté à la propriété styleSheet de tf2 avant la définition de sa propriété htmlText. Dans ce cas, lorsque la propriété htmlText est suivie, elle inclut uniquement le texte HTML qui a été affecté à l’origine à la propriété htmlText, ce qui indique qu’aucune balise supplémentaire n’a été ajoutée par Flash Player.

package {
    import flash.display.Sprite;
    import flash.text.StyleSheet;
    import flash.text.TextField;

    public class TextField_text extends Sprite {
        public function TextField_text() {
            var tf1:TextField = createCustomTextField(10, 10, 400, 22);
            tf1.htmlText = "<b>Lorem ipsum dolor sit amet.</b>";

            // htmlText: <P ALIGN="LEFT"><FONT FACE="Times New Roman" SIZE="12" COLOR="#000000" LETTERSPACING="0" KERNING="0"><b>Lorem ipsum dolor sit amet.</b></FONT></P>
            trace("htmlText: " + tf1.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf1.text);
            
            var tf2:TextField = createCustomTextField(10, 50, 400, 22);
            tf2.styleSheet = new StyleSheet();
            tf2.htmlText = "<b>Lorem ipsum dolor sit amet.</b>";
            // htmlText: <b>Lorem ipsum dolor sit amet.</b>
            trace("htmlText: " + tf2.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf2.text);
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

textColor

propriété 
textColor:uint

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Couleur du texte dans un champ de texte, au format hexadécimal. Le système de couleur hexadécimal utilise les six chiffres pour représenter les valeurs de couleur. Chaque chiffre a 16 valeurs ou caractères possibles. La plage de caractères va de 0 à 9, puis de A à F. Par exemple, le noir correspond à 0x000000 et le blanc à 0xFFFFFF.

La valeur par défaut est 0 (0x000000).



Implémentation
    public function get textColor():uint
    public function set textColor(value:uint):void

Exemple  ( Comment utiliser cet exemple )
Le code ActionScript suivant crée un objet TextField et affecte à la propriété textColor la couleur rouge (0xFF0000).
package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_textColor extends Sprite {
        public function TextField_textColor() {
            var tf:TextField = createCustomTextField(10, 10, 100, 300);
            tf.text = "This will be red text";
            tf.textColor = 0xFF0000;            
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

textHeight

propriété 
textHeight:Number  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Hauteur du texte en pixels.



Implémentation
    public function get textHeight():Number

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant crée un objet TextField et lui affecte du texte. Les instructions trace affichent les valeurs des propriétés textWidth et textHeight. Par comparaison, les propriétés width et height s’affichent également. (Tenez compte du fait que les valeurs qui s’affichent pour textHeight et textWidth dépendent de la police utilisée sur votre ordinateur).
package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_textHeight extends Sprite {
        public function TextField_textHeight() {
            var tf:TextField = createCustomTextField(10, 10, 100, 150);
            tf.text = "Sample text";
            
            trace("textWidth: " + tf.textWidth); // textWidth: 55.75
            trace("textHeight: " + tf.textHeight); // textHeight: 13.450000000000001
            trace("width: " + tf.width); // width: 100
            trace("height: " + tf.height); // height: 150
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            result.background = true;
            addChild(result);
            return result;
        }
    }
}

textInteractionMode

propriété 
textInteractionMode:String  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 11, Flash Lite 4

Propriété du mode d’interaction ; la valeur par défaut est TextInteractionMode.NORMAL. Sur les plates-formes mobiles, le mode normal permet de faire défiler le texte, mais pas de le sélectionner. L’utilisateur peut passer au mode sélectionnable via le menu contextuel intégré au champ de texte. Sur les ordinateurs de bureau, le mode normal permet de faire défiler le champ de texte et de le sélectionner.



Implémentation
    public function get textInteractionMode():String

textWidth

propriété 
textWidth:Number  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Largeur du texte en pixels.



Implémentation
    public function get textWidth():Number

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant crée un objet TextField et lui affecte du texte. Les instructions trace affichent les valeurs des propriétés textWidth et textHeight. Par comparaison, les propriétés width et height s’affichent également. (Tenez compte du fait que les valeurs qui s’affichent pour textHeight et textWidth dépendent de la police utilisée sur votre ordinateur).
package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_textHeight extends Sprite {
        public function TextField_textHeight() {
            var tf:TextField = createCustomTextField(10, 10, 100, 150);
            tf.text = "Sample text";
            
            trace("textWidth: " + tf.textWidth); // textWidth: 55.75
            trace("textHeight: " + tf.textHeight); // textHeight: 13.450000000000001
            trace("width: " + tf.width); // width: 100
            trace("height: " + tf.height); // height: 150
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            result.background = true;
            addChild(result);
            return result;
        }
    }
}

thickness

propriété 
thickness:Number

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9

Epaisseur des bords du glyphe dans ce champ de texte. Cette propriété s’applique uniquement lorsque flash.text.AntiAliasType est défini sur flash.text.AntiAliasType.ADVANCED.

La plage de thickness est comprise entre -200 et 200. Si vous tentez de définir thickness sur une valeur en dehors de cette plage, cette propriété est définie sur la valeur valide la plus proche, soit -200 ou 200.

La valeur par défaut est 0.



Implémentation
    public function get thickness():Number
    public function set thickness(value:Number):void

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant montre l’effet de la modification de la propriété thickness d’un objet TextField. Vous devez intégrer la police et définir la propriété antiAliasType sur ADVANCED.
package
{
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.AntiAliasType;
    import flash.text.GridFitType;
    import flash.text.TextFormat;

    public class thicknessExample extends Sprite
    {
        public function thicknessExample()
        {
    var format1:TextFormat = new TextFormat();
    format1.font="Arial";
    format1.size=24;
    var lTxt:String = "The quick brown fox";

    var tf1:TextField=createCustomTextField(0,lTxt,format1,-200);
    var tf2:TextField=createCustomTextField(30,lTxt,format1,0);
    var tf3:TextField=createCustomTextField(60,lTxt,format1,200);
        }

        private function createCustomTextField(y:Number,fldTxt:String,format:TextFormat,fldThickness:Number):TextField 
       {
            var result:TextField = new TextField();
            result.y=y;
            result.text=fldTxt;
            result.embedFonts=true;
            result.autoSize=TextFieldAutoSize.LEFT;
            result.antiAliasType=AntiAliasType.ADVANCED;
            result.gridFitType=GridFitType.PIXEL;
            result.thickness=fldThickness;
            result.setTextFormat(format);
            addChild(result);
            return result;
        }
    }
}

type

propriété 
type:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Type du champ de texte. L’une des constantes TextFieldType suivantes : TextFieldType.DYNAMIC, qui spécifie un champ de texte dynamique, que l’utilisateur ne peut pas modifier, ou TextFieldType.INPUT, qui spécifie un champ de texte de saisie, que l’utilisateur peut modifier.

La valeur par défaut est dynamic.



Implémentation
    public function get type():String
    public function set type(value:String):void

Valeur émise
ArgumentError — Le paramètre type spécifié n’appartient pas à flash.text.TextFieldType.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )
L’exemple suivant crée deux champs de texte : tfDynamic et tfInput. Le texte est entré dans les deux champs de texte. Cependant, tfDynamic voit sa propriété type définie sur TextFieldType.DYNAMIC, tandis que tfInput voit sa propriété type définie sur TextFieldType.INPUT, ce qui signifie que l’utilisateur peut modifier le texte de tfInput mais ne peut que consulter le texte de tfDynamic.
package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_type extends Sprite {
        public function TextField_type() {
            var tfDynamic:TextField = createCustomTextField(10, 10, 100, 20);
            tfDynamic.type = TextFieldType.DYNAMIC;
            tfDynamic.text = "hello";

            var tfInput:TextField = createCustomTextField(10, 45, 100, 20);
            tfInput.type = TextFieldType.INPUT;
            tfInput.text = "world";
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.background = true;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

useRichTextClipboard

propriété 
useRichTextClipboard:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9

Spécifie si le formatage du texte peut être copié et collé en même temps que le corps du texte. Lorsque défini sur true, Flash Player copie et colle le formatage (tel que les paramètres d’alignement, gras et italique) lorsque vous copiez et collez entre différents champs. Les champs de texte d’origine et de destination pour la procédure de copie et collage doivent disposer d’une propriété useRichTextClipboard définie sur true. La valeur par défaut est false.



Implémentation
    public function get useRichTextClipboard():Boolean
    public function set useRichTextClipboard(value:Boolean):void

Exemple  ( Comment utiliser cet exemple )
Cet exemple crée un champ de saisie de texte (tf1) et deux champs de texte dynamiques (tf2 et tf3). Le code affecte à chaque champ de texte dynamique un objet TextFormat (police Courier Bold). La propriété useRichTextClipboard du champ de texte tf2 est définie sur false. La propriété useRichTextClipboard du champ de texte tf3 est définie sur true. Lorsque vous copiez le texte du champ tf2 pour le coller dans le champ tf1, le texte collé ne reproduit pas le formatage. Lorsque vous copiez le texte du champ tf3 (dont la propreté useRichTextClipboard est définie sur true) pour le coller dans le champ tf1, le texte collé reproduit le formatage.
package
{
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.text.TextFormat;

    public class useRichTextClipboard extends Sprite
    {
        public function useRichTextClipboard()
        {
    var format1:TextFormat = new TextFormat();
    format1.font="Courier";
    format1.bold=true;

    var tf1:TextField = createCustomTextField(10, 10, 200, 20);
    tf1.type=TextFieldType.INPUT;
    tf1.useRichTextClipboard=true;

    var tf2:TextField = createCustomTextField(220, 10, 200, 20);
    tf2.text="1.Text loses format";
    tf2.setTextFormat(format1);
    tf2.useRichTextClipboard=false;

    var tf3:TextField = createCustomTextField(220, 50, 200, 20);
    tf3.text="2.Text includes format";
    tf3.setTextFormat(format1);
    tf3.useRichTextClipboard=true;
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField 
       {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.background = true;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

wordWrap

propriété 
wordWrap:Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Valeur booléenne indiquant si le champ de texte comporte un retour à la ligne. Si la valeur de wordWrap est true, le champ de texte comporte un retour à la ligne ; si la valeur est false, le champ de texte ne comporte pas de retour à la ligne. La valeur par défaut est false.



Implémentation
    public function get wordWrap():Boolean
    public function set wordWrap(value:Boolean):void

Exemple  ( Comment utiliser cet exemple )
L’exemple suivant révèle la différence entre la définition du paramètre wordWrap sur true et sa définition sur false : Deux occurrences TextField sont créées, dont le contenu est trop important pour leur largeur. La propriété wordWrap du premier (appelée tfWrap) est définie sur true. Elle est définie sur false pour le deuxième (tfNoWrap).
package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_wordWrap extends Sprite {
        public function TextField_wordWrap() {
            var tfWrap:TextField = createCustomTextField(10, 10, 100, 100);
            tfWrap.wordWrap = true;
            tfWrap.text = "(wordWrap = true):\nThis is very long text that will certainly extend beyond the width of this text field";

            var tfNoWrap:TextField = createCustomTextField(10, 150, 100, 100);
            tfNoWrap.wordWrap = false;
            tfNoWrap.text = "(wordWrap = false):\nThis is very long text that will certainly extend beyond the width of this text field";
        }

        private function createCustomTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.background = true;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}
Détails du constructeur

TextField

()Constructeur
public function TextField()

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Crée une occurrence de TextField. Après avoir créé une occurrence de TextField, utilisez la méthode addChild() ou addChildAt() de l’objet DisplayObjectContainer parent pour ajouter l’occurrence de TextField à la liste d’affichage.

La taille par défaut d’un champ de texte est de 100 x 100 pixels.


Exemple  ( Comment utiliser cet exemple )

L’exemple suivant indique comment créer de façon dynamique un objet TextField de saisie dans ActionScript 3.0 en définissant la propriété type de l’objet de champ de texte sur la constante TextFieldType.INPUT. Exemple fourni par ActionScriptExamples.com.
var theTextField:TextField = new TextField();
theTextField.type = TextFieldType.INPUT;
theTextField.border = true;
theTextField.x = 10;
theTextField.y = 10;
theTextField.multiline = true;
theTextField.wordWrap = true;
addChild(theTextField);
Détails de la méthode

appendText

()méthode
public function appendText(newText:String):void

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Ajoute la chaîne spécifiée par le paramètre newText à la fin du texte du champ de texte. Cette méthode est plus efficace que l’affectation d’addition (+=) pour une propriété text (telle que someTextField.text += moreText), notamment pour les champs de texte dont le contenu est volumineux.

Paramètres

newText:String — Chaîne à ajouter au texte existant.


Exemple  ( Comment utiliser cet exemple )

L’exemple suivant affiche l’heure si ce n’est pas le week-end ou le texte « It’s the weekend » si ça l’est. Il compte également le nombre de caractères jusqu’à une certaine position et le nombre de lignes du champ de texte.

Le champ de texte outputText est défini pour s’adapter automatiquement au texte en se redimensionnant sous forme de texte justifié à gauche via la propriété autoSize. La propriété outputText.text écrit la première ligne du contenu et la méthode appendText() ajoute le reste du contenu (il n’est pas nécessaire de commencer par la propriété text. La méthode appendText() peut également être utilisée pour ajouter du texte depuis le début). Le fait de définir la propriété text une seconde fois remplace le texte d’origine. Utilisez l’opérateur += pour ajouter du contenu avec la propriété text.

L’instruction if vérifie si la date correspond à un Samedi (6) ou à un Dimanche (0). Si ce n’est pas le cas, la méthode toLocaleTimeString() renvoie l’heure locale, qui est ajoutée au contenu du champ de texte.

La propriété length est utilisée pour lire le nombre de caractères juste avant que la fonction ne soit appelée, et la propriété numLines compte le nombre de lignes du champ de texte. Notez que les lignes vides comptent dans le nombre de lignes et les espaces vides et les sauts de ligne (\n) sont pris en compte dans la longueur du contenu.

  package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
 
    public class TextField_appendTextExample extends Sprite {
         
        public function TextField_appendTextExample() {
            var outputText:TextField = new TextField();
            var today:Date = new Date();
                
            outputText.x = 10;
            outputText.y = 10;
            outputText.background = true;
            outputText.autoSize = TextFieldAutoSize.LEFT;
 
            outputText.text = "WHAT TIME IS IT?" + "\n\n";
 
            if((today.day == 0) || (today.day == 6)) {
                outputText.appendText("It's the weekend.");
                outputText.appendText("\n\n");
           
            } else {
                outputText.appendText("The time is: ");
                outputText.appendText(today.toLocaleTimeString() + ".\n\n");  
            }

            outputText.appendText("Number of characters including line breaks and spaces so far: ");
            outputText.appendText(outputText.length.toString() + "\n");
            outputText.appendText("Number of lines in the outputText: ");
            outputText.appendText(outputText.numLines.toString());   

            this.addChild(outputText);
        }
    }
}

getCharBoundaries

()méthode 
public function getCharBoundaries(charIndex:int):Rectangle

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie un rectangle représentant le cadre de sélection du caractère.

Paramètres

charIndex:int — Valeur d’index de base zéro du caractère (par exemple, la première position est 0, la deuxième position est 1, etc.).

Valeur renvoyée
Rectangle — Un rectangle avec des valeurs x et y minimales et maximales qui définissent le cadre de sélection du caractère.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, la méthode getCharBoundaries() est utilisée pour marquer (mettre en évidence) un caractère sélectionné par l’utilisateur.

La classe définit l’objet Shape spotlight qui servira à tracer un rectangle autour de chaque caractère sélectionné. Lorsque l’utilisateur clique sur le champ de texte myTextField, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getCharIndexAtPoint() obtient l’index du caractère sur lequel s’effectue le clic à partir des coordonnées localX et localY du clic de la souris, lié au Sprite contenant. La méthode getCharIndexAtPoint() renvoie -1 si le point (clic de la souris) n’a pas été effectué sur un caractère. Comme le champ de texte peut être plus grand que le texte, l’(index) du nombre entier renvoyé est vérifié pour s’assurer que l’utilisateur a cliqué sur un caractère. L’entier d’index est également utilisé par getCharBoundaries() pour obtenir un objet Rectangle qui gère la limite du caractère. La méthode clear() efface tout objet Shape spotlight précédemment affiché. Un nouveau rectangle, dont la taille correspond aux limites de hauteur et de largeur du caractère, est produit à l’emplacement du caractère (avec un décalage à partir des coordonnées (10, 10)) via les coordonnées x et y du rectangle frame. Pour mettre le caractère en évidence, l’objet Shape spotlight est coloré en jaune et l’opacité est définie sur 35 pour cent, de manière à ce que le caractère soit visible. Notez que les espaces sont également considérés comme des caractères.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.geom.Rectangle;
    import flash.events.MouseEvent;
    import flash.text.TextFieldAutoSize;
    import flash.display.Shape;

    public class TextField_getCharBoundariesExample extends Sprite
    {
        private var myTextField:TextField = new TextField();    
        private var spotlight:Shape = new Shape();
        
        public function TextField_getCharBoundariesExample() {
            
            myTextField.x = 10;
            myTextField.y = 10; 
            myTextField.border = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;
            
            myTextField.text = "Selected a character from this text by clicking on it."

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
            
            this.addChild(myTextField);    
            this.addChild(spotlight);
         }

        private function clickHandler (e:MouseEvent):void {
            var index:int = myTextField.getCharIndexAtPoint(e.localX, e.localY);
 
            if (index != -1) {
                 var frame:Rectangle = myTextField.getCharBoundaries(index);

                spotlight.graphics.clear();    
                spotlight.graphics.beginFill(0xFFFF00, .35);
                spotlight.graphics.drawRect((frame.x + 10), (frame.y + 10), frame.width, frame.height);            
                spotlight.graphics.endFill();
            }
        } 
    }
}

getCharIndexAtPoint

()méthode 
public function getCharIndexAtPoint(x:Number, y:Number):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie la valeur d’index de base zéro du caractère au point spécifié par les paramètres x et y.

Paramètres

x:Number — Coordonnée x du caractère.
 
y:Number — Coordonnée y du caractère.

Valeur renvoyée
int — Valeur d’index de base zéro du caractère (par exemple, la première position est 0, la deuxième position est 1, etc.). Renvoie -1 si le point n’est pas au-dessus d’un caractère.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, lorsqu’un utilisateur clique sur un caractère, ce dernier apparaît en miroir dans un autre champ de texte au-dessus du texte.

Le premier champ de texte gère le texte que l’utilisateur va sélectionner. Pour être certain que l’utilisateur a cliqué sur le texte mais ne l’a pas sélectionné, la propriété selectable est définie sur false. Lorsque l’utilisateur clique sur le champ de texte firstTextField, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getCharIndexAtPoint() renvoie l’index du caractère à partir des coordonnées localX et localY du clic de la souris. Comme le champ de texte peut être plus grand que le texte, l’(index) du nombre entier renvoyé est vérifié pour s’assurer que l’utilisateur a cliqué sur un caractère (la méthode getCharIndexAtPoint() renvoie -1 si le point (clic de la souris) n’a pas été effectué sur un caractère). Les coordonnées de la souris sont utilisées pour définir les coordonnées du nouveau champ de texte où le caractère mis en miroir doit apparaître. La couleur du caractère dans le second champ de texte est définie sur rouge. Enfin, le texte du second champ est défini sur le caractère sélectionné, récupéré via la méthode charAt(). Notez que l’utilisation de la propriété text à la place de la méthode appendText() écrasera le caractère dans le second champ de texte au lieu de l’ajouter.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.geom.Rectangle;
    import flash.events.MouseEvent;
    import flash.text.TextFieldAutoSize;
    
    public class TextField_getCharIndexAtPointExample extends Sprite {
        private var firstTextField:TextField = new TextField();    
        private var secondTextField:TextField = new TextField();
        
        public function TextField_getCharIndexAtPointExample() {

            firstTextField.x = 100;
            firstTextField.y = 100; 
            firstTextField.width = 260;
            firstTextField.height = 20;
            firstTextField.border = true;
            firstTextField.background = true;
            firstTextField.selectable = false;
            
            firstTextField.text = "Selected a character from this text by clicking on it."

            firstTextField.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(firstTextField);    
            this.addChild(secondTextField);
         }

        private function clickHandler (e:MouseEvent):void {
            var index:int = firstTextField.getCharIndexAtPoint(e.localX, e.localY);

            if (index != -1) {
                secondTextField.x = mouseX;
                secondTextField.y =  70;
                secondTextField.border = true;
                secondTextField.selectable = false;
                secondTextField.background = true;
                secondTextField.textColor = 0xFF0000;
                secondTextField.autoSize = TextFieldAutoSize.LEFT;
                secondTextField.text = firstTextField.text.charAt(index);    
            }
        } 
    }
}

getFirstCharInParagraph

()méthode 
public function getFirstCharInParagraph(charIndex:int):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

En fonction d’un caractère d’index, renvoie l’index du premier caractère dans le même paragraphe.

Paramètres

charIndex:int — Valeur d’index de base zéro du caractère (par exemple, le premier caractère est 0, le deuxième caractère est 1, etc.).

Valeur renvoyée
int — Valeur d’index de base zéro du premier caractère dans le même paragraphe.

Valeur émise
RangeError — Le caractère d’index spécifié est hors limites.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, une mise en forme de paragraphe est appliquée au contenu du champ de texte. Lorsque l’utilisateur clique sur un paragraphe, le texte de ce dernier est aligné à droite, puis retrouve son format (par défaut) original (aligné à gauche) lorsque l’utilisateur clique de nouveau sur le paragraphe.

Dans le constructeur, le champ de texte myTextField est défini pour renvoyer le texte à la ligne. La méthode getTextFormat renvoie le format d’origine du premier caractère du contenu du champ de texte, placé dans l’objet TextFormat originalFormat. Un nouvel objet TextFormat (newFormat) est également défini et le format justifié à droite est affecté à sa propriété align. Lorsque l’utilisateur clique sur le champ de texte, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getCharIndexAtPoint() renvoie l’index du caractère à partir des coordonnées localX et localY du clic de la souris. La première instruction if vérifie si l’utilisateur a cliqué sur un caractère. Via l’entier clickIndex renvoyé par la méthode getCharIndexAtPoint(), la méthode getFirstCharInParagraph() renvoie l’index du premier caractère du paragraphe dans lequel l’utilisateur a cliqué. L’index du dernier caractère du paragraphe est déterminé en ajoutant la longueur du paragraphe (via la méthode getParagraphLength()) à l’index du premier caractère du paragraphe, moins le dernier caractère (\n). La seconde instruction if vérifie le format du premier caractère du paragraphe. Si sa valeur d’alignement correspond au format original (justifié à gauche), le nouveau format est appliqué à tous les caractères du paragraphe. Dans le cas contraire, le format du paragraphe est réinitialisé sur son format d’origine. L’alignement, ainsi que le formatage tel que les retraits, les puces, les taquets de tabulation et les marges gauches et droites, sont des formats destinés aux paragraphes. Notez qu’une fois que le retour à la ligne ou le saut de ligne est utilisé, le formatage ne s’applique qu’à la première ligne du paragraphe si l’argument endIndex n’est pas défini pour la méthode setTextFormat().

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.events.MouseEvent;
    import flash.text.TextFormat;
    import flash.text.TextFormatAlign;

    public class TextField_getFirstCharInParagraphExample extends Sprite
    {
        private var myTextField:TextField = new TextField();
        private var originalFormat:TextFormat = new TextFormat();
        private var newFormat:TextFormat = new TextFormat(); 
        
        public function TextField_getFirstCharInParagraphExample() {
            myTextField.x = 10;
            myTextField.y = 10; 
            myTextField.border = true;
            myTextField.wordWrap = true;
            myTextField.width = 300;
            myTextField.height = 300; 
            myTextField.background = true;
             
            myTextField.appendText("The TextField class is used to create display objects for "
                        + "text display and input. All dynamic and input text fields in a SWF file " 
                        + "are instances of the TextField class. You can use the TextField class "
                        + "to perform low-level text rendering. However, in Flex, you typically use "
                        + "the Label, Text, TextArea, and TextInput controls to process text. "  
                        + "You can give a text field an instance name in the Property inspector "
                        + "and use the methods and properties of the TextField class to manipulate it with ActionScript. "
                        + "TextField instance names are displayed in the Movie Explorer and in the Insert "
                        + "Target Path dialog box in the Actions panel.\n\n"  
                        + "To create a text field dynamically, use the TextField constructor.\n\n"
                        + "The methods of the TextField class let you set, select, and manipulate "  
                        + "text in a dynamic or input text field that you create during authoring or at runtime.\n\n");

            originalFormat = myTextField.getTextFormat(0);

            newFormat.align = TextFormatAlign.RIGHT;

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
  
            this.addChild(myTextField);
        }

        private function clickHandler(e:MouseEvent):void {
            var clickIndex:int = myTextField.getCharIndexAtPoint(e.localX, e.localY);
                  
            if(clickIndex != -1) {
                var paragraphFirstIndex:int = myTextField.getFirstCharInParagraph(clickIndex);
                var paragraphEndIndex:int = paragraphFirstIndex + ((myTextField.getParagraphLength(clickIndex) - 1));
            
                if (myTextField.getTextFormat(paragraphFirstIndex).align == originalFormat.align) {
                     myTextField.setTextFormat(newFormat, paragraphFirstIndex, paragraphEndIndex);
                }else {
                     myTextField.setTextFormat(originalFormat, paragraphFirstIndex, paragraphEndIndex);
                }
            } 
        }
    }
}
 

getImageReference

()méthode 
public function getImageReference(id:String):DisplayObject

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie une référence DisplayObject pour l’id donné, pour une image ou un fichier SWF qui a été ajouté à un champ de texte qui applique le format HTML à l’aide de la balise <img>. La balise <img> est au format suivant :

   <img src = 'filename.jpg' id = 'instanceName' >

Paramètres

id:String — L’id à faire correspondre (dans l’attribut id de la balise <img>).

Valeur renvoyée
DisplayObject — L’objet d’affichage qui correspond à l’image ou au fichier SWF possédant l’attribut id correspondant dans la balise <img> du champ de texte. Pour les médias chargés à partir d’une source externe, cet objet est de type Loader et, une fois chargé, l’objet média devient l’enfant de cet objet Loader. Pour le média intégré dans le fichier SWF, il s’agit de l’objet chargé. S’il n’existe pas de balise <img> avec un paramètre id correspondant, la méthode renvoie null.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, lorsque l’utilisateur clique dans le champ de texte, l’image du champ est définie sur une opacité de 25 pour cent et pivote de 90 degrés par rapport à sa position d’origine. L’image continue à pivoter à chaque clic suivant.

L’image (image.jpg) est incluse via le code HTML (ici, le fichier image est supposé être dans le même répertoire que le fichier SWF). Un attribut id doit être défini pour la balise img pour pouvoir accéder à l’image via la méthode getImageReference(). La propriété htmlText est utilisée pour inclure un contenu de chaîne au format HTML. Lorsque l’utilisateur clique sur le champ de texte myTextField, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getImageReference() renvoie une référence aux images sous forme d’objet DisplayObject. Cette référence peut être utilisée pour manipuler l’image, comme tout objet DisplayObject. Ici, les propriétés alpha (transparence) et rotation sont définies. La propriété transform peut également être utilisée pour accéder à la matrice, à la transformation de couleur et aux limites de pixel de l’objet d’affichage. Notez également que flash.display.DisplayObject doit être importé.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.display.DisplayObject;
    
    import flash.text.TextFieldAutoSize;
    
    public class TextField_getImageReferenceExample extends Sprite
    {
        private var myTextField:TextField = new TextField();
        
        public function TextField_getImageReferenceExample()
        {
            var myText1:String = "<p>Here is an image we want to mainpulate: <img src='image.jpg' id='testimage'></p>";

            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.width = 250;
            myTextField.height = 250;
            myTextField.background = true;
            myTextField.border = true;
            myTextField.border = true;
            myTextField.multiline = true;

            myTextField.htmlText = myText1;
            
            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
            
            this.addChild(myTextField);
        }
 
        private function clickHandler(e:MouseEvent):void {
            var imageRef:DisplayObject = myTextField.getImageReference("testimage");
 
            imageRef.rotation += 90;
            imageRef.x = 125;
            imageRef.y = 125;
            imageRef.alpha = 0.25;      
        }
    }
}

getLineIndexAtPoint

()méthode 
public function getLineIndexAtPoint(x:Number, y:Number):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie la valeur d’index de base zéro de la ligne au point spécifié par les paramètres x et y.

Paramètres

x:Number — Coordonnée x de la ligne.
 
y:Number — Coordonnée y de la ligne.

Valeur renvoyée
int — Valeur d’index de base zéro de la ligne (par exemple, la première ligne est 0, la deuxième ligne est 1, etc.). Renvoie -1 si le point n’est pas au-dessus d’une ligne.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, lorsqu’un utilisateur sélectionne une ligne dans le sonnet de Shakespeare, cette ligne est copiée (ajoutée) dans un nouveau champ de texte.

Dans le constructeur, le champ de texte poem est défini pour ne pas aller à la ligne (puisqu’il s’agit d’un poème). La propriété autoSize est également utilisée pour définir le texte de sorte qu’il s’ajuste automatiquement et se redimensionne sous forme de texte justifié à gauche. Le champ de texte poemCopy est placé sous le champ de texte poem. Lorsqu’un utilisateur clique sur une des lignes du poème, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getLineIndexAtPoint() renvoie l’index de la ligne dans laquelle l’utilisateur a cliqué sur la base des coordonnées localX et localY du clic de la souris (comme ici le poème original est adapté à la taille du champ de texte, il n’est pas nécessaire de vérifier la présence d’une erreur de plage (RangeError) renvoyée par la méthode getCharIndexAtPoint()). L’index de la ligne est ensuite utilisé pour obtenir le contenu de la ligne sous forme de chaîne avec la méthode getLineText(), alors ajouté au contenu du champ de texte poemCopy. La copie peut se poursuivre de façon continue mais, après un certain point, le texte sortira de la plage du champ de texte poemCopy affichable.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.events.MouseEvent;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;

    public class TextField_getLineIndexAtPointExample extends Sprite {
        private var poem:TextField = new TextField();
        private var poemCopy:TextField = new TextField();
        
        public function TextField_getLineIndexAtPointExample() {
            poem.border = true;
            poem.autoSize = TextFieldAutoSize.LEFT;
            poem.x = 10;
            poem.wordWrap = false;

            poemCopy.height = 250;
            poemCopy.width = 270;
            poemCopy.y = 230;
            poemCopy.x = 10;
            poemCopy.background = true;
            poemCopy.border = true;
            poemCopy.wordWrap = false;
            
            poem.appendText("Let me not to the marriage of true minds\n"
                              + "Admit impediments. love is not love\n"
                              + "Which alters when it alteration finds\n"
                              + "Or bends with the remover to remove:\n"
                              + "O no! it is an ever-fixed mark\n" 
                              + "That looks on tempests and is never shaken;\n"
                              + "It is the star to every wandering bark,\n"
                              + "Whose worth's unknown, although his height be taken.\n"
                              + "Love's not Time's fool, though rosy lips and cheeks\n"
                              + "Within his bending sickle's compass come:\n"
                              + "Love alters not with his brief hours and weeks,\n"
                              + "But bears it out even to the edge of doom.\n"
                              + "If this be error and upon me proved,\n"
                              + "I never writ, nor no man ever loved.");

           poem.addEventListener(MouseEvent.CLICK, clickHandler); 

           this.addChild(poem); 
           this.addChild(poemCopy);
        }
    
        private function clickHandler(e:MouseEvent):void {
                var index:int = poem.getLineIndexAtPoint(e.localX, e.localY);
                var s:String;

                s = poem.getLineText(index);
                poemCopy.appendText(s + "\n");
        }
    }
}

getLineIndexOfChar

()méthode 
public function getLineIndexOfChar(charIndex:int):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie la valeur d’index de base zéro de la ligne qui contient le caractère spécifié par le paramètre charIndex.

Paramètres

charIndex:int — Valeur d’index de base zéro du caractère (par exemple, le premier caractère est 0, le deuxième caractère est 1, etc.).

Valeur renvoyée
int — Valeur d’index de base zéro de la ligne.

Valeur émise
RangeError — Le caractère d’index spécifié est hors limites.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, la méthode getLineIndexOfChar() renvoie les numéros de ligne des 100ème et 500ème caractères du champ de texte.

Le champ de texte myTextField est défini pour aller à la ligne et se redimensionner sous forme de texte justifié à gauche. La méthode getLineIndexOfChar() renvoie l’index de la ligne des index des caractères spécifiés (100 et 500). Ces informations sont ensuite ajoutées après le paragraphe. Notez que comme l’index de la ligne commence à 0, l’index de la ligne (index) est augmenté de 1 pour obtenir le numéro de ligne. De même, si l’affichage est redimensionné, le numéro de ligne peut changer mais les informations ici demeureront les mêmes puisque la méthode n’est invoquée qu’une seule fois.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class TextField_getLineIndexOfCharExample extends Sprite 
    {
        public function TextField_getLineIndexOfCharExample()
        {
            var myTextField:TextField = new TextField();
            
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.width = 200;
            myTextField.background = true;  
            myTextField.border = true;
            myTextField.wordWrap = true;
            myTextField.autoSize = TextFieldAutoSize.LEFT;

            myTextField.appendText("The TextField class is used to create display objects for "
                + "text display and input. All dynamic and input text fields in a SWF file" 
                + "are instances of the TextField class. You can use the TextField class "
                + "to perform low-level text rendering. However, in Flex, you typically use "
                + "the Label, Text, TextArea, and TextInput controls to process text. "  
                + "You can give a text field an instance name in the Property inspector "
                + "and use the methods and properties of the TextField class to manipulate it with ActionScript. "
                + "TextField instance names are displayed in the Movie Explorer and in the Insert "
                + "Target Path dialog box in the Actions panel.\n\n");

            var index:int = myTextField.getLineIndexOfChar(100);
            myTextField.appendText("100th character is in line: " +  (index + 1) + "\n");
            index = myTextField.getLineIndexOfChar(500);
            myTextField.appendText("500th character is in line: " + (index + 1));

            this.addChild(myTextField);
        }
    }
}

getLineLength

()méthode 
public function getLineLength(lineIndex:int):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie le nombre de caractères d’une ligne de texte donnée.

Paramètres

lineIndex:int — Nombre de lignes pour lesquelles vous souhaitez connaître la longueur.

Valeur renvoyée
int — Nombre de caractères dans la ligne.

Valeur émise
RangeError — Le numéro de ligne spécifié est hors limites.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, une fois que l’utilisateur sélectionne une ligne, la longueur de cette ligne (nombre de caractères) apparaît dans un champ de texte distinct.

Sous forme d’illustration, le champ de texte myTextField, qui affiche le texte à compter, est défini sur INPUT, ce qui signifie que les utilisateurs peuvent modifier les lignes ou ajouter des lignes entre les lignes ou à la fin (une ligne vide est créée à l’aide du saut de ligne (\n) à la fin de la dernière ligne). Le champ de texte countLines, dans lequel apparaît le résultat du comptage de la longueur de ligne, est défini au-dessous du champ de texte myTextField et son texte n’est pas sélectionnable. Lorsque l’utilisateur clique sur une ligne du champ de texte myTextField, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getLineIndexAtPoint() renvoie l’index de la ligne dans laquelle l’utilisateur a cliqué en utilisant les coordonnées localX et localY du clic de la souris. L’instruction if vérifie si l’utilisateur a cliqué sur un caractère. Dans l’affirmative, la méthode getLineLength(), à l’aide de l’index de la ligne, renvoie le nombre de caractères présents dans la ligne. Notez que les lignes vides placées entre les lignes incluent le second saut de ligne (\n) et présente un compte de 1 caractère, alors que le compte de la ligne située après la dernière ligne est de 0. Les espaces comptent également pour un caractère. Les utilisateurs peuvent écrire une nouvelle ligne ou modifier une ligne et obtenir le compte de caractères de la ligne en cliquant sur celle-ci. Si le renvoi à la ligne est utilisé et que l’écran est redimensionné, l’index de la ligne peut changer.

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class TextField_getLineLengthExample extends Sprite {
        private var myTextField:TextField = new TextField();
        private var countLines:TextField = new TextField();  

        public function TextField_getLineLengthExample() {
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.width = 350;
            myTextField.height = 150;
            myTextField.background = true;
            myTextField.border = true;
            myTextField.type = TextFieldType.INPUT;
            
            myTextField.appendText("Click on the lines to count its number of characters:\n\n");
            myTextField.appendText("This is a short line.\n");
            myTextField.appendText("This is a longer line than the last line.\n\n");
            myTextField.appendText("This one is even longer than the one before. It has two sentences.\n");

            this.addChild(myTextField);

            countLines.border = true;
            countLines.x = 10;
            countLines.y = 180;
            countLines.height = 30;
            countLines.width = 200;
            countLines.background = true;
            countLines.selectable = false;

           this.addChild(countLines);    

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function clickHandler(e:MouseEvent):void {
            var index:int = myTextField.getLineIndexAtPoint(e.localX, e.localY);
        
            if (index != -1) {
            var lenght:int = myTextField.getLineLength(index);

            countLines.text = "Number of characters in the line is: " + lenght.toString();
            }
        }
    }
}

getLineMetrics

()méthode 
public function getLineMetrics(lineIndex:int):flash.text:TextLineMetrics

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie les informations métriques relatives à une ligne de texte donnée.

Paramètres

lineIndex:int — Nombre de lignes pour lesquelles vous désirez des informations métriques.

Valeur renvoyée
flash.text:TextLineMetrics — Un objet TextLineMetrics.

Valeur émise
RangeError — Le numéro de ligne spécifié est hors limites.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

L’exemple suivant présente des valeurs de mesures de ligne pour deux lignes de texte mises en forme différemment.

Le texte ajouté correspond à deux lignes à partir de Song of Myself de Walt Whitman. Un nouvel objet TextFormat (newFormat) est utilisé pour définir le format de la seconde ligne. La première ligne gère le format par défaut. La méthode getLineMetrics() renvoie un objet TextLineMetrics pour une ligne spécifique (l’index de la ligne commence à 0). Via les objets TextLineMetrics metrics1 et metrics2 des lignes un et deux, respectivement, les valeurs ascendante, descendante, de hauteur et de poids de la ligne sont récupérées et affichées. Les nombres qui en résultent sont convertis en chaînes mais ne sont pas arrondis. Notez que cette valeur est liée à la ligne et non pas à un caractère spécifique. Elle reflète la plage de caractères d’une ligne. Par exemple, si une ligne présente des caractères différents avec des formats de hauteur différents, le caractère présentant la hauteur la plus élevée détermine la valeur. Cela signifie également que lorsque le format du caractère est modifié, certaines valeurs de mesures peuvent également changer.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.text.TextFieldAutoSize;
    import flash.text.AntiAliasType;
    import flash.text.TextFormat;
 
    public class TextField_getLineMetricsExample extends Sprite {

        public function TextField_getLineMetricsExample() {
            var myTextField:TextField = new TextField();
            var newFormat:TextFormat = new TextFormat(); 

            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.wordWrap = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;
            
            myTextField.appendText("A child said What is the grass? fetching it to me with full hands;\n");
            myTextField.appendText("How could I answer the child? I do not know what it is any more than he.\n\n");

            newFormat.size = 14;
            newFormat.font = "Arial";
            newFormat.italic = true;
            myTextField.setTextFormat(newFormat, 67, 139);
               
            var metrics1:TextLineMetrics = myTextField.getLineMetrics(0);
             
            myTextField.appendText("Metrics ascent for the line 1 is: " + metrics1.ascent.toString() + "\n");
            myTextField.appendText("Metrics descent is: " + metrics1.descent.toString() + "\n");
            myTextField.appendText("Metrics height is: " + metrics1.height.toString() + "\n"); 
            myTextField.appendText("Metrics width is: " + metrics1.width.toString() + "\n\n");

            var metrics2:TextLineMetrics = myTextField.getLineMetrics(1);
             
            myTextField.appendText("Metrics ascent for the line 2 is: " + metrics2.ascent.toString() + "\n");
            myTextField.appendText("Metrics descent is: " + metrics2.descent.toString() + "\n");
            myTextField.appendText("Metrics height is: " + metrics2.height.toString() + "\n"); 
            myTextField.appendText("Metrics width is: " + metrics2.width.toString() + "\n");

            addChild(myTextField);
        }
    }
}

getLineOffset

()méthode 
public function getLineOffset(lineIndex:int):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie l’index du premier caractère de la ligne spécifiée par le paramètre lineIndex.

Paramètres

lineIndex:int — Valeur d’index de base zéro de la ligne (par exemple, la première ligne est 0, la deuxième ligne est 1, etc.).

Valeur renvoyée
int — Valeur d’index de base zéro du premier caractère de la ligne.

Valeur émise
RangeError — Le numéro de ligne spécifié est hors limites.

Exemple  ( Comment utiliser cet exemple )

L’exemple suivant recherche le premier caractère de la ligne 4, qui change si l’écran (et le champ de texte) est redimensionné.

Le champ de texte myTextField est défini sur un renvoi à la ligne. Le champ de texte countField affichera le premier caractère de la ligne 4. Lorsque l’utilisateur clique sur le champ de texte myTextField, la méthode clickHandler() est invoquée.

Dans la méthode clickHandler(), la méthode getLineOffset() renvoie l’index du premier caractère dans l’index de ligne 3, correspondant à la quatrième ligne du texte (l’index de la première ligne est 0). La méthode charAt() est utilisée pour obtenir le caractère à l’aide de l’index du premier caractère de la quatrième ligne. Le contenu du champ de texte countField est actualisé sur la base de ces informations via la propriété text du champ de texte countField. L’utilisation de la propriété countField.text signifie qu’après chaque clic le contenu du champ de texte countField est remplacé. Si l’utilisateur redimensionne l’affichage, le contenu est renvoyé à la ligne et le premier caractère de la ligne 4 peut changer. En cas de nouveau clic sur le champ myTextField, le contenu du champ de texte countField est mis à jour avec le nouveau premier caractère de la quatrième ligne.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.events.MouseEvent;

    public class TextField_getLineOffsetExample extends Sprite {
        private var myTextField:TextField = new TextField();
        private var countField:TextField = new TextField();
        
        public function TextField_getLineOffsetExample() {
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.width = 150;
            myTextField.height = 300;
            myTextField.background = true;
            myTextField.border = true;
            myTextField.wordWrap = true;

            countField.height = 20;
            countField.width = 200;
            countField.x = 10;
            countField.y = 320;
            countField.selectable = false;
            
            myTextField.appendText("The TextField class is used to create display objects for "
                        + "text display and input. All dynamic and input text fields in a SWF file " 
                        + "are instances of the TextField class. You can use the TextField class "
                        + "to perform low-level text rendering. However, in Flex, you typically use "
                        + "the Label, Text, TextArea, and TextInput controls to process text. "  
                        + "You can give a text field an instance name in the Property inspector "
                        + "and use the methods and properties of the TextField class to manipulate it with ActionScript.");

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
        
            this.addChild(myTextField);
            this.addChild(countField);
        }
    
            private function clickHandler(e:MouseEvent):void {
                var c:String;
                var index:int;
                
                index = myTextField.getLineOffset(3);
                c = myTextField.text.charAt(index);
                countField.text = "The first character of line 4 is: " + c;
            }
    }
}

getLineText

()méthode 
public function getLineText(lineIndex:int):String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie le texte de la ligne spécifiée par le paramètre lineIndex.

Paramètres

lineIndex:int — Valeur d’index de base zéro de la ligne (par exemple, la première ligne est 0, la deuxième ligne est 1, etc.).

Valeur renvoyée
String — Chaîne de texte contenue dans la ligne spécifiée.

Valeur émise
RangeError — Le numéro de ligne spécifié est hors limites.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, les numéros de ligne de toutes les occurrences du terme « love » utilisées dans le sonnet de Shakespeare sont identifiés et affichés.

Le champ de texte poem est défini pour s’adapter automatiquement au texte et se redimensionner sous forme de texte justifié à gauche. La propriété wordWrap étant définie sur false, les lignes du poème n’iront pas à la ligne, bien qu’avec l’utilisation de la propriété autoSize, cela n’est généralement pas un problème. La boucle for procède à une itération sur les lignes du sonnet via la propriété numLines du champ de texte. La méthode getLineText() renvoie le contenu de la ligne sous forme de chaîne (notez que la propriété numLines renvoie le nombre de lignes en commençant à la ligne 1, alors que pour la méthode getLineText(), le numéro de lignes commence à 0). A l’aide du modèle d’expression standard (/love/i), l’instruction if recherche toute sous-chaîne du mot en majuscule ou en minuscule. Si le modèle est trouvé, la méthode search renvoie l’index de la première sous-chaîne correspondante, ou renvoie -1 dans le cas contraire (s’il n’y a pas de correspondance). Le numéro de ligne ou le terme « love » a été trouvé ((i + 1)) est alors placé dans la chaîne lineResult. La méthode de chaîne convertit l’argument de nombre ((i + 1)) en chaîne tant qu’il y a un autre argument correspondant à une chaîne («   »). Le résultat de lignes de la recherche comprend les lignes présentant les termes « loved » ou « Love’s ». Si la chaîne « Love was found in lines: » a été ajoutée avant la boucle for, le terme « Love » de cette ligne aura également été inclus.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
 
    public class TextField_getLineTextExample extends Sprite {
           
        public function TextField_getLineTextExample() {
           var poem:TextField = new TextField();
           var lineResult:String = ""; 
           var pattern:RegExp = /love/i;

            poem.x = 10;
            poem.y = 10;
            poem.background = true;
            poem.wordWrap = false;
            poem.autoSize = TextFieldAutoSize.LEFT;
            
            poem.text = "Let me not to the marriage of true minds\n"
                              + "Admit impediments. love is not love\n"
                              + "Which alters when it alteration finds\n"
                              + "Or bends with the remover to remove:\n"
                              + "O no! it is an ever-fixed mark\n" 
                              + "That looks on tempests and is never shaken;\n"
                              + "It is the star to every wandering bark,\n"
                              + "Whose worth's unknown, although his height be taken.\n"
                              + "Love's not Time's fool, though rosy lips and cheeks\n"
                              + "Within his bending sickle's compass come:\n"
                              + "Love alters not with his brief hours and weeks,\n"
                              + "But bears it out even to the edge of doom.\n"
                              + "If this be error and upon me proved,\n"
                              + "I never writ, nor no man ever loved.\n\n";

            for (var i:int = 0; i < poem.numLines; i++) {

                var s:String = poem.getLineText(i);
                        
                if(s.search(pattern) != -1) {
                    lineResult += (i + 1) + " ";
                }
            }

            poem.appendText("Love was found in lines: " + lineResult);
             
            this.addChild(poem);                      
        }
    }
}

getParagraphLength

()méthode 
public function getParagraphLength(charIndex:int):int

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

En fonction d’un caractère d’index, renvoie la longueur du paragraphe qui contient le caractère donné. La longueur est mesurée à partir du premier caractère du paragraphe (tel que renvoyé par getFirstCharInParagraph()) et non pas par rapport à l’index de caractères qui a été transmis.

Paramètres

charIndex:int — Valeur d’index de base zéro du caractère (par exemple, le premier caractère est 0, le deuxième caractère est 1, etc.).

Valeur renvoyée
int — Renvoie le nombre de caractères du paragraphe.

Valeur émise
RangeError — Le caractère d’index spécifié est hors limites.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, lorsqu’un utilisateur sélectionne un paragraphe, la longueur du paragraphe et le nombre de caractères « s » qu’il contient s’affichent dans un champ de texte distinct.

Le champ de texte myTextField affiche les paragraphes que l’utilisateur sélectionne. Lorsque l’utilisateur clique sur le champ de texte, l’événement MouseEvent.CLICK est distribué et la méthode clickHandler() est appelée. La longueur du paragraphe et le nombre de caractères « s » s’affichent dans le champ de texte countField, placées au-dessous du champ de texte myTextField.

Dans la méthode clickHandler(), la méthode getCharIndexAtPoint() renvoie l’index du caractère à partir des coordonnées localX et localY du clic de la souris. La première instruction if vérifie si l’utilisateur a cliqué sur un caractère. La méthode getFirstCharInParagraph() utilise cet index pour renvoyer l’index du premier caractère du même paragraphe. La longueur du paragraphe renvoyée par la méthode getParagraphLength() est utilisée avec l’index du premier caractère du paragraphe pour déterminer l’index de la fin du paragraphe. Une boucle for procède à une itération sur le paragraphe en recherchant le nombre de caractères « s ».

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.events.MouseEvent;

    public class TextField_getParagraphLengthExample extends Sprite {
        private var myTextField:TextField = new TextField();
        private var countField:TextField = new TextField();

        public function TextField_getParagraphLengthExample() {
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.border = true;
            myTextField.wordWrap = true;
            myTextField.width = 300;
            myTextField.height = 280;
            
            myTextField.appendText("The TextField class is used to create display objects for "
                        + "text display and input. All dynamic and input text fields in a SWF file" 
                        + "are instances of the TextField class. You can use the TextField class "
                        + "to perform low-level text rendering. However, in Flex, you typically use "
                        + "the Label, Text, TextArea, and TextInput controls to process text. "  
                        + "You can give a text field an instance name in the Property inspector "
                        + "and use the methods and properties of the TextField class to manipulate it with ActionScript. "
                        + "TextField instance names are displayed in the Movie Explorer and in the Insert "
                        + "Target Path dialog box in the Actions panel.\n\n"  
                        + "To create a text field dynamically, use the TextField() constructor.\n\n"
                        + "The methods of the TextField class let you set, select, and manipulate "  
                        + "text in a dynamic or input text field that you create during authoring or at runtime.");

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
            
            countField.x = 10;
            countField.y = 300;
            countField.height = 50;
            countField.width = 250;
            countField.background = true;
            countField.selectable = false;

            this.addChild(myTextField);
            this.addChild(countField);
        }

        private function clickHandler(e:MouseEvent):void {
            var index:int = myTextField.getCharIndexAtPoint(e.localX, e.localY);
            
            if(index != -1) {
                var beginParag:int = myTextField.getFirstCharInParagraph(index);
                var paragLength:int = myTextField.getParagraphLength(index);
                var endParag:int = beginParag + paragLength;
                var sCount:uint = 0;

                for (var i:int = beginParag; i <= endParag; i++) {
                    if ((myTextField.text.charAt(i) == "s") || (myTextField.text.charAt(i) == "S")) {
                        sCount++; 
                    }

                countField.text = "Paragraph length is: " + paragLength.toString() + "\n" 
                        + "Number of 's' characters in the paragraph: " + sCount.toString();
                }
            }
        }
    }
}

getTextFormat

()méthode 
public function getTextFormat(beginIndex:int = -1, endIndex:int = -1):flash.text:TextFormat

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Renvoie un objet TextFormat qui contient des informations de formatage pour la plage de texte délimitée par les paramètres beginIndex et endIndex. Seules les propriétés communes à l’ensemble du texte spécifié sont définies dans l’objet TextFormat obtenu. Toute propriété qui est mixed, ce qui signifie qu’elle a différentes valeurs à différents endroits du texte, a la valeur null.

Si vous ne spécifiez pas de valeurs pour ces paramètres, cette méthode s’applique à l’ensemble du texte dans le champ de texte.

Le tableau suivant décrit trois utilisations possibles :

UtilisationDescription
my_textField.getTextFormat()Renvoie un objet TextFormat contenant des informations de mise en forme pour l’ensemble du texte d’un champ de texte. Seules les propriétés communes à l’ensemble du texte d’un champ de texte sont définies dans l’objet TextFormat obtenu. Toute propriété qui est mixed, ce qui signifie qu’elle a différentes valeurs à différents endroits du texte, a la valeur null.
my_textField.getTextFormat(beginIndex:Number)Renvoie un objet TextFormat contenant une copie du format de texte du caractère à la position beginIndex.
my_textField.getTextFormat(beginIndex:Number,endIndex:Number)Renvoie un objet TextFormat contenant des informations de mise en forme pour la plage de texte de beginIndex à endIndex-1. Seules les propriétés communes à l’ensemble du texte de la plage spécifiée sont définies dans l’objet TextFormat obtenu. Toute propriété qui est mixte (c.-à-d. a différentes valeurs à différents endroits de la plage) a sa valeur définie sur null.

Paramètres

beginIndex:int (default = -1) — Facultatif ; un entier qui spécifie le début d’une plage de texte au sein du champ de texte.
 
endIndex:int (default = -1) — Facultatif ; entier qui spécifie la position du premier caractère après la plage de texte souhaitée. Comme prévu, la spécification des valeurs beginIndex et endIndex, entraîne la lecture du texte de beginIndex à endIndex-1.

Valeur renvoyée
flash.text:TextFormat — Objet TextFormat qui représente les propriétés de mise en forme du texte spécifié.

Valeur émise
RangeError — La valeur beginIndex ou endIndex est hors limite.

Eléments de l’API associés


Exemple
Comment utiliser cet exemple
Consultez l’exemple de la méthode getFirstCharInParagraph() ou setTextFormat() pour une illustration de l’utilisation de la méthode getTextFormat().

isFontCompatible

()méthode 
public static function isFontCompatible(fontName:String, fontStyle:String):Boolean

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: Flash Player 10, AIR 1.5, Flash Lite 4

Renvoie true si une police incorporée est disponible avec les paramètres fontName et fontStyle spécifiés, où Font.fontType est flash.text.FontType.EMBEDDED. Depuis Flash Player 10, un fichier SWF peut contenir deux sortes de polices incorporées. Les polices incorporées normales ne sont utilisées qu’avec des objets TextField. Les polices incorporées CFF ne sont utilisées qu’avec les classes flash.text.engine. Les deux types sont différenciés par la propriété fontType de la classe Font, renvoyée par la fonction enumerateFonts().

Un objet TextField ne peut pas utiliser de police de type EMBEDDED_CFF. Si embedFonts est défini sur true et que la seule police disponible au moment de l’exécution avec le nom et le style spécifiés est de type EMBEDDED_CFF, Flash Player ne peut pas restituer le texte, comme si aucune police n’était disponible avec ce nom et ce style.

Si les deux polices EMBEDDED et EMBEDDED_CFF sont disponibles avec le même nom et le même style, la police EMBEDDED est sélectionnée et le texte est restitué avec la police EMBEDDED.

Paramètres

fontName:String — Nom de la police incorporée à vérifier.
 
fontStyle:String — Spécifie le style de police à vérifier. Utilisez flash.text.FontStyle.

Valeur renvoyée
Booleantrue si une police incorporée compatible est disponible, sinon false.

Valeur émise
ArgumentError — Le paramètre fontStyle spécifié n’appartient pas à flash.text.FontStyle.

Eléments de l’API associés

replaceSelectedText

()méthode 
public function replaceSelectedText(value:String):void

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Remplace la sélection actuelle par le contenu du paramètre value. Le texte est inséré au niveau de la sélection actuelle, à l’aide du format de caractère par défaut actuel et du format de paragraphe par défaut. Le texte n’est pas traité en tant que texte HTML.

Vous pouvez utiliser la méthode replaceSelectedText() pour insérer et effacer du texte sans perturber le formatage des caractères et de paragraphe du reste du texte.

Remarque : cette méthode ne fonctionne pas lorsqu’une feuille de style est appliquée au champ de texte.

Paramètres

value:String — La chaîne devant remplacer le texte sélectionné.


Valeur émise
Error — Cette méthode ne peut pas être appliquée à un champ de texte associé à une feuille de style.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, l’utilisateur efface une partie du texte dans le premier champ de texte en le sélectionnant et remplace un texte sélectionné dans le second champ de texte par la chaîne « NEW TEXT ».

Deux objets TextField différents sont créés et des écouteurs d’événement sont ajoutés pour les événements MouseEvent.MOUSE_UP. Un relâchement du bouton de la souris survient lorsque l’utilisateur libère le bouton de la souris, événement se produisant généralement après la sélection d’un texte. Notez que le paramètre par défaut d’un champ de texte est que son texte soit sélectionné.

Dans la méthode mouseHandler1(), lorsqu’un utilisateur libère le bouton de la souris dans le champ de texte myTextField1, le texte est effacé et remplacé par une chaîne vide. Cela peut continuer jusqu’à ce que tout le texte soit effacé. Dans la méthode mouseHandler2(), lorsqu’un utilisateur sélectionne du texte dans le champ de texte myTextField2, les propriétés selectionBeginIndex et selectionEndIndex sont vérifiées pour voir si des caractères ont été sélectionnés (les propriétés selectionBeginIndex et selectionEndIndex n’ont pas la même valeur si du texte a été sélectionné). Le texte sélectionné est alors remplacé par la chaîne « NEW TEXT ». Cela peut continuer jusqu’à ce que le texte original du second champ de texte soit remplacé par la chaîne « NEW TEXT ».

package {
    import flash.display.Sprite;
    import flash.text.TextField;    
    import flash.events.MouseEvent;

    public class TextField_replaceSelectedTextExample extends Sprite {
        private var myTextField1:TextField = new TextField();
        private var myTextField2:TextField = new TextField();
        
        public function TextField_replaceSelectedTextExample() {
            myTextField1.x = 10;
            myTextField1.width = 300;
            myTextField1.height = 50; 
            myTextField1.background = true; 
            myTextField1.border = true;
            myTextField1.text = "Select the text you want to remove from the line.";
            
            myTextField2.x = 10;
            myTextField2.y = 60;
            myTextField2.width = 300;
            myTextField2.height = 50;
            myTextField2.background = true;
            myTextField2.border = true;
            myTextField2.text = "Select the text you want to replace with NEW TEXT.";
            
            myTextField1.addEventListener(MouseEvent.MOUSE_UP, mouseHandler1);
            myTextField2.addEventListener(MouseEvent.MOUSE_UP, mouseHandler2);
            
            this.addChild(myTextField1);
            this.addChild(myTextField2);
        }
        
        private function mouseHandler1(e:MouseEvent):void {
            myTextField1.replaceSelectedText("");
        }

        private function mouseHandler2(e:MouseEvent):void {
            if(myTextField2.selectionBeginIndex != myTextField2.selectionEndIndex) {
                myTextField2.replaceSelectedText("NEW TEXT");    
            }
        }
    }
}

replaceText

()méthode 
public function replaceText(beginIndex:int, endIndex:int, newText:String):void

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Remplace la plage de caractères que les paramètres beginIndex et endIndex spécifient par le contenu du paramètre newText. Comme prévu, le texte situé entre de beginIndex et endIndex-1 est remplacé.

Remarque : cette méthode ne fonctionne pas lorsqu’une feuille de style est appliquée au champ de texte.

Paramètres

beginIndex:int — Valeur d’index de base zéro pour la position de début de la plage de remplacement.
 
endIndex:int — Position d’index de base zéro du premier caractère après la plage de texte désirée.
 
newText:String — Texte à utiliser pour remplacer la plage de caractères spécifiée.


Valeur émise
Error — Cette méthode ne peut pas être appliquée à un champ de texte associé à une feuille de style.

Exemple  ( Comment utiliser cet exemple )

L’exemple suivant utilise la méthode replaceText() pour supprimer, remplacer et insérer du texte dans un champ de texte.

Le champ de texte outputText est défini pour s’adapter automatiquement au texte et se redimensionner sous forme de texte justifié à gauche. Avec le premier appel de la méthode replaceText(), la première ligne (« This is the wrong heading ») est remplacée par « THIS IS THE HEADING FOR EVERYONE ». Avec le second appel de la méthode, le texte « CORRECT » est inséré entre « THE » et « HEADING ». Avec le troisième appel de la méthode, les mots « FOR EVERYONE » sont supprimés. Notez qu’à chaque appel de la méthode appendText(), les index de début et de fin du texte en cours sont modifiés. Ici, seul le texte final (après modification) apparaît.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    
    public class TextField_replaceTextExample extends Sprite {

        public function TextField_replaceTextExample() {
            var outputText:TextField = new TextField();

            outputText.x = 10;
            outputText.y = 10;
            outputText.background = true;
            outputText.autoSize = TextFieldAutoSize.LEFT;
            
            outputText.appendText("This is the wrong heading");
            outputText.appendText("\n\n"); 
            outputText.appendText("This is the body of the text.");

            outputText.replaceText(0, 25, "THIS IS THE HEADING FOR EVERYONE");

            outputText.replaceText(12, 12, "CORRECT ");
            
            outputText.replaceText(27, 40, "");
            
           this.addChild(outputText);
         }
    }
}

setSelection

()méthode 
public function setSelection(beginIndex:int, endIndex:int):void

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Définit comme sélectionné le texte désigné par les valeurs d’index des premier et dernier caractères, spécifiés par les paramètres beginIndex et endIndex. Si les valeurs des deux paramètres sont identiques, cette méthode définit le point d’insertion, comme si vous définissiez la propriété caretIndex.

Paramètres

beginIndex:int — Valeur d’index de base zéro du premier caractère de la sélection (par exemple, le premier caractère est 0, le deuxième est 1, etc.).
 
endIndex:int — Valeur d’index basée sur zéro du dernier caractère de la sélection.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, une plage de texte prédéfinie est sélectionnée lorsque l’utilisateur clique en un endroit quelconque du champ de texte (mettant en surbrillance les mots « TEXT IN ALL CAPS »).

Deux écouteurs d’événement pour le champ de texte myTextField répondent aux clics de souris et aux relâchements du bouton de la souris par l’utilisateur. Un relâchement du bouton de la souris survient lorsque l’utilisateur libère le bouton de la souris, événement se produisant généralement après la sélection d’un texte. Notez que le paramètre par défaut d’un champ de texte est que son texte soit sélectionné. Lorsque l’utilisateur clique dans le texte, la méthode clickHandler() est invoquée. Lorsque du texte est sélectionné et que le bouton de la souris est relâché, la méthode mouseUpHandler() est invoquée.

Dans les deux méthodes clickHandler() et mouseUpHandler(), la méthode setSelection() définit uniquement la sélection des caractères situés entre les index 54 et 70 (TEXT IN ALL CAPS).

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    
    public class TextField_setSelectionExample extends Sprite
    {
        private var myTextField:TextField = new TextField();

        public function TextField_setSelectionExample() {
            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.text = "No matter where you click on this text field only the TEXT IN ALL CAPS is selected.";

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
            myTextField.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            this.addChild(myTextField);
        }

        private function clickHandler(event:MouseEvent):void {
            myTextField.setSelection(54, 70);
        }

        private function mouseUpHandler(event:MouseEvent):void {
            myTextField.setSelection(54, 70);
        }

    }
}

setTextFormat

()méthode 
public function setTextFormat(format:flash.text:TextFormat, beginIndex:int = -1, endIndex:int = -1):void

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Applique à la partie sélectionnée d’un champ de texte le format spécifié par le paramètre format. La valeur de format doit être un objet TextFormat qui spécifie les modifications à apporter au formatage du texte. Seules les propriétés non null de format sont appliquées au champ de texte. Toute propriété de format qui est définie sur null n’est pas appliquée. Par défaut, toutes les propriétés d’un nouvel objet TextFormat créé sont définies sur null.

Remarque : cette méthode ne fonctionne pas lorsqu’une feuille de style est appliquée au champ de texte.

La méthode setTextFormat() modifie le formatage de texte appliquée à une plage de caractères ou à l’ensemble du corps de texte d’un champ de texte. Pour appliquer les propriétés de format à l’ensemble du texte du champ, ne spécifiez pas de valeur pour beginIndex et endIndex. Pour appliquer les propriétés de format à une plage de texte, spécifiez les valeurs des paramètres beginIndex et endIndex. Vous pouvez utiliser la propriété length pour déterminer les valeurs d’index.

Les deux types d’information de formatage d’un objet TextFormat correspondent au formatage au niveau des caractères et au formatage au niveau du paragraphe. Chaque caractère d’un champ de texte peut avoir ses propres paramètres de mise en forme de caractère, tels que le nom et la taille de la police, gras et italique.

Pour les paragraphes, le premier caractère du paragraphe est analysé pour les paramètres de mise en forme du paragraphe entier. La marge gauche, la marge droite et le retrait sont des exemples de paramètres de mise en forme de paragraphe.

Tout texte inséré manuellement par l’utilisateur, ou remplacé par la méthode replaceSelectedText(), reçoit le formatage par défaut pour un nouveau texte, et non celui spécifié pour le point d’insertion du texte. Pour définir le formatage par défaut du nouveau texte, utilisez defaultTextFormat.

Paramètres

format:flash.text:TextFormat — Un objet TextFormat qui contient des informations de format de caractères et de paragraphes.
 
beginIndex:int (default = -1) — Facultatif ; entier qui spécifie la position d’index de base zéro indiquant le premier caractère de la plage de texte désirée.
 
endIndex:int (default = -1) — Facultatif ; entier qui spécifie le premier caractère après la plage de texte désirée. Si vous spécifiez les valeurs beginIndex et endIndex, le texte situé entre beginIndex et endIndex-1 est mis à jour.

UtilisationDescription
my_textField.setTextFormat(textFormat:TextFormat)Applique les propriétés de textFormat à l’ensemble du texte dans le champ de texte.
my_textField.setTextFormat(textFormat:TextFormat, beginIndex:int)Applique les propriétés de textFormat au texte qui commence à la position beginIndex.
my_textField.setTextFormat(textFormat:TextFormat, beginIndex:int, endIndex:int)Applique les propriétés du paramètre textFormat à la plage de texte de la position beginIndex à la position endIndex-1.

Notez que tout texte inséré manuellement par l’utilisateur, ou remplacé par la méthode replaceSelectedText(), reçoit le formatage par défaut pour un nouveau texte, et non celui spécifié pour le point d’insertion du texte. Pour définir le formatage par défaut du nouveau texte du champ, appliquez la propriété defaultTextFormat.


Valeur émise
Error — Cette méthode ne peut pas être appliquée à un champ de texte associé à une feuille de style.
 
RangeError — La valeur beginIndex ou endIndex est hors limite.

Eléments de l’API associés


Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, lorsque l’utilisateur clique sur le texte, le format d’une plage de texte définie, « TEXT IN ALL CAPS », bascule entre le format de texte par défaut et le nouveau format.

Un écouteur d’événement pour le champ de texte myTextField est ajouté pour répondre aux clics de souris en invoquant la méthode clickHandler(). Dans la méthode clickHandler(), la méthode getTextFormat() renvoie le format en cours d’un caractère (index 55) de la plage de texte prévue, qui est alors placée dans l’objet TextFormat currentTextFormat. L’instructionif vérifie le format de texte currentTextFormat pour voir si le caractère de la plage utilise le nouveau format (la police est définie sur 18). Si ce n’est pas le cas, le nouveau format définit la taille de police sur 18 points, la couleur sur rouge et souligne et met en italique la plage de texte située entre 54 et 70 (TEXT IN ALL CAPS). Si le caractère de la plage utilise le nouveau format, le format de la plage est réinitialisé sur le format par défaut (original) du champ de texte.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;  
    import flash.text.TextFieldAutoSize;  
    import flash.events.MouseEvent;

    public class TextField_setTextFormatExample extends Sprite {
        private var myTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextField_setTextFormatExample() {
            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.selectable = false;
            myTextField.background = true;
            myTextField.text = "No matter where you click on this text field only the TEXT IN ALL CAPS changes format.";

            myTextField.addEventListener(MouseEvent.CLICK, clickHandler);

            newFormat.color = 0xFF0000;
            newFormat.size = 18;
            newFormat.underline = true;
            newFormat.italic = true;
                
            this.addChild(myTextField);
        }

        private function clickHandler(event:MouseEvent):void {
            var currentTextFormat:TextFormat = myTextField.getTextFormat(55);
            
            if(currentTextFormat.size != 18) {
                myTextField.setTextFormat(newFormat, 54, 70);
            }
            else {
                myTextField.setTextFormat(myTextField.defaultTextFormat);
            }    
        }    
    }
}
Détails de l’événement

change

Evénement
Type d’objet d’événement: flash.events.Event
propriété Event.type = flash.events.Event.CHANGE

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Distribué après la modification d’une valeur de contrôle, contrairement à l’événement textInput, qui est distribué avant la modification de la valeur. Contrairement à la version de modèle d’événements W3C DOM de l’événement change, qui ne distribue l’événement que lorsque le contrôle a perdu le focus, la version ActionScript 3.0 de l’événement change est distribuée dès que le contrôle change. Par exemple, si un utilisateur tape du texte dans un champ de texte, un événement change est distribué à chaque pression de touche.

La constante Event.CHANGE définit la valeur de la propriété type de l’objet d’événement change.

Les propriétés de cet événement sont les suivantes :

PropriétéValeur
bubblestrue
cancelablefalse ; il n’existe aucun comportement par défaut à annuler.
currentTargetL’objet qui traite activement l’objet Event avec un écouteur d’événements.
targetObjet dont la valeur a été modifiée. La propriété target ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d’événement. Utilisez la propriété currentTarget pour accéder à l’objet de la liste d’affichage qui traite actuellement l’événement.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, le texte saisi par l’utilisateur (saisie utilisateur) est immédiatement copié (en miroir) dans un autre champ de texte au format de texte différent.

Deux champs de textes sont créés, l’un pour la saisie de l’utilisateur et l’autre (headingTextField), pour la copie de cette saisie. Un objet TextFormat est également créé et le format de texte par défaut est attribué au champ de texte headingTextField. Lorsque le contenu du champ de texte est modifié, la méthode changeHandler() est invoquée et affecte le contenu du champ de texte inputTextField au champ de texte headingTextField (si la méthode a été appelée pour l’événement TextEvent.TEXT_INPUT et non pour l’événement Event.CHANGE, le contenu de la saisie de l’utilisateur n’est copié qu’après une nouvelle saisie utilisateur).

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.text.TextFormat;
    import flash.text.TextFormatAlign;
    import flash.events.Event;
    
    import flash.events.TextEvent;

    public class TextField_Event_changeExample extends Sprite {
        private var inputTextField:TextField = new TextField(); 
        private var headingTextField:TextField = new TextField(); 
        private var newFormat:TextFormat = new TextFormat();
         
        public function TextField_Event_changeExample() {
            headingTextField.x = 10;
            headingTextField.y = 10;
            headingTextField.height = 30;
            headingTextField.width = 400;
            headingTextField.background = true;
            headingTextField.backgroundColor = 0xF5F5DC;
            headingTextField.selectable = false;
 
            inputTextField.x = 10;
            inputTextField.y = 70;
            inputTextField.height = 20;
            inputTextField.width = 230;
            inputTextField.background = true;
            inputTextField.border = true;
            inputTextField.maxChars = 40;
            inputTextField.wordWrap = true;
            inputTextField.type = TextFieldType.INPUT;

            inputTextField.addEventListener(Event.CHANGE, changeHandler);

            newFormat.bold = true;
            newFormat.size = 18;
            newFormat.color = 0xFF0000;
            newFormat.align = TextFormatAlign.CENTER;

            headingTextField.defaultTextFormat = newFormat;

            this.addChild(inputTextField);
            this.addChild(headingTextField);
        }

        private function changeHandler(e:Event):void {
            headingTextField.text = inputTextField.text;
        }
    }
}

link

Evénement  
Type d’objet d’événement: flash.events.TextEvent
propriété TextEvent.type = flash.events.TextEvent.LINK

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Distribué lorsqu’un utilisateur clique sur un lien hypertexte dans un champ de texte HTML dont l’URL commence par « event: ». La partie de l’URL qui suit « event: » est placée dans la propriété text de l’événement LINK.

Remarque : le comportement par défaut, qui consiste à ajouter du texte au champ de texte, se produit uniquement lorsque Flash Player génère l’événement. Dans ce cas, ceci se produit lorsqu’un utilisateur tente de saisir du texte. Vous ne pouvez pas placer du texte dans un champ de texte en lui envoyant des événements textInput.

Définit la valeur de la propriété type d’un objet événement link.

Les propriétés de cet événement sont les suivantes :

PropriétéValeur
bubblestrue
cancelablefalse ; il n’existe aucun comportement par défaut à annuler.
currentTargetL’objet qui traite activement l’objet Event avec un écouteur d’événements.
targetChamp de texte contenant l’hyperlien sur lequel l’utilisateur a cliqué. La propriété target ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d’événement. Utilisez la propriété currentTarget pour accéder à l’objet de la liste d’affichage qui traite actuellement l’événement.
textReste de l’URL après « event: »

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, la fonction playMP3() est définie. Un objet TextField nommé list est créé et renseigné avec du texte HTML. Le texte « Track 1 » et « Track 2 » constitue des liens dans le champ de texte. La fonction playMP3() est appelée lorsque l’utilisateur clique sur l’un ou l’autre lien. Le nom du fichier MP3, qui suit la chaîne « event: » dans l’attribut href de la balise HTML, est transmis à la méthode linkHandler() en tant que propriété text de l’objet d’événement link.
package {
    import flash.display.Sprite;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;
    import flash.events.TextEvent;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class TextField_event_link extends Sprite
    {
        private var myMP3:Sound;
        public function TextField_event_link() {
            myMP3 = new Sound();
            var list:TextField = new TextField();
            list.autoSize = TextFieldAutoSize.LEFT;
            list.multiline = true;
            list.htmlText = "<a href=\"event:track1.mp3\">Track 1</a><br>";
            list.htmlText += "<a href=\"event:track2.mp3\">Track 2</a><br>";
            addEventListener(TextEvent.LINK, linkHandler);
            addChild(list);
        }
        
        private function playMP3(mp3:String):void {
            try {    
                myMP3.load(new URLRequest(mp3));
                myMP3.play();
            }
            catch(err:Error) {
                trace(err.message);
            }
            myMP3.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
        }
        
        private function linkHandler(linkEvent:TextEvent):void {
            playMP3(linkEvent.text);
        }
        
        private function errorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}

scroll

Evénement  
Type d’objet d’événement: flash.events.Event
propriété Event.type = flash.events.Event.SCROLL

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Distribué par un objet TextField après une opération de défilement effectuée par l’utilisateur.

La constante Event.SCROLL définit la valeur de la propriété type d’un objet événement scroll.

Les propriétés de cet événement sont les suivantes :

PropriétéValeur
bubblesfalse
cancelablefalse ; il n’existe aucun comportement par défaut à annuler.
currentTargetL’objet qui traite activement l’objet Event avec un écouteur d’événements.
targetObjet Textfield que l’utilisateur a fait défiler. La propriété target ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d’événement. Utilisez la propriété currentTarget pour accéder à l’objet de la liste d’affichage qui traite actuellement l’événement.

Exemple  ( Comment utiliser cet exemple )

L’exemple suivant définit deux objets TextField. Deux gestionnaires d’événement sont associés au premier objet TextField. Lorsque vous cliquez dans le premier champ de texte, l’événement mouseDown est déclenché et le gestionnaire mouseDownScroll associé est appelé. Le gestionnaire mouseDownScroll() entraîne le défilement du champ. L’événement scroll est ensuite déclenché et le gestionnaire scrollHandler() actualise le second champ de texte pour afficher la position actuelle du défilement.
package
{
    import flash.display.Sprite;
    import flash.text.*;
    import flash.events.Event;
    import flash.events.TextEvent;
    import flash.events.MouseEvent;

    public class TextScrollExample extends Sprite
    {
        private var myTextBox1:TextField = new TextField();
        private var myTextBox2:TextField = new TextField();
        private var myText:String = "Hello world and welcome to the show. It's really nice to meet you. Take your coat off and stay a while. OK, show is over. Hope you had fun. You can go home now. Don't forget to tip your waiter. There are mints in the bowl by the door. Thank you. Please come again.";

        public function TextScrollExample()
        {
            myTextBox1.text = myText;
            myTextBox1.width = 200;
            myTextBox1.height = 50;
            myTextBox1.multiline = true;
            myTextBox1.wordWrap = true;
            myTextBox1.background = true;
            myTextBox1.border = true;
            
            myTextBox2.x=220;
            myTextBox2.text="scrolled to line: " + myTextBox1.scrollV;

            addChild(myTextBox1);
            addChild(myTextBox2);
            myTextBox1.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownScroll);
            myTextBox1.addEventListener(Event.SCROLL, scrollHandler);
        }

        public function mouseDownScroll(event:MouseEvent):void
        {
            myTextBox1.scrollV++;
        }
        public function scrollHandler(event:Event):void
        {
           myTextBox2.text="scrolled to line: " + myTextBox1.scrollV;
        }
    }
}

textInput

Evénement  
Type d’objet d’événement: flash.events.TextEvent
propriété TextEvent.type = flash.events.TextEvent.TEXT_INPUT

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

Flash Player distribue l’événement textInput lorsqu’un utilisateur entre un ou plusieurs caractères de texte. Différentes méthodes de saisie de texte peuvent générer cet événement, ce qui inclut les claviers standard, les éditeurs de méthode d’entrée (IME), les systèmes de reconnaissance vocale, voire même la copie de texte simple sans formatage ni ajout de style.

Définit la valeur de la propriété type d’un objet événement textInput.

Remarque : cet événement n’est pas distribué pour les touches Supprimer ou Retour arrière.

Les propriétés de cet événement sont les suivantes :

PropriétéValeur
bubblestrue
cancelabletrue ; appelez la méthode preventDefault() pour annuler le comportement par défaut.
currentTargetL’objet qui traite activement l’objet Event avec un écouteur d’événements.
targetChamp de texte dans lequel sont entrés des caractères. La cible ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d’événement. Utilisez la propriété currentTarget pour accéder à l’objet de la liste d’affichage qui traite actuellement l’événement.
textCaractère ou série de caractères entré par l’utilisateur.

Exemple  ( Comment utiliser cet exemple )

L’exemple suivant définit deux objets TextField : le premier est un champ de saisie de texte et le deuxième est un champ de texte dynamique. Lorsque vous entrez des caractères dans le premier champ de texte, un événement textInput est déclenché, le gestionnaire textInputHandler() est appelé, et les caractères s’affichent dans le second champ de texte. Lorsque vous collez un bloc de texte dans le champ de saisie, le gestionnaire de l’événement copie l’ensemble du bloc dans l’autre champ.
package
{
    import flash.display.Sprite;
    import flash.text.*;
    import flash.events.Event;
    import flash.events.TextEvent;
    import flash.events.MouseEvent;

    public class TextInputExample extends Sprite
    {
        private var myTextBox1:TextField = new TextField();
        private var myTextBox2:TextField = new TextField();

        public function TextInputExample()
        {
            myTextBox1.type = TextFieldType.INPUT;
            myTextBox1.width = 200;
            myTextBox1.height = 20;
            myTextBox1.background = true;
            myTextBox1.border = true;
            
            myTextBox2.x=220;

            addChild(myTextBox1);
            addChild(myTextBox2);
            myTextBox1.addEventListener(TextEvent.TEXT_INPUT,textInputHandler);
        }

        public function textInputHandler(event:TextEvent):void
        {
           myTextBox2.text=event.text;
        }
    }
}

textInteractionModeChange

Evénement  
Type d’objet d’événement: flash.events.Event

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 11, Flash Lite 4

Flash Player distribue l’événement textInteractionModeChange lorsqu’un utilisateur modifie le mode d’interaction d’un champ de texte. Par exemple, sur Android, l’utilisateur peut passer du mode NORMAL au mode SELECTION à l’aide des options du menu contextuel.

TextFieldExample.as

L’exemple suivant a recours à la classe TextFieldExample pour afficher un message texte. Cette opération s’accomplit de la façon suivante :
  1. Une propriété label de type TextField est créée.
  2. Le constructeur de classe appelle la fonction configureLabel().
  3. La méthode configureLabel() crée tout d’abord un objet TextField et l’affecte à la propriété label, puis définit ses paramètres de la façon suivante :
    • Justifie le champ de texte à gauche.
    • Active le remplissage d’arrière-plan.
    • Active la bordure.
  4. La méthode configureLabel() crée la variable format et l’affecte à une nouvelle occurrence de TextFormat en définissant ses paramètres de la façon suivante :
    • Type de police = Verdana
    • Couleur de la police = rouge uni
    • Taille de la police = 10
    • Soulignement = true
  5. La propriété defaultTextFormat du champ de texte label est définie sur format et l’occurrence de label est ajoutée à la liste d’affichage, qui affiche tout d’abord un champ de texte vide sur la scène.
  6. Le constructeur définit le texte du champ de texte label sur "Hello world and welcome to the show." en appelant la méthode setLabel().
package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFieldExample extends Sprite {
        private var label:TextField;
        private var labelText:String = "Hello world and welcome to the show.";

        public function TextFieldExample() {
            configureLabel();
            setLabel(labelText);
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}




[ X ]Pourquoi existe-t-il du contenu en anglais ?
Certaines parties du Guide de référence ActionScript 3.0 sont en anglais

Tout le contenu du Guide de référence ActionScript 3.0 n’a pas été traduit dans toutes les langues. Si un élément de langage n’est pas traduit, il s’affiche en anglais. Par exemple, la classe ga.controls.HelpBox n’est traduite dans aucune langue. Ainsi, dans la version française du guide de référence, la classe ga.controls.HelpBox apparaît en anglais.