Video  - AS3

指出套用到解碼視訊做為後置處理之一部份的濾鏡類型。 預設值為 0，可讓視訊壓縮程式視需要套用消除馬賽克的濾鏡。

視訊的壓縮可能會產生不想要的雜訊。 您可以使用 deblocking 屬性來設定濾鏡，以便減少馬賽克和環狀色斑 (針對使用 On2 轉碼器壓縮的視訊)。

「馬賽克」是指組成每個視訊影格的區塊邊界之間的可見瑕疵。 「環狀色斑」是指視訊影像內各元素周圍的扭曲邊緣。

您可以使用兩種消除馬賽克濾鏡： 一種是在 Sorenson 轉碼器中，而另一種則在 On2 VP6 轉碼器中。 此外，當您使用 On2 VP6 轉碼器時，可以使用消除環狀色斑濾鏡。 若要設定濾鏡，請使用下列其中一個值：

• 0 - 讓視訊壓縮程式視需要套用消除馬賽克濾鏡。
• 1 - 不使用消除馬賽克濾鏡。
• 2 - 使用 Sorenson 消除馬賽克濾鏡。
• 3 - (僅適用於 On2 視訊) 使用 On2 消除馬賽克濾鏡，但不使用消除環狀色斑濾鏡。
• 4 - (僅適用於 On2 視訊) 使用 On2 消除馬賽克和消除環狀色斑濾鏡。
• 5 - (僅適用於 On2 視訊) 使用 On2 消除馬賽克和消除環狀色斑濾鏡。

如果使用 Sorenson 轉碼器時為視訊選取 2 以上的值，Sorenson 解碼器會預設為 2。

使用消除馬賽克濾鏡會影響整體的播放效果，因此高頻寬的視訊通常都不會用到。 如果使用者的系統功能不夠強，在啟用消除馬賽克濾鏡時，可能會遇到播放視訊方面的困難。

指定是否需要在視訊縮放時進行平滑處理 (漸變影格)。 如果要讓平滑處理作業發揮作用，執行階段就必須處於高品質的模式中 (預設)。預設值是 false (不平滑處理)。

若要使用 Flash Player 9.0.115.0 和更新版本播放視訊，請將此屬性設定為 true，以便利用 Mip 映射影像最佳化。

指定視訊串流高度的整數，以像素為單位。 對於即時串流來說，這個值和 Camera 物件的 Camera.height 屬性相同，此 Camera 物件指的是正在捕捉視訊串流的 Camera 物件。 針對錄製的視訊檔案，此值為視訊的高度。若是錄製的視訊，則當此值變更時就會傳送 NetStream.Video.DimensionChange 事件。

例如，若您要確保不論 Video 物件在舞台上實際的大小如何，使用者所看到的視訊和它們被擷取時大小相同，則您可能要使用這個屬性。

相關 API 元素

指定視訊串流寬度的整數，以像素為單位。 對於即時串流來說，這個值和 Camera 物件的 Camera.width 屬性相同，此 Camera 物件指的是正在捕捉視訊串流的 Camera 物件。 針對錄製的視訊檔案，此值為視訊的寬度。若是錄製的視訊，則當此值變更時就會傳送 NetStream.Video.DimensionChange 事件。

例如，若您要確保不論 Video 物件在舞台上實際的大小如何，使用者所看到的視訊和它們被擷取時大小相同，則您可能要使用這個屬性。

相關 API 元素

會建立新的 Video 實體。 如果沒有提供 width 和 height 參數的值，就會使用預設值。 您也可以在初始建構之後，使用 Video.width 和 Video.height 設定 Video 物件的寬度和高度屬性。 建立新的 Video 物件後，寬度或高度就不允許輸入零這個值。如果您傳遞零，就會套用預設值。

建立 Video 後，請呼叫 DisplayObjectContainer.addChild() 或 DisplayObjectContainer.addChildAt() 方法，將 Video 物件加入父 DisplayObjectContainer 物件。

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

指定來自攝影機且即將在應用程式中 Video 物件邊界範圍內顯示的視訊串流。

使用這個方法附加使用者擷取的即時視訊至 Video 物件。您可以在擷取即時視訊的相同本機電腦或裝置上播放，也可以將它傳到 Flash Media Server 並使用伺服器將它串流給其他使用者。

注意：在 iOS AIR 應用程式中，當應用程式使用 GPU 顯示模式時，無法顯示攝影機視訊。

參數

相關 API 元素

指定即將在應用程式中 Video 物件邊界範圍內顯示的視訊串流。 視訊串流是以 NetStream.play() 播放的視訊檔案、Camera 物件或 null。如果您使用視訊檔案，它可以儲存在本機檔案系統或 Flash Media Server 上。如果 netStream 引數的值是 null，則視訊便不會於 Video 物件中播放。

如果視訊檔案只包含音效，您就不必使用這個方法；呼叫 NetStream.play() 時，就會自動播放視訊檔案的音效部分。若要控制與視訊檔案關聯的音效，請使用播放視訊檔案之 NetStream 物件的 soundTransform 屬性。

參數

相關 API 元素

清除目前顯示在 Video 物件 (而非視訊串流) 中的影像。這個方法有助於處理目前的影像。例如，您可以清除上一個影像或顯示待用資訊，而不必隱藏 Video 物件。

相關 API 元素

在這個範例中，是將建立 Video 和 NetStream 物件的程式碼與呼叫 Video.attachNetStream() 和 NetStream.play() 置入處理常式函數中。 只有在嘗試連線至 NetConnection 物件成功後才會呼叫處理常式，也就是 netStatus 事件傳回的 info 物件中含有表示成功的 code 屬性。 建議您先等候連線成功，然後再呼叫 NetStream.play()。

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }