Date

套件	最上層
類別	public final dynamic class Date
繼承	Date Object

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

Date 類別代表日期與時間資訊。 Date 類別的實體代表特定的時間點，您可以查詢或修改如月份、日期、小時及秒數等屬性。 Date 類別可讓您擷取相對於全球時間 (格林威治標準時間，現在稱為全球時間或 UTC) 或相對於本地時間 (由執行 Flash Player 之作業系統的本地時區設定所決定) 的日期與時間值。 Date 類別的方法並不是靜態的，但是只會套用到呼叫方法時所指定的個別 Date 物件。 Date.UTC() 與 Date.parse() 方法則是例外，這兩者都是靜態方法。

Date 類別會根據作業系統和執行階段的版本，使用不同的方式來處理日光節約時間。Flash Player 6 和更新的版本會根據下列作業系統，使用這些方法來處理日光節約時間：

Windows - Date 物件會針對日光節約時間自動調整它的輸出。 Date 物件可偵測出目前所在的地區是否有使用日光節約時間；如果有的話，它會偵測從標準時間到日光節約時間之間的轉換日期與時間。但是，目前有效的轉換日期也會套用到過去和未來的日期，因此，如果某個地區的轉換日期不同，那麼針對過去日期所計算的日光節約時間偏差值可能就會不正確。
Mac OS X - Date 物件會針對日光節約時間自動調整它的輸出。 Mac OS X 中的時區資訊資料庫可用來判斷目前或過去的任何日期或時間是否應套用日光節約時間的偏差值。
Mac OS 9 - 作業系統僅提供足夠資訊來決定目前的日期與時間是否應套用日光節約時間的偏差值。因此，Date 物件會假設目前的日光節約時間偏差值會套用至過去或未來的所有日期與時間。

Flash Player 5 在下列作業系統中處理日光節約時間的方式如下：

Windows - 永遠套用美國的日光節約時間規則，這對於使用日光節約時間但是轉換時間與美國不同的歐洲和其他地區來說，可能會導致時間轉換不正確。Flash 可正確地偵測出目前所在的地區是否有使用日光節約時間。

若要使用 Date 類別，請使用 new 運算子建構 Date 實體。

ActionScript 3.0 會新增數個存取子屬性，而且這些屬性可用來取代存取或修改 Date 實體的許多 Date 類別方法。 ActionScript 3.0 也包含 toString() 方法的幾種新變化，以符合 ECMA-262 第三版，這些變化包括：Date.toLocaleString()、Date.toTimeString()、Date.toLocaleTimeString()、Date.toDateString() 和 Date.toLocaleDateString()。

若要計算相對時間或經過的時間，請參閱 flash.utils 套件中的 getTimer() 方法。

檢視範例

相關 API 元素

flash.utils.getTimer()

公用屬性

隱藏繼承公用屬性

顯示繼承公用屬性

	屬性		定義自
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		date : Number 根據本地時間，Date 物件所指定月份中的日期別 (從 1 到 31 的整數)。	Date
		dateUTC : Number 根據全球時間 (UTC)，Date 物件月份中的日期別 (從 1 到 31 的整數)。	Date
		day : Number [唯讀] 根據本地時間，由此 Date 指定的星期別 (0 代表星期日，1 代表星期一，其他依此類推)。	Date
		dayUTC : Number [唯讀] 根據全球時間 (UTC)，此 Date 的星期別 (0 代表星期日，1 代表星期一，其他依此類推)。	Date
		fullYear : Number 根據本地時間，Date 物件的完整年份 (四位數的數字，如 2000)。	Date
		fullYearUTC : Number 根據全球時間 (UTC)，Date 物件的四位數年份。	Date
		hours : Number 根據本地時間，Date 物件當天的小時部分 (從 0 到 23 的整數)。	Date
		hoursUTC : Number 根據全球時間 (UTC)，Date 物件當天的小時數 (從 0 到 23 的整數)。	Date
		milliseconds : Number 根據本地時間，Date 物件的毫秒部分 (從 0 到 999 的整數)。	Date
		millisecondsUTC : Number 根據全球時間 (UTC)，Date 物件的毫秒部分 (從 0 到 999 的整數)。	Date
		minutes : Number 根據本地時間，Date 物件的分鐘部分 (從 0 到 59 的整數)。	Date
		minutesUTC : Number 根據全球時間 (UTC)，Date 物件的分鐘部分 (從 0 到 59 的整數)。	Date
		month : Number 根據本地時間，Date 物件的月份部分 (0 代表一月，1 代表二月，其他依此類推)。	Date
		monthUTC : Number 根據全球時間 (UTC)，Date 物件的月份部分 (從 0 [一月] 到 11 [十二月])。	Date
		seconds : Number 根據本地時間，Date 物件的秒鐘部分 (從 0 到 59 的整數)。	Date
		secondsUTC : Number 根據全球時間 (UTC)，Date 物件的秒鐘部分 (從 0 到 59 的整數)。	Date
		time : Number Date 物件從全球時間 1970 年一月 1 日午夜開始計算的毫秒數。	Date
		timezoneOffset : Number [唯讀] 電腦本地時間與全球時間 (UTC) 之間相差的分鐘數。	Date

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0) 會建構新的 Date 物件，用來保存指定的日期與時間。	Date
		getDate():Number 根據本地時間傳回 Date 物件指定之月份中的日期別 (從 1 到 31 的整數)。	Date
		getDay():Number 根據本地時間傳回此 Date 物件指定的星期別 (0 代表星期日，1 代表星期一，其他依此類推)。	Date
		getFullYear():Number 根據本地時間傳回 Date 物件的完整年份 (四位數的數字，如 2000)。	Date
		getHours():Number 根據本地時間傳回 Date 物件的當天小時數部分 (從 0 到 23 的整數)。	Date
		getMilliseconds():Number 根據本地時間傳回 Date 物件的毫秒部分 (從 0 到 999 的整數)。	Date
		getMinutes():Number 根據本地時間傳回 Date 物件的分鐘部分 (從 0 到 59 的整數)。	Date
		getMonth():Number 根據本地時間傳回此 Date 的月份部分 (0 代表一月，1 代表二月，其他依此類推)。	Date
		getSeconds():Number 根據本地時間傳回 Date 物件的秒數部分 (從 0 到 59 的整數)。	Date
		getTime():Number 會傳回 Date 物件從全球時間 1970 年一月 1 日午夜開始計算的毫秒數。	Date
		getTimezoneOffset():Number 會傳回電腦本地時間與全球時間 (UTC) 之間相差的分鐘數。	Date
		getUTCDate():Number 根據全球時間 (UTC) 傳回 Date 物件中月份的日期別 (從 1 到 31 的整數)。	Date
		getUTCDay():Number 根據全球時間 (UTC) 傳回此 Date 的星期別 (0 代表星期日，1 代表星期一，其他依此類推)。	Date
		getUTCFullYear():Number 根據全球時間 (UTC) 傳回 Date 物件的四位數年份。	Date
		getUTCHours():Number 根據全球時間 (UTC) 傳回 Date 物件的當天小時數 (從 0 到 23 的整數)。	Date
		getUTCMilliseconds():Number 根據全球時間 (UTC) 傳回 Date 物件的毫秒部分 (從 0 到 999 的整數)。	Date
		getUTCMinutes():Number 根據全球時間 (UTC) 傳回 Date 物件的分鐘部分 (從 0 到 59 的整數)。	Date
		getUTCMonth():Number 根據全球時間 (UTC) 傳回 Date 物件的月份部分 (從 0 [一月] 到 11 [十二月])。	Date
		getUTCSeconds():Number 根據全球時間 (UTC) 傳回 Date 物件的秒數部分 (從 0 到 59 的整數)。	Date
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		parse(date:String):Number [靜態] 將代表日期的字串轉換成數字形式，該數字等於從 UTC 時間 1970 年一月 1 日開始經過的毫秒數。	Date
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		setDate(day:Number):Number 根據本地時間設定月份中的日期別，並傳回以毫秒為單位的新時間。	Date
		setFullYear(year:Number, month:Number, day:Number):Number 根據本地時間設定年份，並傳回以毫秒為單位的新時間。	Date
		setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number 根據本地時間設定小時，並傳回以毫秒為單位的新時間。	Date
		setMilliseconds(millisecond:Number):Number 根據本地時間設定毫秒，並傳回以毫秒為單位的新時間。	Date
		setMinutes(minute:Number, second:Number, millisecond:Number):Number 根據本地時間設定分鐘，並傳回以毫秒為單位的新時間。	Date
		setMonth(month:Number, day:Number):Number 根據本地時間設定月份及選擇性的月份日期別，並傳回以毫秒為單位的新時間。	Date
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		setSeconds(second:Number, millisecond:Number):Number 根據本地時間設定秒數，並傳回以毫秒為單位的新時間。	Date
		setTime(millisecond:Number):Number 使用從 1970 年一月 1 日午夜開始到當時的毫秒數來設定日期，並傳回以毫秒為單位的新時間。	Date
		setUTCDate(day:Number):Number 根據全球時間 (UTC) 設定月份中的日期別，並傳回以毫秒為單位的新時間。	Date
		setUTCFullYear(year:Number, month:Number, day:Number):Number 使用全球時間 (UTC) 設定年份，並傳回以毫秒為單位的新時間。	Date
		setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number 使用全球時間 (UTC) 設定小時，並傳回以毫秒為單位的新時間。	Date
		setUTCMilliseconds(millisecond:Number):Number 使用全球時間 (UTC) 設定毫秒，並傳回以毫秒為單位的新時間。	Date
		setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number 使用全球時間 (UTC) 設定分鐘，並傳回以毫秒為單位的新時間。	Date
		setUTCMonth(month:Number, day:Number):Number 根據全球時間 (UTC) 設定月份及選擇性地設定日期別，並傳回以毫秒為單位的新時間。	Date
		setUTCSeconds(second:Number, millisecond:Number):Number 根據全球時間 (UTC) 設定秒數及選擇性地設定毫秒數，並傳回以毫秒為單位的新時間。	Date
		toDateString():String 只傳回星期別與日期的字串形式，而不包括時間或時區。	Date
		toJSON(k:String):* 提供可覆寫的方法，用於自訂 Date 物件中值的 JSON 編碼。	Date
		toLocaleDateString():String 只傳回星期別與日期的字串形式，而不包括時間或時區。	Date
		toLocaleString():String 傳回本地時間之星期別、日期、時間的字串形式。	Date
		toLocaleTimeString():String 只傳回時間的字串形式，而不包括星期別、日期、年份或時區。	Date
		toString():String 會傳回星期別、日期、時間及時區的字串形式。	Date
		toTimeString():String 只傳回時間與時區的字串形式，而不包括星期別與日期。	Date
		toUTCString():String 會傳回全球時間 (UTC) 之星期別、日期及時間的字串形式。	Date
		UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number [靜態] 傳回全球時間 1970 年一月 1 日午夜與參數中指定之時間之間相差的毫秒數。	Date
		valueOf():Number 會傳回 Date 物件從全球時間 1970 年一月 1 日午夜開始計算的毫秒數。	Date

屬性詳細資訊

屬性

date:Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間，Date 物件在月份中指定的日期別 (從 1 到 31 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

實作
AS3 function get date():Number
AS3 function set date(value:Number):void

相關 API 元素

getDate()
setDate()

dateUTC

屬性

dateUTC:Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC)，Date 物件之月份中的日期別 (從 1 到 31 的整數)。

實作
AS3 function get dateUTC():Number
AS3 function set dateUTC(value:Number):void

相關 API 元素

getUTCDate()
setUTCDate()

day

屬性

day:Number [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間，由此 Date 指定的星期別 (0 代表星期天，1 代表星期一，其他依此類推)。本地時間是由執行 Flash 執行階段的作業系統決定。

實作
AS3 function get day():Number

相關 API 元素

getDay()

dayUTC

屬性

dayUTC:Number [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC)，此 Date 的星期別 (0 代表星期天，1 代表星期一，其他依此類推)。

實作
AS3 function get dayUTC():Number

相關 API 元素

getUTCDay()

fullYear

屬性

fullYear:Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間，Date 物件的完整年份 (四位數的數字，如 2000)。本地時間是由執行 Flash 執行階段的作業系統決定。

實作
AS3 function get fullYear():Number
AS3 function set fullYear(value:Number):void

相關 API 元素

getFullYear()
setFullYear()

fullYearUTC

屬性

fullYearUTC:Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC)，Date 物件的四位數年份。

實作
AS3 function get fullYearUTC():Number
AS3 function set fullYearUTC(value:Number):void

相關 API 元素

getUTCFullYear()
setUTCFullYear()

hours

屬性

hours:Number

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

根據本地時間，Date 物件的當天小時數部分 (從 0 到 23 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

實作
AS3 function get hours():Number
AS3 function set hours(value:Number):void

相關 API 元素

getHours()
setHours()

hoursUTC

屬性

hoursUTC:Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC)，Date 物件的當天小時數 (從 0 到 23 的整數)。

實作
AS3 function get hoursUTC():Number
AS3 function set hoursUTC(value:Number):void

相關 API 元素

getUTCHours()
setUTCHours()

milliseconds

屬性

milliseconds:Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間，Date 物件的毫秒部分 (從 0 到 999 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

實作
AS3 function get milliseconds():Number
AS3 function set milliseconds(value:Number):void

相關 API 元素

屬性

timezoneOffset:Number [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

電腦本地時間與全球時間 (UTC) 之間相差的分鐘數。更明確地說，這個值就是為了與 UTC 時間相等，要與電腦本地時間值相加的分鐘數。如果您電腦的時間設定為晚於 UTC，此值就是負值。

實作
AS3 function get timezoneOffset():Number

相關 API 元素

getTimezoneOffset()

建構函式詳細資料

Date

()

建構函式

public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會建構新的 Date 物件，用來保存指定的日期與時間。

Date() 建構函式會利用七個參數 (year、month 和 millisecond 等) 來指定精細程度達毫秒的日期和時間。根據傳遞的引數數目及資料類型，新建構的 Date 物件會包含不同的日期。

如果沒有傳遞任何引數，便會對 Date 物件指派目前的日期與時間。
如果您傳遞資料類型 Number 的一個引數，便會根據從 1970 年一月 1 日 0:00:000 GMT 以來的毫秒數 (由 lone 引數指定)，對 Date 物件指派時間值。
如果您傳遞資料類型 String 的一個引數，而且字串包含有效的日期，Date 物件便會包含依據該日期的時間值。
如果您傳遞兩個或更多個引數，便會對 Date 物件指派根據所傳遞之引數值的時間值，其值代表日期的年份、月份、日期、小時、分鐘、秒數及毫秒。

如果您將字串傳遞到 Date 類別建構函式，其日期可以具有各種格式，不過必須至少包含月份、日期及年份。例如，Feb 1 2005 是有效的，Feb 2005 卻是無效的。下列清單指出一些有效的格式：

星期別月份日期小時:分鐘:秒數 GMT 年份 (例如，"Tue Feb 1 00:00:00 GMT-0800 2005"，此格式符合 toString())。
星期別月份日期年份小時:分鐘:秒數 AM/PM (例如，"Tue Feb 1 2005 12:00:00 AM"，此格式符合 toLocaleString())。
星期別月份日期年份 (例如，"Tue Feb 1 2005"，此格式符合 toDateString())。
月份/日期別/年份 (例如，"02/01/2005")
月份/年份 (例如，「02/2005」)

參數

	`yearOrTimevalue:Object` — 如果有指定其他參數，這個數字便代表年份 (如 1965)；否則，它就代表時間值。如果該數字代表年份，0 到 99 之間的值代表 1900 到 1999；否則就必須指定四位數的完整年份。如果該數字代表時間值 (未指定其他參數)，就是 GMT 時間 1970 年 1月 1 日 0:00:00 前或後的毫秒數；負值表示在 GMT 時間 1970 年 1月 1 日 0:00:00「之前」的時間，而正值表示之後的時間。

	`month:Number` — 從 0 (一月) 到 11 (十二月) 的整數。

	`date:Number` (default = `1`) — 從 1 到 31 的整數。

	`hour:Number` (default = `0`) — 從 0 (午夜零點) 到 23 (晚上 11 點) 的整數。

	`minute:Number` (default = `0`) — 從 0 到 59 的整數。

	`second:Number` (default = `0`) — 從 0 到 59 的整數。

	`millisecond:Number` (default = `0`) — 從 0 到 999 毫秒的整數。

相關 API 元素

getMonth()
getDate()
getFullYear()

方法詳細資訊

getDate

()

方法

AS3 function getDate():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回 Date 物件指定之月份中的日期別 (從 1 到 31 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件代表月份中的日期別 (1 - 31)。

相關 API 元素

getMonth()
getFullYear()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getDate() 方法，以擷取月份中的日期別。

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

getDay

()

方法

AS3 function getDay():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回此 Date 指定的星期別 (0 代表星期天，1 代表星期一，其他依此類推)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件代表的星期別之數字版本 (0 - 6)。

範例 ( 如何使用本範例 )

下列範例會建立包含元素 [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] 的新 Array 物件 weekDayLabels，以及包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20) 等參數的新 Date 物件 someBirthday。然後會呼叫 getDay() 方法兩次，這樣會顯示月份的日期為 6，然後再使用 weekDayLabels 顯示一週的星期別。


var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

getFullYear

()

方法

AS3 function getFullYear():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回 Date 物件的完整年份 (四位數的數字，如 2000)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件代表的完整年份。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getFullYear() 方法，以擷取四位數的年份。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

getHours

()

方法

AS3 function getHours():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回 Date 物件的當天小時數部分 (從 0 到 23 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件代表的當天小時數 (0 - 23)。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getHours() 和 getMinutes() 方法，這樣會擷取 24 小時格式的小時和分鐘數。最後，會建立 localTime 字串，並將它指定給呼叫 getUSClockTime() 函數的結果，接著會再次呼叫 getHours() 和 getMinutes()，最後產生的時間為 03:05 PM。


var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

getMilliseconds

()

方法

AS3 function getMilliseconds():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回 Date 物件的毫秒部分 (從 0 到 999 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件的毫秒部分。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getMilliseconds() 方法，此方法會在建立 Date 物件 now 時擷取它的毫秒數。


var now:Date = new Date();
trace(now.getMilliseconds());

getMinutes

()

方法

AS3 function getMinutes():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回 Date 物件的分鐘部分 (從 0 到 59 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件的分鐘部分。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getMinutes() 方法，此方法會在建立 Date 物件 now 時擷取它的分鐘數。


var now:Date = new Date();
trace(now);
trace(now.getMinutes());

getMonth

()

方法

AS3 function getMonth():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回此 Date 的月份部分 (0 代表一月，1 代表二月，其他依此類推)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件的月份 (0 - 11) 部分。

範例 ( 如何使用本範例 )

下列範例會建立包含元素 January 到 December 的新 Array 物件 monthLabels 以及不含任何參數的新 Date 物件 now。然後會呼叫 getMonth() 方法兩次，第一次會傳回月份號碼，第二次會傳回 Date 物件 now 建立的月份名稱。


var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

getSeconds

()

方法

AS3 function getSeconds():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據本地時間傳回 Date 物件的秒數部分 (從 0 到 59 的整數)。本地時間是由執行 Flash 執行階段的作業系統決定。

傳回值

Number — Date 物件的秒數部分 (0 到 59)。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getSeconds() 方法，此方法會在建立 Date 物件 now 時擷取它的秒數。


var now:Date = new Date();
trace(now.getSeconds());

getTime

()

方法

AS3 function getTime():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會傳回 Date 物件從全球時間 1970 年一月 1 日午夜到當時的毫秒數。在比較兩個或多個 Date 物件時，可使用這個方法來表示特定的時刻。

傳回值

Number — Date 物件所代表，從 1970 年 1 月 1 日到當時的毫秒數。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 mlk，包含 year (1929)、month (0 = January) 和 day (15) 等參數。然後會呼叫 getTime() 方法來擷取從 1970 年一月 1 日午夜開始算起的毫秒數，而由於年份設定為 1929，所以這是負值。


var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

下列範例會建立新的 Date 物件 now (不含任何參數)，然後使用下列 DateMath (底下所建立) 類別方法，將從建立原始 Date 物件 now 時算起的時間加入到此物件中：

addSeconds()：將 30 秒加入至 now。
addMinutes()：將 30 分鐘加入至 now。
addHours()：將 6 小時加入至 Date 物件 now。
addDays()：將 30 天加入至 Date 物件 now。
addWeeks()：將 4 週加入至 now。


var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

注意：執行 Date 數學運算時，請務必使用 getTime，因為它將在閏年期間繼續運作，而且不需使用一堆 if 邏輯，例如下列虛擬程式碼：

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }

getTimezoneOffset

()

方法

AS3 function getTimezoneOffset():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會傳回電腦本地時間與全球時間 (UTC) 之間相差的分鐘數。

傳回值

Number — 為了與 UTC 時間相等，要與電腦本地時間值相加的分鐘數。如果您電腦的時間設定為晚於 UTC，傳回值就是負值。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getTimezoneOffset() 方法，此方法會擷取建立 now 時的時間與全球時間之間的差異 (以分鐘為單位)。然後，透過將結果除以 60 的動作，將時區偏移值轉換成小時。


var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

getUTCDate

()

方法

AS3 function getUTCDate():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的月份中的日期別 (從 1 到 31 的整數)。

傳回值

Number — Date 物件代表的 UTC 月份中之日期別 (1 到 31)。

相關 API 元素

getDate()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getUTCDate() 方法，以根據 UTC 擷取月份中的日期別。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

getUTCDay

()

方法

AS3 function getUTCDay():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回此 Date 的星期別 (0 代表星期天，1 代表星期一，其他依此類推)。

傳回值

Number — Date 物件代表的 UTC 星期別 (0 到 6)。

相關 API 元素

getDay()

範例 ( 如何使用本範例 )

下列範例會建立包含元素 [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] 的新 Array 物件 weekDayLabels，以及包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20) 等參數的新 Date 物件 someBirthday。然後會根據 UTC 呼叫 getUTCDay() 方法兩次，這樣會顯示月份的日期為 6，然後再使用 weekDayLabels 顯示一週的星期別。


var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

getUTCFullYear

()

方法

AS3 function getUTCFullYear():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的四位數年份。

傳回值

Number — Date 物件代表的四位數 UTC 年份。

相關 API 元素

getFullYear()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getUTCFullYear() 方法，以根據 UTC 擷取四位數的年份。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

getUTCHours

()

方法

AS3 function getUTCHours():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的當天小時數 (從 0 到 23 的整數)。

傳回值

Number — Date 物件代表的 UTC 當天小時數 (0 到 23)。

相關 API 元素

getHours()

範例 ( 如何使用本範例 )


var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

getUTCMilliseconds

()

方法

AS3 function getUTCMilliseconds():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的毫秒部分 (從 0 到 999 的整數)。

傳回值

Number — Date 物件的 UTC 毫秒部分。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getUTCMilliseconds() 方法，此方法會在建立 Date 物件 now 時擷取它的毫秒數 (根據 UTC)。


var now:Date = new Date();
trace(now.getUTCMilliseconds());

getUTCMinutes

()

方法

AS3 function getUTCMinutes():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的分鐘部分 (從 0 到 59 的整數)。

傳回值

Number — Date 物件的 UTC 分鐘部分。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getUTCMinutes() 方法，此方法會在建立 Date 物件 now 時擷取它的分鐘數 (根據 UTC)。


var now:Date = new Date();
trace(now.getUTCMinutes());

getUTCMonth

()

方法

AS3 function getUTCMonth():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的月份部分 (從 0 [一月] 到 11 [十二月])。

傳回值

Number — Date 物件的 UTC 月份部分。

相關 API 元素

getMonth()

範例 ( 如何使用本範例 )

下列範例會建立包含元素 January 到 December 的新 Array 物件 monthLabels 以及不含任何參數的新 Date 物件 now。然後會呼叫 getUTCMonth() 方法兩次，第一次會傳回月份號碼，第二次會傳回 Date 物件 now 建立的月份名稱 (根據 UTC)。


var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

getUTCSeconds

()

方法

AS3 function getUTCSeconds():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會根據全球時間 (UTC) 傳回 Date 物件的秒數部分 (從 0 到 59 的整數)。

傳回值

Number — Date 物件的 UTC 秒數部分。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getUTCSeconds() 方法，此方法會在建立 Date 物件 now 時擷取它的秒數 (根據 UTC)。


var now:Date = new Date();
trace(now.getUTCSeconds());

parse

()

方法

public static function parse(date:String):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

將代表日期的字串轉換成數字形式，該數字等於從 UTC 時間 1970 年一月 1 日開始經過的毫秒數。

參數

date:String — 符合 Date.toString() 輸出格式的日期字串形式。 Date.toString() 輸出的日期格式為：

     Day Mon DD HH:MM:SS TZD YYYY

例如：

     Wed Apr 12 15:30:17 GMT-0700 2006

「時區指派」(TZD) 永遠會以 GMT-HHMM 或 UTC-HHMM 的形式顯示，並指出相對於「格林威治標準時間」(GMT，現在也稱為全球時間 (UTC)) 的小時與分鐘偏移值。年份、月份及日期別等詞可用正斜線 (/) 或空白字元來分隔，但絕不能使用破折號 (-) 來分隔。其他支援的格式包括下列各項 (您可以包含這些格式的一部分，也就是只有月份、日期別及年份)：

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD

傳回值

Number — 此數字代表從 UTC 時間 1970 年 1 月 1 日所經過的毫秒數。

相關 API 元素

Date.toString()

範例 ( 如何使用本範例 )

下列範例會將 1974 年十一月 30 日的日期字串指定給 dateParsed。然後會呼叫 Date.parse() 方法，將日期轉換成從 1970 年一月 1 日到當時的毫秒數。

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

setDate

()

方法

AS3 function setDate(day:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定月份中的日期別，並傳回以毫秒為單位的新時間。本地時間是由執行 Flash 執行階段的作業系統決定。

參數

day:Number — 從 1 到 31 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getDate() 方法，以擷取月份中的日期別。接下來會呼叫 setDate() (將 day 參數設定為 20)，然後再次呼叫 getDate()，這樣會擷取月份中新設定的日期別。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

setFullYear

()

方法

AS3 function setFullYear(year:Number, month:Number, day:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定年份，並傳回以毫秒為單位的新時間。如果有指定 month 與 day 參數，也會將其設定為本地時間。本地時間是由執行 Flash 執行階段的作業系統決定。

呼叫這個方法並不會修改 Date 的其他欄位，但是如果呼叫此方法會變更星期別，Date.getUTCDay() 與 Date.getDay() 即可報告新值。

參數

	`year:Number` — 指定年份的四位數數字。兩位數的數字並不代表四位數的年份，例如 99 並不是代表 1999 年，而是 99 年。

	`month:Number` — 從 0 (一月) 到 11 (十二月) 的整數。

	`day:Number` — 從 1 到 31 的數字。

傳回值

Number — 以毫秒為單位的新時間。

相關 API 元素

getUTCDay()
getDay()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getFullYear() 方法，以擷取四位數的年份。接下來會呼叫 setFullYear() (將 year 參數設定為 2000)，然後再次呼叫 getFullYear()，這樣會擷取新設定的年份。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

setHours

()

方法

AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定小時，並傳回以毫秒為單位的新時間。本地時間是由執行 Flash 執行階段的作業系統決定。

參數

	`hour:Number` — 從 0 (午夜零點) 到 23 (晚上 11 點) 的整數。

	`minute:Number` — 從 0 到 59 的整數。

	`second:Number` — 從 0 到 59 的整數。

	`millisecond:Number` — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getHours() 和 getMinutes() 方法，以擷取小時與分鐘數。接下來會呼叫 setHours() (將 hour 參數設定為 12)，然後再次呼叫 getHours() 和 getMinutes()，這樣會擷取新設定的小時與分鐘數。


var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

setMilliseconds

()

方法

AS3 function setMilliseconds(millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定毫秒，並傳回以毫秒為單位的新時間。本地時間是由執行 Flash 執行階段的作業系統決定。

參數

millisecond:Number — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getMilliseconds() 方法，以擷取建立 now 時的毫秒數。接著以額外的 setMilliseconds() 呼叫來建立另一個新的 Date 物件 before (millisecond 參數設定為 4)，然後再次呼叫 getMilliseconds()，以擷取新設定的毫秒數。


var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

setMinutes

()

方法

AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定分鐘，並傳回以毫秒為單位的新時間。本地時間是由執行 Flash 執行階段的作業系統決定。

參數

	`minute:Number` — 從 0 到 59 的整數。

	`second:Number` — 從 0 到 59 的整數。

	`millisecond:Number` — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getMinutes() 方法，以擷取建立 now 時的分鐘數。接著以額外的 setMinutes() 呼叫來建立另一個新的 Date 物件 before (minute 參數設定為 0)，然後再次呼叫 getMinutes()，以擷取新設定的分鐘數。


var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

setMonth

()

方法

AS3 function setMonth(month:Number, day:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定月份及選擇性的月份日期別，並傳回以毫秒為單位的新時間。本地時間是由執行 Flash 執行階段的作業系統決定。

參數

	`month:Number` — 從 0 (一月) 到 11 (十二月) 的整數。

	`day:Number` — 從 1 到 31 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立包含元素 January 到 December 的新 Array 物件 monthLabels 以及不含任何參數的新 month 物件 now。然後會呼叫 getMonth() 方法，以擷取建立 now 時的月份。接下來會呼叫 setMonth() (將 month 參數設定為 0)，然後再次呼叫 getMonth()，這樣會擷取新設定的月份。


var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

setSeconds

()

方法

AS3 function setSeconds(second:Number, millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據本地時間設定秒數，並傳回以毫秒為單位的新時間。本地時間是由執行 Flash 執行階段的作業系統決定。

參數

	`second:Number` — 從 0 到 59 的整數。

	`millisecond:Number` — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getseconds() 方法，以擷取建立 now 時的秒數。接下來會呼叫 setSeconds() (將 second 參數設定為 0)，然後再次呼叫 getSeconds()，以擷取新設定的秒數。


var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

setTime

()

方法

AS3 function setTime(millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

使用從 1970 年一月 1 日午夜開始到當時的毫秒數來設定日期，並傳回以毫秒為單位的新時間。

參數

millisecond:Number — 整數值，其中 0 表示全球時間 (UTC) 1 月 1 日午夜零點。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 setTime() 方法 (將 millisecond 參數設定為 -1292601600000)，這樣會將時間設定為 Tue Jan 15 00:00:00 GMT-0800 1929。


var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

setUTCDate

()

方法

AS3 function setUTCDate(day:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC) 設定月份中的日期別，並傳回以毫秒為單位的新時間。呼叫這個方法並不會修改 Date 物件的其他欄位，但是如果呼叫此方法會變更星期別，則 Date.getUTCDay() 與 Date.getDay() 方法即可報告新值。

參數

day:Number — 數字，從 1 到 31 的整數。

傳回值

Number — 以毫秒為單位的新時間。

相關 API 元素

getUTCDay()
getDay()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。會呼叫 getUTCDate() 方法，並正確地傳回月份中的日期別。接下來會呼叫 setUTCDate() (day 參數設定為 1)，而且 trace() 陳述式會確認日期已正確設定。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

setUTCFullYear

()

方法

AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

使用全球時間 (UTC) 設定年份，並傳回以毫秒為單位的新時間。

這個方法也可選擇性地設定月份與月份中的日期別。呼叫這個方法並不會修改其他欄位，但是如果呼叫此方法會變更星期別，Date.getUTCDay() 與 Date.getDay() 方法即可報告新值。

參數

	`year:Number` — 整數，代表指定為完整四位數的年份，如 2000。

	`month:Number` — 從 0 (一月) 到 11 (十二月) 的整數。

	`day:Number` — 從 1 到 31 的整數。

傳回值

Number — 整數。

相關 API 元素

getUTCDay()
getDay()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。會呼叫 getUTCFullYear() 方法，並正確地傳回四位數的年份。接下來會呼叫 setUTCFullYear() (year 參數設定為 1975)，而且 trace() 陳述式會確認年份已正確設定。


var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

setUTCHours

()

方法

AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

使用全球時間 (UTC) 設定小時，並傳回以毫秒為單位的新時間。分鐘、秒數及毫秒都可選擇性地指定。

參數

	`hour:Number` — 從 0 (午夜零點) 到 23 (晚上 11 點) 的整數。

	`minute:Number` — 從 0 到 59 的整數。

	`second:Number` — 從 0 到 59 的整數。

	`millisecond:Number` — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後會呼叫 getHours()、getMinutes()、getUTCHours() 和 getUTCMinutes() 方法，以擷取小時與分鐘數。接下來會呼叫 setUTCHours() (hour 參數設定為 12)，然後會重新呼叫 getHours()、getMinutes()、getUTCHours() 和 getUTCMinutes() 方法，並正確顯示更新的小時數。


var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

setUTCMilliseconds

()

方法

AS3 function setUTCMilliseconds(millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

使用全球時間 (UTC) 設定毫秒，並傳回以毫秒為單位的新時間。

參數

millisecond:Number — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getUTCMilliseconds() 方法，以擷取建立 now 時的 UTCMilliseconds。接著以額外的 setUTCMilliseconds() 呼叫來建立另一個新的 Date 物件 before (millisecond 參數設定為 4)，然後再次呼叫 getUTCMilliseconds()，以擷取新設定的毫秒數。



var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

setUTCMinutes

()

方法

AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

使用全球時間 (UTC) 設定分鐘，並傳回以毫秒為單位的新時間。您可以選擇性地指定秒數與毫秒。

參數

	`minute:Number` — 從 0 到 59 的整數。

	`second:Number` — 從 0 到 59 的整數。

	`millisecond:Number` — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getUTCMinutes() 方法，以擷取建立 now 時的 UTCMinutes。接著以額外的 setUTCMinutes() 呼叫來建立另一個新的 Date 物件 before (minute 參數設定為 0)，然後再次呼叫 getUTCMinutes()，以擷取新設定的分鐘數。


var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

setUTCMonth

()

方法

AS3 function setUTCMonth(month:Number, day:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC) 設定月份及選擇性地設定日期別，並傳回以毫秒為單位的新時間。呼叫這個方法並不會修改其他欄位，但是如果呼叫此方法會變更星期別，Date.getUTCDay() 與 Date.getDay() 方法即可報告新值。

參數

	`month:Number` — 從 0 (一月) 到 11 (十二月) 的整數。

	`day:Number` — 從 1 到 31 的整數。

傳回值

Number — 以毫秒為單位的新時間。

相關 API 元素

getDay()

範例 ( 如何使用本範例 )

下列範例會建立包含元素 January 到 December 的新 Array 物件 UTCMonthLabels 以及不含任何參數的新 UTCMonth 物件 now。然後會呼叫 getUTCMonth() 方法，以擷取建立 now 時的 UTCMonth。接下來會呼叫 setUTCMonth() (將 month 參數設定為 0)，然後再次呼叫 getUTCMonth()，這樣會擷取新設定的月份。


var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

setUTCSeconds

()

方法

AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

根據全球時間 (UTC) 設定秒數及選擇性地設定毫秒數，並傳回以毫秒為單位的新時間。

參數

	`second:Number` — 從 0 到 59 的整數。

	`millisecond:Number` — 從 0 到 999 的整數。

傳回值

Number — 以毫秒為單位的新時間。

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now，而不含任何參數。然後會呼叫 getUTCSeconds() 方法，以擷取建立 now 時的秒數。接下來會呼叫 setUTCSeconds() (將 second 參數設定為 0)，然後再次呼叫 getUTCSeconds()，以擷取新設定的秒數。


var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

toDateString

()

方法

AS3 function toDateString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

只傳回星期別與日期的字串形式，而不包括時間或時區。可與下列方法相對照：

Date.toTimeString()，只傳回時間與時區
Date.toString()，不但傳回星期別與日期，也傳回時間與時區。

傳回值

String — 只有星期別與日期的字串形式。

相關 API 元素

toString()

範例 ( 如何使用本範例 )

下列範例會建立新的 Date 物件 now (不含任何參數)，然後會在 trace() 陳述式內呼叫下列方法：

toString：顯示在建立 now 時，now 的所有參數。
toDateString()：顯示建立 now 時的 day、month 和 year 參數。


var now:Date = new Date();
trace(now);
trace(now.toDateString());

toJSON

()

方法

AS3 function toJSON(k:String):*

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 11, AIR 3, Flash Lite 4

提供可覆寫的方法，用於自訂 Date 物件中值的 JSON 編碼。

JSON.stringify() 方法會在周遊的每個物件上尋找 toJSON() 方法。如果找到 toJSON() 方法，JSON.stringify() 就會在每次遇到值時呼叫方法，以便傳入與值配對的索引鍵。

Date 提供的 toJSON() 預設實作會傳回 Date.toString() 的輸出。想要以任何其他格式將 Date 物件匯出至 JSON 的用戶端可以提供自己的實作。提供的方式是，重新定義類別原型上的 toJSON() 方法。

toJSON() 方法可以傳回任何類型的值。如果傳回物件，stringify() 就會遞迴至該物件。如果 toJSON() 傳回字串，stringify() 不會遞迴，而是繼續它的周遊。

參數

k:String — JSON.stringify() 在這個物件周遊中所遇到索引鍵值配對的索引鍵

傳回值

* — 物件的 Date.toString() 值。

相關 API 元素

Object
Object.prototype

toLocaleDateString

()

方法

AS3 function toLocaleDateString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

只傳回星期別與日期的字串形式，而不包括時間或時區。此方法會傳回與 Date.toDateString 相同的值。可與下列方法相對照：

Date.toTimeString()，只傳回時間與時區
Date.toString()，不但傳回星期別與日期，也傳回時間與時區。

傳回值

String — 只有星期別與日期的 String 形式。

toLocaleString

()

方法

AS3 function toLocaleString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

傳回本地時間之星期別、日期、時間的字串形式。與 Date.toString() 方法對照下，該方法會傳回在字串結尾列出年份的相同資訊 (加上時區)。

傳回值

String — 本地時區中 Date 物件的字串形式。

toLocaleTimeString

()

方法

AS3 function toLocaleTimeString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

只傳回時間的字串形式，而不包括星期別、日期、年份或時區。與 Date.toTimeString() 方法相較之下，該方法會傳回時間與時區。

傳回值

String — 只有時間與時區的字串形式。

相關 API 元素

toTimeString()

toString

()

方法

AS3 function toString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會傳回星期別、日期、時間及時區的字串形式。輸出的日期格式為：

     Day Mon Date HH:MM:SS TZD YYYY

例如：

     Wed Apr 12 15:30:17 GMT-0700 2006

傳回值

String — Date 物件的字串形式。

範例 ( 如何使用本範例 )

下列範例會建立不含任何參數的新 Date 物件 now，然後在 trace() 陳述式內呼叫 toString，這樣會顯示在建立 now 時 now 的所有參數。



var now:Date = new Date();
trace(now);

toTimeString

()

方法

AS3 function toTimeString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

只傳回時間與時區的字串形式，而不包括星期別與日期。與 Date.toDateString() 方法對照下，該方法只會傳回星期別與日期。

傳回值

String — 只有時間與時區的字串形式。

相關 API 元素

toDateString()

toUTCString

()

方法

AS3 function toUTCString():String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會傳回全球時間 (UTC) 之星期別、日期及時間的字串形式。例如，2005 年二月 1 日的日期會傳回 Tue Feb 1 00:00:00 2005 UTC。

傳回值

String — Date 物件使用 UTC 時間表示的字串形式。

相關 API 元素

toString()

UTC

()

方法

 public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

傳回全球時間 1970 年一月 1 日午夜與參數中指定之時間之間相差的毫秒數。這個方法會使用全球時間，而 Date 建構函式則使用本地時間。

如果您想要將 UTC 日期傳遞到 Date 類別建構函式，這個方法便相當有用。由於 Date 類別建構函式接受毫秒偏移值做為引數，所以您可以使用 Date.UTC() 方法將 UTC 日期轉換成對應的毫秒偏移值，並將該偏移值傳送為 Date 類別建構函式的引數：

參數

	`year:Number` — 代表年份的四位數整數 (例如 2000)。

	`month:Number` — 從 0 (一月) 到 11 (十二月) 的整數。

	`date:Number` (default = `1`) — 從 1 到 31 的整數。

	`hour:Number` (default = `0`) — 從 0 (午夜零點) 到 23 (晚上 11 點) 的整數。

	`minute:Number` (default = `0`) — 從 0 到 59 的整數。

	`second:Number` (default = `0`) — 從 0 到 59 的整數。

	`millisecond:Number` (default = `0`) — 從 0 到 999 的整數。

傳回值

Number — 從 1970 年 1 月 1 日和指定之時間與日期的毫秒數。

範例 ( 如何使用本範例 )

下列範例會使用本地時間建立新的 Date 物件 someBirthday，包含 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute ( 20) 等參數。然後，對 setTime() 方法內 UTC() 的呼叫會將相同的參數重設為全球時間。


var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

valueOf

()

方法

AS3 function valueOf():Number

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會傳回 Date 物件從全球時間 1970 年一月 1 日午夜到當時的毫秒數。

傳回值

Number — Date 物件所代表，從 1970 年一月 1 日到當時的毫秒數。

範例 ( 如何使用本範例 )

下列範例會建立不包含任何參數的新 Date 物件 now，然後會呼叫 getTime() 方法，此方法會擷取建立 now 的時間與 1970 年一月 1 日午夜之間的毫秒數，然後會呼叫 valueOf() (它會擷取相同的數字)。



var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());

範例如何使用本範例

DateExample.as

下列範例會示範使用 Date() 建構函式指定下列變數的各種方式：

myDate1 會呼叫 Date() (不含任何參數)，後者會將 myDate1 設定為目前的日期和時間 (根據系統目前的日期和時間)。
myDate2 會呼叫 Date()，並將 year (2000)、month (0 = January) 和 day (1) 參數傳遞給它。
myDate3 會呼叫 Date()，並將 year (65 = 1965)、month (2 = March)、day (6)、hour (9)、minute (30)、second (15) 和 millisecond -+ (0) 當做參數傳遞。
myDate4 會呼叫 Date()，所用的時間值代表在 GMT 時間 1970 年一月 1 日 0:00:00「之前」的毫秒數 (因為該值是負值)。


package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}

法律聲明 | 線上隱私權政策

Date - AS3

類別 x

date

dateUTC

day

dayUTC

fullYear

fullYearUTC

hours

hoursUTC

milliseconds

millisecondsUTC

minutes

minutesUTC

month

monthUTC

seconds

secondsUTC

time

timezoneOffset

Date

getDate

getDay

getFullYear

getHours

getMilliseconds

getMinutes

getMonth

getSeconds

getTime

getTimezoneOffset

getUTCDate

getUTCDay

getUTCFullYear

getUTCHours

getUTCMilliseconds

getUTCMinutes

getUTCMonth

getUTCSeconds

parse

setDate

setFullYear

setHours

setMilliseconds

setMinutes

setMonth

setSeconds

setTime

setUTCDate

setUTCFullYear

setUTCHours

setUTCMilliseconds

setUTCMinutes

setUTCMonth

setUTCSeconds

toDateString

toJSON

toLocaleDateString

toLocaleString

toLocaleTimeString

toString

toTimeString

toUTCString

UTC

valueOf