SoundMixer  - AS3

Anger ljuduppspelningsläge för alla Sound-objekt. På mobila enheter med dessa egenskaper ställs ljudegenskaparna och standarder in enligt plattformsidiomen. I datorer och TV-miljöer finns det inga funktionella skillnader mellan ljuduppspelningslägena.

Giltiga värden för den här egenskapen definieras i klassen AudioPlaybackMode.

Obs! Om ett program ställer in audioPlaybackMode=AudioPlaybackMode.VOICE i iOS kan andra program inte ändra det till AudioPlaybackMode.MEDIA.

Använd läget AudioPlaybackMode.VOICE så lite som möjligt och försök att växla till AudioPlaybackMode.MEDIA så fort du kan efter ett röstsamtal, så att andra program kan använda medieläget.

När du ändrar läge för ljuduppspelning i iOS kommer ursprungliga appar som spelar musik att pausas tillfälligt.

Standardvärdet är AudioPlaybackMode.MEDIA.

Relaterade API-element

Hur många sekunder ett inbäddat direktuppspelat ljud ska förhandsinläsas till en buffert innan direktuppspelningen startar. Det går inte att få åtkomst till data i ett inläst ljud, inklusive bufferttiden, med en SWF-fil i en annan domän om du inte implementerar en korsdomänprincipfil. Mer information om säkerhet och ljud finns i beskrivningen av klassen Sound. Kod i en fil som finns i en annan domän kan inte komma åt data i ett inläst ljud, inklusive bufferttiden, om du inte implementerar en korsdomänprincipfil. I säkerhetssandlådan i ett AIR-program kan kod däremot få åtkomst till data i ljudfiler från alla källor. Mer information om säkerhet och ljud finns i beskrivningen av Sound-klassen.

Egenskapen SoundMixer.bufferTime påverkar bufferttiden för inbäddade direktuppspelade ljud i en SWF-fil och är beroende av dynamiskt skapade Sound-objekt (Sound-objekt som skapats i ActionScript). Värdet för SoundMixer.bufferTime kan inte överskrida eller ställa in standardvärdet för bufferttiden som anges i SoundLoaderContext-objektet som skickas till Sound.load()-metoden.

Relaterade API-element

Det SoundTransform-objekt som styr globala ljudegenskaper. Ett SoundTransform-objekt innehåller egenskaper för inställning av volym, panorering och vänstra och högra högtalaren. Objektet SoundTransform som används i den här egenskapen tillhandahåller slutliga ljudinställningar som används på alla ljud efter att eventuella enskilda ljudinställningar tillämpas.

Relaterade API-element

Växlar högtalartelefonen när enheten är försatt i röstläge. I vanliga smarta telefoner kommer hörluren att användas för ljudutdata när inställningen för SoundMixer.audioPlaybackMode är AudioPlaybackMode.VOICE. Egenskapen useSpeakerphoneForVoice används för att åsidosätta standardutdata så att du kan implementera en högtalartelefonsknapp i ett telefonprogram. Den här egenskapen har ingen effekt i andra lägen än AudioPlaybackMode.VOICE. I stationära datorer och TV-miljöer har egenskapen ingen effekt.

Obs! Om ditt program har ställt in audioPlaybackMode=VOICE i iOS och ett annat program också spelar upp i röstläge kan du inte ställa in useSpeakerphoneForVoice=true.

Obs! På Android måste du ange android.permission.MODIFY_AUDIO_SETTINGS i AIR-programbeskrivningsfilen, annars har en ändring av det här värdet ingen effekt. Dessutom är den här inställningen en global enhetsinställning. Andra program som körs på enheten kan ändra den underliggande enhetsinställningen när som helst.

Standardvärdet är false.

Relaterade API-element

Avgör om det finns ljud som inte är tillgängliga på grund av säkerhetsbegränsningar. Exempelvis går det inte att komma åt ett ljud som har lästs in från en annan domän än domänen för innehållet som anropar metoden, om inte servern för ljudet har en URL-principfil som beviljar åtkomst till domänen för innehållet. Ljudet kan fortfarande läsas in och spelas upp, men åtgärder på låg nivå, som t.ex. inhämtning av ID3-metadata för ljudet, kan inte utföras på otillgängliga ljud.

Om AIR-programinnehåll i programmets säkerhetssandlåda anropar den här metoden returneras alltid false. Alla ljud, inklusive de som har lästs in från andra domäner, kan kommas åt av innehåll i programmets säkerhetssandlåda.

Relaterade API-element

Tar en ögonblicksbild av den aktuella ljudvågen och placerar den i det angivna ByteArray-objektet. Värdena formateras som normaliserade flyttalsvärden inom intervallet -1,0 till 1,0. ByteArray-objektet som skickades till outputArray-parametern skrivs över med de nya värdena. Storleken på ByteArray-objektet som skapats är fast på 512 flyttalsvärden, där de första 256 värdena representerar den vänstra kanalen, och de andra 256 värdena representerar den högra kanalen.

Obs! Den här metoden är föremål för lokala filsäkerhetsbegränsningar och begränsningar för korsdomäninläsning. Om du arbetar med lokala filer eller ljud som har lästs in från en server i en annan domän än det anropande innehållet, måste du kanske hantera sandlådebegränsningar med hjälp av en korsdomänprincipfil. Mer information finns i beskrivningen av Sound-klassen. Den här metoden kan dessutom inte användas för att extrahera data från RTMP-flöden, även om den anropas av innehåll som finns i samma domän som RTMP-servern.

Metoden stöds över RTMP i Flash Player 9.0.115.0 och senare i Adobe AIR. Du kan styra åtkomst till flöden på Flash Media Server i ett skript på servern. Mer information finns under egenskaperna Client.audioSampleAccess och Client.videoSampleAccess i Språkreferens för Serverside ActionScript för Adobe Flash Media Server.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Slutar spela upp alla ljud.

>I Flash Professional stoppar den här metoden inte spelhuvudet. Ljud som är inställda på att direktuppspelas börjar spelas upp igen när spelhuvudet rör sig över bildrutorna de finns i.

Överväg följande säkerhetsmodell när du använder den här egenskapen:

• Om metoden SoundMixer.stopAll() anropas stoppas som standard bara ljud i samma säkerhetssandlåda som objektet som anropar metoden. Alla ljud vars uppspelning inte startades från samma sandlåda som det anropande objektet stoppas inte.
• Om du läser in ljudet med metoden load() i Sound-klassen kan du ange en context-parameter som är ett SoundLoaderContext-objekt. Om du anger egenskapen checkPolicyFile för SoundLoaderContext-objektet till true söker Flash Player eller Adobe AIR efter en korsdomänprincipfil på den server som ljudet läses in från. Om det finns en korsdomänprincipfil och filen godkänner domänen för det anropande innehållet kan filen stoppa det inlästa ljudet med metoden SoundMixer.stopAll(), annars kan den inte göra det.

I Adobe AIR begränsas emellertid inte innehåll i säkerhetssandlådan application (innehåll som installeras med AIR-programmet) av de här säkerhetsbegränsningarna.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}