FlowElement  - AS3

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_clearStyleExample extends Sprite{    
        public function FlowElement_clearStyleExample()
        {
            // create a container and a TextFlow object
            var container:Sprite = new Sprite();
            this.addChild(container);
            var textFlow:TextFlow = new TextFlow();
            
            // create a paragraph and set lineThrough style to true 
            var paragraph:ParagraphElement = new ParagraphElement();
            paragraph.setStyle("color", 204);
            // create two spans of text
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();            
            span1.text = "After calling clearStyle(), the value of color for span1 is: ";     
            span2.text = " but the value of span1.getStyle() for color is ";
            span3.text = " because getStyle() returns the inherited value that's applied to the style.";
            span1.clearStyle("color");        // undefined
            span1.text += span1.color;
            paragraph.addChild(span1);
            paragraph.addChild(span2);
            span2.text += span1.getStyle("color");    //204 
            paragraph.addChild(span3);
            
            textFlow.addChild(paragraph);
            // add controller, then update controller to display text
            var firstController:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(firstController);
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_deepCopyExample extends Sprite{    
        public function FlowElement_deepCopyExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            // add text to the spans and spans to the paragraph
            span1.text = "Hello, ";
            span2.text = "World!";
            p.fontSize = 48;
            p.addChild(span1);
            p.addChild(span2);
            // make a deep copy of paragraph p, starting at relative offset 3; copy to end
            var p2:ParagraphElement = p.deepCopy(3, -1) as ParagraphElement; 
            // add copied paragraph (p2) to textflow; add composer and controller 
            // and update controller to display text
            textFlow.addChild(p2);
            var controller:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers();    // 'lo, World!'
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getAbsoluteStartExample extends Sprite
    {    
        public function FlowElement_getAbsoluteStartExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            // add text to the spans, spans to the paragraph, and paragraph to the text flow
            span1.text = "The start of span2 ";
            span2.text = "in this paragraph is at index: ";
            p.fontSize = 20;
            p.addChild(span1);
            p.addChild(span2);
            textFlow.addChild(p);
            // find the starting position of span2 and update controller to display text
            span2.text += span2.getAbsoluteStart();  // 19
            var controller:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers();  
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getCharAtPositionExample extends Sprite
    {        
        public function FlowElement_getCharAtPositionExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
                        
            //create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to the two spans, calling getCharAtPosition() to return the
            // character at relative position 27 in the first span
            span1.text = "The character at offset 27 in this paragraph is: ";
            span2.text =  span1.getCharAtPosition(27) + ".";    // i
            
            // add spans to paragraph p   
            p.addChild(span1);
            p.addChild(span2);
            
            // add paragraph p to text flow and update controller to display it
            textFlow.addChild(p);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getCharCodeAtPositionExample extends Sprite
    {        
        public function FlowElement_getCharCodeAtPositionExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
            
            //create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to spans; use getCharCodeAtPosition() to add char code from pos. 16
            // of span1
            
            span1.text = "The character code at offset 16 in this paragraph is: ";
            span2.text =  String(span1.getCharCodeAtPosition(16)) + ".";    // 100 (d)
            
            // add spans to paragraph p   
            p.addChild(span1);
            p.addChild(span2);
            
            // add paragraph p to text flow and update controller to display it
            textFlow.addChild(p);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getElementRelativeStartExample extends Sprite
    {        
        public function FlowElement_getElementRelativeStartExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
            
            //create TextFlow, ParagraphElement, SpanElement, and LinkElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var link:LinkElement = new LinkElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            
            // add text to first two spans
            span1.text = "The relative start of the link SpanElement (";
            span2.text =  ") in this paragraph is at position ";
            
            // create link span, add text and corresponding URL and add to link
            var linkSpan:SpanElement = new SpanElement();
            linkSpan.text = "Adobe's website";
            link.href = "http://www.adobe.com";
            link.addChild(linkSpan);
            
            // add first span, link, and second span to paragraph p   
            p.addChild(span1);
            p.addChild(link);
            p.addChild(span2);
            
            // call getElementRelativeStart() to get start of linkSpan and add to span 3
            span3.text = String(linkSpan.getElementRelativeStart(p)) + ".";  // 44.
            p.addChild(span3);
            
            // add paragraph p to text flow and update controller to display it
            textFlow.addChild(p);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getNextSiblingExample extends Sprite
    {        
        public function FlowElement_getNextSiblingExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var nextSpanElement:SpanElement = new SpanElement();
            // add text, set font size, add spans to paragraph, add paragraph to text flow
            span1.text = "Hello, ";
            span2.text = "World!";
            p.fontSize = 48;
            p.addChild(span1);
            p.addChild(span2);
            textFlow.addChild(p);
            // get next SpanElement for span1 and set its color to red; display text
            nextSpanElement = SpanElement(span1.getNextSibling());
            nextSpanElement.color = 0xCC0000;
            textFlow.flowComposer.addController(new ContainerController(this,stage.stageWidth,stage.stageHeight));
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getParagraphExample extends Sprite
    {        
        public function FlowElement_getParagraphExample()
        {
            // create a container and a controller for it and add to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
                        
            //create TextFlow, ParagraphElement, SpanElement, and LinkElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var link:LinkElement = new LinkElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to first span
            span1.text = "Text that includes a link to ";
            
            // create link span, add text and corresponding URL and add to link
            var linkSpan:SpanElement = new SpanElement();
            linkSpan.text = "Adobe's website";
            link.href = "http://www.adobe.com";
            link.addChild(linkSpan);
            
            // add text to second span and add spans and link to paragraph p
            span2.text = ". Notice that paragraph p2 is identical to paragraph p."; 
            p.addChild(span1);
            p.addChild(link);
            p.addChild(span2);
            
            // call getParagraph() to retrieve paragaph for LinkElement 
            var p2:ParagraphElement = link.getParagraph();
            
            // add paragraph p2 to the text flow and display it
            textFlow.addChild(p2);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getPreviousSiblingExample extends Sprite
    {        
        public function FlowElement_getPreviousSiblingExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var prevSpanElement:SpanElement = new SpanElement();
            // add text, set font size, add spans to paragraph, add paragraph to text flow
            span1.text = "Hello, ";
            span2.text = "World!";
            p.fontSize = 48;
            p.addChild(span1);
            p.addChild(span2);
            textFlow.addChild(p);
            // get previous SpanElement for span2 and set its color to red; display text
            prevSpanElement = SpanElement(span2.getPreviousSibling());
            prevSpanElement.color = 0xCC0000;
            textFlow.flowComposer.addController(new ContainerController(this,400,200));
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getStyleExample extends Sprite
    {        
        public function FlowElement_getStyleExample()
        {
            // create a container and a TextFlow object
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            var textFlow:TextFlow = new TextFlow();
            
            // create a paragraph and set lineThrough style to true 
            var paragraph:ParagraphElement = new ParagraphElement();
            paragraph.setStyle("lineThrough", true);
            // create two spans of text
            var p1Span1:SpanElement = new SpanElement();
            var p1Span2:SpanElement = new SpanElement();            
            p1Span1.text = "It was a dark and stormy night. ";
            p1Span2.text = "The quick red fox jumped over the lazy brown dog.";
            paragraph.addChild(p1Span1);
            paragraph.addChild(p1Span2);
            
            // call getStyle() for 1st span to see if lineThrough is on
            if(p1Span1.getStyle("lineThrough") == true)
                p1Span1.setStyle("lineThrough", false)    // if so, turn it off for this span
            textFlow.addChild(paragraph);
            
            // add composer and controller, then update controller to display text
            var controller:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getTextFlowExample extends Sprite
    {        
        public function FlowElement_getTextFlowExample()
        {
            // create a container and a controller for it and add to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController(container, 400, 200);
            this.stage.addChild( container );
                        
            //create TextFlow, ParagraphElement, SpanElement, and LinkElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var link:LinkElement = new LinkElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to first span
            span1.text = "Text that includes a link to ";
            
            // create link span, add text and corresponding URL and add to link
            var linkSpan:SpanElement = new SpanElement();
            linkSpan.text = "Adobe's website";
            link.href = "http://www.adobe.com";
            link.addChild(linkSpan);
            
            // add text to second span, add spans and link to paragraph p, and
            // add paragraph p to textFlow
            span2.text = ". Notice that textFlow2 is identical to textFlow."; 
            p.addChild(span1);
            p.addChild(link);
            p.addChild(span2);
            textFlow.addChild(p);
            
            // use getTextFlow() with LinkElement to return its TextFlow; update controller
            // and display it
            var textFlow2:TextFlow = link.getTextFlow();     
            textFlow2.flowComposer.addController( controller );                               
            textFlow2.flowComposer.updateAllControllers();
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flash.text.engine.FontPosture;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_setStyleExample extends Sprite
    {        
        public function FlowElement_setStyleExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
            
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to the spans
            span1.text = "Hello, ";
            span2.text = "World!";
            
            // set the color style for span2 and add spans to paragraph p
            span2.setStyle("color", 0xCC0000);
            p.addChild(span1);
            p.addChild(span2);
            
            // add paragraph to text flow, set fontStyle for the text flow to italic,
            // and update controller to display the paragraph
            textFlow.addChild(p);
            textFlow.setStyle("fontStyle", FontPosture.ITALIC);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_shallowCopyExample extends Sprite
    {        
        public function FlowElement_shallowCopyExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            // add text to the spans, spans to the paragraph
            span1.text = "paragraph2 has  ";
            span3.text = " children, so it would display nothing."
            p.fontSize = 20;
            p.addChild(span1);
            p.addChild(span2);
            p.addChild(span3);
            // create paragraph p2 as a shallow copy of paragraph p
            var p2:ParagraphElement = p.shallowCopy(3, -1) as ParagraphElement; 
            // add the number of children that p2 has to span2 for paragraph p
            span2.text += p2.numChildren;    // 0
            // add paragraph p to textFlow and update controller to display it
            textFlow.addChild(p);
            var controller:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers();  
        }
    }
}