FlowGroupElement

包	flashx.textLayout.elements
类	public class FlowGroupElement
继承	FlowGroupElement FlowElement Object
子类	ParagraphFormattedElement, SubParagraphGroupElementBase

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

FlowGroupElement 类是 FlowElement 对象的基类，这些对象可以有一组子对象。这些类包括 TextFlow、ParagraphElement、DivElement 和 LinkElement。

您无法直接创建 FlowGroupElement 对象。调用 new FlowGroupElement() 时会引发一个错误异常。

默认 MXML 属性mxmlChildren

公共属性

隐藏继承的公共属性

显示继承的公共属性

	属性		由以下参数定义
		alignmentBaseline : * TextLayoutFormat：指定主要基线对齐到的基线。	FlowElement
		backgroundAlpha : * TextLayoutFormat：背景的 Alpha（透明度）值（如果在层叠期间未定义，则使用默认值）。	FlowElement
		backgroundColor : * TextLayoutFormat：文本的背景颜色（如果在层叠期间未定义，则使用默认值）。	FlowElement
		baselineShift : * TextLayoutFormat：从 dominantBaseline 值偏移基线的数量。	FlowElement
		blockProgression : * TextLayoutFormat：指定线位置的垂直或水平行进。	FlowElement
		breakOpportunity : * TextLayoutFormat：控制在将连续文本断开为多行时允许行断开的位置。	FlowElement
		cffHinting : * TextLayoutFormat：用于此文本的 CFF 提示的类型。	FlowElement
		clearFloats : * TextLayoutFormat：控制文本在浮点周围的环绕方式。	FlowElement
		color : * TextLayoutFormat：文本的颜色。	FlowElement
		columnCount : * TextLayoutFormat：文本列数（如果在层叠期间未定义，则使用默认值）。	FlowElement
		columnGap : * TextLayoutFormat：指定要在列之间留出的装订线空间量（以像素为单位），如果在层叠期间未定义，则使用默认值。	FlowElement
		columnWidth : * TextLayoutFormat：列宽（以像素为单位）（如果在层叠期间未定义，则使用默认值）。	FlowElement
		computedFormat : flashx.textLayout.formats:ITextLayoutFormat [只读] 返回对于该元素有效的计算得出的格式属性。	FlowElement
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		coreStyles : Object [只读] 返回此 FlowElement 的 coreStyles。	FlowElement
		digitCase : * TextLayoutFormat：用于此文本的数字大小写类型。	FlowElement
		digitWidth : * TextLayoutFormat：用于此文本的数字宽度类型。	FlowElement
		direction : * TextLayoutFormat：指定文本在文本块中的默认双向嵌入级别。	FlowElement
		dominantBaseline : * TextLayoutFormat：指定该元素的哪条基线紧贴到 alignmentBaseline 以确定元素在该行上的垂直位置。	FlowElement
		firstBaselineOffset : * TextLayoutFormat：指定容器中第一行的基线位置。	FlowElement
		fontFamily : * TextLayoutFormat：要使用的字体的名称或用逗号分隔的字体名称列表。	FlowElement
		fontLookup : * TextLayoutFormat：要使用的字体查找。	FlowElement
		fontSize : * TextLayoutFormat：文本的大小（以像素为单位）。	FlowElement
		fontStyle : * TextLayoutFormat：文本的样式。	FlowElement
		fontWeight : * TextLayoutFormat：文本的粗细。	FlowElement
		format : flashx.textLayout.formats:ITextLayoutFormat TextLayoutFormat 属性直接应用于该元素。	FlowElement
		id : String 将一个标识名称指定给该元素，以允许通过引用 id 为该元素设置样式。	FlowElement
		justificationRule : * TextLayoutFormat：用于将段落中的文本两端对齐的规则。	FlowElement
		justificationStyle : * TextLayoutFormat：用于将段落两端对齐的样式。	FlowElement
		kerning : * TextLayoutFormat：字距调整可调整某些字符对之间的像素以提高可读性。	FlowElement
		leadingModel : * TextLayoutFormat：指定行距模型，它是行距基准和行距方向的组合。	FlowElement
		ligatureLevel : * TextLayoutFormat：控制可以在该文本中使用字体中定义的哪些连字。	FlowElement
		lineBreak : * TextLayoutFormat：控制容器内的换行（如果在层叠期间未定义，则使用默认值）。	FlowElement
		lineHeight : * TextLayoutFormat：文本的行距控制。	FlowElement
		lineThrough : * TextLayoutFormat：若为 true，则应用删除线（一条穿过文本中间的直线）。	FlowElement
		linkActiveFormat : * TextLayoutFormat：定义用于处于正常状态的链接的格式属性。	FlowElement
		linkHoverFormat : * TextLayoutFormat：定义当鼠标在链接边界内（悬停）时用于悬停状态链接的格式属性。	FlowElement
		linkNormalFormat : * TextLayoutFormat：定义用于处于正常状态的链接的格式属性。	FlowElement
		listAutoPadding : * TextLayoutFormat：指定当列表相应侧的内边距值为 auto 时，列表开始边缘的自动缩进。	FlowElement
		listMarkerFormat : * TextLayoutFormat：定义列表标记的格式属性。	FlowElement
		listStylePosition : * TextLayoutFormat：合法值为 ListStylePosition.INSIDE、ListStylePosition.OUTSIDE、FormatValue.INHERIT。默认值未定义，指示未设置。如果在层叠期间未定义，则此属性将从一个祖代继承值。	FlowElement
		listStyleType : * TextLayoutFormat：合法值为 ListStyleType.UPPER_ALPHA、ListStyleType.LOWER_ALPHA、ListStyleType.UPPER_ROMAN、ListStyleType.LOWER_ROMAN、ListStyleType.NONE、ListStyleType.DISC、ListStyleType.CIRCLE、ListStyleType.SQUARE、ListStyleType.BOX、ListStyleType.CHECK、ListStyleType.DIAMOND、ListStyleType.HYPHEN、ListStyleType.ARABIC_INDIC、ListStyleType.BENGALI、ListStyleType.DECIMAL、ListStyleType.DECIMAL_LEADING_ZERO、ListStyleType.DEVANAGARI、ListStyleType.GUJARATI、ListStyleType.GURMUKHI、ListStyleType.KANNADA、ListStyleType.PERSIAN、ListStyleType.THAI、ListStyleType.URDU、ListStyleType.CJK_EARTHLY_BRANCH、ListStyleType.CJK_HEAVENLY_STEM、ListStyleType.HANGUL、ListStyleType.HANGUL_CONSTANT、ListStyleType.HIRAGANA、ListStyleType.HIRAGANA_IROHA、ListStyleType.KATAKANA、ListStyleType.KATAKANA_IROHA、ListStyleType.LOWER_ALPHA、ListStyleType.LOWER_GREEK、ListStyleType.LOWER_LATIN、ListStyleType.UPPER_ALPHA、ListStyleType.UPPER_GREEK、ListStyleType.UPPER_LATIN、FormatValue.INHERIT。默认值未定义，指示未设置。如果在层叠期间未定义，则此属性将从一个祖代继承值。	FlowElement
		locale : * TextLayoutFormat：文本的区域设置。	FlowElement
		mxmlChildren : Array 为该对象追加一个子对象数组。	FlowGroupElement
		numChildren : int [只读] 返回该 FlowGroupElement 对象具有的 FlowElement 子对象的数目。	FlowGroupElement
		paddingBottom : * TextLayoutFormat：底部边界区（像素数）。	FlowElement
		paddingLeft : * TextLayoutFormat：左侧边界区（像素数）。	FlowElement
		paddingRight : * TextLayoutFormat：右侧边界区（像素数）。	FlowElement
		paddingTop : * TextLayoutFormat：顶部边界区（像素数）。	FlowElement
		paragraphEndIndent : * TextLayoutFormat：一个数字，指定段落结束边缘的缩进量（像素数）。	FlowElement
		paragraphSpaceAfter : * TextLayoutFormat：一个数字，指定在段落后留出的空白（像素数）。	FlowElement
		paragraphSpaceBefore : * TextLayoutFormat：一个数字，指定在段落前留出的空白（像素数）。	FlowElement
		paragraphStartIndent : * TextLayoutFormat：一个数字，指定段落开始边缘的缩进量（像素数）。	FlowElement
		parent : FlowGroupElement [只读] 返回该 FlowElement 对象的父项。	FlowElement
		parentRelativeEnd : int [只读] 返回该 FlowElement 对象在父项中的相对结束位置。	FlowElement
		parentRelativeStart : int [只读] 返回该 FlowElement 对象在父项中的相对起始位置。	FlowElement
		renderingMode : * TextLayoutFormat：用于此文本的呈现模式。	FlowElement
		styleName : * TextLayoutFormat：为元素指定一个标识类，从而可以通过引用 styleName 来设置元素样式。	FlowElement
		styles : Object [只读] 返回此 FlowElement 的样式。	FlowElement
		tabStops : * TextLayoutFormat：指定与段落关联的制表位。	FlowElement
		textAlign : * TextLayoutFormat：段落中的行与容器的对齐方式。	FlowElement
		textAlignLast : * TextLayoutFormat：两端对齐文本中段落最后一行（或唯一的一行）与容器的对齐方式。	FlowElement
		textAlpha : * TextLayoutFormat：文本的 Alpha（透明度）值。	FlowElement
		textDecoration : * TextLayoutFormat：文本上的装饰。	FlowElement
		textIndent : * TextLayoutFormat：一个数字，指定段落第一行的缩进量（以像素为单位）。	FlowElement
		textJustify : * TextLayoutFormat：指定文本两端对齐的选项。	FlowElement
		textLength : int [只读] 返回该 FlowElement 对象及其子对象拥有的文本总长度。	FlowElement
		textRotation : * TextLayoutFormat：确定要旋转此文本的度数。	FlowElement
		tracking : Object [只写] 设置间隙，且与 trackingRight 属性同义。	FlowElement
		trackingLeft : * TextLayoutFormat：像素数（或字体大小的百分比，如 120%），指示应用于每个字符左侧的间隙数（手动字距调整）。	FlowElement
		trackingRight : * TextLayoutFormat：像素数（或字体大小的百分比，如 120%）表示要应用到每个字符右边的间距的量（手动字距调整）。	FlowElement
		typeName : String 每个 FlowElement 都具有 typeName。	FlowElement
		typographicCase : * TextLayoutFormat：用于此文本的印刷大小写的类型。	FlowElement
		userStyles : Object 允许您针对 FlowElement 对象读写用户样式。	FlowElement
		verticalAlign : * TextLayoutFormat：垂直对齐或两端对齐（如果在层叠期间未定义，则使用默认值）。	FlowElement
		whiteSpaceCollapse : * TextLayoutFormat：将文本导入到 TextFlow 中时压缩或保留空白。	FlowElement
		wordSpacing : * TextLayoutFormat：指定在两端对齐期间使用的单词之间的最佳间距、最小间距和最大间距（作为普通间距宽度的乘数）。	FlowElement

公共方法

隐藏继承的公共方法

显示继承的公共方法

	方法		由以下参数定义
		FlowGroupElement() 基类 - 调用 new FlowGroupElement() 时会引发错误异常。	FlowGroupElement
		addChild(child:FlowElement):FlowElement 追加一个 FlowElement 子对象。	FlowGroupElement
		addChildAt(index:uint, child:FlowElement):FlowElement 在指定索引位置添加一个 FlowElement 子对象。	FlowGroupElement
		clearStyle(styleProp:String):void 从该 FlowElement 对象清除 styleProp 参数指定的样式。	FlowElement
		deepCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement 生成此 FlowElement 对象的深层副本，包括任何子对象，在两个指定的字符位置之间复制内容，并将该副本作为 FlowElement 对象返回。	FlowElement
		equalUserStyles(otherElement:FlowElement):Boolean 将此元素的 userStyles 与其它元素的 userStyles 比较。	FlowElement
		findChildIndexAtPosition(relativePosition:int):int 对于给定的相对文本位置，查找包含该相对位置的第一个 FlowElement 子对象的索引。	FlowGroupElement
		findLeaf(relativePosition:int):FlowLeafElement 对于给定的相对文本位置，查找包含该位置的叶元素。	FlowGroupElement
		getAbsoluteStart():int 返回该元素在文本流中的起始位置（绝对索引）。	FlowElement
		getCharAtPosition(relativePosition:int):String 返回相对于该 FlowElement 对象的指定位置的字符。	FlowElement
		getCharCodeAtPosition(relativePosition:int):int 返回相对于该 FlowElement 对象的指定位置的字符代码。	FlowElement
		getChildAt(index:int):FlowElement 返回位于指定索引的 FlowElement 子对象。	FlowGroupElement
		getChildIndex(child:FlowElement):int 在子对象中搜索指定的 FlowElement 对象，并返回其索引位置。	FlowGroupElement
		getElementRelativeStart(ancestorElement:FlowElement):int 返回该元素相对于祖代元素的起始位置。	FlowElement
		getFirstLeaf():FlowLeafElement 返回该组的第一个 FlowLeafElement 子项。	FlowGroupElement
		getLastLeaf():FlowLeafElement 返回该组的最后一个 FlowLeafElement 子项。	FlowGroupElement
		getNextSibling():FlowElement 返回文本流层次结构中的下一个 FlowElement 同级对象。	FlowElement
		getParagraph():ParagraphElement 返回与该元素关联的 ParagraphElement 对象。	FlowElement
		getPreviousSibling():FlowElement 返回文本流层次结构中的上一个 FlowElement 同级对象。	FlowElement
		getStyle(styleProp:String):* 返回由 styleProp 参数指定的样式值，该参数指定样式名称，可以包括任何用户样式名称。	FlowElement
		getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String [覆盖]	FlowGroupElement
		getTextFlow():flashx.textLayout.elements:TextFlow 沿文本流层次结构向上移动，返回该元素的 TextFlow 根对象。	FlowElement
		hasOwnProperty(name:String):Boolean 表示对象是否已经定义了指定的属性。	Object
		initialized(document:Object, id:String):void 创建实现对象且初始化在 MXML 标签上指定的所有组件属性后针对 MXML 对象进行调用。	FlowElement
		isPrototypeOf(theClass:Object):Boolean 表示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		propertyIsEnumerable(name:String):Boolean 表示指定的属性是否存在、是否可枚举。	Object
		removeChild(child:FlowElement):FlowElement 从组中删除指定的 FlowElement 子对象。	FlowGroupElement
		removeChildAt(index:uint):FlowElement 删除位于指定索引位置的 FlowElement 子对象。	FlowGroupElement
		replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void 以指定的新元素替换组中的子元素。	FlowGroupElement
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		setStyle(styleProp:String, newValue:*):void 将 styleProp 参数指定的样式设置为 newValue 参数指定的值。	FlowElement
		shallowCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement 生成此 FlowElement 对象的副本，复制两个指定的字符位置之间的内容。	FlowElement
		splitAtIndex(childIndex:int):FlowGroupElement 在 childIndex 参数指定的位置拆分该对象。	FlowGroupElement
		splitAtPosition(relativePosition:int):FlowElement 在由 relativePosition 参数指定的位置处拆分此 FlowElement 对象，该位置是此元素的文本中的相对位置。	FlowElement
		toLocaleString():String 返回此对象的字符串表示形式，其格式设置遵守区域设置特定的约定。	Object
		toString():String 返回指定对象的字符串表示形式。	Object
		valueOf():Object 返回指定对象的原始值。	Object

属性详细信息

mxmlChildren

属性

mxmlChildren:Array

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

为该对象追加一个子对象数组。使用 replaceChildren() 方法在数组中追加每个元素。在 mxml 编译导入时使用。

实现
public function get mxmlChildren():Array
public function set mxmlChildren(value:Array):void

引发

TypeError — 如果数组元素不是 FlowElement 或 String

numChildren

属性

numChildren:int [只读]

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

返回该 FlowGroupElement 对象具有的 FlowElement 子对象的数目。

实现
public function get numChildren():int

构造函数详细信息

()

构造函数

public function FlowGroupElement()

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

基类 - 调用 new FlowGroupElement() 时会引发错误异常。

方法详细信息

addChild

()

方法

public function addChild(child:FlowElement):FlowElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

追加一个 FlowElement 子对象。新的子对象将添加到子对象列表末尾。

参数

child:FlowElement — 要追加的子元素。

FlowElement — 添加的 FlowElement 子对象

示例 ( 如何使用本示例 )

该示例调用 addChild() 为段落添加一个跨距并将段落添加到文本流。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildExample extends Sprite
    {        
        public function FlowGroupElement_addChildExample()
        {
            // create string for text flow
            var simpleText:String = "It was a dark and stormy night.";        
                    
            // define TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span:SpanElement = new SpanElement;
            span.text = simpleText;
            // add span to paragraph and add paragraph to text flow
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

addChildAt

()

方法

public function addChildAt(index:uint, child:FlowElement):FlowElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

在指定索引位置添加一个 FlowElement 子对象。

参数

	`index:uint` — 要添加子元素的位置的索引，第一个位置为 0。

	`child:FlowElement` — 要添加的子元素。

FlowElement — 添加的 FlowElement 子对象

引发

RangeError — index 超出了范围。

示例 ( 如何使用本示例 )

该示例调用 addChildAt 为段落添加三个跨距。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildAtExample extends Sprite
    {        
        public function FlowGroupElement_addChildAtExample()
        {
            // define text strings for the contents of the text flow
            var textA:String = "It was a dark and stormy night. ";
            var textB:String = "The quick red fox jumped over the lazy brown dog. ";
            var textC:String = "Mary had a little lamb. ";
            // define TextFlow, ParagraphElement and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            span1.text = textA;
            span2.text = textB;
            span3.text = textC;
            // add spans at specified positions
            paragraph.addChildAt(0, span2);
            paragraph.addChildAt(0, span1);
            paragraph.addChildAt(1, span3);
            textFlow.addChild(paragraph);
            // assign composer, controller, and update to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findChildIndexAtPosition

()

方法

public function findChildIndexAtPosition(relativePosition:int):int

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

对于给定的相对文本位置，查找包含该相对位置的第一个 FlowElement 子对象的索引。由于存在零长度 FlowElement，多个子对象可以包含相对位置。

检查子对象，查找包含相对位置的 FlowElement。提供的相对位置相对于该 FlowElement。

参数

relativePosition:int — 相对于该元素的位置

int — 包含 relativePosition 的第一个子元素的索引

示例 ( 如何使用本示例 )

该示例查找文本中相对位置处的子对象的索引，并将其颜色设置为红色。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findChildIndexAtPositionExample extends Sprite
    {        
        public function FlowGroupElement_findChildIndexAtPositionExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the index of the child containing relative offset 21; set color to red
            var index:int = textFlow.findChildIndexAtPosition(21);
            textFlow.getChildAt(index).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findLeaf

()

方法

public function findLeaf(relativePosition:int):FlowLeafElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

对于给定的相对文本位置，查找包含该位置的叶元素。

在流元素层次结构中向下查找，以找到包含指定位置的 FlowLeafElement。指定的位置相对于该 FlowElement 对象。

参数

relativePosition:int — 要查找的相对文本索引。

FlowLeafElement — 包含相对位置的叶元素。

示例 ( 如何使用本示例 )

该示例创建两个段落，查找相对位置 55 处的 FlowLeafElement，并将其颜色设置为红色。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findLeafExample extends Sprite
    {        
        public function FlowGroupElement_findLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the FlowLeafElement object containing relative offset 55; set color to red
            var leaf:SpanElement = textFlow.findLeaf(55) as SpanElement;
            leaf.color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildAt

()

方法

public function getChildAt(index:int):FlowElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

返回位于指定索引的 FlowElement 子对象。

参数

index:int — 查找 FlowElement 对象的位置。

FlowElement — 位于指定位置的 FlowElement 子对象。

示例 ( 如何使用本示例 )

该示例使用 getChildAt() 方法访问文本流中的段落，并将一个跨距的颜色更改为红色。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getChildAtExample extends Sprite
    {        
        public function FlowGroupElement_getChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the paragraph at index position 1
            var para:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
            // find the span at index position 1 of the paragraph and color it red
            para.getChildAt(1).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildIndex

()

方法

public function getChildIndex(child:FlowElement):int

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

在子对象中搜索指定的 FlowElement 对象，并返回其索引位置。

参数

child:FlowElement — 要在子对象中查找的 FlowElement 对象项。

int — 指定的子对象的索引位置。如果未找到 child，则返回 -1。

getFirstLeaf

()

方法

public function getFirstLeaf():FlowLeafElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

返回该组的第一个 FlowLeafElement 子项。

FlowLeafElement — 第一个 FlowLeafElement 对象。

示例 ( 如何使用本示例 )

此例创建了两个段落，找到了第一个 FlowLeafElement 对象，并将其颜色设置为红色。

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getFirstLeafExample extends Sprite
    {        
        public function FlowGroupElement_getFirstLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a </flow:span>"+
                        "<flow:span fontStyle=\"italic\">dark and stormy</flow:span>"+
                        "<flow:span> night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // get first FlowLeafElement object and set its color to red
            var leaf:SpanElement = textFlow.getFirstLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            // add composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getLastLeaf

()

方法

public function getLastLeaf():FlowLeafElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

返回该组的最后一个 FlowLeafElement 子项。

FlowLeafElement — 最后一个 FlowLeafElement 对象。

示例 ( 如何使用本示例 )

此例创建了两个段落，找到了最后一个 FlowLeafElement 对象，并将其颜色设置为红色。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getLastLeafExample extends Sprite
    {        
        public function FlowGroupElement_getLastLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            //find last leaf, set its color to red and display text
            var leaf:SpanElement = textFlow.getLastLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getText

()

方法

override public function getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String

参数

	`relativeStart:int` (default = `0`)

	`relativeEnd:int` (default = `-1`)

	`paragraphSeparator:String` (default = " ")

String

removeChild

()

方法

public function removeChild(child:FlowElement):FlowElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

从组中删除指定的 FlowElement 子对象。

参数

child:FlowElement — 要删除的子元素。

FlowElement — 删除的 FlowElement 子对象

引发

ArgumentError — 未找到 child。

示例 ( 如何使用本示例 )

该示例删除位于文本流第二段中的第三个跨距。

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildExample extends Sprite
    {        
        public function FlowGroupElement_removeChildExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            // get paragraph with ID = 'para2' and remove its child with name = 'span4'
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.removeChild(textFlow.getElementByID("span4"));
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

removeChildAt

()

方法

public function removeChildAt(index:uint):FlowElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

删除位于指定索引位置的 FlowElement 子对象。

参数

index:uint — 要删除子元素的位置。

FlowElement — 从指定位置删除的 FlowElement 子对象。

引发

RangeError — index 超出了范围。

示例 ( 如何使用本示例 )

该示例调用 removeChildAt() 来删除三个段落中的第二个子对象。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildAtExample extends Sprite
    {        
        public function FlowGroupElement_removeChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Mary had a little lamb. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow, import text, add composer and controller 
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // remove child at index position 1 (with first position = 0); display text
            textFlow.removeChildAt(1);
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

replaceChildren

()

方法

public function replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

以指定的新元素替换组中的子元素。使用 beginChildIndex 和 endChildIndex 参数可以控制操作，如下所述：

要删除元素，请勿传递任何替换元素。
要插入元素，请为 beginChildIndex 和 endChildIndex 传递相同的值。新元素将会插入到指定索引之前。
要追加元素，请为 beginChildIndex 和 endChildIndex 传递 numChildren。

否则，该方法将替换指定元素，从 beginChildIndex 的元素开始直到 endChildIndex（不含）为止。

参数

	`beginChildIndex:int` — 子项数组中替换范围的起始位置的索引值。

	`endChildIndex:int` — 子项数组中替换范围的结束位置之后的索引值。

	`... rest` — 要替换指定范围元素的元素。可以是一个包含流元素或其数组或矢量的序列。

引发

RangeError — 指定的 beginChildIndex 或 endChildIndex 超出了范围。

示例 ( 如何使用本示例 )

该示例将用两个新跨距来替换第二段中的三个跨距。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_replaceChildrenExample extends Sprite
    {        
        public function FlowGroupElement_replaceChildrenExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
            
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // define two new SpanElement objects
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            span1.text = "Mary had a little lamb. ";
            span2.text = "And this little pig stayed home. ";
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,600));
            // get paragraph with ID = 'para2' and replace its children with span1 and span2
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.replaceChildren(0, 3, [span1, span2]);
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

splitAtIndex

()

方法

public function splitAtIndex(childIndex:int):FlowGroupElement

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5

在 childIndex 参数指定的位置拆分该对象。如果该组元素有父项，则创建该对象的一个浅副本，并使用该索引之前的元素替换其子元素。将 childIndex 之后的元素移至副本中。

参数

childIndex:int

FlowGroupElement — 新 FlowGroupElement 对象。

引发

RangeError — 如果 childIndex 大于子项的长度。

法律声明 | 在线隐私策略

FlowGroupElement - AS3

包x

语言元素

附录

包 flashx.textLayout.elements

mxmlChildren

numChildren