File  - AS3

包含應用程式已安裝檔案的檔案夾。

這個物件的 url 屬性會使用 app URL 配置 (而非 file URL 配置)。這表示 url 字串是以 "app:" 開頭來指定的 (而非 "file:")。此外，如果您建立一個相對於 File.applicationDirectory 目錄的 File 物件 (使用 resolvePath() 方法)，該 File 物件的 url 屬性也會使用 app URL 配置。

注意：您無法寫入其路徑是使用 app: URL 配置的檔案或目錄。您也無法刪除或建立其路徑是使用 app: URL 配置的檔案或檔案夾。修改應用程式目錄中的內容並非好的做法，基於安全考量，某些平台會封鎖此動作。如果您要儲存應用程式特有的資料，請考慮使用應用程式儲存目錄 (File.applicationStorageDirectory)。如果您想讓應用程式儲存目錄中的任何內容能夠存取應用程式權限的功能 (AIR API)，可以使用安全執行程序橋接來公開該功能。

applicationDirectory 屬性提供可跨平台參考應用程式目錄的方法。如果您使用 nativePath 或 url 屬性設定 File 物件來參考應用程式目錄，則該屬性只會在路徑有效的平台上運作。

在 Android 上，指向應用程式目錄的 File 物件 nativePath 屬性為空白字串。請使用 url 屬性來存取應用程式檔案。

相關 API 元素

應用程式的私用儲存目錄。

每個 AIR 應用程式都有一個唯一且持續的應用程式儲存目錄，這是在您第一次存取 File.applicationStorageDirectory 時建立的。這個目錄對於每一個應用程式與使用者而言都具有唯一性。這個目錄是可讓您方便地儲存使用者或應用程式特有資料的位置。

解除安裝 AIR 應用程式時，解除安裝程式是否刪除應用程式儲存目錄與其檔案，取決於平台。

這個物件的 url 屬性會使用 app-storage URL 配置 (而非 file URL 配置)。這表示 url 字串是以 "app-storage:" 開頭來指定的 (而非 "file:")。此外，如果您建立一個相對於 File.applicationStoreDirectory 目錄的 File 物件 (使用 resolvePath() 方法)，該 File 物件的 url 也會使用 app-storage URL 配置 (如範例所示)。

applicationStorageDirectory 屬性提供可跨平台參考應用程式儲存目錄的方法。如果您使用 nativePath 或 url 屬性設定 File 物件來參考應用程式儲存目錄，則該屬性只會在路徑有效的平台上運作。

注意 (僅限 Mac OS)：為符合 Mac App Store 需求，這個目錄的實體位置已在 AIR 3.2 與 AIR 3.3 之間變更：

• 3.2 命名空間和更早版本：~/Library/Preferences/appid/Local Store/
• 3.3 命名空間和更新版本：path/Library/Application Support/appid/Local Store/，其中 path 是 ~/Library/Containers/bundle-id/Data (安全執行程序的環境) 或 ~ (若在安全執行程序環境外執行)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

應用程式的快取目錄。

cacheDirectory 屬性提供參考快取目錄的方法。您的應用程式應該將快取目錄用來儲存從伺服器下載的檔案，或是以其他方式重新產生的檔案。您應放入快取目錄的檔案範例包括資料庫快取檔案和可下載的內容，例如雜誌、報紙和地圖應用程式所使用的內容。

如果您使用 nativePath 或 url 屬性設定 File 物件來參考快取目錄，則該屬性只會在路徑有效的平台上運作。

如果作業系統不支援快取目錄，則 cacheDirectory 為 null

使用者的桌面目錄。

desktopDirectory 屬性提供可跨平台參考桌面目錄的方法。如果您使用 nativePath 或 url 屬性設定 File 物件來參考桌面目錄，則該屬性只會在路徑有效的平台上運作。

若作業系統不支援桌面目錄，將改用檔案系統中合適的目錄。

AIR for TV 裝置不具有使用者桌面目錄的概念。因此，desktopDirectory 屬性與 File.userDirectory 屬性參照相同的目錄位置。對於應用程式而言，使用者目錄是唯一的。

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

使用者的文件目錄。

在 Windows 上，這是 My Documents 目錄 (例如，C:\Documents and Settings\userName\My Documents)。在 Mac OS 上，預設位置是 /Users/userName/Documents。在 Linux 上，預設位置是 /home/userName/Documents (英文版系統)，而且此屬性會遵守 xdg-user-dirs 設定。

documentsDirectory 屬性提供可跨平台參考文件目錄的方法。如果您使用 nativePath 或 url 屬性設定 File 物件來參考文件目錄，則該屬性只會在路徑有效的平台上運作。

若作業系統不支援文件目錄，將改用檔案系統中合適的目錄。

AIR for TV 裝置不具有使用者文件目錄的概念。因此，documentsDirectory 屬性與 File.userDirectory 屬性參照相同的目錄位置。對於應用程式而言，使用者目錄是唯一的。

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

指出參考檔案或目錄是否已經下載 (從網際網路)。

這個屬性只在檔案可標示為已經下載的作業系統上才有意義：

• Windows XP Service Pack 2 和更新版本，以及在 Windows Vista 上
• Mac OS 10.5 與更新的版本

在不能標示已下載檔案的系統 (例如 Linux) 上，此屬性沒有意義 (並且設定為 false)。

相關 API 元素

指出參考的檔案或目錄是否存在。如果 File 物件指向現有檔案或目錄，則此值為 true，否則為 false。

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

包含為檔案所定義之圖示的 Icon 物件。Icon 物件是對應於各種圖示狀態的 BitmapData 物件陣列。在 Linux 上，Icon 物件不包含任何圖示。在 Android 上，icon 屬性為 null。

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

指出是否參考目錄。如果 File 物件指向目錄，則此值為 true，否則為 false。

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

指出參考的檔案或目錄是否「隱藏」。如果參考的檔案或目錄是隱藏的，則此值為 true，否則為 false。

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

指出參考的目錄是否為套件。

如果參考的目錄是套件，則此值為 true，否則為 false。請注意，File 類別不允許直接建立套件。

• 在 Mac OS 上，目錄可以指定為套件，並在 Finder 中顯示為單一檔案而非目錄。如果參考的目錄是套件，這個屬性會設定為 true，但如果檔案不是目錄、不存在或不是套件，則會設定為 false。
• 在其他作業系統上，這個屬性一定會設定為 false。

指出參考是否為符號連結。

如果 File 物件是符號連結，則此值為 true，否則為 false。請注意，File 類別不允許直接建立符號連結。

符號連結可讓檔案指向磁碟上的另一個檔案或目錄。儘管相似，但符號連結與 Mac OS 的替身及 Windows 的捷徑不同。替身或捷徑一定會回報為檔案 (而非目錄)，而且讀取或寫入替身或捷徑絕不會影響它所指向的原始檔案或目錄。另一方面，符號連結的行為通常與它所指向的檔案或目錄相同。它可以回報為檔案或目錄，而且讀取或寫入符號連結會影響它所指向的原始檔案或目錄，而非符號連結本身。不過，刪除符號連結只會刪除此連結，而非連結的目標。

Mac^® OS^®、Linux 和 Windows^® Vista^® 都支援符號連結。此外，在 Windows 上，對於參考連接點 (在 NTFS 檔案系統中使用) 的 File 物件，isSymbolicLink 屬性是設定為 true。

主機作業系統使用的行末字元序列。

在 Mac OS 和 Linux 上，這是換行字元 (字元碼 0x0A 十六進位值)。在 Windows 上，這是歸位字元 (字元碼 0x0D 十六進位值)，後面接著換行字元 (字元碼 0x0A 十六進位值)。

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

主機作業系統表示中的完整路徑。在 Mac OS 和 Linux 上，系統會使用正斜線 (/) 字元做為路徑分隔符號。但在 Windows 中，您可以使用正斜線字元或反斜線 (\) 字元做為路徑分隔符號來「設定」nativePath 屬性，而且 AIR 就會自動將正斜線取代為正確的反斜線字元。

在為了直接設定 nativePath 屬性而寫入程式碼前，請先考慮這樣做是否會產生平台專用的程式碼。例如，像是 "C:\\Documents and Settings\\bob\\Desktop" 的原生路徑僅適用於 Windows。建議您使用下列靜態屬性，因為這些屬性代表常用的目錄並且適用於所有平台：

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

您可以使用 resolvePath() 方法取得這些目錄的相對路徑。

一些 Flex API (例如 SWFLoader 類別的 source 屬性) 使用 URL (File 物件的 url 屬性)，而不是原生路徑 (nativePath 屬性)。

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

包含這個 File 物件所參考檔案或目錄的目錄。

如果檔案或目錄不存在，parent 屬性仍然會傳回指向包含目錄的 File 物件，即使該目錄不存在。

這個屬性與 resolvePath("..") 的傳回值完全相同，唯一的不同是根目錄的父輩為 null。

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

判斷應用程式是否已獲得存取檔案系統的權限。

相關 API 元素

指出執行階段是否防止這個 File 物件備份到雲端。

如果這個屬性設定為 true，則不會在提供這項服務的平台上自動備份至雲端。這個屬性的預設值為 false。

主機作業系統的路徑組件分隔字元。

在 Mac OS 和 Linux 上，這是正斜線 (/) 字元。在 Windows 上，這是反斜線 (\) 字元。

注意：在字串常值中使用反斜線字元時，請記得輸入兩次字元 (如 "directory\\file.ext")。字串常值中的每對反斜線各代表字串中的一個反斜線。

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

此 File 位置上的可用空間 (以位元組為單位)。

如果 File 物件參考目錄，則 spaceAvailable 會指出目錄中檔案可使用的空間。如果 File 物件參考檔案，則 spaceAvailable 會指出檔案可成長的空間。如果檔案位置不存在，spaceAvailable 會設定為 0。如果 File 物件參考符號連結，則 spaceAvailable 會指出符號連結所指向位置的可用空間。

目錄或檔案的可用空間通常與包含目錄或檔案之磁碟上的可用空間相同。不過，可用空間可能會將帳戶配額和每個目錄限制納入考量。

將檔案或目錄加入至磁碟，通常需要比檔案實際大小或目錄內容大小更大的空間。例如，作業系統可能需要更多空間來儲存索引資訊。必要的磁區也可能會使用額外的空間。此外，可用空間會動態變更。因此，您無法預期為儲存檔案配置「所有」空間。

主機作業系統所使用的預設編碼。

可能值包含 "windows-1252"、"shift-jis"、"cn-gb"、"iso-8859-1" 等等。如需完整清單，請參閱「支援的字元集」。

當您使用 FileStream 類別的 readMultiByte() 和 writeMultiByte() 方法時，可以使用此值。

相關 API 元素

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

這個檔案路徑的 URL。

如果這是應用程式儲存目錄中某個路徑的參考，則 URL 配置就是 "app-storage"；如果這是應用程式目錄中某個路徑的參考，則 URL 配置就是 "app"；否則，配置就是 "file"。

「指定」值給 url 屬性時，您可以使用空格字元 (而非 "%20")；AIR 會自動將字串編碼 (例如，將空格轉換為 "%20")。

相關 API 元素

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

使用者的目錄。

在 Windows 上，這是 My Documents 目錄的父輩 (例如，C:\Documents and Settings\userName)。在 Mac OS 上，它是 /Users/userName. 在 Linux 上，它是 /home/userName。

userDirectory 屬性提供可跨平台參考使用者目錄的方法。如果您直接設定 File 物件的 nativePath 或 url 屬性，則該屬性只會在路徑有效的平台上運作。

若作業系統不支援使用者目錄，將改用檔案系統中合適的目錄。

在 AIR for TV 裝置上，userDirectory 屬性參照對於應用程式而言是唯一的使用者目錄。

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

File 類別的建構函數。

如果您傳遞 path 引數，File 物件就會指向指定路徑，而且會傳送 nativePath 屬性和 url 屬性以反映該路徑。

雖然您可以傳遞 path 引數來指定檔案路徑，但請先考慮這樣做是否會產生平台專用的程式碼。例如，像是 "C:\\Documents and Settings\\bob\\Desktop" 的原生路徑或 "file:///C:/Documents%20and%20Settings/bob/Desktop" 這類型的 URL 僅適用於 Windows。建議您使用下列靜態屬性，因為這些屬性代表常用的目錄並且適用於所有平台：

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

接著，您可以使用 resolvePath() 方法取得這些目錄的相對路徑。例如，下列程式碼會將 File 物件指向應用程式儲存目錄中的 settings.xml 檔案：

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

重要：如果您在 path 參數中傳遞 URL 字串，會將 URL 解碼以解析檔案路徑。例如，new File("file:///c:/test/demo%20file%201%2e0.txt") 陳述式會使用原生路徑 "c:\test\demo file 1.0.txt" 建立 File 物件。(URL 會使用 file:、app: 或 app-storage: scheme 前置詞)。不過，如果省略有效的 URL 前置詞，會將路徑字串視為原生路徑，並且不會執行解碼。在驗證來自可能不受信任之來源的路徑時，您必須將此行為列入考量。如果直接驗證輸入字串，URL 解碼可能會允許攻擊者略過您的驗證檢查。總是驗證實體化之檔案物件的最後路徑：

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

相關 API 元素

顯示目錄選擇器對話方塊，讓使用者選取目錄。當使用者選取目錄時，會傳送 select 事件。select 事件的 target 屬性就是指向所選取目錄的 File 物件。

目錄選擇器對話方塊不一定會顯示在由其他視窗所「擁有」的視窗前面 (owner 屬性不是 Null 的視窗)。若要避免發生視窗排序問題，請在呼叫此方法之前隱藏擁有的視窗。

注意：在 Android 裝置上，不支援 browseForDirectory()。File 物件會立即傳送 cancel 事件。

參數

相關 API 元素

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

顯示「開啟檔案」對話方塊，讓使用者選取要開啟的檔案。

當使用者選取檔案時，會傳送 select 事件。select 事件的 target 屬性就是指向所選取檔案的 File 物件。

「開啟檔案」對話方塊不一定會顯示在由其他視窗所「擁有」的視窗前面 (owner 屬性不是 Null 的視窗)。若要避免發生視窗排序問題，請在呼叫此方法之前隱藏擁有的視窗。

注意：在 Android 裝置上，無法設定檔案對話方塊標題。title 參數會遭到忽略。

參數

相關 API 元素

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

顯示「開啟檔案」對話方塊，讓使用者選取一個或多個要開啟的檔案。

當使用者選取檔案時，會傳送 selectMultiple 事件。select 事件的 target 屬性就是這個 File 物件。這個 File 物件與含有 browseForOpenMultiple() 方法的 browseForOpen() 不同，它不會更新以參考任何所選的檔案。相反地，產生的 selectMultiple 事件會包含所選檔案的陣列。

「開啟檔案」對話方塊不一定會顯示在由其他視窗所「擁有」的視窗前面 (owner 屬性不是 Null 的視窗)。若要避免發生視窗排序問題，請在呼叫此方法之前隱藏擁有的視窗。

注意：在 Android 裝置上，無法設定檔案對話方塊標題。title 參數會遭到忽略。

參數

相關 API 元素

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

顯示「儲存檔案」對話方塊，讓使用者選取檔案目的地。

當使用者選取檔案時，會傳送 select 事件。select 事件的 target 屬性就是指向所選取 Save 目的地的 File 物件。

「儲存檔案」對話方塊不一定會顯示在由其他視窗所「擁有」的視窗前面 (owner 屬性不是 Null 的視窗)。若要避免發生視窗排序問題，請在呼叫此方法之前隱藏擁有的視窗。

注意：在 Android 裝置上，無法設定檔案對話方塊標題。title 參數會遭到忽略。

參數

相關 API 元素

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

取消任何待處理的非同步作業。

標準化 File 路徑。

如果 File 物件代表現有檔案或路徑，則標準化會調整該路徑以符合實際檔案或目錄名稱的大小寫。如果 File 物件是符號連結，則標準化會調整該路徑以符合連結指向的檔案或目錄，不論所指向的檔案或目錄是否存在。在區分大小寫的檔案系統上 (例如 Linux)，同時存在多個名稱僅大小寫不同的檔案時，canonicalize() 方法就會調整路徑來對應找到的第一個檔案 (尋找的順序由檔案系統決定)。

此外，在 Windows 上，標準化會將短檔案名稱轉換成長檔案名稱。

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

傳回這個 File 物件的副本。不會複製事件註冊。

注意：這個方法不會複製檔案本身。它只會複製 ActionScript File 物件實體。若要複製檔案，請使用 copyTo() 方法。

將這個 File 物件所指定之位置上的檔案或目錄複製到 newLocation 參數所指定的位置。複製程序會建立任何必要的上層目錄 (如果可能)。使用 copyTo() 覆寫檔案時，也會覆寫檔案特質。

參數

相關 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

開始將這個 File 物件所指定之位置上的檔案或目錄複製到 destination 參數所指定的位置。

完成時，會傳送 complete 事件 (成功) 或 ioError 事件 (不成功)。複製程序會建立任何必要的上層目錄 (如果可能)。

參數

相關 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

建立指定的目錄和任何必要的上層目錄。如果目錄已存在，則不會採取動作。

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

傳回新暫存目錄的參考。這是系統暫存目錄路徑中的新目錄。

這個方法可讓您識別新的唯一目錄，免除查詢系統以檢查目錄是否新且唯一的步驟。

關閉應用程式之前，您可能要刪除暫存目錄，因為某些裝置不會自動刪除暫存目錄。

相關 API 元素

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

傳回新暫存檔案的參考。這是系統暫存目錄路徑中的新檔案。

這個方法可讓您識別新的唯一檔案，免除查詢系統以檢查檔案是否新且唯一的步驟。

在關閉應用程式之前，您可能要刪除暫存檔案，因為它不會自動被刪除。

相關 API 元素

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

刪除目錄。如果這個 File 實際上是目錄的符號連結，系統就會移除此連結，而非目錄。

參數

相關 API 元素

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

以非同步方式刪除目錄。如果這個 File 實際上是目錄的符號連結，系統就會移除此連結，而非目錄。

參數

相關 API 元素

刪除檔案。如果這個 File 實際上是符號連結，系統就會移除此連結，而非目標檔案。

相關 API 元素

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

以非同步方式刪除檔案。如果這個 File 實際上是符號連結，系統就會移除此連結，而非目標檔案。

相關 API 元素

傳回對應於這個 File 物件所代表目錄中之檔案和目錄的 File 物件陣列。這個方法不會探索子目錄的內容。

相關 API 元素

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

以非同步方式擷取對應於這個 File 物件所代表目錄內容的 File 物件陣列。

相關 API 元素

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

找出兩個 File 路徑之間的相對路徑。

相對路徑是可附加至此參考 (據以解析) 以找出第二個 (參數) 參考的組件清單。使用 "/" 分隔字元傳回相對路徑。

或者，相對路徑也可以包含 ".." 參考，但這種路徑不會跨越顯著的磁碟邊界。

參數

傳回 File 物件的陣列，並列出檔案系統根目錄。

例如，在 Windows 上，這是磁碟清單，如 C: 磁碟機和 D: 磁碟機。此陣列中不包含空白磁碟機，如未插入光碟片的 CD 或 DVD 光碟機。在 Mac OS 和 Linux 中，這個方法一定會傳回電腦的唯一根目錄 (即「/」目錄)

在根目錄無法讀取的檔案系統上 (例如 Android 檔案系統)，傳回的 File 物件的屬性不一定會反映真實值。例如，在 Android 上，spaceAvailable 屬性會報告 0。

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

將這個 File 物件所指定位置上的檔案或目錄移至 destination 參數指定的位置。

若要重新命名檔案，請設定 destination 參數以指向檔案目錄中的路徑，但使用不同的檔案名稱。

移動程序會建立任何必要的上層目錄 (如果可能)。

參數

相關 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

開始將這個 File 物件所指定之位置上的檔案或目錄移至 newLocation 參數所指定的位置。

若要重新命名檔案，請設定 destination 參數以指向檔案目錄中的路徑，但使用不同的檔案名稱。

移動程序會建立任何必要的上層目錄 (如果可能)。

參數

相關 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

將檔案或目錄移至垃圾筒。

注意：在不具有可復原資源回收筒功能的作業系統上，將會立即移除檔案。

相關 API 元素

以非同步方式，將檔案或目錄移至資源回收筒。

注意：在不具有可復原資源回收筒功能的作業系統上，將會立即移除檔案。

相關 API 元素

在由作業系統註冊用來開啟此檔案類型的應用程式中開啟檔案。

AIR 拒絕您使用 File.openWithDefaultApplication() 方法開啟特定檔案。在 Windows 中，AIR 會防止您開啟特定檔案類型的檔案 (具有下列副檔名的檔案)。在 Mac OS 與 Linux 上，AIR 可防止您開啟由特定應用程式啟動的檔案，這些特定應用程式如下所指定。嘗試使用 openWithDefaultApplication() 方法開啟這些檔案會產生例外。然而，以原生安裝程式 (擴充的桌面設定檔應用程式) 所安裝的 AIR 應用程式不會受限於這些限制；它們可以開啟任何類型的檔案。

您無法從應用程式目錄開啟文件。

下表列出在 Windows 上禁止的副檔名，以及在 Mac OS 及 Linux 上被禁止的應用程式：

相關 API 元素

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

要求權限以存取檔案系統。

根據 path 參數 (字串)，使用此 File 物件路徑的相對路徑來建立新的 File 物件。

相對路徑或絕對路徑都可以做為 path 參數。

如果您指定相對路徑，指定的 path 會「附加」至 File 物件的路徑。不過，在 path 中使用 ".." 會傳回非 File 物件子系的結果路徑。產生的參考不需要參考實際的檔案系統位置。

如果您指定絕對檔案參考，此方法會傳回指向該路徑的 File 物件。絕對檔案參考應該使用使用者作業系統的有效原生路徑語法 (如 Windows 上的 "C:\\test")。請「勿」使用 URL (如 "file:///c:/test") 做為 path 參數。

所有產生的路徑都會一般化，如下所示：

• 任何 "." 元素都會被忽略。
• 任何 ".." 元素都會參考其父項目。
• 到達檔案系統根目錄或應用程式持續儲存區根目錄的 ".." 參考不能通過該節點；它會被忽略。

請一律使用正斜線 (/) 字元做為路徑分隔符號。在 Windows 中，您也可以使用反斜線 (\) 字元，但不建議使用。使用反斜線字元會使應用程式在其他的平台上無法使用。

在 Linux 中，檔案名稱和目錄名稱一律會區分大小寫。

參數

當待處理的非同步作業取消時傳送。

這個事件具有下列屬性：

當非同步作業完成時傳送。

這個事件具有下列屬性：

當目錄清單因為呼叫 getDirectoryListingAsync() 方法變成可供使用時傳送。

這個事件具有下列屬性：

相關 API 元素

當非同步檔案作業期間發生錯誤時傳送。

這個事件具有下列屬性：

當應用程式要求權限以存取檔案系統時傳送。檢查 status 屬性的值，以判斷是否已授與或拒絕權限

相關 API 元素

當作業違反安全性限制時傳送。

這個事件具有下列屬性：

當使用者從檔案或目錄瀏覽對話方塊中選取檔案或目錄時傳送。

這個事件具有下列屬性：

當使用者從呼叫 browseForOpenMultiple() 方法所開啟的對話方塊中選取檔案時傳送。

相關 API 元素