Guide de référence ActionScript® 3.0 pour la plate-forme Adobe® Flash®
Accueil  |  Masquer la liste des packages et des classes |  Packages  |  Classes  |  Nouveautés  |  Index  |  Annexes  |  Pourquoi existe-t-il du contenu en anglais ?
Filtres : Récupération des données du serveur...
Récupération des données du serveur...
flash.text 

TextFormat  - AS3

Packageflash.text
Classepublic class TextFormat
HéritageTextFormat Inheritance Object
Sous-classes UITextFormat

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9, Flash Lite 4

La classe TextFormat représente les informations de formatage de caractères. Utilisez la classe TextFormat pour personnaliser le formatage des champs de texte. Vous pouvez formater le texte des champs statiques et dynamiques. Les propriétés de la classe TextFormat s’appliquent aux polices de périphérique et intégrées. Cependant, pour les polices incorporées, le texte en gras et en italique nécessite en fait des polices spécifiques. Pour afficher du texte en gras ou en italiques avec une police incorporée, vous devez intégrer les variations en gras et en italiques de cette police.

Vous devez utiliser le constructeur new TextFormat() pour créer un objet TextFormat avant de définir les propriétés. Lorsque vous appliquez un objet TextFormat à un champ de texte avec la propriété TextField.defaultTextFormat ou la méthode TextField.setTextFormat(), seules ses propriétés définies sont appliquées. Utilisez la propriété TextField.defaultTextFormat pour appliquer une mise en forme AVANT d’ajouter du texte au TextField, et la méthode setTextFormat() pour ajouter une mise en forme APRES avoir ajouté du texte au TextField. Les propriétés TextFormat ont la valeur null par défaut, dans la mesure où Flash Player applique son propre format par défaut en l’absence de valeurs pour ces propriétés. Le format par défaut que Flash Player utilise pour chaque propriété (si sa valeur est null) prend la forme suivante :

align = « left »
blockIndent = 0
bold = false
bullet = false
color = 0x000000
font = « Times New Roman » (la police par défaut est Times sur le Mac Système X)
indent = 0
italic = false
kerning = false
leading = 0
leftMargin = 0
letterSpacing = 0
rightMargin = 0
size = 12
tabStops = [] (tableau vide)
target = "" (chaîne vide)
underline = false
url = "" (chaîne vide)

La mise en forme par défaut de chaque propriété figure également dans la description des propriétés.

Consulter les exemples

Plus d’exemples

Informations complémentaires

Eléments de l’API associés



Propriétés publiques
 PropriétéDéfini par
  align : String
Indique l’alignement du paragraphe.
TextFormat
  blockIndent : Object
Indique l’indentation du bloc en pixels.
TextFormat
  bold : Object
Spécifie si le texte est en gras.
TextFormat
  bullet : Object
Indique que le texte fait partie d’une liste à puces.
TextFormat
  color : Object
Indique la couleur du texte.
TextFormat
 Inheritedconstructor : Object
Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.
Object
  font : String
Nom de la police pour du texte dans ce format de texte, sous forme de chaîne.
TextFormat
  indent : Object
Indique l’indentation à appliquer de la marge gauche au premier caractère du paragraphe.
TextFormat
  italic : Object
Indique si le texte concerné par ce format doit être en italiques.
TextFormat
  kerning : Object
Valeur booléenne indiquant si le crénage est activé (true) ou désactivé (false).
TextFormat
  leading : Object
Entier représentant le montant d’espace vertical (appelé interlignage) entre les lignes.
TextFormat
  leftMargin : Object
Marge gauche du paragraphe, en pixels.
TextFormat
  letterSpacing : Object
Nombre représentant la quantité d’espace répartie uniformément entre tous les caractères.
TextFormat
  rightMargin : Object
Marge droite du paragraphe, en pixels.
TextFormat
  size : Object
La taille en pixels de ce format de texte.
TextFormat
  tabStops : Array
Spécifie des taquets de tabulation personnalisés, sous forme d’un tableau d’entiers non négatifs.
TextFormat
  target : String
Indique la fenêtre cible dans laquelle s’affiche le lien hypertexte.
TextFormat
  underline : Object
Indique si le texte qui utilise ce format texte est souligné (true) ou non (false).
TextFormat
  url : String
Indique l’URL cible du texte concerné par ce format.
TextFormat
Méthodes publiques
 MéthodeDéfini par
  
TextFormat(font:String = null, size:Object = null, color:Object = null, bold:Object = null, italic:Object = null, underline:Object = null, url:String = null, target:String = null, align:String = null, leftMargin:Object = null, rightMargin:Object = null, indent:Object = null, leading:Object = null)
Crée un objet TextFormat avec les propriétés spécifiées.
TextFormat
 Inherited
Indique si la propriété spécifiée d’un objet est définie.
Object
 Inherited
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.
Object
 Inherited
Indique si la propriété spécifiée existe et est énumérable.
Object
 Inherited
Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.
Object
 Inherited
Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.
Object
 Inherited
Renvoie la représentation sous forme de chaîne de l’objet spécifié.
Object
 Inherited
Renvoie la valeur primitive de l’objet spécifié.
Object
Détails de la propriété

align

propriété
align:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique l’alignement du paragraphe. Les valeurs valides sont des constantes TextFormatAlign.

La valeur par défaut est TextFormatAlign.LEFT.



Implémentation
    public function get align():String
    public function set align(value:String):void

Valeur émise
ArgumentError — Le paramètre align spécifié n’appartient pas à flash.text.TextFormatAlign.

Eléments de l’API associés


Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

blockIndent

propriété 
blockIndent:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique l’indentation du bloc en pixels. L’indentation d’un bloc est appliquée à l’ensemble d’un bloc de texte ; c’est-à-dire à toutes les lignes du texte. Par contraste, l’indentation normale (TextFormat.indent) affecte seulement la première ligne de chaque paragraphe. Si cette propriété est null, l’objet TextFormat ne spécifie pas l’indentation d’un bloc (l’indentation de bloc est de 0).



Implémentation
    public function get blockIndent():Object
    public function set blockIndent(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

bold

propriété 
bold:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Spécifie si le texte est en gras. La valeur par défaut est null, ce qui signifie qu’aucune police en gras n’est utilisée. Si la valeur est true, le texte est en gras.



Implémentation
    public function get bold():Object
    public function set bold(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

bullet

propriété 
bullet:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique que le texte fait partie d’une liste à puces. Dans une liste à puces, chaque paragraphe du texte apparaît en retrait. A gauche de la première ligne de chaque paragraphe, le symbole d’une puce s’affiche. La valeur par défaut est null, ce qui signifie qu’aucune liste à puces n’est utilisée.



Implémentation
    public function get bullet():Object
    public function set bullet(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

color

propriété 
color:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique la couleur du texte. Nombre contenant trois composants RVB 8 bits ; par exemple, 0xFF0000 correspond au rouge et 0x00FF00 au vert. La valeur par défaut est null, ce qui signifie que Flash Player utilise la couleur noire (0x000000).



Implémentation
    public function get color():Object
    public function set color(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

font

propriété 
font:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Nom de la police pour du texte dans ce format de texte, sous forme de chaîne. La valeur par défaut est null, ce qui signifie que Flash Player utilise la police Times New Roman pour le texte.



Implémentation
    public function get font():String
    public function set font(value:String):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

indent

propriété 
indent:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique l’indentation à appliquer de la marge gauche au premier caractère du paragraphe. La valeur par défaut est null, ce qui indique qu’aucune indentation n’est utilisée.



Implémentation
    public function get indent():Object
    public function set indent(value:Object):void

Eléments de l’API associés


Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

italic

propriété 
italic:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique si le texte concerné par ce format doit être en italiques. La valeur par défaut est null, ce qui signifie qu’aucun caractère ne sera en italiques.



Implémentation
    public function get italic():Object
    public function set italic(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

kerning

propriété 
kerning:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9.

Valeur booléenne indiquant si le crénage est activé (true) ou désactivé (false). Le crénage modifie le nombre de pixels séparant chaque paire de caractères pour améliorer la lisibilité et ne doit être employé que si nécessaire, dans les titres en grande police, par exemple. Le crénage est supporté uniquement pour les polices incorporées.

Certaines polices, telles que Verdana, et les polices à espacement fixe, telles que Courier New, ne prennent pas en charge le crénage.

La valeur par défaut est null, ce qui signifie que le crénage est désactivé.



Implémentation
    public function get kerning():Object
    public function set kerning(value:Object):void

leading

propriété 
leading:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Entier représentant le montant d’espace vertical (appelé leading) entre les lignes. La valeur par défaut est null, ce qui indique que le montant d’interlignage est défini sur 0.



Implémentation
    public function get leading():Object
    public function set leading(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

leftMargin

propriété 
leftMargin:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Marge gauche du paragraphe, en pixels. La valeur par défaut est null, ce qui indique que la marge gauche est de 0 pixels.



Implémentation
    public function get leftMargin():Object
    public function set leftMargin(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

letterSpacing

propriété 
letterSpacing:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9.

Nombre représentant la quantité d’espace répartie uniformément entre tous les caractères. Cette valeur spécifie le nombre de pixels à ajouter après chaque caractère. La valeur par défaut est null, ce qui signifie que les lettres sont séparées par 0 pixels. Vous pouvez utiliser des valeurs décimales telles que 1.75.



Implémentation
    public function get letterSpacing():Object
    public function set letterSpacing(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

rightMargin

propriété 
rightMargin:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Marge droite du paragraphe, en pixels. La valeur par défaut est null, ce qui indique que la marge droite est de 0 pixels.



Implémentation
    public function get rightMargin():Object
    public function set rightMargin(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

size

propriété 
size:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

La taille en pixels de ce format de texte. La valeur par défaut est null, ce qui signifie qu’une taille de 12 pixels est utilisée.



Implémentation
    public function get size():Object
    public function set size(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

tabStops

propriété 
tabStops:Array

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Spécifie des taquets de tabulation personnalisés, sous forme d’un tableau d’entiers non négatifs. Chaque taquet de tabulation est spécifié en pixels. Si des taquets de tabulation personnalisés ne sont pas spécifiés (null), le taquet de tabulation par défaut est 4 (largeur moyenne de caractère).



Implémentation
    public function get tabStops():Array
    public function set tabStops(value:Array):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

target

propriété 
target:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique la fenêtre cible dans laquelle s’affiche le lien hypertexte. Si la fenêtre cible est une chaîne vide, le texte s’affiche dans la fenêtre cible par défaut _self. Vous pouvez choisir un nom personnalisé ou l’un des quatre noms suivants : _self spécifie l’image active dans la fenêtre actuelle, _blank spécifie une nouvelle fenêtre, _parent spécifie le parent de l’image active et _top spécifie l’image de plus haut niveau dans la fenêtre active. Si la propriété TextFormat.url est une chaîne vide ou null, vous pouvez obtenir ou définir cette propriété, mais la propriété n’aura aucun effet.



Implémentation
    public function get target():String
    public function set target(value:String):void

Eléments de l’API associés


Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

underline

propriété 
underline:Object

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique si le texte qui utilise ce format texte est souligné (true) ou non (false). Ce soulignement est similaire à celui créé par la balise <U> mais ce dernier n’est pas un vrai soulignement, étant donné qu’il ne saute pas correctement les lettres à jambage. La valeur par défaut est null, ce qui indique qu’aucune partie du texte n’est soulignée.



Implémentation
    public function get underline():Object
    public function set underline(value:Object):void

Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .

url

propriété 
url:String

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Indique l’URL cible du texte concerné par ce format. Si la propriété url est une chaîne vide, le texte ne comporte pas de lien hypertexte. La valeur par défaut est null, ce qui indique que le texte ne comporte pas de lien hypertexte.

Remarque : le texte et le format qui lui est associé doivent être définis avec la propriété htmlText pour que le lien hypertexte fonctionne.



Implémentation
    public function get url():String
    public function set url(value:String):void

Eléments de l’API associés


Exemple
Comment utiliser cet exemple
Consultez l’exemple TextFormat() constructor pour une illustration de l’utilisation de cette propriété .
Détails du constructeur

TextFormat

()Constructeur
public function TextFormat(font:String = null, size:Object = null, color:Object = null, bold:Object = null, italic:Object = null, underline:Object = null, url:String = null, target:String = null, align:String = null, leftMargin:Object = null, rightMargin:Object = null, indent:Object = null, leading:Object = null)

Version du langage: ActionScript 3.0
Versions du moteur d’exécution: AIR 1.0, Flash Player 9., Flash Lite 4

Crée un objet TextFormat avec les propriétés spécifiées. Vous pouvez modifier les propriétés de l’objet TextFormat pour modifier le format des champs de texte.

Tout paramètre peut être défini sur null pour indiquer qu’il n’est pas défini. Tous les paramètres sont facultatifs ; tous les paramètres omis sont traités comme null.

Paramètres
font:String (default = null) — Le nom de la police du texte sous forme de chaîne.
 
size:Object (default = null) — Un entier qui indique la taille, en pixels.
 
color:Object (default = null) — La couleur du texte qui utilise ce format. Nombre contenant trois composants RVB 8 bits ; par exemple, 0xFF0000 correspond au rouge et 0x00FF00 au vert.
 
bold:Object (default = null) — Valeur booléenne qui spécifie si le texte est en gras.
 
italic:Object (default = null) — Valeur booléenne qui spécifie si le texte est en italiques.
 
underline:Object (default = null) — Valeur booléenne qui spécifie si le texte est souligné.
 
url:String (default = null) — URL correspondant au lien hypertexte du texte de ce format de texte. Si l’url est une chaîne vide, le texte ne comporte pas de lien hypertexte.
 
target:String (default = null) — Fenêtre cible dans laquelle s’affiche le lien hypertexte. Si la fenêtre cible est une chaîne vide, le texte s’affiche dans la fenêtre cible par défaut _self. Si le paramètre url est défini sur une chaîne vide ou sur la valeur null, vous pouvez obtenir ou définir cette propriété, mais la propriété n’aura aucun effet.
 
align:String (default = null) — L’alignement du paragraphe, en tant que valeur TextFormatAlign.
 
leftMargin:Object (default = null) — Indique la marge gauche du paragraphe, en pixels.
 
rightMargin:Object (default = null) — Indique la marge droite du paragraphe, en pixels.
 
indent:Object (default = null) — Entier indiquant l’indentation à appliquer de la marge gauche au premier caractère du paragraphe.
 
leading:Object (default = null) — Nombre qui indique le montant d’interlignage vertical entre les lignes.

Exemple  ( Comment utiliser cet exemple )

Dans l’exemple suivant, un utilisateur peut sélectionner dans une liste diverses options de mise en forme du texte pour les appliquer au contenu d’un autre champ de texte. Si l’utilisateur clique sur le contenu du champ de texte, le formatage retrouve son format par défaut (original).

Le champ de texte formatTextField présente la liste de toutes les options des propriétés de la classe TextField (à l’exception de kerning) sur une ligne distincte. Lorsqu’un utilisateur clique sur une ligne du champ de texte formatTextField, la méthode formatTextFieldClickHandler() est déclenchée.

La méthode formatTextFieldClickHandler() appelle la méthode TextField.getLineIndexAtPoint() pour obtenir l’index de la ligne sur lequel l’utilisateur a cliqué, puis la méthode TextField.getLineText() pour obtenir le contenu de la ligne. L’instruction switch vérifie le contenu de la ligne et définit une propriété de l’objet TextFormat newformat en conséquence. La méthode setTextFormat() définit ensuite le format de texte du champ de texte contentTextField sur le nouveau format. En cliquant sur les différentes lignes formatTextField, un utilisateur peut appliquer une autre mise en forme au champ de texte contentTextField (le paramètre tab est un tableau qui définit un taquet de tabulation distinct pour chaque tabulation de la ligne). Si la ligne url ou target est sélectionnée, l’utilisateur doit cliquer sur le champ de texte contentTextField pour activer le lien et afficher le contenu de l’URL cible (page d’accueil Flex). La valeur par défaut de la propriété target est « _self », ce qui signifie que le contenu s’affiche dans la fenêtre active lorsque l’utilisateur sélectionne la ligne url. Pour utiliser la propriété target, une URL doit déjà être définie dans la propriété url.

Si un utilisateur clique sur le champ de texte contentTextField, la méthode contentTextFieldClickHandler() est déclenchée, ce qui définit le format du champ et l’objet TextFormat newFormat sur le format par défaut (original) du champ de texte. Cette opération supprime toutes les modifications de mise en forme effectuées par l’utilisateur.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}
TextFormatExample.as

L’exemple suivant crée la classe TextFieldExample pour afficher un message texte à l’emplacement par défaut (x = 0, y = 0). Pour ce faire, exécutez la procédure suivante :
  1. Une propriété label de type TextField est créée.
  2. Le constructeur de classe appelle la fonction configureLabel().
  3. La fonction configureLabel() crée tout d’abord un objet TextField et l’affecte à label, puis définit ses paramètres de la façon suivante :
    • Justifie le champ de texte à gauche ;
    • Active le remplissage d’arrière-plan ;
    • Active la bordure.
  4. Ensuite, la méthode configureLabel() crée la variable locale format et l’affecte à une nouvelle occurrence de TextFormat en définissant ses paramètres de la façon suivante :
    • Type de police = Verdana
    • Couleur de la police = rouge uni
    • Taille de la police = 10
    • Soulignement = true
  5. La propriété defaultTextFormat de l’étiquette est définie sur format, et l’occurrence label vient s’ajouter à la liste d’affichage, qui affiche tout d’abord un champ de texte sans texte (sous forme de petit cadre avec un fond blanc) sur la scène.
  6. Enfin (au niveau du constructeur), le texte de l’étiquette est défini sur « Hello World and welcome to the show », aux coordonnées x = 0, y = 0 en appelant setLabel().
 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}




[ X ]Pourquoi existe-t-il du contenu en anglais ?
Certaines parties du Guide de référence ActionScript 3.0 sont en anglais

Tout le contenu du Guide de référence ActionScript 3.0 n’a pas été traduit dans toutes les langues. Si un élément de langage n’est pas traduit, il s’affiche en anglais. Par exemple, la classe ga.controls.HelpBox n’est traduite dans aucune langue. Ainsi, dans la version française du guide de référence, la classe ga.controls.HelpBox apparaît en anglais.