MovieClip  - AS3

Определяет номер кадра, в котором точка воспроизведения находится на временной шкале экземпляра MovieClip. Если фрагмент ролика содержит несколько монтажных кадров, это значение является номером кадра в текущем монтажном кадре.

mc1.gotoAndStop(mc1.currentFrame + 5);

Подпись текущего кадра на временной шкале экземпляра MovieClip. Если текущий кадр не имеет подписи, значение свойства currentLabel равно null.

Текущая подпись, в которой точка воспроизведения расположена на временной шкале экземпляра MovieClip. Если у текущего кадра нет подписи, для currentLabel используется имя предыдущего кадра с подписью. Если текущий и предыдущий кадры не имеют подписи, currentLabel возвращает значение null.

trace(mc1.currentLabel);

Возвращает массив объектов FrameLabel для текущего монтажного кадра. Если экземпляр MovieClip не использует монтажных кадров, массив включает все метки кадров из всего экземпляра MovieClip.

Связанные элементы API

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

Текущий монтажный кадр, в котором точка воспроизведения расположена на временной шкале экземпляра MovieClip.

Связанные элементы API

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Логическое значение, определяющее включение фрагмента ролика. По умолчанию свойство enabled имеет значение true. Если для enabled задано значение false, отключаются карды фрагмента ролика с подписями Over, Down и Up. Фрагмент ролика продолжает получать события (например, mouseDown, mouseUp, keyDown и keyUp).

Свойство enabled управляет только кнопочными свойствами фрагмента ролика. Свойство enabled можно изменить в любое время; обновленный фрагмент ролика немедленно включается или выключается. Если enabled имеет значение false, объект не включается в автоматическую последовательность перехода с помощью клавиши Tab.

mc1.enabled = false;

Число кадров, загружаемых из потокового SWF-файла. Можно использовать свойство framesLoaded, чтобы определить, будет ли содержимое конкретного кадра и всех предшествующих загружаться и открываться локально в обозревателе. Также его можно использовать для отслеживания загрузки больших SWF-файлов. Например, можно показывать пользователям сообщение о том, что SWF-файл загружается, до того момента, пока не закончит загружаться заданный кадр файла.

Если фрагмент ролика содержит несколько монтажных кадров, свойство framesLoaded возвращает количество кадров, загруженных для всех монтажных кадров фрагмента ролика.

Связанные элементы API

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Логическое значение, определяющее воспроизведение в настоящий момент фрагмента ролика.

Массив объектов Scene, каждый из которых содержит имя, число кадров и подписи кадров для одного из монтажных кадров в экземпляре MovieClip.

Связанные элементы API

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

Общее число кадров в экземпляре MovieClip.

Если фрагмент ролика содержит несколько кадров, свойство totalFrames возвращает общее количество кадров во всех монтажных кадрах фрагмента ролика.

 trace(mc1.totalFrames);

Указывает, могут ли другие экранные объекты, представленные экземплярами SimpleButton или MovieClip, получать события отпускания мыши или другие события отпускания пользовательского ввода. Свойство trackAsMenu позволяет создавать меню. Свойство trackAsMenu можно задать для любого объекта SimpleButton или MovieClip. По умолчанию свойство trackAsMenu имеет значение false.

Свойство trackAsMenu можно изменить в любой момент; модифицированный фрагмент ролика немедленно начинает использовать новое поведение.

 mc1.trackAsMenu = true;

Создает новый экземпляр MovieClip. Создав MovieClip, вызовите метод addChild() или addChildAt() контейнера экранных объектов, находящегося в рабочей области.

Запускает воспроизведение SWF-файла с заданного кадра. Это происходит после того, как завершается выполнения всех оставшихся действий. Чтобы указать монтажный кадр и кадр, задайте значение для параметра scene.

Параметры

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Переводит точку воспроизведения в заданный кадр фрагмента ролика и останавливает ее в этом кадре. Это происходит после того, как завершается выполнения всех оставшихся действий. Если требуется указать монтажный кадр вместе с кадром, задайте параметр scene.

Параметры

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Переводит точку воспроизведения в следующий кадр и останавливает ее. Это происходит после того, как завершается выполнения всех оставшихся действий.

Связанные элементы API

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Перемещает точку воспроизведения в следующий монтажный кадр экземпляра MovieClip. Это происходит после того, как завершается выполнения всех оставшихся действий.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Перемещает точку воспроизведения по временной шкале фрагмента ролика.

Связанные элементы API

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Переводит точку воспроизведения в предыдущий кадр и останавливает ее. Это происходит после того, как завершается выполнения всех оставшихся действий.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Перемещает точку воспроизведения в предыдущий монтажный кадр экземпляра MovieClip. Это происходит после того, как завершается выполнения всех оставшихся действий.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Останавливает точку воспроизведения во фрагменте ролика.

1. Функция конструктора определяет текстовое поле, используемое для отображения значений свойств объекта MovieClipExample (расширяющего MovieClip).
2. Возвращаемое значение метода getPropertiesString() используется в качестве текстового поля outputText. Метод getPropertiesString() возвращает строку, заполненную значениями следующих свойств фрагмента ролика: currentFrame, currentLabel, currentScene, framesLoaded, totalFrames и trackAsMenu.
3. Две строки кода в функции конструктора настраивают свойства width и height текстового поля outputText.
4. Последняя строка функции конструктора добавляет текстовое поле outputText в список отображения.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}